[PATCH v2 8/8] newlib: libc: aeabi_memset M-profile PACBTI-enablement
Victor Do Nascimento
victor.donascimento@arm.com
Wed Aug 3 15:35:24 GMT 2022
Add function prologue/epilogue to conditionally add BTI landing pads
and/or PAC code generation & authentication instructions depending on
compilation flags.
---
newlib/libc/machine/arm/aeabi_memset-thumb2.S | 47 ++++++++++++++++++-
1 file changed, 46 insertions(+), 1 deletion(-)
diff --git a/newlib/libc/machine/arm/aeabi_memset-thumb2.S b/newlib/libc/machine/arm/aeabi_memset-thumb2.S
index eaca1d8d7..8bd4b5eaa 100644
--- a/newlib/libc/machine/arm/aeabi_memset-thumb2.S
+++ b/newlib/libc/machine/arm/aeabi_memset-thumb2.S
@@ -26,14 +26,43 @@
* SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/
+#include "pacbti.h"
+
.thumb
.syntax unified
.global __aeabi_memset
.type __aeabi_memset, %function
+ .fnstart
+ .cfi_startproc
ASM_ALIAS __aeabi_memset4 __aeabi_memset
ASM_ALIAS __aeabi_memset8 __aeabi_memset
__aeabi_memset:
+#if __HAVE_PAC_LEAF
+#if __ARM_FEATURE_BTI_DEFAULT
+ pacbti ip, lr, sp
+#else
+ pac ip, lr, sp
+#endif /* __ARM_FEATURE_BTI_DEFAULT */
+ .cfi_register 143, 12
+ push {r4, r5, r6, ip}
+ .save {r4, r5, r6, ra_auth_code}
+ .cfi_def_cfa_offset 16
+ .cfi_offset 4, -16
+ .cfi_offset 5, -12
+ .cfi_offset 6, -8
+ .cfi_offset 143, -4
+#else
+#if __ARM_FEATURE_BTI_DEFAULT
+ bti
+#endif /* __ARM_FEATURE_BTI_DEFAULT */
push {r4, r5, r6}
+ .save {r4, r5, r6}
+ .cfi_def_cfa_offset 12
+ .cfi_offset 4, -12
+ .cfi_offset 5, -8
+ .cfi_offset 6, -4
+#endif /* __HAVE_PAC_LEAF */
+
lsls r4, r0, #30
beq 10f
subs r4, r1, #1
@@ -98,10 +127,26 @@ __aeabi_memset:
cmp r3, r4
bne 8b
9:
+#if __HAVE_PAC_LEAF
+ pop {r4, r5, r6, ip}
+ .cfi_restore 143
+ .cfi_restore 6
+ .cfi_restore 5
+ .cfi_restore 4
+ .cfi_def_cfa_offset 0
+ aut ip, lr, sp
+#else
pop {r4, r5, r6}
- bx lr
+ .cfi_restore 6
+ .cfi_restore 5
+ .cfi_restore 4
+ .cfi_def_cfa_offset 0
+#endif /* __HAVE_PAC_LEAF */
+ bx lr
10:
mov r4, r1
mov r3, r0
b 3b
+ .cfi_endproc
+ .fnend
.size __aeabi_memset, . - __aeabi_memset
--
2.36.1
More information about the Newlib
mailing list