[1/2] RFC: refactor BFD check into autoconf macro
Tom Tromey
tromey@redhat.com
Thu Dec 13 19:51:00 GMT 2012
This patch is just preparation for the next one.
It moves a BFD check into an autoconf macro in acinclude.m4.
This way we can reuse it for another similar check.
Tested by rebuilding.
Tom
* acinclude.m4 (GDB_AC_CHECK_BFD): New macro.
* configure.ac: Use GDB_AC_CHECK_BFD.
* configure: Rebuild.
---
gdb/acinclude.m4 | 34 ++++++++++++++++++++++++++++++++++
gdb/configure | 45 +++++++++++++++++++++++----------------------
gdb/configure.ac | 29 +++--------------------------
3 files changed, 60 insertions(+), 48 deletions(-)
diff --git a/gdb/acinclude.m4 b/gdb/acinclude.m4
index 0873f66..c2f3a2d 100644
--- a/gdb/acinclude.m4
+++ b/gdb/acinclude.m4
@@ -424,3 +424,37 @@ AC_DEFUN([GDB_AC_WITH_DIR], [
AC_SUBST([$1])
GDB_AC_DEFINE_RELOCATABLE([$1], [$2], ${ac_define_dir})
])
+
+dnl GDB_AC_CHECK_BFD([MESSAGE], [CV], [CODE], [HEADER])
+dnl Check whether BFD provides a feature.
+dnl MESSAGE is the "checking" message to display.
+dnl CV is the name of the cache variable where the result is stored.
+dnl The result will be "yes" or "no".
+dnl CODE is some code to compile that checks for the feature.
+dnl A link test is run.
+dnl HEADER is the name of an extra BFD header to include.
+AC_DEFUN([GDB_AC_CHECK_BFD], [
+ OLD_CFLAGS=$CFLAGS
+ OLD_LDFLAGS=$LDFLAGS
+ OLD_LIBS=$LIBS
+ # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
+ # points somewhere with bfd, with -I/foo/lib and -L/foo/lib. We
+ # always want our bfd.
+ CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
+ LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
+ intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
+ # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
+ if test "$plugins" = "yes"; then
+ LIBS="-ldl $LIBS"
+ fi
+ LIBS="-lbfd -liberty $intl $LIBS"
+ AC_CACHE_CHECK([$1], [$2],
+ [AC_TRY_LINK(
+ [#include <stdlib.h>
+ #include "bfd.h"
+ #include "$4"
+ ],
+ [return $3;], [[$2]=yes], [[$2]=no])])
+ CFLAGS=$OLD_CFLAGS
+ LDFLAGS=$OLD_LDFLAGS
+ LIBS=$OLD_LIBS])
diff --git a/gdb/configure.ac b/gdb/configure.ac
index 5797561..26c88f4 100644
--- a/gdb/configure.ac
+++ b/gdb/configure.ac
@@ -2015,40 +2015,17 @@ esac
AC_SUBST(WIN32LIBS)
# Add ELF support to GDB, but only if BFD includes ELF support.
-OLD_CFLAGS=$CFLAGS
-OLD_LDFLAGS=$LDFLAGS
-OLD_LIBS=$LIBS
-# Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
-# points somewhere with bfd, with -I/foo/lib and -L/foo/lib. We
-# always want our bfd.
-CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
-LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
-intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
-# -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
-if test "$plugins" = "yes"; then
- LIBS="-ldl $LIBS"
-fi
-LIBS="-lbfd -liberty $intl $LIBS"
-AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
-[AC_TRY_LINK(
-[#include <stdlib.h>
-#include "bfd.h"
-#include "elf-bfd.h"
-],
-[bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
-gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
+GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
+ [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
if test $gdb_cv_var_elf = yes; then
CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
AC_DEFINE(HAVE_ELF, 1,
[Define if ELF support should be included.])
# -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
if test "$plugins" = "yes"; then
- OLD_LIBS="-ldl $OLD_LIBS"
+ LIBS="-ldl $LIBS"
fi
fi
-CFLAGS=$OLD_CFLAGS
-LDFLAGS=$OLD_LDFLAGS
-LIBS=$OLD_LIBS
# Add any host-specific objects to GDB.
CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
--
1.7.7.6
More information about the Gdb-patches
mailing list