6.1: AC_CONFIG_SUBDIRS changes for autoconf 2.5x
Maciej W. Rozycki
macro@ds2.pg.gda.pl
Tue Apr 20 14:54:00 GMT 2004
Hello,
Autoconf 2.5x requires AC_CONFIG_SUBDIRS arguments to be literals, to be
able to handle `./configure --help=recursive'. Here's an appropriate
change for gdb. I've maintained this patch since gdb 5.2 and autoconf
2.53 with no problems. I believe the change is neutral to autoconf 2.13.
The change has been successfully used in native builds for i386-linux and
mipsel-linux as well as in cross-builds for a mipsel-linux host.
gdb/ChangeLog, gdb/testsuite/ChangeLog, sim/ChangeLog,
sim/testsuite/ChangeLog:
2004-04-20 Maciej W. Rozycki <macro@ds2.pg.gda.pl>
* configure.in: Use literals as arguments to AC_CONFIG_SUBDIRS
throughout.
* configure: Regenerate.
Please apply.
With these changes, the gdb subdir is working just fine for me with
current autoconf (which is 2.59a from the CVS; 2.59 would work, too). I
have changes for autoconf 2.59 available for sim as well, but they are
probably incompatible to autoconf 2.13 -- I can submit them anyway if
there's desire to convert sim to 2.5x at this time.
Maciej
--
+ Maciej W. Rozycki, Technical University of Gdansk, Poland +
+--------------------------------------------------------------+
+ e-mail: macro@ds2.pg.gda.pl, PGP key available +
gdb-6.1-config-subdirs.patch
diff -up --recursive --new-file gdb-6.1.macro/gdb/configure.in gdb-6.1/gdb/configure.in
--- gdb-6.1.macro/gdb/configure.in 2004-02-26 00:41:46.000000000 +0000
+++ gdb-6.1/gdb/configure.in 2004-04-14 19:07:02.000000000 +0000
@@ -69,7 +69,6 @@ CONFIG_INSTALL=
CONFIG_UNINSTALL=
AC_CONFIG_SUBDIRS(doc testsuite)
-configdirs=
. $srcdir/configure.host
@@ -1223,7 +1222,7 @@ if test "${enable_gdbtk}" = "yes"; then
fi
fi
- configdirs="${configdirs} gdbtk"
+ AC_CONFIG_SUBDIRS(gdbtk)
fi
AC_SUBST(X_CFLAGS)
@@ -1349,22 +1348,20 @@ AC_ARG_ENABLE(multi-ice,
*) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
esac])
if test "x$enable_multi_ice" = xyes; then
- configdirs="$configdirs multi-ice"
+ AC_CONFIG_SUBDIRS(multi-ice)
fi
# We only build gdbserver automatically if host and target are the same.
if test "x$target" = "x$host"; then
AC_MSG_CHECKING(whether gdbserver is supported on this host)
if test "x$build_gdbserver" = xyes; then
- configdirs="$configdirs gdbserver"
+ AC_CONFIG_SUBDIRS(gdbserver)
AC_MSG_RESULT(yes)
else
AC_MSG_RESULT(no)
fi
fi
-AC_CONFIG_SUBDIRS($configdirs)
-
# If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
# (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
# version.
diff -up --recursive --new-file gdb-6.1.macro/gdb/testsuite/configure.in gdb-6.1/gdb/testsuite/configure.in
--- gdb-6.1.macro/gdb/testsuite/configure.in 2004-02-22 12:58:01.000000000 +0000
+++ gdb-6.1/gdb/testsuite/configure.in 2004-04-14 19:07:02.000000000 +0000
@@ -26,13 +26,10 @@ AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_CANONICAL_TARGET
-# Directories that need to be configured in all configurations.
-configdirs=
-
# Add HP-specific tests when appropriate.
case $target in
hppa*-*-hpux*)
- configdirs="$configdirs gdb.hp" ;;
+ AC_CONFIG_SUBDIRS(gdb.hp) ;;
esac
# With stabs.
@@ -57,7 +54,7 @@ esac])
# Add stabs tests when appropriate.
if test $with_stabs = yes; then
- configdirs="$configdirs gdb.stabs"
+ AC_CONFIG_SUBDIRS(gdb.stabs)
fi
# Enable gdbtk.
@@ -76,7 +73,7 @@ esac
# Add gdbtk tests when appropriate.
if test $enable_gdbtk = yes; then
- configdirs="$configdirs gdb.gdbtk"
+ AC_CONFIG_SUBDIRS(gdb.gdbtk)
fi
# Enable shared libraries.
@@ -111,7 +108,6 @@ AC_CHECK_HEADERS(pthread.h)
AC_EXEEXT
-AC_CONFIG_SUBDIRS($configdirs)
AC_OUTPUT([Makefile gdb.arch/Makefile gdb.asm/Makefile gdb.base/Makefile \
gdb.cp/Makefile gdb.disasm/Makefile gdb.java/Makefile gdb.mi/Makefile \
gdb.objc/Makefile gdb.threads/Makefile gdb.trace/Makefile])
diff -up --recursive --new-file gdb-6.1.macro/sim/configure.in gdb-6.1/sim/configure.in
--- gdb-6.1.macro/sim/configure.in 2004-01-26 08:12:43.000000000 +0000
+++ gdb-6.1/sim/configure.in 2004-04-14 19:10:47.000000000 +0000
@@ -38,7 +38,10 @@ esac])
# If the user passes --enable-sim built it regardless of $(CC).
only_if_gcc=no
only_if_enabled=no
-extra_subdirs=common
+
+# Additional subdirectories to be optionally configured.
+igen_subdir=no
+testsuite_subdir=no
# WHEN ADDING ENTRIES TO THIS MATRIX:
# Make sure that the left side always has two dashes. Otherwise you
@@ -48,29 +51,29 @@ extra_subdirs=common
case "${target}" in
arm*-*-* | thumb*-*-*)
sim_target=arm
- extra_subdirs="${extra_subdirs} testsuite"
+ testsuite_subdir=yes
;;
strongarm*-*-*)
sim_target=arm
- extra_subdirs="${extra_subdirs} testsuite"
+ testsuite_subdir=yes
;;
xscale-*-*)
sim_target=arm
- extra_subdirs="${extra_subdirs} testsuite"
+ testsuite_subdir=yes
;;
d10v-*-*) sim_target=d10v ;;
# OBSOLETE d30v-*-*)
# OBSOLETE sim_target=d30v
# OBSOLETE only_if_gcc=yes
-# OBSOLETE extra_subdirs="${extra_subdirs} igen"
+# OBSOLETE igen_subdir=yes
# OBSOLETE ;;
# OBSOLETE fr30-*-*) sim_target=fr30 ;;
frv-*-*) sim_target=frv
- extra_subdirs="${extra_subdirs} testsuite"
+ testsuite_subdir=yes
;;
h8300*-*-*)
sim_target=h8300
- extra_subdirs="${extra_subdirs} testsuite"
+ testsuite_subdir=yes
;;
h8500-*-*) sim_target=h8500 ;;
i960-*-*) sim_target=i960 ;;
@@ -81,20 +84,21 @@ case "${target}" in
# The MIPS simulator can only be compiled by gcc.
sim_target=mips
only_if_gcc=yes
- extra_subdirs="${extra_subdirs} igen testsuite"
+ igen_subdir=yes
+ testsuite_subdir=yes
;;
mn10300*-*-*)
# The mn10300 simulator can only be compiled by gcc.
sim_target=mn10300
only_if_gcc=yes
- extra_subdirs="${extra_subdirs} igen"
+ igen_subdir=yes
;;
mn10200*-*-*)
sim_target=mn10200
;;
sh*-*-*)
sim_target=sh
- extra_subdirs="${extra_subdirs} testsuite"
+ testsuite_subdir=yes
;;
powerpc*-*-eabi* | powerpc*-*-solaris* | powerpc*-*-sysv4* | \
powerpc*-*-elf* | powerpc*-*-linux* | powerpc*-*-netbsd* )
@@ -103,29 +107,28 @@ case "${target}" in
# unless asked to.
sim_target=ppc
only_if_gcc=yes
- #extra_subdirs="${extra_subdirs}"
;;
tic80-*-*)
sim_target=tic80
only_if_gcc=yes
- extra_subdirs="${extra_subdirs} igen"
+ igen_subdir=yes
;;
v850-*-*)
# The V850 simulator can only be compiled by gcc.
sim_target=v850
- extra_subdirs="${extra_subdirs} igen"
+ igen_subdir=yes
only_if_gcc=yes
;;
v850e-*-*)
# The V850 simulator can only be compiled by gcc.
sim_target=v850
- extra_subdirs="${extra_subdirs} igen"
+ igen_subdir=yes
only_if_gcc=yes
;;
v850ea-*-*)
# The V850 simulator can only be compiled by gcc.
sim_target=v850
- extra_subdirs="${extra_subdirs} igen"
+ igen_subdir=yes
only_if_gcc=yes
;;
w65-*-*)
@@ -158,7 +161,7 @@ esac
# Is there a testsuite directory for the target?
testdir=`echo ${target} | sed -e 's/-.*-/-/'`
if test -r ${srcdir}/testsuite/${testdir}/configure ; then
- extra_subdirs="${extra_subdirs} testsuite"
+ testsuite_subdir=yes
fi
@@ -186,8 +189,39 @@ yes)
esac
if test x"${sim_target}" != xnone ; then
- configdirs="${extra_subdirs} ${sim_target}"
- AC_CONFIG_SUBDIRS($configdirs)
+
+ AC_CONFIG_SUBDIRS(common)
+
+ if test "${igen_subdir}" = yes; then
+ AC_CONFIG_SUBDIRS(igen)
+ fi
+ if test "${testsuite_subdir}" = yes; then
+ AC_CONFIG_SUBDIRS(testsuite)
+ fi
+
+ case "${sim_target}" in
+ arm) AC_CONFIG_SUBDIRS(arm) ;;
+ d10v) AC_CONFIG_SUBDIRS(d10v) ;;
+# OBSOLETE d30v) AC_CONFIG_SUBDIRS(d30v) ;;
+ erc32) AC_CONFIG_SUBDIRS(erc32) ;;
+# OBSOLETE fr30) AC_CONFIG_SUBDIRS(fr30) ;;
+ h8300) AC_CONFIG_SUBDIRS(h8300) ;;
+ h8500) AC_CONFIG_SUBDIRS(h8500) ;;
+ i960) AC_CONFIG_SUBDIRS(i960) ;;
+ m32r) AC_CONFIG_SUBDIRS(m32r) ;;
+ m68hc11) AC_CONFIG_SUBDIRS(m68hc11) ;;
+ mcore) AC_CONFIG_SUBDIRS(mcore) ;;
+ mips) AC_CONFIG_SUBDIRS(mips) ;;
+ mn10200) AC_CONFIG_SUBDIRS(mn10200) ;;
+ mn10300) AC_CONFIG_SUBDIRS(mn10300) ;;
+ sh) AC_CONFIG_SUBDIRS(sh) ;;
+ ppc) AC_CONFIG_SUBDIRS(ppc) ;;
+ tic80) AC_CONFIG_SUBDIRS(tic80) ;;
+ v850) AC_CONFIG_SUBDIRS(v850) ;;
+ w65) AC_CONFIG_SUBDIRS(w65) ;;
+ z8k) AC_CONFIG_SUBDIRS(z8k) ;;
+ esac
+
fi
AC_OUTPUT(Makefile)
diff -up --recursive --new-file gdb-6.1.macro/sim/testsuite/configure.in gdb-6.1/sim/testsuite/configure.in
--- gdb-6.1.macro/sim/testsuite/configure.in 1999-04-16 01:35:14.000000000 +0000
+++ gdb-6.1/sim/testsuite/configure.in 2003-11-06 15:50:47.000000000 +0000
@@ -12,14 +12,16 @@ AC_SUBST(CC)
AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/../..)
AC_CANONICAL_SYSTEM
-# Directories to use in all configurations.
-configdirs=""
-
# add test sub-directory for appropriate targets
testdir=`echo ${target} | sed -e 's/-.*-/-/'`
-if test -r ${srcdir}/${testdir}/configure ; then
- configdirs="${configdirs} $testdir"
-fi
+case $testdir in
+ d10v-elf) AC_CONFIG_SUBDIRS(d10v-elf) ;;
+ d30v-elf) AC_CONFIG_SUBDIRS(d30v-elf) ;;
+ fr30-elf) AC_CONFIG_SUBDIRS(fr30-elf) ;;
+ m32r-elf) AC_CONFIG_SUBDIRS(m32r-elf) ;;
+ mips64el-elf) AC_CONFIG_SUBDIRS(mips64el-elf) ;;
+ *) ;;
+esac
# add any extra subdirectories
case $target in
@@ -34,7 +36,4 @@ case $target in
esac
AC_SUBST(arch)
-# configure the subdirectories too
-AC_CONFIG_SUBDIRS($configdirs)
-
AC_OUTPUT(Makefile)
More information about the Gdb-patches
mailing list