New DWARF 5 sections?

[Fangrui Song]

On Sat, Jan 23, 2021 at 10:23 AM Sebastian Huber
<sebastian.huber@embedded-brains.de> wrote:
>
> Hello,
>
> I use a linker script which adds all unexpected sections into a memory
> region of length 0:
>
> MEMORY {
>      UNEXPECTED_SECTIONS : ORIGIN = 0xffffffff, LENGTH = 0
> }
>
> SECTIONS {
>
> ...
>
>      .unexpected_sections : { *(*) } > UNEXPECTED_SECTIONS
> }
>
> It seems there are some new debug sections produced by GCC 11 which uses
> DWARF 5 by default such as:
>
>   .debug_loclists
>   .debug_rnglists
>   .debug_line_str
>
> These sections are not covered by the default linker script for example
> on arm (and other targets):
>
> arm-rtems7-ld --verbose
> GNU ld (GNU Binutils) 2.36.50.20210122
>    Supported emulations:
>     armelf
> using internal linker script:
> ==================================================
>
> ...
>
>    /* Stabs debugging sections.  */
>    .stab          0 : { *(.stab) }
>    .stabstr       0 : { *(.stabstr) }
>    .stab.excl     0 : { *(.stab.excl) }
>    .stab.exclstr  0 : { *(.stab.exclstr) }
>    .stab.index    0 : { *(.stab.index) }
>    .stab.indexstr 0 : { *(.stab.indexstr) }
>    .comment       0 : { *(.comment) }
>    .gnu.build.attributes : { *(.gnu.build.attributes
> .gnu.build.attributes.*) }
>    /* DWARF debug sections.
>       Symbols in the DWARF debugging sections are relative to the beginning
>       of the section so we begin them at 0.  */
>    /* DWARF 1 */
>    .debug          0 : { *(.debug) }
>    .line           0 : { *(.line) }
>    /* GNU DWARF 1 extensions */
>    .debug_srcinfo  0 : { *(.debug_srcinfo) }
>    .debug_sfnames  0 : { *(.debug_sfnames) }
>    /* DWARF 1.1 and DWARF 2 */
>    .debug_aranges  0 : { *(.debug_aranges) }
>    .debug_pubnames 0 : { *(.debug_pubnames) }
>    /* DWARF 2 */
>    .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
>    .debug_abbrev   0 : { *(.debug_abbrev) }
>    .debug_line     0 : { *(.debug_line .debug_line.* .debug_line_end) }
>    .debug_frame    0 : { *(.debug_frame) }
>    .debug_str      0 : { *(.debug_str) }
>    .debug_loc      0 : { *(.debug_loc) }
>    .debug_macinfo  0 : { *(.debug_macinfo) }
>    /* SGI/MIPS DWARF 2 extensions */
>    .debug_weaknames 0 : { *(.debug_weaknames) }
>    .debug_funcnames 0 : { *(.debug_funcnames) }
>    .debug_typenames 0 : { *(.debug_typenames) }
>    .debug_varnames  0 : { *(.debug_varnames) }
>    /* DWARF 3 */
>    .debug_pubtypes 0 : { *(.debug_pubtypes) }
>    .debug_ranges   0 : { *(.debug_ranges) }
>    /* DWARF Extension.  */
>    .debug_macro    0 : { *(.debug_macro) }
>    .debug_addr     0 : { *(.debug_addr) }
>    .ARM.attributes 0 : { KEEP (*(.ARM.attributes)) KEEP
> (*(.gnu.attributes)) }
>    .note.gnu.arm.ident 0 : { KEEP (*(.note.gnu.arm.ident)) }
>    /DISCARD/ : { *(.note.GNU-stack) *(.gnu_debuglink) *(.gnu.lto_*) }
> }
>
> Are these sections missing?

There is also

+               .debug_str_offsets      0 : { *(.debug_str_offsets) }

The comment "DWARF Extension." for .debug_macro and .debug_addr can be changed..

There is a pending Linux kernel doing something similar. Let me check
whether I can contribute a patch:)