This is the mail archive of the
xsl-list@mulberrytech.com
mailing list .
Re: Copying and Transforming/Recursion? - Revisited
- To: xsl-list at mulberrytech dot com
- Subject: Re: Copying and Transforming/Recursion? - Revisited
- From: David Carlisle <davidc at nag dot co dot uk>
- Date: Thu, 12 Oct 2000 15:11:45 GMT
- References: <3A6A4957259DD311AFDF00902773C74035A6C0@gebo.pandemonium.fr>
- Reply-To: xsl-list at mulberrytech dot com
> You and others make this sound trivial to the point that I must just not be
> grasping a fundamental...
Just take a stylesheet that does the identity transform, add one extra
template and you are done. (or two since your example output also
junked the submittedvalues element)
===================================================
<xml>
<submittedValues>
<submittedValue fieldname='title'>mr.</submittedValue>
</submittedValues>
<display>
<p>
title:<input type='text' fieldname='title' value=''/>
</p>
</display>
</xml>
===================================================
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0"
>
<xsl:output method="xml" indent="yes"/>
<!-- copy most stuff -->
<xsl:template match="*" >
<xsl:copy>
<xsl:copy-of select="@*"/>
<xsl:apply-templates/>
</xsl:copy>
</xsl:template>
<!-- modify input -->
<xsl:template match="input" >
<xsl:copy>
<xsl:copy-of select="@*"/>
<xsl:attribute name="value">
<xsl:value-of
select="//submittedValue[@fieldname=current()/@fieldname]"/>
</xsl:attribute>
</xsl:copy>
</xsl:template>
<!-- junk this -->
<xsl:template match="submittedValues" />
</xsl:stylesheet>
===================================================
bash$ xt r.xml r.xsl
<?xml version="1.0" encoding="utf-8"?>
<xml>
<display>
<p>
title:<input type="text" fieldname="title" value="mr."/>
</p>
</display>
</xml>
XSL-List info and archive: http://www.mulberrytech.com/xsl/xsl-list