Re: [PATCH]: Optimization for strpbrk on PowerPC

[Adhemerval Zanella <azanella at linux dot vnet dot ibm dot com>]

On 28-02-2014 12:07, R Vidya wrote:
> Hi
>     Agree, I am also seeing performance improvement with x86_64 approach
> The advantage I am seeing with this approach is that it avoids scanning duplicate
> chars in the needle via hash table/dictionary in addition to loop unrolling.
>
> Adhemerval ,
> Lets push the current implementation and work on similar approach for Power7
> shortly. thanks.
>
> Regards
> Vidya

Here is a better optimized strpbrk based on Ondrej comments with 
Vidya multilib infrastructure.

This patch add a optimized strpbrk for POWER7 by using a different
algorithm than default implementation: it constructs a table based on
the 'accept' argument and use this table to check for any occurance on
the input string. The idea is similar as x86_64 uses.
For PowerPC some tunings were added, such as unroll loops and align
table stack memory to 16 bytes (so VSX clean can ran without
alignment issues).

---

2014-03-03  Adhemerval Zanella  <azanella@linux.vnet.ibm.com>
	    Vidya Ranganathan  <vidya@linux.vnet.ibm.com>

        * string/strpbrk.c (strpbrk): Using macro to redefine symbol name.
        * sysdeps/powerpc/powerpc64/multiarch/Makefile: Add strpbrk-power7
	and strpbrk-ppc64 objects.
	* sysdeps/powerpc/powerpc64/multiarch/ifunc-impl-list.c
	(__libc_ifunc_impl_list): Add new strpbrk optimized symbols.
	* sysdeps/powerpc/powerpc64/multiarch/strpbrk-power7.S: New file:
	multiarch strpbrk for POWER7.
	* sysdeps/powerpc/powerpc64/multiarch/strpbrk-ppc64.c: New file:
	multiarch strpbrk for PPC64.
	* sysdeps/powerpc/powerpc64/multiarch/strpbrk.c: New file: strpbrk
	ifunc selector.
	* sysdeps/powerpc/powerpc64/power7/strpbrk.S: New file: optimited
	strpbrk for POWER7.

--

diff --git a/string/strpbrk.c b/string/strpbrk.c
index ce33b68..2955644 100644
--- a/string/strpbrk.c
+++ b/string/strpbrk.c
@@ -25,9 +25,13 @@
 
 #undef strpbrk
 
+#ifndef STRPBRK
+#define STRPBRK strpbrk
+#endif
+
 /* Find the first occurrence in S of any character in ACCEPT.  */
 char *
-strpbrk (s, accept)
+STRPBRK (s, accept)
      const char *s;
      const char *accept;
 {
diff --git a/sysdeps/powerpc/powerpc64/multiarch/Makefile b/sysdeps/powerpc/powerpc64/multiarch/Makefile
index 3c47316..5fe8a0c 100644
--- a/sysdeps/powerpc/powerpc64/multiarch/Makefile
+++ b/sysdeps/powerpc/powerpc64/multiarch/Makefile
@@ -13,7 +13,8 @@ sysdep_routines += memcpy-power7 memcpy-a2 memcpy-power6 memcpy-cell \
 		   wcschr-power6 wcschr-ppc64 wcsrchr-power7 wcsrchr-power6 \
 		   wcsrchr-ppc64 wcscpy-power7 wcscpy-power6 wcscpy-ppc64 \
 		   wordcopy-power7 wordcopy-power6 wordcopy-ppc64 \
-		   strcpy-power7 strcpy-ppc64 stpcpy-power7 stpcpy-ppc64
+		   strcpy-power7 strcpy-ppc64 stpcpy-power7 stpcpy-ppc64 \
+		   strpbrk-power7 strpbrk-ppc64
 
 CFLAGS-strncase-power7.c += -mcpu=power7 -funroll-loops
 CFLAGS-strncase_l-power7.c += -mcpu=power7 -funroll-loops
diff --git a/sysdeps/powerpc/powerpc64/multiarch/ifunc-impl-list.c b/sysdeps/powerpc/powerpc64/multiarch/ifunc-impl-list.c
index 6bbdd4e..96ec23b 100644
--- a/sysdeps/powerpc/powerpc64/multiarch/ifunc-impl-list.c
+++ b/sysdeps/powerpc/powerpc64/multiarch/ifunc-impl-list.c
@@ -238,5 +238,13 @@ __libc_ifunc_impl_list (const char *name, struct libc_ifunc_impl *array,
 	      IFUNC_IMPL_ADD (array, i, wcscpy, 1,
 			      __wcscpy_ppc))
 
+  /* Support sysdeps/powerpc/powerpc64/multiarch/strpbrk.c.  */
+  IFUNC_IMPL (i, name, strpbrk,
+	      IFUNC_IMPL_ADD (array, i, strpbrk,
+			      hwcap & PPC_FEATURE_HAS_VSX,
+			      __strpbrk_power7)
+	      IFUNC_IMPL_ADD (array, i, strpbrk, 1,
+			     __strpbrk_ppc))
+
   return i;
 }
diff --git a/sysdeps/powerpc/powerpc64/multiarch/strpbrk-power7.S b/sysdeps/powerpc/powerpc64/multiarch/strpbrk-power7.S
new file mode 100644
index 0000000..663ca36
--- /dev/null
+++ b/sysdeps/powerpc/powerpc64/multiarch/strpbrk-power7.S
@@ -0,0 +1,40 @@
+/* Optimized strpbrk implementation for POWER7.
+   Copyright (C) 2014 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, see
+   <http://www.gnu.org/licenses/>.  */
+
+#include <sysdep.h>
+
+#undef EALIGN
+#define EALIGN(name, alignt, words)				\
+  .section ".text";						\
+  ENTRY_2(__strpbrk_power7)					\
+  .align ALIGNARG(alignt);					\
+  EALIGN_W_##words;						\
+  BODY_LABEL(__strpbrk_power7):					\
+  cfi_startproc;						\
+  LOCALENTRY(__strpbrk_power7)
+
+#undef END
+#define END(name)						\
+  cfi_endproc;							\
+  TRACEBACK(__strpbrk_power7)					\
+  END_2(__strpbrk_power7)
+
+#undef libc_hidden_builtin_def
+#define libc_hidden_builtin_def(name)
+
+#include <sysdeps/powerpc/powerpc64/power7/strpbrk.S>
diff --git a/sysdeps/powerpc/powerpc64/multiarch/strpbrk-ppc64.c b/sysdeps/powerpc/powerpc64/multiarch/strpbrk-ppc64.c
new file mode 100644
index 0000000..8dea70e
--- /dev/null
+++ b/sysdeps/powerpc/powerpc64/multiarch/strpbrk-ppc64.c
@@ -0,0 +1,30 @@
+/* Copyright (C) 2014 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, see
+   <http://www.gnu.org/licenses/>.  */
+
+#include <string.h>
+
+#define STRPBRK __strpbrk_ppc
+#ifdef SHARED
+
+# undef libc_hidden_builtin_def
+# define libc_hidden_builtin_def(name) \
+  __hidden_ver1 (__strpbrk_ppc, __GI_strpbrk, __strpbrk_ppc);
+#endif
+
+extern __typeof (strpbrk) __strpbrk_ppc attribute_hidden;
+
+#include <string/strpbrk.c>
diff --git a/sysdeps/powerpc/powerpc64/multiarch/strpbrk.c b/sysdeps/powerpc/powerpc64/multiarch/strpbrk.c
new file mode 100644
index 0000000..8b05536
--- /dev/null
+++ b/sysdeps/powerpc/powerpc64/multiarch/strpbrk.c
@@ -0,0 +1,31 @@
+/* Multiple versions of strpbrk. PowerPC64 version.
+   Copyright (C) 2014 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, see
+   <http://www.gnu.org/licenses/>.  */
+
+#ifndef NOT_IN_libc
+# include <string.h>
+# include <shlib-compat.h>
+# include "init-arch.h"
+
+extern __typeof (strpbrk) __strpbrk_ppc attribute_hidden;
+extern __typeof (strpbrk) __strpbrk_power7 attribute_hidden;
+
+libc_ifunc (strpbrk,
+	    (hwcap & PPC_FEATURE_HAS_VSX)
+	    ? __strpbrk_power7
+	    : __strpbrk_ppc);
+#endif
diff --git a/sysdeps/powerpc/powerpc64/power7/strpbrk.S b/sysdeps/powerpc/powerpc64/power7/strpbrk.S
new file mode 100644
index 0000000..5a5e03f
--- /dev/null
+++ b/sysdeps/powerpc/powerpc64/power7/strpbrk.S
@@ -0,0 +1,144 @@
+/* Optimized strpbrk implementation for PowerPC64/POWER7.
+   Copyright (C) 2014 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, see
+   <http://www.gnu.org/licenses/>.  */
+
+#include <sysdep.h>
+
+/* char [r3] *strpbrk(const char [r4] *s, const char [r5] *accept)  */
+
+	.machine power7
+EALIGN (strpbrk, 4, 0)
+	CALL_MCOUNT 3
+
+	/* The idea to speed up the algorithm is to create a lookup table
+	   for fast check if input character should be considered.  For ASCII
+	   or ISO-8859-X character sets it has 256 positions.  */
+	lbz	r10,0(r4)
+
+	/* First the table should be cleared and to avoid unaligned accesses
+	   when using the VSX stores the table address is aligned to 16
+	   bytes.  */
+	xxlxor	v0,v0,v0
+	addi	r9,r1,-272	/* Allocates ALIGN(256 + 15, 8) bytes  */
+	li	r5,16
+	li	r6,32
+	li	r8,48
+	cmpdi	cr7,r10,0	/* accept[0] == '\0' ?  */
+	addi	r12,r9,64
+	/* Clear the table with 0 values  */
+	stxvw4x v0,r0,r9
+	addi	r11,r9,128
+	addi	r7,r9,192
+	stxvw4x	v0,r9,r5
+	li	r0,1
+	stxvw4x v0,r9,r6
+	stxvw4x v0,r9,r8
+	stxvw4x v0,r0,r12
+	stxvw4x v0,r12,r5
+	stxvw4x v0,r12,r6
+	stxvw4x v0,r12,r8
+	stxvw4x v0,r0,r11
+	stxvw4x v0,r11,r5
+	stxvw4x v0,r11,r6
+	stxvw4x v0,r11,r8
+	stxvw4x v0,r0,r7
+	stxvw4x v0,r7,r5
+	stxvw4x v0,r7,r6
+	stxvw4x v0,r7,r8
+	beq	cr7,L(finish_table) /* If accept[0] == '\0' skip  */
+
+	/* Initialize the table as:
+	   for (i=0; accept[i]; i++
+	     table[accept[i]]] = 1  */
+	.p2align 4,,15
+L(init_table):
+	stbx	r0,r9,r10
+	lbzu	r10,1(r4)
+	cmpdi	r0,r10,0
+	bne	cr0,L(init_table)
+L(finish_table):
+	/* set table[0] = 1  */
+	li	r4,1
+	stb	r4,0(r9)
+	b	L(mainloop)
+
+	/* Unrool the loop 4 times and check using the table as:
+	   i = 0;
+	   while (1)
+	     {
+	       if (table[input[i++]] == 1)
+	         return (s[i -1] ? s + i - 1: NULL);
+	       if (table[input[i++]] == 1)
+	         return (s[i -1] ? s + i - 1: NULL);
+	       if (table[input[i++]] == 1)
+	         return (s[i -1] ? s + i - 1: NULL);
+	       if (table[input[i++]] == 1)
+	         return (s[i -1] ? s + i - 1: NULL);
+	     }  */
+	.p2align 4,,15
+L(unroll):
+	lbz	r0,1(r3)
+	lbzx	r8,r9,r0
+	cmpwi	cr6,r8,1
+	beq	cr6,L(checkend2)
+	lbz	r10,2(r3)
+	lbzx	r4,r9,r10
+	cmpwi	cr7,r4,1
+	beq	cr7,L(checkend3)
+	lbz	r12,3(r3)
+	addi	r3,r3,4
+	lbzx	r11,r9,r12
+	cmpwi	cr0,r11,1
+	beq	cr0,L(checkend)
+L(mainloop):
+	lbz	r12,0(r3)
+	addi	r11,r3,1
+	addi	r5,r3,2
+	addi	r7,r3,3
+	lbzx	r6,r9,r12
+	cmpwi	cr1,r6,1
+	bne	cr1,L(unroll)
+	cmpdi	cr0,r12,0
+	beq	cr0,L(nullfound)
+L(end):
+	blr
+
+	.p2align 4,,15
+L(checkend):
+	cmpdi	cr1,r12,0
+	mr	r3,r7
+	bne	cr1,L(end)
+L(nullfound):
+	/* return NULL  */
+	li 3,0
+	blr
+
+	.p2align 4,,15
+L(checkend2):
+	cmpdi	cr7,r0,0
+	mr	r3,r11
+	beq	cr7,L(nullfound)
+	blr
+
+	.p2align 4,,15
+L(checkend3):
+	cmpdi	cr6,r10,0
+	mr	r3,r5
+	beq	cr6,L(nullfound)
+	blr
+END (strpbrk)
+libc_hidden_builtin_def (strpbrk)