This is the mail archive of the
libc-alpha@sourceware.org
mailing list for the glibc project.
[PATCH 15/36] PowerPC: strchr multilib for PowerPC32
- From: Adhemerval Zanella <azanella at linux dot vnet dot ibm dot com>
- To: "GNU C. Library" <libc-alpha at sourceware dot org>
- Date: Mon, 19 Aug 2013 18:28:34 -0300
- Subject: [PATCH 15/36] PowerPC: strchr multilib for PowerPC32
- References: <52127ABC dot 40008 at linux dot vnet dot ibm dot com>
2013-08-19 Adhemerval Zanella <azanella@linux.vnet.ibm.com>
* sysdeps/powerpc/powerpc32/power7/strchr.S: Move to ...
* sysdeps/powerpc/powerpc32/multiarch/strchr-power7.S: ... here.
(strchr): Rename symbol name to __strchr_power7 and remove
the libc_hidden_builtin_def and weak_alias definitions.
* sysdeps/powerpc/powerpc32/multiarch/strchr-ppc32.S: New file:
default strchr implementation for PPC32.
* sysdeps/powerpc/powerpc32/multiarch/rtld-strchr.S: New file:
default loader strchr implementation for PPC32.
* sysdeps/powerpc/powerpc32/multiarch/strchr.c: New file:
multiarch strchr for PPC32.
* sysdeps/powerpc/powerpc32/multiarch/Makefile: Added strchr
multiarch objects.
* sysdeps/powerpc/powerpc32/multiarch/ifunc-impl-list
(__libc_ifunc_impl_list): Likewise.
--
diff --git a/sysdeps/powerpc/powerpc32/multiarch/Makefile b/sysdeps/powerpc/powerpc32/multiarch/Makefile
index d469746..83b26a5 100644
--- a/sysdeps/powerpc/powerpc32/multiarch/Makefile
+++ b/sysdeps/powerpc/powerpc32/multiarch/Makefile
@@ -8,7 +8,7 @@ sysdep_routines += memcpy-power7 memcpy-a2 memcpy-power6 memcpy-cell \
strnlen-power7 strnlen-ppc32 strncmp-power7 strncmp-power4 \
strncmp-ppc32 strcasecmp-power7 strcasecmp_l-power7 \
strncase-power7 strncase_l-power7 strchrnul-power7 \
- strchrnul-ppc32
+ strchrnul-ppc32 strchr-power7 strchr-ppc32
CFLAGS-strncase-power7.c += -mcpu=power7 -funroll-loops
CFLAGS-strncase_l-power7.c += -mcpu=power7 -funroll-loops
diff --git a/sysdeps/powerpc/powerpc32/multiarch/ifunc-impl-list.c b/sysdeps/powerpc/powerpc32/multiarch/ifunc-impl-list.c
index b813875..35d6c7c 100644
--- a/sysdeps/powerpc/powerpc32/multiarch/ifunc-impl-list.c
+++ b/sysdeps/powerpc/powerpc32/multiarch/ifunc-impl-list.c
@@ -117,6 +117,14 @@ __libc_ifunc_impl_list (const char *name, struct libc_ifunc_impl *array,
IFUNC_IMPL_ADD (array, i, strchrnul, 1,
__strchrnul_ppc32))
+ /* Support sysdeps/powerpc/powerpc32/multiarch/strchr.c. */
+ IFUNC_IMPL (i, name, strchr,
+ IFUNC_IMPL_ADD (array, i, strchr,
+ hwcap & PPC_FEATURE_HAS_VSX,
+ __strchr_power7)
+ IFUNC_IMPL_ADD (array, i, strchr, 1,
+ __strchr_ppc32))
+
#ifdef SHARED
/* Support sysdeps/powerpc/powerpc32/multiarch/memset.c. */
IFUNC_IMPL (i, name, memset,
diff --git a/sysdeps/powerpc/powerpc32/multiarch/rtld-strchr.S b/sysdeps/powerpc/powerpc32/multiarch/rtld-strchr.S
new file mode 100644
index 0000000..d75786c
--- /dev/null
+++ b/sysdeps/powerpc/powerpc32/multiarch/rtld-strchr.S
@@ -0,0 +1,18 @@
+/* Copyright (C) 2013 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#include <sysdeps/powerpc/powerpc32/strchr.S>
diff --git a/sysdeps/powerpc/powerpc32/multiarch/strchr-power7.S b/sysdeps/powerpc/powerpc32/multiarch/strchr-power7.S
new file mode 100644
index 0000000..32bc5bb
--- /dev/null
+++ b/sysdeps/powerpc/powerpc32/multiarch/strchr-power7.S
@@ -0,0 +1,198 @@
+/* Optimized strchr implementation for PowerPC32/POWER7 using cmpb insn.
+ Copyright (C) 2010-2013 Free Software Foundation, Inc.
+ Contributed by Luis Machado <luisgpm@br.ibm.com>.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+
+/* int [r3] strchr (char *s [r3], int c [r4]) */
+ .machine power7
+ENTRY (__strchr_power7)
+ CALL_MCOUNT
+ dcbt 0,r3
+ clrrwi r8,r3,2 /* Align the address to word boundary. */
+ cmpwi cr7,r4,0
+ lwz r12,0(r8) /* Load word from memory. */
+ li r0,0 /* Word with null chars to use
+ with cmpb. */
+
+ rlwinm r6,r3,3,27,28 /* Calculate padding. */
+
+ beq cr7,L(null_match)
+
+ /* Replicate byte to word. */
+ rlwimi r4,r4,8,16,23
+ rlwimi r4,r4,16,0,15
+
+ /* Now r4 has a word of c bytes and r0 has
+ a word of null bytes. */
+
+ cmpb r10,r12,r4 /* Compare each byte against c byte. */
+ cmpb r11,r12,r0 /* Compare each byte against null byte. */
+
+ /* Move the words left and right to discard the bits that are
+ not part of the string and to bring them back as zeros. */
+
+ slw r10,r10,r6
+ slw r11,r11,r6
+ srw r10,r10,r6
+ srw r11,r11,r6
+ or r5,r10,r11 /* OR the results to speed things up. */
+ cmpwi cr7,r5,0 /* If r5 == 0, no c or null bytes
+ have been found. */
+ bne cr7,L(done)
+
+ mtcrf 0x01,r8
+
+ /* Are we now aligned to a doubleword boundary? If so, skip to
+ the main loop. Otherwise, go through the alignment code. */
+
+ bt 29,L(loop)
+
+ /* Handle WORD2 of pair. */
+ lwzu r12,4(r8)
+ cmpb r10,r12,r4
+ cmpb r11,r12,r0
+ or r5,r10,r11
+ cmpwi cr7,r5,0
+ bne cr7,L(done)
+ b L(loop) /* We branch here (rather than falling through)
+ to skip the nops due to heavy alignment
+ of the loop below. */
+
+ .p2align 5
+L(loop):
+ /* Load two words, compare and merge in a
+ single register for speed. This is an attempt
+ to speed up the null-checking process for bigger strings. */
+ lwz r12,4(r8)
+ lwzu r9,8(r8)
+ cmpb r10,r12,r4
+ cmpb r11,r12,r0
+ cmpb r6,r9,r4
+ cmpb r7,r9,r0
+ or r12,r10,r11
+ or r9,r6,r7
+ or r5,r12,r9
+ cmpwi cr7,r5,0
+ beq cr7,L(loop)
+
+ /* OK, one (or both) of the words contains a c/null byte. Check
+ the first word and decrement the address in case the first
+ word really contains a c/null byte. */
+
+ cmpwi cr6,r12,0
+ addi r8,r8,-4
+ bne cr6,L(done)
+
+ /* The c/null byte must be in the second word. Adjust the address
+ again and move the result of cmpb to r10 so we can calculate the
+ pointer. */
+
+ mr r10,r6
+ mr r11,r7
+ addi r8,r8,4
+
+ /* r5 has the output of the cmpb instruction, that is, it contains
+ 0xff in the same position as the c/null byte in the original
+ word from the string. Use that to calculate the pointer. */
+L(done):
+ cntlzw r4,r10 /* Count leading zeroes before c matches. */
+ cntlzw r0,r11 /* Count leading zeroes before null matches. */
+ cmplw cr7,r4,r0
+ bgt cr7,L(no_match)
+ srwi r0,r4,3 /* Convert leading zeroes to bytes. */
+ add r3,r8,r0 /* Return address of the matching c byte
+ or null in case c was not found. */
+ blr
+
+ .align 4
+L(no_match):
+ li r3,0
+ blr
+
+/* We are here because strchr was called with a null byte. */
+ .align 4
+L(null_match):
+ /* r0 has a word of null bytes. */
+
+ cmpb r5,r12,r0 /* Compare each byte against null bytes. */
+
+ /* Move the words left and right to discard the bits that are
+ not part of the string and to bring them back as zeros. */
+
+ slw r5,r5,r6
+ srw r5,r5,r6
+ cmpwi cr7,r5,0 /* If r10 == 0, no c or null bytes
+ have been found. */
+ bne cr7,L(done_null)
+
+ mtcrf 0x01,r8
+
+ /* Are we now aligned to a doubleword boundary? If so, skip to
+ the main loop. Otherwise, go through the alignment code. */
+
+ bt 29,L(loop_null)
+
+ /* Handle WORD2 of pair. */
+ lwzu r12,4(r8)
+ cmpb r5,r12,r0
+ cmpwi cr7,r5,0
+ bne cr7,L(done_null)
+ b L(loop_null) /* We branch here (rather than falling through)
+ to skip the nops due to heavy alignment
+ of the loop below. */
+
+ /* Main loop to look for the end of the string. Since it's a
+ small loop (< 8 instructions), align it to 32-bytes. */
+ .p2align 5
+L(loop_null):
+ /* Load two words, compare and merge in a
+ single register for speed. This is an attempt
+ to speed up the null-checking process for bigger strings. */
+ lwz r12,4(r8)
+ lwzu r11,8(r8)
+ cmpb r5,r12,r0
+ cmpb r10,r11,r0
+ or r6,r5,r10
+ cmpwi cr7,r6,0
+ beq cr7,L(loop_null)
+
+ /* OK, one (or both) of the words contains a null byte. Check
+ the first word and decrement the address in case the first
+ word really contains a null byte. */
+
+ cmpwi cr6,r5,0
+ addi r8,r8,-4
+ bne cr6,L(done_null)
+
+ /* The null byte must be in the second word. Adjust the address
+ again and move the result of cmpb to r10 so we can calculate the
+ pointer. */
+
+ mr r5,r10
+ addi r8,r8,4
+
+ /* r5 has the output of the cmpb instruction, that is, it contains
+ 0xff in the same position as the null byte in the original
+ word from the string. Use that to calculate the pointer. */
+L(done_null):
+ cntlzw r0,r5 /* Count leading zeros before the match. */
+ srwi r0,r0,3 /* Convert leading zeros to bytes. */
+ add r3,r8,r0 /* Return address of the matching null byte. */
+ blr
+END (__strchr_power7)
diff --git a/sysdeps/powerpc/powerpc32/multiarch/strchr-ppc32.S b/sysdeps/powerpc/powerpc32/multiarch/strchr-ppc32.S
new file mode 100644
index 0000000..7f49ae0
--- /dev/null
+++ b/sysdeps/powerpc/powerpc32/multiarch/strchr-ppc32.S
@@ -0,0 +1,41 @@
+/* PowerPC32 default implementation of strchr.
+ Copyright (C) 2013 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+
+#ifdef SHARED
+# undef ENTRY
+# define ENTRY(name) \
+ .globl C_SYMBOL_NAME(__strchr_ppc32); \
+ .type C_SYMBOL_NAME(__strchr_ppc32),@function; \
+ .align ALIGNARG(2); \
+ C_LABEL(__strchr_ppc32) \
+ cfi_startproc; \
+ CALL_MCOUNT
+
+# undef END
+# define END(name) \
+ cfi_endproc; \
+ ASM_SIZE_DIRECTIVE(__strchr_ppc32) \
+
+# undef libc_hidden_builtin_def
+# define libc_hidden_builtin_def(name) \
+ .globl __GI_strchr; __GI_strchr = __strchr_ppc32
+#endif
+
+#include <sysdeps/powerpc/powerpc32/strchr.S>
diff --git a/sysdeps/powerpc/powerpc32/multiarch/strchr.c b/sysdeps/powerpc/powerpc32/multiarch/strchr.c
new file mode 100644
index 0000000..b22a686
--- /dev/null
+++ b/sysdeps/powerpc/powerpc32/multiarch/strchr.c
@@ -0,0 +1,35 @@
+/* Multiple versions of strchr.
+ Copyright (C) 2013 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+/* Define multiple versions only for definition in libc. */
+#if defined SHARED && !defined NOT_IN_libc
+# include <string.h>
+# include <shlib-compat.h>
+# include "init-arch.h"
+
+extern __typeof (strchr) __strchr_ppc32 attribute_hidden;
+extern __typeof (strchr) __strchr_power7 attribute_hidden;
+
+/* Avoid DWARF definition DIE on ifunc symbol so that GDB can handle
+ ifunc symbol properly. */
+libc_ifunc (strchr,
+ (hwcap & PPC_FEATURE_HAS_VSX)
+ ? __strchr_power7
+ : __strchr_ppc32);
+weak_alias (strchr, index)
+#endif
diff --git a/sysdeps/powerpc/powerpc32/power7/strchr.S b/sysdeps/powerpc/powerpc32/power7/strchr.S
deleted file mode 100644
index 0ecadb2..0000000
--- a/sysdeps/powerpc/powerpc32/power7/strchr.S
+++ /dev/null
@@ -1,200 +0,0 @@
-/* Optimized strchr implementation for PowerPC32/POWER7 using cmpb insn.
- Copyright (C) 2010-2013 Free Software Foundation, Inc.
- Contributed by Luis Machado <luisgpm@br.ibm.com>.
- This file is part of the GNU C Library.
-
- The GNU C Library is free software; you can redistribute it and/or
- modify it under the terms of the GNU Lesser General Public
- License as published by the Free Software Foundation; either
- version 2.1 of the License, or (at your option) any later version.
-
- The GNU C Library is distributed in the hope that it will be useful,
- but WITHOUT ANY WARRANTY; without even the implied warranty of
- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
- Lesser General Public License for more details.
-
- You should have received a copy of the GNU Lesser General Public
- License along with the GNU C Library; if not, see
- <http://www.gnu.org/licenses/>. */
-
-#include <sysdep.h>
-
-/* int [r3] strchr (char *s [r3], int c [r4]) */
- .machine power7
-ENTRY (strchr)
- CALL_MCOUNT
- dcbt 0,r3
- clrrwi r8,r3,2 /* Align the address to word boundary. */
- cmpwi cr7,r4,0
- lwz r12,0(r8) /* Load word from memory. */
- li r0,0 /* Word with null chars to use
- with cmpb. */
-
- rlwinm r6,r3,3,27,28 /* Calculate padding. */
-
- beq cr7,L(null_match)
-
- /* Replicate byte to word. */
- rlwimi r4,r4,8,16,23
- rlwimi r4,r4,16,0,15
-
- /* Now r4 has a word of c bytes and r0 has
- a word of null bytes. */
-
- cmpb r10,r12,r4 /* Compare each byte against c byte. */
- cmpb r11,r12,r0 /* Compare each byte against null byte. */
-
- /* Move the words left and right to discard the bits that are
- not part of the string and to bring them back as zeros. */
-
- slw r10,r10,r6
- slw r11,r11,r6
- srw r10,r10,r6
- srw r11,r11,r6
- or r5,r10,r11 /* OR the results to speed things up. */
- cmpwi cr7,r5,0 /* If r5 == 0, no c or null bytes
- have been found. */
- bne cr7,L(done)
-
- mtcrf 0x01,r8
-
- /* Are we now aligned to a doubleword boundary? If so, skip to
- the main loop. Otherwise, go through the alignment code. */
-
- bt 29,L(loop)
-
- /* Handle WORD2 of pair. */
- lwzu r12,4(r8)
- cmpb r10,r12,r4
- cmpb r11,r12,r0
- or r5,r10,r11
- cmpwi cr7,r5,0
- bne cr7,L(done)
- b L(loop) /* We branch here (rather than falling through)
- to skip the nops due to heavy alignment
- of the loop below. */
-
- .p2align 5
-L(loop):
- /* Load two words, compare and merge in a
- single register for speed. This is an attempt
- to speed up the null-checking process for bigger strings. */
- lwz r12,4(r8)
- lwzu r9,8(r8)
- cmpb r10,r12,r4
- cmpb r11,r12,r0
- cmpb r6,r9,r4
- cmpb r7,r9,r0
- or r12,r10,r11
- or r9,r6,r7
- or r5,r12,r9
- cmpwi cr7,r5,0
- beq cr7,L(loop)
-
- /* OK, one (or both) of the words contains a c/null byte. Check
- the first word and decrement the address in case the first
- word really contains a c/null byte. */
-
- cmpwi cr6,r12,0
- addi r8,r8,-4
- bne cr6,L(done)
-
- /* The c/null byte must be in the second word. Adjust the address
- again and move the result of cmpb to r10 so we can calculate the
- pointer. */
-
- mr r10,r6
- mr r11,r7
- addi r8,r8,4
-
- /* r5 has the output of the cmpb instruction, that is, it contains
- 0xff in the same position as the c/null byte in the original
- word from the string. Use that to calculate the pointer. */
-L(done):
- cntlzw r4,r10 /* Count leading zeroes before c matches. */
- cntlzw r0,r11 /* Count leading zeroes before null matches. */
- cmplw cr7,r4,r0
- bgt cr7,L(no_match)
- srwi r0,r4,3 /* Convert leading zeroes to bytes. */
- add r3,r8,r0 /* Return address of the matching c byte
- or null in case c was not found. */
- blr
-
- .align 4
-L(no_match):
- li r3,0
- blr
-
-/* We are here because strchr was called with a null byte. */
- .align 4
-L(null_match):
- /* r0 has a word of null bytes. */
-
- cmpb r5,r12,r0 /* Compare each byte against null bytes. */
-
- /* Move the words left and right to discard the bits that are
- not part of the string and to bring them back as zeros. */
-
- slw r5,r5,r6
- srw r5,r5,r6
- cmpwi cr7,r5,0 /* If r10 == 0, no c or null bytes
- have been found. */
- bne cr7,L(done_null)
-
- mtcrf 0x01,r8
-
- /* Are we now aligned to a doubleword boundary? If so, skip to
- the main loop. Otherwise, go through the alignment code. */
-
- bt 29,L(loop_null)
-
- /* Handle WORD2 of pair. */
- lwzu r12,4(r8)
- cmpb r5,r12,r0
- cmpwi cr7,r5,0
- bne cr7,L(done_null)
- b L(loop_null) /* We branch here (rather than falling through)
- to skip the nops due to heavy alignment
- of the loop below. */
-
- /* Main loop to look for the end of the string. Since it's a
- small loop (< 8 instructions), align it to 32-bytes. */
- .p2align 5
-L(loop_null):
- /* Load two words, compare and merge in a
- single register for speed. This is an attempt
- to speed up the null-checking process for bigger strings. */
- lwz r12,4(r8)
- lwzu r11,8(r8)
- cmpb r5,r12,r0
- cmpb r10,r11,r0
- or r6,r5,r10
- cmpwi cr7,r6,0
- beq cr7,L(loop_null)
-
- /* OK, one (or both) of the words contains a null byte. Check
- the first word and decrement the address in case the first
- word really contains a null byte. */
-
- cmpwi cr6,r5,0
- addi r8,r8,-4
- bne cr6,L(done_null)
-
- /* The null byte must be in the second word. Adjust the address
- again and move the result of cmpb to r10 so we can calculate the
- pointer. */
-
- mr r5,r10
- addi r8,r8,4
-
- /* r5 has the output of the cmpb instruction, that is, it contains
- 0xff in the same position as the null byte in the original
- word from the string. Use that to calculate the pointer. */
-L(done_null):
- cntlzw r0,r5 /* Count leading zeros before the match. */
- srwi r0,r0,3 /* Convert leading zeros to bytes. */
- add r3,r8,r0 /* Return address of the matching null byte. */
- blr
-END (strchr)
-weak_alias (strchr, index)
-libc_hidden_builtin_def (strchr)