[PATCH 07/36] PowerPC: memrchr multilib for PowerPC32

[Adhemerval Zanella <azanella at linux dot vnet dot ibm dot com>]

2013-08-19  Adhemerval Zanella  <azanella@linux.vnet.ibm.com>

	* sysdeps/powerpc/powerpc32/power7/memrchr.S: Move to ...
	* sysdeps/powerpc/powerpc32/multiarch/memrchr-power7.S : ... here.
	(__memrchr): Rename symbol name to __memrchr_power7 and remove the
	libc_hidden_builtin_def and weak_alias.
	* sysdeps/powerpc/powerpc32/multiarch/memrchr-ppc32.c: New file:
	default memrchr PPC32 implementation.
	* sysdeps/powerpc/powerpc32/multiarch/memrchr.c: New file: multiarch
	memrchr for PPC32.
	* sysdeps/powerpc/powerpc32/multiarch/Makefile: Added memrchr
	multiarch objects.
	* sysdeps/powerpc/powerpc32/multiarch/ifunc-impl-list
	(__libc_ifunc_impl_list): Likewise.

--

diff --git a/sysdeps/powerpc/powerpc32/multiarch/Makefile b/sysdeps/powerpc/powerpc32/multiarch/Makefile
index 9feb3c6..fde4fbf 100644
--- a/sysdeps/powerpc/powerpc32/multiarch/Makefile
+++ b/sysdeps/powerpc/powerpc32/multiarch/Makefile
@@ -3,5 +3,5 @@ sysdep_routines += memcpy-power7 memcpy-a2 memcpy-power6 memcpy-cell \
 		   memcpy-power4 memcpy-ppc32 memcmp-power7 memcmp-power4 \
 		   memcmp-ppc32 memset-power7 memset-power6 memset-power4 \
 		   memset-ppc32 mempcpy-power7 mempcpy-ppc32 memchr-power7 \
-		   memchr-ppc32
+		   memchr-ppc32 memrchr-power7 memrchr-ppc32
 endif
diff --git a/sysdeps/powerpc/powerpc32/multiarch/ifunc-impl-list.c b/sysdeps/powerpc/powerpc32/multiarch/ifunc-impl-list.c
index 279cc0b..4b3dd75 100644
--- a/sysdeps/powerpc/powerpc32/multiarch/ifunc-impl-list.c
+++ b/sysdeps/powerpc/powerpc32/multiarch/ifunc-impl-list.c
@@ -63,6 +63,13 @@ __libc_ifunc_impl_list (const char *name, struct libc_ifunc_impl *array,
 			      __memchr_power7)
 	      IFUNC_IMPL_ADD (array, i, memchr, 1,
 			      __memchr_ppc32))
+  /* Support sysdeps/powerpc/powerpc32/multiarch/memrchr.c.  */
+  IFUNC_IMPL (i, name, memrchr,
+	      IFUNC_IMPL_ADD (array, i, memrchr,
+			      hwcap & PPC_FEATURE_HAS_VSX,
+			      __memrchr_power7)
+	      IFUNC_IMPL_ADD (array, i, memrchr, 1,
+			      __memrchr_ppc32))
 
 #ifdef SHARED
   /* Support sysdeps/powerpc/powerpc32/multiarch/memset.c.  */
diff --git a/sysdeps/powerpc/powerpc32/multiarch/memrchr-power7.S b/sysdeps/powerpc/powerpc32/multiarch/memrchr-power7.S
new file mode 100644
index 0000000..0aaf017
--- /dev/null
+++ b/sysdeps/powerpc/powerpc32/multiarch/memrchr-power7.S
@@ -0,0 +1,173 @@
+/* Optimized memrchr implementation for PowerPC32/POWER7 using cmpb insn.
+   Copyright (C) 2010-2013 Free Software Foundation, Inc.
+   Contributed by Luis Machado <luisgpm@br.ibm.com>.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, see
+   <http://www.gnu.org/licenses/>.  */
+
+#include <sysdep.h>
+
+/* int [r3] memrchr (char *s [r3], int byte [r4], int size [r5])  */
+	.machine  power7
+ENTRY (__memrchr_power7)
+	CALL_MCOUNT
+	dcbt	0,r3
+	mr	r7,r3
+	add	r3,r7,r5      /* Calculate the last acceptable address.  */
+	cmplw	cr7,r3,r7     /* Is the address equal or less than r3?  */
+
+	/* Replicate BYTE to word.  */
+	rlwimi	r4,r4,8,16,23
+	rlwimi	r4,r4,16,0,15
+	bge	cr7,L(proceed)
+
+	li	r3,-1	      /* Make r11 the biggest if r4 <= 0.  */
+L(proceed):
+	li	r6,-4
+	addi	r9,r3,-1
+	clrrwi  r8,r9,2
+	addi	r8,r8,4
+	neg	r0,r3
+	rlwinm	r0,r0,3,27,28 /* Calculate padding.  */
+
+	cmplwi	r5,16
+	ble	L(small_range)
+
+	lwbrx	r12,r8,r6     /* Load reversed word from memory.  */
+	cmpb	r10,r12,r4    /* Check for BYTE in WORD1.  */
+	slw	r10,r10,r0
+	srw	r10,r10,r0
+	cmplwi	cr7,r10,0     /* If r10 == 0, no BYTEs have been found.  */
+	bne	cr7,L(done)
+
+	/* Are we done already?  */
+	addi	r9,r8,-4
+	cmplw	cr6,r9,r7
+	ble	cr6,L(null)
+
+	mtcrf   0x01,r8
+	/* Are we now aligned to a doubleword boundary?  If so, skip to
+	   the main loop.  Otherwise, go through the alignment code.  */
+	mr	r8,r9
+	bt	29,L(loop_setup)
+
+	/* Handle WORD2 of pair.  */
+	lwbrx	r12,r8,r6
+	cmpb	r10,r12,r4
+	cmplwi	cr7,r10,0
+	bne	cr7,L(done)
+
+	/* Are we done already?  */
+	addi	r8,r8,-4
+	cmplw	cr6,r8,r7
+	ble	cr6,L(null)
+
+L(loop_setup):
+	li	r0,-8
+	sub	r5,r8,r7
+	srwi	r9,r5,3	      /* Number of loop iterations.  */
+	mtctr	r9	      /* Setup the counter.  */
+	b	L(loop)
+	/* Main loop to look for BYTE backwards in the string.  Since it's a
+	   small loop (< 8 instructions), align it to 32-bytes.  */
+	.p2align  5
+L(loop):
+	/* Load two words, compare and merge in a
+	   single register for speed.  This is an attempt
+	   to speed up the byte-checking process for bigger strings.  */
+
+	lwbrx	r12,r8,r6
+	lwbrx	r11,r8,r0
+	addi	r8,r8,-4
+	cmpb	r10,r12,r4
+	cmpb	r9,r11,r4
+	or	r5,r9,r10     /* Merge everything in one word.  */
+	cmplwi	cr7,r5,0
+	bne	cr7,L(found)
+	addi	r8,r8,-4
+	bdnz	L(loop)
+	/* We're here because the counter reached 0, and that means we
+	   didn't have any matches for BYTE in the whole range.  Just return
+	   the original range.  */
+	addi	r9,r8,4
+	cmplw	cr6,r9,r7
+	bgt	cr6,L(loop_small)
+	b	L(null)
+
+	/* OK, one (or both) of the words contains BYTE.  Check
+	   the first word and decrement the address in case the first
+	   word really contains BYTE.  */
+	.align	4
+L(found):
+	cmplwi	cr6,r10,0
+	addi	r8,r8,4
+	bne	cr6,L(done)
+
+	/* BYTE must be in the second word.  Adjust the address
+	   again and move the result of cmpb to r10 so we can calculate the
+	   pointer.  */
+
+	mr	r10,r9
+	addi	r8,r8,-4
+
+	/* r10 has the output of the cmpb instruction, that is, it contains
+	   0xff in the same position as BYTE in the original
+	   word from the string.  Use that to calculate the pointer.
+	   We need to make sure BYTE is *before* the end of the
+	   range.  */
+L(done):
+	cntlzw	r0,r10	      /* Count leading zeroes before the match.  */
+	srwi	r6,r0,3	      /* Convert leading zeroes to bytes.  */
+	addi	r0,r6,1
+	sub	r3,r8,r0
+	cmplw	r3,r7
+	blt	L(null)
+	blr
+
+	.align	4
+L(null):
+	li	r3,0
+	blr
+
+/* Deals with size <= 16.  */
+	.align	4
+L(small_range):
+	cmplwi	r5,0
+	beq	L(null)
+
+	lwbrx	r12,r8,r6     /* Load reversed word from memory.  */
+	cmpb	r10,r12,r4    /* Check for null bytes in WORD1.  */
+	slw	r10,r10,r0
+	srw	r10,r10,r0
+	cmplwi	cr7,r10,0
+	bne	cr7,L(done)
+
+	addi	r8,r8,-4
+	cmplw	r8,r7
+	ble	L(null)
+	b	L(loop_small)
+
+	.p2align  5
+L(loop_small):
+	lwbrx	r12,r8,r6
+	cmpb	r10,r12,r4
+	cmplwi	cr6,r10,0
+	bne	cr6,L(done)
+	addi	r8,r8,-4
+	cmplw	r8,r7
+	ble	L(null)
+	b	L(loop_small)
+
+END (__memrchr_power7)
diff --git a/sysdeps/powerpc/powerpc32/multiarch/memrchr-ppc32.c b/sysdeps/powerpc/powerpc32/multiarch/memrchr-ppc32.c
new file mode 100644
index 0000000..19ae015
--- /dev/null
+++ b/sysdeps/powerpc/powerpc32/multiarch/memrchr-ppc32.c
@@ -0,0 +1,25 @@
+/* PowerPC32 default implementation of memrchr.
+   Copyright (C) 2013 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, see
+   <http://www.gnu.org/licenses/>.  */
+
+#ifndef NOT_IN_libc
+# define MEMRCHR  __memrchr_ppc32
+# include <string.h>
+extern void *__memrchr_ppc32 (const void *, int, size_t);
+#endif
+
+#include <string/memrchr.c>
diff --git a/sysdeps/powerpc/powerpc32/multiarch/memrchr.c b/sysdeps/powerpc/powerpc32/multiarch/memrchr.c
new file mode 100644
index 0000000..c3dde9c
--- /dev/null
+++ b/sysdeps/powerpc/powerpc32/multiarch/memrchr.c
@@ -0,0 +1,37 @@
+/* Multiple versions of memrchr.
+   Copyright (C) 2013 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, see
+   <http://www.gnu.org/licenses/>.  */
+
+#ifndef NOT_IN_libc
+# include <string.h>
+# include <shlib-compat.h>
+# include "init-arch.h"
+
+extern __typeof (__memrchr) __memrchr_ppc32 attribute_hidden;
+extern __typeof (__memrchr) __memrchr_power7 attribute_hidden;
+
+/* Avoid DWARF definition DIE on ifunc symbol so that GDB can handle
+   ifunc symbol properly.  */
+libc_ifunc (__memrchr,
+	    (hwcap & PPC_FEATURE_HAS_VSX)
+            ? __memrchr_power7
+            : __memrchr_ppc32);
+
+weak_alias (__memrchr, memrchr)
+#else
+#include <string/memrchr.c>
+#endif
diff --git a/sysdeps/powerpc/powerpc32/power7/memrchr.S b/sysdeps/powerpc/powerpc32/power7/memrchr.S
deleted file mode 100644
index d1e3fda..0000000
--- a/sysdeps/powerpc/powerpc32/power7/memrchr.S
+++ /dev/null
@@ -1,175 +0,0 @@
-/* Optimized memrchr implementation for PowerPC32/POWER7 using cmpb insn.
-   Copyright (C) 2010-2013 Free Software Foundation, Inc.
-   Contributed by Luis Machado <luisgpm@br.ibm.com>.
-   This file is part of the GNU C Library.
-
-   The GNU C Library is free software; you can redistribute it and/or
-   modify it under the terms of the GNU Lesser General Public
-   License as published by the Free Software Foundation; either
-   version 2.1 of the License, or (at your option) any later version.
-
-   The GNU C Library is distributed in the hope that it will be useful,
-   but WITHOUT ANY WARRANTY; without even the implied warranty of
-   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
-   Lesser General Public License for more details.
-
-   You should have received a copy of the GNU Lesser General Public
-   License along with the GNU C Library; if not, see
-   <http://www.gnu.org/licenses/>.  */
-
-#include <sysdep.h>
-
-/* int [r3] memrchr (char *s [r3], int byte [r4], int size [r5])  */
-	.machine  power7
-ENTRY (__memrchr)
-	CALL_MCOUNT
-	dcbt	0,r3
-	mr	r7,r3
-	add	r3,r7,r5      /* Calculate the last acceptable address.  */
-	cmplw	cr7,r3,r7     /* Is the address equal or less than r3?  */
-
-	/* Replicate BYTE to word.  */
-	rlwimi	r4,r4,8,16,23
-	rlwimi	r4,r4,16,0,15
-	bge	cr7,L(proceed)
-
-	li	r3,-1	      /* Make r11 the biggest if r4 <= 0.  */
-L(proceed):
-	li	r6,-4
-	addi	r9,r3,-1
-	clrrwi  r8,r9,2
-	addi	r8,r8,4
-	neg	r0,r3
-	rlwinm	r0,r0,3,27,28 /* Calculate padding.  */
-
-	cmplwi	r5,16
-	ble	L(small_range)
-
-	lwbrx	r12,r8,r6     /* Load reversed word from memory.  */
-	cmpb	r10,r12,r4    /* Check for BYTE in WORD1.  */
-	slw	r10,r10,r0
-	srw	r10,r10,r0
-	cmplwi	cr7,r10,0     /* If r10 == 0, no BYTEs have been found.  */
-	bne	cr7,L(done)
-
-	/* Are we done already?  */
-	addi	r9,r8,-4
-	cmplw	cr6,r9,r7
-	ble	cr6,L(null)
-
-	mtcrf   0x01,r8
-	/* Are we now aligned to a doubleword boundary?  If so, skip to
-	   the main loop.  Otherwise, go through the alignment code.  */
-	mr	r8,r9
-	bt	29,L(loop_setup)
-
-	/* Handle WORD2 of pair.  */
-	lwbrx	r12,r8,r6
-	cmpb	r10,r12,r4
-	cmplwi	cr7,r10,0
-	bne	cr7,L(done)
-
-	/* Are we done already?  */
-	addi	r8,r8,-4
-	cmplw	cr6,r8,r7
-	ble	cr6,L(null)
-
-L(loop_setup):
-	li	r0,-8
-	sub	r5,r8,r7
-	srwi	r9,r5,3	      /* Number of loop iterations.  */
-	mtctr	r9	      /* Setup the counter.  */
-	b	L(loop)
-	/* Main loop to look for BYTE backwards in the string.  Since it's a
-	   small loop (< 8 instructions), align it to 32-bytes.  */
-	.p2align  5
-L(loop):
-	/* Load two words, compare and merge in a
-	   single register for speed.  This is an attempt
-	   to speed up the byte-checking process for bigger strings.  */
-
-	lwbrx	r12,r8,r6
-	lwbrx	r11,r8,r0
-	addi	r8,r8,-4
-	cmpb	r10,r12,r4
-	cmpb	r9,r11,r4
-	or	r5,r9,r10     /* Merge everything in one word.  */
-	cmplwi	cr7,r5,0
-	bne	cr7,L(found)
-	addi	r8,r8,-4
-	bdnz	L(loop)
-	/* We're here because the counter reached 0, and that means we
-	   didn't have any matches for BYTE in the whole range.  Just return
-	   the original range.  */
-	addi	r9,r8,4
-	cmplw	cr6,r9,r7
-	bgt	cr6,L(loop_small)
-	b	L(null)
-
-	/* OK, one (or both) of the words contains BYTE.  Check
-	   the first word and decrement the address in case the first
-	   word really contains BYTE.  */
-	.align	4
-L(found):
-	cmplwi	cr6,r10,0
-	addi	r8,r8,4
-	bne	cr6,L(done)
-
-	/* BYTE must be in the second word.  Adjust the address
-	   again and move the result of cmpb to r10 so we can calculate the
-	   pointer.  */
-
-	mr	r10,r9
-	addi	r8,r8,-4
-
-	/* r10 has the output of the cmpb instruction, that is, it contains
-	   0xff in the same position as BYTE in the original
-	   word from the string.  Use that to calculate the pointer.
-	   We need to make sure BYTE is *before* the end of the
-	   range.  */
-L(done):
-	cntlzw	r0,r10	      /* Count leading zeroes before the match.  */
-	srwi	r6,r0,3	      /* Convert leading zeroes to bytes.  */
-	addi	r0,r6,1
-	sub	r3,r8,r0
-	cmplw	r3,r7
-	blt	L(null)
-	blr
-
-	.align	4
-L(null):
-	li	r3,0
-	blr
-
-/* Deals with size <= 16.  */
-	.align	4
-L(small_range):
-	cmplwi	r5,0
-	beq	L(null)
-
-	lwbrx	r12,r8,r6     /* Load reversed word from memory.  */
-	cmpb	r10,r12,r4    /* Check for null bytes in WORD1.  */
-	slw	r10,r10,r0
-	srw	r10,r10,r0
-	cmplwi	cr7,r10,0
-	bne	cr7,L(done)
-
-	addi	r8,r8,-4
-	cmplw	r8,r7
-	ble	L(null)
-	b	L(loop_small)
-
-	.p2align  5
-L(loop_small):
-	lwbrx	r12,r8,r6
-	cmpb	r10,r12,r4
-	cmplwi	cr6,r10,0
-	bne	cr6,L(done)
-	addi	r8,r8,-4
-	cmplw	r8,r7
-	ble	L(null)
-	b	L(loop_small)
-
-END (__memrchr)
-weak_alias (__memrchr, memrchr)
-libc_hidden_builtin_def (memrchr)