OUTPUT_ARCH(mips)

/**** Start point ****/
ENTRY(__reset_vector)

SECTIONS
{
  .text 0x80000000 : /*0xbf000000 :*/
  {
    _ftext = ABSOLUTE(.) ;	/* Start of code and read-only data */
    reset.o (.text)		/* Reset entry point		    */
    init.o (.text)
    _ecode = ABSOLUTE(.) ;	/* End of code 			    */
    * (.text)
    . = ALIGN(8);
    _etext_init = ABSOLUTE(.);	/* End of code and read-only data   */
  } = 0
    
  .data : 
  AT( _etext_init )
  {
    _fdata = ABSOLUTE(.);	/* Start of initialised data	    */
    *(.rodata) 
    *(.data)
    . = ALIGN(8);
    *(.lit8) 
    *(.lit4) 
    *(.sdata) 

    . = ALIGN(8);

    _edata  = ABSOLUTE(.);	/* End of initialised data	    */
  }

  /**** Uninitialised data ****/

  . = ALIGN(4);
  _fbss = .;			/* Start of unitialised data	    */
  .sbss : 
  { 
    *(.sbss) 
    *(.scommon)
  }
  .bss :
  {
    *(.bss)
    *(COMMON)
  }
  . = ALIGN(4);
  _gp = ABSOLUTE(.); /* Base of small data		    */
  _end = . ;		/* End */


  .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
  .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }

  /DISCARD/ :
  {
    *(.reginfo)
  }
}