testsuite/systemtap.pass1-4/buildok.exp

   1 set self buildok
   2 foreach file [lsort [glob -nocomplain $srcdir/$self/*.stp]] {
   3     set test $self/[file tail $file]
   4     verbose -log "Running $file"
   5     set rc [stap_run_batch $file]
   6
   7     # Use setup_kfail <pr number> <target triplet> for known bugs.
   8     #
   9     # (Note that tcl doesn't like comments directly inside the switch
  10     # statement, but comments can go in sub-blocks.)
  11     switch $test {
  12         buildok/fortyfive.stp -
  13         buildok/nd_syscalls-all-probes.stp -
  14         buildok/nd_syscalls-arch-detailed.stp -
  15         buildok/nd_syscalls-detailed.stp -
  16         buildok/nd_syscalls2-detailed.stp {
  17             # Any test that uses nd_syscalls probes do not work on ia64.
  18             if {$rc != 0 && [istarget ia64-*-*]} { setup_kfail 6971 ia64-*-* }
  19         }
  20
  21         buildok/memory-write_shared_copy.stp {
  22             if {$rc != 0} { setup_kfail 1155 *-*-* } }
  23
  24         buildok/memory-mmap.stp -
  25         buildok/memory-write_shared_copy.stp -
  26         buildok/networking-change_rx_flag.stp -
  27         buildok/nfs-fop.check_flags.stp -
  28         buildok/nfs_proc-detailed.stp -
  29         buildok/nfsd-detailed.stp -
  30         buildok/rpc-detailed.stp -
  31         buildok/scheduler-cpu_off.stp -
  32         buildok/scheduler-ctxswitch.stp -
  33         buildok/scheduler-migrate.stp -
  34         buildok/signal-check_ignored.stp -
  35         buildok/signal-handle.stp -
  36         buildok/tty-resize.stp -
  37         buildok/vfs-detailed.stp {
  38             # Use setup_kfail GCC <target triplet> for
  39             # debuginfo-quality problems.
  40             if {$rc != 0} { setup_kfail GCC *-*-* } }
  41
  42         buildok/per-process-syscall.stp -
  43         buildok/utrace.stp {
  44             # Use setup_kfail UTRACE <target triplet> for systems
  45             # without utrace.
  46             if {$rc != 0 && ![utrace_p]} { setup_kfail UTRACE *-*-*} }
  47
  48         buildok/pretty-uprobes.stp -
  49         buildok/ucontext-symbols-embedded.stp -
  50         buildok/ucontext-unwind-embedded.stp {
  51             # Use setup_kfail UPROBES <target triplet> for systems
  52             # without uprobes. (ia64 has utrace, but not uprobes.)
  53             if {$rc != 0 && ![uprobes_p]} { setup_kfail UPROBES *-*-* } }
  54
  55         buildok/twentyeightprime.stp {
  56             # Use setup_kfail UPROBES <target triplet> for systems
  57             # without uprobes. (ia64 has utrace, but not uprobes.)
  58             if {$rc != 0 && ![uprobes_p]} { setup_kfail UPROBES *-*-* }
  59
  60             # Use setup_kfail INODE_UPROBES <target triplet> for
  61             # systems with inode uprobes, where absolute probes don't
  62             # work.
  63             if {$rc != 0 && [inode_uprobes_p]} {
  64                 setup_kfail INODE_UPROBES *-*-* }
  65         }
  66
  67         buildok/context-symbols-embedded.stp -
  68         buildok/context-unwind-embedded.stp {
  69             # Use setup_kfail UNWIND <target triplet> for systems
  70             # with an unsupported dwarf unwind architecture
  71             if {$rc != 0 && [istarget ia64-*-*]} {
  72                 setup_kfail UNWIND ia64-*-* } }
  73
  74         buildok/fortyseven.stp {
  75             if {$rc != 0} { setup_kfail 15065 *-*-* } }
  76     }
  77     if {$rc == 0} { pass $test } else { fail $test }
  78 }