sysdeps/unix/sysv/linux/alpha/getitimer.S

   1 /* Copyright (C) 1998 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Library General Public License as
   6    published by the Free Software Foundation; either version 2 of the
   7    License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Library General Public License for more details.
  13
  14    You should have received a copy of the GNU Library General Public
  15    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  16    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  17    Boston, MA 02111-1307, USA.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22
  23 /* The problem here is that initially we made struct timeval compatible with
  24    OSF/1, using int32.  But we defined time_t with uint64, and later found
  25    that POSIX requires tv_sec to be time_t.
  26
  27    So now we have to do compatibility stuff.  */
  28
  29 /* The variable is shared between all wrappers around signal handling
  30    functions which have RT equivalents.  */
  31 .comm __libc_missing_axp_tv64, 4
  32
  33 .text
  34
  35 #if defined HAVE_ELF && defined PIC && defined DO_VERSIONING
  36 #define GETITIMER       __getitimer_tv64
  37 #else
  38 #define GETITIMER       getitimer
  39 #endif
  40
  41 LEAF(GETITIMER, 16)
  42         ldgp    gp, 0(pv)
  43         subq    sp, 16, sp
  44 #ifdef PROF
  45         .set noat
  46         lda     AT, _mcount
  47         jsr     AT, (AT), _mcount
  48         .set at
  49 #endif
  50         .prologue 1
  51
  52         ldl     t0, __libc_missing_axp_tv64
  53
  54         /* Save arguments in case we do need to fall back.  */
  55         stq     a0, 0(sp)
  56         stq     a1, 8(sp)
  57
  58         bne     t0, $do32
  59
  60         ldi     v0, SYS_ify(getitimer)
  61         callsys
  62         bne     a3, $err64
  63
  64         /* Everything ok.  */
  65         addq    sp, 16, sp
  66         ret
  67
  68         /* If we didn't get ENOSYS, it is a real error.  */
  69         .align 3
  70 $err64: cmpeq   v0, ENOSYS, t0
  71         beq     t0, $error
  72         stl     t0, __libc_missing_axp_tv64
  73
  74         /* Recover the saved arguments.  */
  75         ldq     a1, 8(sp)
  76         ldq     a0, 0(sp)
  77
  78         .align 3
  79 $do32:  ldi     v0, SYS_ify(osf_getitimer)
  80         callsys
  81         bne     a3, $error
  82
  83         /* Copy back to proper format.  */
  84         ldq     a1, 8(sp)
  85         ldl     t0, 0(a1)
  86         ldl     t1, 4(a1)
  87         ldl     t2, 8(a1)
  88         ldl     t3, 12(a1)
  89         stq     t0, 0(a1)
  90         stq     t1, 8(a1)
  91         stq     t2, 16(a1)
  92         stq     t3, 24(a1)
  93
  94         addq    sp, 16, sp
  95         ret
  96
  97         .align 3
  98 $error:
  99         lda     pv, __syscall_error
 100         addq    sp, 16, sp
 101         jmp     zero, (pv), __syscall_error
 102
 103 END(GETITIMER)
 104
 105 #if defined HAVE_ELF && defined PIC && defined DO_VERSIONING
 106 default_symbol_version (__getitimer_tv64, getitimer, GLIBC_2.1)
 107 #endif