sysdeps/i386/i686/multiarch/bzero.S

   1 /* Multiple versions of bzero
   2    Copyright (C) 2010, 2012 Free Software Foundation, Inc.
   3    Contributed by Intel Corporation.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22 #include <init-arch.h>
  23
  24 /* Define multiple versions only for the definition in lib.  */
  25 #ifndef NOT_IN_libc
  26 # ifdef SHARED
  27         .text
  28 ENTRY(__bzero)
  29         .type   __bzero, @gnu_indirect_function
  30         pushl   %ebx
  31         cfi_adjust_cfa_offset (4)
  32         cfi_rel_offset (ebx, 0)
  33         LOAD_PIC_REG(bx)
  34         cmpl    $0, KIND_OFFSET+__cpu_features@GOTOFF(%ebx)
  35         jne     1f
  36         call    __init_cpu_features
  37 1:      leal    __bzero_ia32@GOTOFF(%ebx), %eax
  38         testl   $bit_SSE2, CPUID_OFFSET+index_SSE2+__cpu_features@GOTOFF(%ebx)
  39         jz      2f
  40         leal    __bzero_sse2@GOTOFF(%ebx), %eax
  41         testl   $bit_Fast_Rep_String, FEATURE_OFFSET+index_Fast_Rep_String+__cpu_features@GOTOFF(%ebx)
  42         jz      2f
  43         leal    __bzero_sse2_rep@GOTOFF(%ebx), %eax
  44 2:      popl    %ebx
  45         cfi_adjust_cfa_offset (-4)
  46         cfi_restore (ebx)
  47         ret
  48 END(__bzero)
  49 # else
  50         .text
  51 ENTRY(__bzero)
  52         .type   __bzero, @gnu_indirect_function
  53         cmpl    $0, KIND_OFFSET+__cpu_features
  54         jne     1f
  55         call    __init_cpu_features
  56 1:      leal    __bzero_ia32, %eax
  57         testl   $bit_SSE2, CPUID_OFFSET+index_SSE2+__cpu_features
  58         jz      2f
  59         leal    __bzero_sse2, %eax
  60         testl   $bit_Fast_Rep_String, FEATURE_OFFSET+index_Fast_Rep_String+__cpu_features
  61         jz      2f
  62         leal    __bzero_sse2_rep, %eax
  63 2:      ret
  64 END(__bzero)
  65 # endif
  66
  67 # undef ENTRY
  68 # define ENTRY(name) \
  69         .type __bzero_ia32, @function; \
  70         .p2align 4; \
  71         __bzero_ia32: cfi_startproc; \
  72         CALL_MCOUNT
  73 # undef END
  74 # define END(name) \
  75         cfi_endproc; .size __bzero_ia32, .-__bzero_ia32
  76
  77 # ifdef SHARED
  78 #  undef libc_hidden_builtin_def
  79 /* IFUNC doesn't work with the hidden functions in shared library since
  80    they will be called without setting up EBX needed for PLT which is
  81    used by IFUNC.  */
  82 #  define libc_hidden_builtin_def(name) \
  83         .globl __GI___bzero; __GI___bzero = __bzero_ia32
  84 # endif
  85 #endif
  86
  87 #include "../bzero.S"