libgloss/mips/pmon.ld

   1 /* The following TEXT start address leaves space for the monitor
   2    workspace. */
   3
   4 ENTRY(_start)
   5 OUTPUT_ARCH("mips:4000")
   6 OUTPUT_FORMAT("elf32-bigmips", "elf32-bigmips", "elf32-littlemips")
   7 GROUP(-lc -lpmon -lgcc)
   8 SEARCH_DIR(.)
   9 __DYNAMIC  =  0;
  10
  11 /*
  12  * Allocate the stack to be at the top of memory, since the stack
  13  * grows down
  14  */
  15 PROVIDE (__stack = 0);
  16 /* PROVIDE (__global = 0); */
  17
  18 /*
  19  * Initalize some symbols to be zero so we can reference them in the
  20  * crt0 without core dumping. These functions are all optional, but
  21  * we do this so we can have our crt0 always use them if they exist.
  22  * This is so BSPs work better when using the crt0 installed with gcc.
  23  * We have to initalize them twice, so we multiple object file
  24  * formats, as some prepend an underscore.
  25  */
  26 PROVIDE (hardware_init_hook = 0);
  27 PROVIDE (software_init_hook = 0);
  28
  29 SECTIONS
  30 {
  31   . = 0xA0020000;
  32   .text : {
  33      _ftext = . ;
  34     *(.init)
  35      eprol  =  .;
  36     *(.text)
  37     *(.text.*)
  38     *(.gnu.linkonce.t*)
  39     *(.mips16.fn.*)
  40     *(.mips16.call.*)
  41     PROVIDE (__runtime_reloc_start = .);
  42     *(.rel.sdata)
  43     PROVIDE (__runtime_reloc_stop = .);
  44     *(.fini)
  45      etext  =  .;
  46      _etext  =  .;
  47   }
  48
  49   .ctors    :
  50   {
  51     /* gcc uses crtbegin.o to find the start of
  52        the constructors, so we make sure it is
  53        first.  Because this is a wildcard, it
  54        doesn't matter if the user does not
  55        actually link against crtbegin.o; the
  56        linker won't look for a file to match a
  57        wildcard.  The wildcard also means that it
  58        doesn't matter which directory crtbegin.o
  59        is in.  */
  60
  61     KEEP (*crtbegin.o(.ctors))
  62
  63     /* We don't want to include the .ctor section from
  64        from the crtend.o file until after the sorted ctors.
  65        The .ctor section from the crtend file contains the
  66        end of ctors marker and it must be last */
  67
  68     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
  69     KEEP (*(SORT(.ctors.*)))
  70     KEEP (*(.ctors))
  71   }
  72
  73   .dtors    :
  74   {
  75     KEEP (*crtbegin.o(.dtors))
  76     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
  77     KEEP (*(SORT(.dtors.*)))
  78     KEEP (*(.dtors))
  79   }
  80
  81   . = .;
  82   .rodata : {
  83     *(.rdata)
  84     *(.rodata)
  85     *(.rodata.*)
  86     *(.gnu.linkonce.r*)
  87   }
  88    _fdata = ALIGN(16);
  89   .data : {
  90     *(.data)
  91     *(.data.*)
  92     *(.gnu.linkonce.d*)
  93   }
  94   . = ALIGN(8);
  95   _gp = . + 0x8000;
  96   __global = _gp;
  97   .lit8 : {
  98     *(.lit8)
  99   }
 100   .lit4 : {
 101     *(.lit4)
 102   }
 103   .sdata : {
 104     *(.sdata)
 105     *(.sdata.*)
 106     *(.gnu.linkonce.s*)
 107   }
 108   . = ALIGN(4);
 109    edata  =  .;
 110    _edata  =  .;
 111    _fbss = .;
 112   .sbss : {
 113     *(.sbss)
 114     *(.scommon)
 115   }
 116   .bss : {
 117     _bss_start = . ;
 118     *(.bss)
 119     *(COMMON)
 120   }
 121
 122    end = .;
 123    _end = .;
 124
 125   /* DWARF debug sections.
 126      Symbols in the DWARF debugging sections are relative to
 127      the beginning of the section so we begin them at 0.  */
 128
 129   /* DWARF 1 */
 130   .debug          0 : { *(.debug) }
 131   .line           0 : { *(.line) }
 132
 133   /* GNU DWARF 1 extensions */
 134   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 135   .debug_sfnames  0 : { *(.debug_sfnames) }
 136
 137   /* DWARF 1.1 and DWARF 2 */
 138   .debug_aranges  0 : { *(.debug_aranges) }
 139   .debug_pubnames 0 : { *(.debug_pubnames) }
 140
 141   /* DWARF 2 */
 142   .debug_info     0 : { *(.debug_info) }
 143   .debug_abbrev   0 : { *(.debug_abbrev) }
 144   .debug_line     0 : { *(.debug_line) }
 145   .debug_frame    0 : { *(.debug_frame) }
 146   .debug_str      0 : { *(.debug_str) }
 147   .debug_loc      0 : { *(.debug_loc) }
 148   .debug_macinfo  0 : { *(.debug_macinfo) }
 149
 150   /* SGI/MIPS DWARF 2 extensions */
 151   .debug_weaknames 0 : { *(.debug_weaknames) }
 152   .debug_funcnames 0 : { *(.debug_funcnames) }
 153   .debug_typenames 0 : { *(.debug_typenames) }
 154   .debug_varnames  0 : { *(.debug_varnames) }
 155 }