libgloss/mips/lsi.ld

   1 /* The following TEXT start address leaves space for the monitor
   2    workspace. */
   3
   4 ENTRY(_start)
   5 OUTPUT_ARCH("mips:4000")
   6 OUTPUT_FORMAT("elf32-bigmips", "elf32-bigmips", "elf32-littlemips")
   7 GROUP(-lc -llsi -lgcc)
   8 SEARCH_DIR(.)
   9 __DYNAMIC  =  0;
  10
  11 /*
  12  * Allocate the stack to be at the top of memory, since the stack
  13  * grows down
  14  */
  15 PROVIDE (__stack = 0);
  16 /* PROVIDE (__global = 0); */
  17
  18 /*
  19  * Initalize some symbols to be zero so we can reference them in the
  20  * crt0 without core dumping. These functions are all optional, but
  21  * we do this so we can have our crt0 always use them if they exist.
  22  * This is so BSPs work better when using the crt0 installed with gcc.
  23  * We have to initalize them twice, so we multiple object file
  24  * formats, as some prepend an underscore.
  25  */
  26 PROVIDE (hardware_init_hook = 0);
  27 PROVIDE (software_init_hook = 0);
  28
  29 SECTIONS
  30 {
  31   . = 0xA0020000;
  32   .text : {
  33      _ftext = . ;
  34     *(.init)
  35      eprol  =  .;
  36     *(.text)
  37     *(.text.*)
  38     *(.gnu.linkonce.t*)
  39     PROVIDE (__runtime_reloc_start = .);
  40     *(.rel.sdata)
  41     PROVIDE (__runtime_reloc_stop = .);
  42     *(.fini)
  43      etext  =  .;
  44      _etext  =  .;
  45   }
  46
  47   .ctors    :
  48   {
  49     /* gcc uses crtbegin.o to find the start of
  50        the constructors, so we make sure it is
  51        first.  Because this is a wildcard, it
  52        doesn't matter if the user does not
  53        actually link against crtbegin.o; the
  54        linker won't look for a file to match a
  55        wildcard.  The wildcard also means that it
  56        doesn't matter which directory crtbegin.o
  57        is in.  */
  58
  59     KEEP (*crtbegin.o(.ctors))
  60
  61     /* We don't want to include the .ctor section from
  62        from the crtend.o file until after the sorted ctors.
  63        The .ctor section from the crtend file contains the
  64        end of ctors marker and it must be last */
  65
  66     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
  67     KEEP (*(SORT(.ctors.*)))
  68     KEEP (*(.ctors))
  69   }
  70
  71   .dtors    :
  72   {
  73     KEEP (*crtbegin.o(.dtors))
  74     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
  75     KEEP (*(SORT(.dtors.*)))
  76     KEEP (*(.dtors))
  77   }
  78
  79   . = .;
  80   .rodata : {
  81     *(.rdata)
  82     *(.rodata)
  83     *(.rodata.*)
  84     *(.gnu.linkonce.r*)
  85   }
  86    _fdata = ALIGN(16);
  87   .data : {
  88     *(.data)
  89     *(.data.*)
  90     *(.gnu.linkonce.d*)
  91     CONSTRUCTORS
  92   }
  93   . = ALIGN(8);
  94   _gp = . + 0x8000;
  95   __global = _gp;
  96   .lit8 : {
  97     *(.lit8)
  98   }
  99   .lit4 : {
 100     *(.lit4)
 101   }
 102   .sdata : {
 103     *(.sdata)
 104     *(.sdata.*)
 105     *(.gnu.linkonce.s*)
 106   }
 107    edata  =  .;
 108    _edata  =  .;
 109    _fbss = .;
 110   .sbss : {
 111     *(.sbss)
 112     *(.scommon)
 113   }
 114   .bss : {
 115     _bss_start = . ;
 116     *(.bss)
 117     *(COMMON)
 118   }
 119    end = .;
 120    _end = .;
 121 }