libgloss/mips/dve.ld

   1 /* Linker script for Densan DVE-R3900/20A board */
   2
   3 ENTRY(_start)
   4 STARTUP(crt0.o)
   5 OUTPUT_ARCH("mips:3000")
   6 OUTPUT_FORMAT("elf32-bigmips", "elf32-bigmips", "elf32-littlemips")
   7 GROUP(-lc -ldve -lgcc)
   8 SEARCH_DIR(.)
   9 __DYNAMIC  =  0;
  10
  11 /*
  12  * Allocate the stack to be at the top of memory, since the stack
  13  * grows down
  14  */
  15 PROVIDE (__stack = 0);
  16 /* PROVIDE (__global = 0); */
  17
  18 /*
  19  * Initalize some symbols to be zero so we can reference them in the
  20  * crt0 without core dumping. These functions are all optional, but
  21  * we do this so we can have our crt0 always use them if they exist.
  22  * This is so BSPs work better when using the crt0 installed with gcc.
  23  * We have to initalize them twice, so we multiple object file
  24  * formats, as some prepend an underscore.
  25  */
  26 PROVIDE (hardware_exit_hook = 0);
  27 PROVIDE (hardware_hazard_hook = 0);
  28 PROVIDE (hardware_init_hook = 0);
  29 PROVIDE (software_init_hook = 0);
  30
  31 SECTIONS
  32 {
  33   . = 0xA0040000;
  34   .text : {
  35      _ftext = . ;
  36     KEEP (*(.init))
  37      eprol  =  .;
  38     *(.text)
  39     *(.text.*)
  40     *(.gnu.linkonce.t.*)
  41     *(.mips16.fn.*)
  42     *(.mips16.call.*)
  43     PROVIDE (__runtime_reloc_start = .);
  44     *(.rel.sdata)
  45     PROVIDE (__runtime_reloc_stop = .);
  46     KEEP (*(.fini))
  47      etext  =  .;
  48      _etext  =  .;
  49   }
  50
  51   .eh_frame_hdr : { *(.eh_frame_hdr) }
  52   .eh_frame : { KEEP (*(.eh_frame)) }
  53   .gcc_except_table : { *(.gcc_except_table) }
  54   .jcr : { KEEP (*(.jcr)) }
  55   .ctors    :
  56   {
  57     /* gcc uses crtbegin.o to find the start of
  58        the constructors, so we make sure it is
  59        first.  Because this is a wildcard, it
  60        doesn't matter if the user does not
  61        actually link against crtbegin.o; the
  62        linker won't look for a file to match a
  63        wildcard.  The wildcard also means that it
  64        doesn't matter which directory crtbegin.o
  65        is in.  */
  66
  67     KEEP (*crtbegin.o(.ctors))
  68
  69     /* We don't want to include the .ctor section from
  70        from the crtend.o file until after the sorted ctors.
  71        The .ctor section from the crtend file contains the
  72        end of ctors marker and it must be last */
  73
  74     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
  75     KEEP (*(SORT(.ctors.*)))
  76     KEEP (*(.ctors))
  77   }
  78
  79   .dtors    :
  80   {
  81     KEEP (*crtbegin.o(.dtors))
  82     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
  83     KEEP (*(SORT(.dtors.*)))
  84     KEEP (*(.dtors))
  85   }
  86
  87   . = .;
  88   .rodata : {
  89     *(.rdata)
  90     *(.rodata)
  91     *(.rodata.*)
  92     *(.gnu.linkonce.r.*)
  93   }
  94    _fdata = ALIGN(16);
  95   .data : {
  96     *(.data)
  97     *(.data.*)
  98     *(.gnu.linkonce.d.*)
  99       CONSTRUCTORS
 100   }
 101   . = ALIGN(8);
 102   _gp = . + 0x8000;
 103   __global = _gp;
 104   .lit8 : {
 105     *(.lit8)
 106   }
 107   .lit4 : {
 108     *(.lit4)
 109   }
 110   .sdata : {
 111     *(.sdata)
 112     *(.sdata.*)
 113     *(.gnu.linkonce.s.*)
 114   }
 115   . = ALIGN(4);
 116    edata  =  .;
 117    _edata  =  .;
 118    _fbss = .;
 119   .sbss : {
 120     *(.sbss)
 121     *(.sbss.*)
 122     *(.gnu.linkonce.sb.*)
 123     *(.scommon)
 124   }
 125   .bss : {
 126     _bss_start = . ;
 127     *(.bss)
 128     *(.bss.*)
 129     *(.gnu.linkonce.b.*)
 130     *(COMMON)
 131   }
 132
 133    end = .;
 134    _end = .;
 135
 136   /* DWARF debug sections.
 137      Symbols in the DWARF debugging sections are relative to
 138      the beginning of the section so we begin them at 0.  */
 139
 140   /* DWARF 1 */
 141   .debug          0 : { *(.debug) }
 142   .line           0 : { *(.line) }
 143
 144   /* GNU DWARF 1 extensions */
 145   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 146   .debug_sfnames  0 : { *(.debug_sfnames) }
 147
 148   /* DWARF 1.1 and DWARF 2 */
 149   .debug_aranges  0 : { *(.debug_aranges) }
 150   .debug_pubnames 0 : { *(.debug_pubnames) }
 151
 152   /* DWARF 2 */
 153   .debug_info     0 : { *(.debug_info) }
 154   .debug_abbrev   0 : { *(.debug_abbrev) }
 155   .debug_line     0 : { *(.debug_line) }
 156   .debug_frame    0 : { *(.debug_frame) }
 157   .debug_str      0 : { *(.debug_str) }
 158   .debug_loc      0 : { *(.debug_loc) }
 159   .debug_macinfo  0 : { *(.debug_macinfo) }
 160   .debug_ranges   0 : { *(.debug_ranges) }
 161
 162   /* SGI/MIPS DWARF 2 extensions */
 163   .debug_weaknames 0 : { *(.debug_weaknames) }
 164   .debug_funcnames 0 : { *(.debug_funcnames) }
 165   .debug_typenames 0 : { *(.debug_typenames) }
 166   .debug_varnames  0 : { *(.debug_varnames) }
 167 }