configure.in

   1 ###############################################################################
   2 ## Copyright (C) 2000-2004 Sistina Software, Inc. All rights reserved.
   3 ## Copyright (C) 2004-2009 Red Hat, Inc. All rights reserved.
   4 ##
   5 ## This copyrighted material is made available to anyone wishing to use,
   6 ## modify, copy, or redistribute it subject to the terms and conditions
   7 ## of the GNU General Public License v.2.
   8 ##
   9 ## You should have received a copy of the GNU General Public License
  10 ## along with this program; if not, write to the Free Software Foundation,
  11 ## Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  12 ################################################################################
  13
  14 AC_PREREQ(2.57)
  15 ################################################################################
  16 dnl -- Process this file with autoconf to produce a configure script.
  17 AC_INIT
  18 AC_CONFIG_SRCDIR([lib/device/dev-cache.h])
  19 AC_CONFIG_HEADERS([lib/misc/configure.h])
  20
  21 ################################################################################
  22 dnl -- Setup the directory where autoconf has auxilary files
  23 AC_CONFIG_AUX_DIR(autoconf)
  24
  25 ################################################################################
  26 dnl -- Get system type
  27 AC_CANONICAL_TARGET([])
  28
  29 case "$host_os" in
  30         linux*)
  31                 CFLAGS="$CFLAGS"
  32                 COPTIMISE_FLAG="-O2"
  33                 CLDFLAGS="$CLDFLAGS -Wl,--version-script,.export.sym"
  34                 CLDWHOLEARCHIVE="-Wl,-whole-archive"
  35                 CLDNOWHOLEARCHIVE="-Wl,-no-whole-archive"
  36                 LDDEPS="$LDDEPS .export.sym"
  37                 LDFLAGS="$LDFLAGS -Wl,--export-dynamic"
  38                 LIB_SUFFIX=so
  39                 DEVMAPPER=yes
  40                 ODIRECT=yes
  41                 DM_IOCTLS=yes
  42                 SELINUX=yes
  43                 REALTIME=yes
  44                 CLUSTER=internal
  45                 FSADM=yes
  46                 ;;
  47         darwin*)
  48                 CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
  49                 COPTIMISE_FLAG="-O2"
  50                 CLDFLAGS="$CLDFLAGS"
  51                 CLDWHOLEARCHIVE="-all_load"
  52                 CLDNOWHOLEARCHIVE=
  53                 LIB_SUFFIX=dylib
  54                 DEVMAPPER=yes
  55                 ODIRECT=no
  56                 DM_IOCTLS=no
  57                 SELINUX=no
  58                 REALTIME=no
  59                 CLUSTER=none
  60                 FSADM=no
  61                 ;;
  62 esac
  63
  64 ################################################################################
  65 dnl -- Checks for programs.
  66 AC_PROG_SED
  67 AC_PROG_AWK
  68 AC_PROG_CC
  69
  70 dnl probably no longer needed in 2008, but...
  71 AC_PROG_GCC_TRADITIONAL
  72 AC_PROG_INSTALL
  73 AC_PROG_LN_S
  74 AC_PROG_MAKE_SET
  75 AC_PROG_MKDIR_P
  76 AC_PROG_RANLIB
  77 AC_PATH_PROG(CFLOW_CMD, cflow)
  78 AC_PATH_PROG(CSCOPE_CMD, cscope)
  79
  80 ################################################################################
  81 dnl -- Check for header files.
  82 AC_HEADER_DIRENT
  83 AC_HEADER_STDC
  84 AC_HEADER_SYS_WAIT
  85 AC_HEADER_TIME
  86
  87 AC_CHECK_HEADERS([locale.h stddef.h syslog.h sys/file.h sys/time.h assert.h \
  88   libgen.h signal.h sys/mman.h sys/resource.h sys/utsname.h sys/wait.h time.h], ,
  89   [AC_MSG_ERROR(bailing out)])
  90
  91 case "$host_os" in
  92         linux*)
  93                 AC_CHECK_HEADERS(asm/byteorder.h linux/fs.h malloc.h,,AC_MSG_ERROR(bailing out)) ;;
  94         darwin*)
  95                 AC_CHECK_HEADERS(machine/endian.h sys/disk.h,,AC_MSG_ERROR(bailing out)) ;;
  96 esac
  97
  98 AC_CHECK_HEADERS([ctype.h dirent.h errno.h fcntl.h getopt.h inttypes.h limits.h \
  99   stdarg.h stdio.h stdlib.h string.h sys/ioctl.h sys/param.h sys/stat.h \
 100   sys/types.h unistd.h], , [AC_MSG_ERROR(bailing out)])
 101 AC_CHECK_HEADERS(termios.h sys/statvfs.h)
 102
 103 ################################################################################
 104 dnl -- Check for typedefs, structures, and compiler characteristics.
 105 AC_C_CONST
 106 AC_C_INLINE
 107 AC_CHECK_MEMBERS([struct stat.st_rdev])
 108 AC_TYPE_OFF_T
 109 AC_TYPE_PID_T
 110 AC_TYPE_SIGNAL
 111 AC_TYPE_SIZE_T
 112 AC_TYPE_MODE_T
 113 AC_CHECK_MEMBERS([struct stat.st_rdev])
 114 AC_STRUCT_TM
 115
 116 ################################################################################
 117 dnl -- Check for functions
 118 AC_CHECK_FUNCS([gethostname getpagesize memset mkdir rmdir munmap setlocale \
 119   strcasecmp strchr strdup strncasecmp strerror strrchr strstr strtol strtoul \
 120   uname], , [AC_MSG_ERROR(bailing out)])
 121 AC_FUNC_ALLOCA
 122 AC_FUNC_CLOSEDIR_VOID
 123 AC_FUNC_FORK
 124 AC_FUNC_LSTAT
 125 AC_FUNC_MALLOC
 126 AC_FUNC_MEMCMP
 127 AC_FUNC_MMAP
 128 AC_FUNC_STAT
 129 AC_FUNC_STRTOD
 130 AC_FUNC_VPRINTF
 131
 132 ################################################################################
 133 dnl -- Enables statically-linked tools
 134 AC_MSG_CHECKING(whether to use static linking)
 135 AC_ARG_ENABLE(static_link,
 136   [  --enable-static_link    Use this to link the tools to their libraries
 137                           statically.  Default is dynamic linking],
 138   STATIC_LINK=$enableval, STATIC_LINK=no)
 139 AC_MSG_RESULT($STATIC_LINK)
 140
 141 ################################################################################
 142 dnl -- Prefix is /usr by default, the exec_prefix default is setup later
 143 AC_PREFIX_DEFAULT(/usr)
 144
 145 ################################################################################
 146 dnl -- Setup the ownership of the files
 147 AC_MSG_CHECKING(file owner)
 148 OWNER="root"
 149
 150 AC_ARG_WITH(user,
 151   [  --with-user=USER        Set the owner of installed files [[USER=root]] ],
 152   [ OWNER="$withval" ])
 153 AC_MSG_RESULT($OWNER)
 154
 155 if test x$OWNER != x; then
 156         OWNER="-o $OWNER"
 157 fi
 158
 159 ################################################################################
 160 dnl -- Setup the group ownership of the files
 161 AC_MSG_CHECKING(group owner)
 162 GROUP="root"
 163 AC_ARG_WITH(group,
 164   [  --with-group=GROUP      Set the group owner of installed files [[GROUP=root]] ],
 165   [ GROUP="$withval" ])
 166 AC_MSG_RESULT($GROUP)
 167
 168 if test x$GROUP != x; then
 169         GROUP="-g $GROUP"
 170 fi
 171
 172 ################################################################################
 173 dnl -- Setup device node ownership
 174 AC_MSG_CHECKING(device node uid)
 175
 176 AC_ARG_WITH(device-uid,
 177   [  --with-device-uid=UID   Set the owner used for new device nodes [[UID=0]] ],
 178   [ DM_DEVICE_UID="$withval" ], [ DM_DEVICE_UID="0" ] )
 179 AC_MSG_RESULT($DM_DEVICE_UID)
 180
 181 ################################################################################
 182 dnl -- Setup device group ownership
 183 AC_MSG_CHECKING(device node gid)
 184
 185 AC_ARG_WITH(device-gid,
 186   [  --with-device-gid=UID   Set the group used for new device nodes [[GID=0]] ],
 187   [ DM_DEVICE_GID="$withval" ], [ DM_DEVICE_GID="0" ] )
 188 AC_MSG_RESULT($DM_DEVICE_GID)
 189
 190 ################################################################################
 191 dnl -- Setup device mode
 192 AC_MSG_CHECKING(device node mode)
 193
 194 AC_ARG_WITH(device-mode,
 195   [  --with-device-mode=MODE Set the mode used for new device nodes [[MODE=0600]] ],
 196   [ DM_DEVICE_MODE="$withval" ], [ DM_DEVICE_MODE="0600" ] )
 197 AC_MSG_RESULT($DM_DEVICE_MODE)
 198
 199 ################################################################################
 200 dnl -- LVM1 tool fallback option
 201 AC_MSG_CHECKING(whether to enable lvm1 fallback)
 202 AC_ARG_ENABLE(lvm1_fallback, [  --enable-lvm1_fallback  Use this to fall back and use LVM1 binaries if
 203                           device-mapper is missing from the kernel],  LVM1_FALLBACK=$enableval, LVM1_FALLBACK=no)
 204 AC_MSG_RESULT($LVM1_FALLBACK)
 205
 206 if test x$LVM1_FALLBACK = xyes; then
 207         AC_DEFINE([LVM1_FALLBACK], 1, [Define to 1 if 'lvm' should fall back to using LVM1 binaries if device-mapper is missing from the kernel])
 208 fi
 209
 210 ################################################################################
 211 dnl -- format1 inclusion type
 212 AC_MSG_CHECKING(whether to include support for lvm1 metadata)
 213 AC_ARG_WITH(lvm1,
 214   [  --with-lvm1=TYPE        LVM1 metadata support: internal/shared/none
 215                           [TYPE=internal] ],
 216   [ LVM1="$withval" ],
 217   [ LVM1="internal" ])
 218 AC_MSG_RESULT($LVM1)
 219
 220 if [[ "x$LVM1" != xnone -a "x$LVM1" != xinternal -a "x$LVM1" != xshared ]];
 221  then  AC_MSG_ERROR(
 222 --with-lvm1 parameter invalid
 223 )
 224 fi;
 225
 226 if test x$LVM1 = xinternal; then
 227         AC_DEFINE([LVM1_INTERNAL], 1, [Define to 1 to include built-in support for LVM1 metadata.])
 228 fi
 229
 230 ################################################################################
 231 dnl -- format_pool inclusion type
 232 AC_MSG_CHECKING(whether to include support for GFS pool metadata)
 233 AC_ARG_WITH(pool,
 234   [  --with-pool=TYPE        GFS pool read-only support: internal/shared/none
 235                           [TYPE=internal] ],
 236   [ POOL="$withval" ],
 237   [ POOL="internal" ])
 238 AC_MSG_RESULT($POOL)
 239
 240 if [[ "x$POOL" != xnone -a "x$POOL" != xinternal -a "x$POOL" != xshared ]];
 241  then  AC_MSG_ERROR(
 242 --with-pool parameter invalid
 243 )
 244 fi;
 245
 246 if test x$POOL = xinternal; then
 247         AC_DEFINE([POOL_INTERNAL], 1, [Define to 1 to include built-in support for GFS pool metadata.])
 248 fi
 249
 250 ################################################################################
 251 dnl -- cluster_locking inclusion type
 252 AC_MSG_CHECKING(whether to include support for cluster locking)
 253 AC_ARG_WITH(cluster,
 254   [  --with-cluster=TYPE     Cluster LVM locking support: internal/shared/none
 255                           [TYPE=internal] ],
 256   [ CLUSTER="$withval" ])
 257 AC_MSG_RESULT($CLUSTER)
 258
 259 if [[ "x$CLUSTER" != xnone -a "x$CLUSTER" != xinternal -a "x$CLUSTER" != xshared ]];
 260  then  AC_MSG_ERROR(
 261 --with-cluster parameter invalid
 262 )
 263 fi;
 264
 265 if test x$CLUSTER = xinternal; then
 266         AC_DEFINE([CLUSTER_LOCKING_INTERNAL], 1, [Define to 1 to include built-in support for clustered LVM locking.])
 267 fi
 268
 269 ################################################################################
 270 dnl -- snapshots inclusion type
 271 AC_MSG_CHECKING(whether to include snapshots)
 272 AC_ARG_WITH(snapshots,
 273   [  --with-snapshots=TYPE   Snapshot support: internal/shared/none
 274                           [TYPE=internal] ],
 275   [ SNAPSHOTS="$withval" ],
 276   [ SNAPSHOTS="internal" ])
 277 AC_MSG_RESULT($SNAPSHOTS)
 278
 279 if [[ "x$SNAPSHOTS" != xnone -a "x$SNAPSHOTS" != xinternal -a "x$SNAPSHOTS" != xshared ]];
 280  then  AC_MSG_ERROR(
 281 --with-snapshots parameter invalid
 282 )
 283 fi;
 284
 285 if test x$SNAPSHOTS = xinternal; then
 286         AC_DEFINE([SNAPSHOT_INTERNAL], 1, [Define to 1 to include built-in support for snapshots.])
 287 fi
 288
 289 ################################################################################
 290 dnl -- mirrors inclusion type
 291 AC_MSG_CHECKING(whether to include mirrors)
 292 AC_ARG_WITH(mirrors,
 293   [  --with-mirrors=TYPE     Mirror support: internal/shared/none
 294                           [TYPE=internal] ],
 295   [ MIRRORS="$withval" ],
 296   [ MIRRORS="internal" ])
 297 AC_MSG_RESULT($MIRRORS)
 298
 299 if [[ "x$MIRRORS" != xnone -a "x$MIRRORS" != xinternal -a "x$MIRRORS" != xshared ]];
 300  then  AC_MSG_ERROR(
 301 --with-mirrors parameter invalid
 302 )
 303 fi;
 304
 305 if test x$MIRRORS = xinternal; then
 306         AC_DEFINE([MIRRORED_INTERNAL], 1, [Define to 1 to include built-in support for mirrors.])
 307 fi
 308
 309 ################################################################################
 310 dnl -- Disable readline
 311 AC_MSG_CHECKING(whether to enable readline)
 312 AC_ARG_ENABLE([readline],
 313   [  --disable-readline      Disable readline support],
 314   [READLINE=$enableval], [READLINE=maybe])
 315 AC_MSG_RESULT($READLINE)
 316
 317 ################################################################################
 318 dnl -- Disable realtime clock support
 319 AC_MSG_CHECKING(whether to enable realtime support)
 320 AC_ARG_ENABLE(realtime, [  --disable-realtime      Disable realtime clock support],
 321 REALTIME=$enableval)
 322 AC_MSG_RESULT($REALTIME)
 323
 324 ################################################################################
 325 dnl -- Build cluster LVM daemon
 326 AC_MSG_CHECKING(whether to build cluster LVM daemon)
 327 AC_ARG_WITH(clvmd,
 328   [  --with-clvmd=TYPE       Build cluster LVM Daemon.
 329                           The following locking combinations are valid:
 330                            * cman,gulm             (RHEL4 or equivalent)
 331                            * cman                  (RHEL5 or equivalent)
 332                            * cman,corosync,openais (or selection of them)
 333                            * all                   (autodetect)
 334                            * none                  (disable build)
 335                           [TYPE=none] ],
 336   [ CLVMD="$withval" ],
 337   [ CLVMD="none" ])
 338 if test x$CLVMD = xyes; then
 339         CLVMD=all
 340 fi
 341 AC_MSG_RESULT($CLVMD)
 342
 343 dnl -- If clvmd enabled without cluster locking, automagically include it
 344 if  test x$CLVMD != xnone && test x$CLUSTER = xnone; then
 345         CLUSTER=internal
 346 fi
 347
 348 dnl -- define build types
 349 if [[ `expr x"$CLVMD" : '.*gulm.*'` != 0 ]]; then
 350         BUILDGULM=yes
 351 fi
 352 if [[ `expr x"$CLVMD" : '.*corosync.*'` != 0 ]]; then
 353         BUILDCOROSYNC=yes
 354 fi
 355 if [[ `expr x"$CLVMD" : '.*openais.*'` != 0 ]]; then
 356         BUILDOPENAIS=yes
 357 fi
 358 if [[ `expr x"$CLVMD" : '.*cman.*'` != 0 ]]; then
 359         BUILDCMAN=yes
 360 fi
 361
 362 dnl -- sanity check around user selection
 363 if test x$BUILDGULM = xyes; then
 364         if test x$BUILDCOROSYNC = xyes || \
 365            test x$BUILDOPENAIS = xyes; then
 366                 AC_MSG_ERROR([requested clvmd configuration is not valid])
 367         fi
 368 fi
 369
 370 dnl -- Init pkg-config with dummy invokation:
 371 dnl -- this is required because PKG_CHECK_MODULES macro is expanded
 372 dnl -- to initialize the pkg-config environment only at the first invokation,
 373 dnl -- that would be conditional in this configure.in.
 374 if  test x$CLVMD != xnone; then
 375         PKG_CHECK_MODULES(PKGCONFIGINIT, pkgconfiginit, [],
 376                 [AC_MSG_RESULT([pkg-config initialized])])
 377 fi
 378
 379 dnl -- define a soft bailout if we are autodetecting
 380 soft_bailout() {
 381         NOTFOUND=1
 382 }
 383
 384 hard_bailout() {
 385         AC_MSG_ERROR([bailing out])
 386 }
 387
 388 dnl -- if clvmd=all then set soft_bailout (we don't want to error)
 389 dnl -- and set all builds to yes. We need to do this here
 390 dnl -- to skip the gulm + openais|corosync sanity check above.
 391 if test x$CLVMD = xall; then
 392         bailout=soft_bailout
 393         BUILDGULM=yes
 394         BUILDCMAN=yes
 395         BUILDCOROSYNC=yes
 396         BUILDOPENAIS=yes
 397 else
 398         bailout=hard_bailout
 399 fi
 400
 401 dnl -- helper macro to check libs without adding them to LIBS
 402 check_lib_no_libs() {
 403         lib_no_libs_arg1=$1
 404         shift
 405         lib_no_libs_arg2=$1
 406         shift
 407         lib_no_libs_args=$@
 408         AC_CHECK_LIB([$lib_no_libs_arg1],
 409                      [$lib_no_libs_arg2],,
 410                      [$bailout],
 411                      [$lib_no_libs_args])
 412         LIBS=$ac_check_lib_save_LIBS
 413 }
 414
 415 dnl -- Look for gulm libraries if required.
 416 if test x$BUILDGULM = xyes; then
 417         PKG_CHECK_MODULES(CCS, libccs, [HAVE_CCS=yes],
 418                 [NOTFOUND=0
 419                 AC_CHECK_HEADERS(ccs.h,,$bailout)
 420                 check_lib_no_libs ccs ccs_connect
 421                 if test $NOTFOUND = 0; then
 422                         AC_MSG_RESULT([no pkg for libccs, using -lccs])
 423                         CCS_LIBS="-lccs"
 424                         HAVE_CCS=yes
 425                 fi])
 426         PKG_CHECK_MODULES(GULM, libgulm, [HAVE_GULM=yes],
 427                 [NOTFOUND=0
 428                 AC_CHECK_HEADERS(libgulm.h,,$bailout)
 429                 check_lib_no_libs gulm lg_core_login
 430                 if test $NOTFOUND = 0; then
 431                         AC_MSG_RESULT([no pkg for libgulm, using -lgulm])
 432                         GULM_LIBS="-lgulm"
 433                         HAVE_GULM=yes
 434                 fi])
 435 fi
 436
 437 dnl -- Look for cman libraries if required.
 438 if test x$BUILDCMAN = xyes; then
 439         PKG_CHECK_MODULES(CMAN, libcman, [HAVE_CMAN=yes],
 440                 [NOTFOUND=0
 441                 AC_CHECK_HEADERS(libcman.h,,$bailout)
 442                 check_lib_no_libs cman cman_init
 443                 if test $NOTFOUND = 0; then
 444                         AC_MSG_RESULT([no pkg for libcman, using -lcman])
 445                         CMAN_LIBS="-lcman"
 446                         HAVE_CMAN=yes
 447                 fi])
 448         CHECKCONFDB=yes
 449         CHECKDLM=yes
 450 fi
 451
 452 dnl -- Look for corosync that's required also for openais build
 453 dnl -- only enough recent version of corosync ship pkg-config files.
 454 dnl -- We can safely rely on that to detect the correct bits.
 455 if test x$BUILDCOROSYNC = xyes || \
 456    test x$BUILDOPENAIS = xyes; then
 457         PKG_CHECK_MODULES(COROSYNC, corosync, [HAVE_COROSYNC=yes], $bailout)
 458         CHECKCONFDB=yes
 459 fi
 460
 461 dnl -- Look for corosync libraries if required.
 462 if test x$BUILDCOROSYNC = xyes; then
 463         PKG_CHECK_MODULES(QUORUM, libquorum, [HAVE_QUORUM=yes], $bailout)
 464         CHECKCPG=yes
 465         CHECKDLM=yes
 466 fi
 467
 468 dnl -- Look for openais libraries if required.
 469 if test x$BUILDOPENAIS = xyes; then
 470         PKG_CHECK_MODULES(SALCK, libSaLck, [HAVE_SALCK=yes], $bailout)
 471         CHECKCPG=yes
 472 fi
 473
 474 dnl -- Below are checks for libraries common to more than one build.
 475
 476 dnl -- Check confdb library.
 477 dnl -- mandatory for corosync build.
 478 dnl -- optional for openais/cman build.
 479
 480 if test x$CHECKCONFDB = xyes; then
 481         PKG_CHECK_MODULES(CONFDB, libconfdb,
 482                           [HAVE_CONFDB=yes],
 483                           [HAVE_CONFDB=no])
 484
 485         AC_CHECK_HEADERS(corosync/confdb.h,
 486                 [HAVE_CONFDB_H=yes],
 487                 [HAVE_CONFDB_H=no])
 488
 489         if test x$HAVE_CONFDB != xyes && \
 490            test x$HAVE_CONFDB_H = xyes; then
 491                 check_lib_no_libs confdb confdb_initialize
 492                 AC_MSG_RESULT([no pkg for confdb, using -lconfdb])
 493                 CONFDB_LIBS="-lconfdb"
 494                 HAVE_CONFDB=yes
 495         fi
 496
 497         if test x$BUILDCOROSYNC = xyes && \
 498            test x$HAVE_CONFDB != xyes &&
 499            test x$CLVMD != xall; then
 500                 AC_MSG_ERROR([bailing out... confdb library is required])
 501         fi
 502 fi
 503
 504 dnl -- Check cpg library.
 505 if test x$CHECKCPG = xyes; then
 506         PKG_CHECK_MODULES(CPG, libcpg, [HAVE_CPG=yes], $bailout)
 507 fi
 508
 509 dnl -- Check dlm library.
 510 if test x$CHECKDLM = xyes; then
 511         PKG_CHECK_MODULES(DLM, libdlm, [HAVE_DLM=yes],
 512                 [NOTFOUND=0
 513                 AC_CHECK_HEADERS(libdlm.h,,$bailout)
 514                 check_lib_no_libs dlm dlm_lock -lpthread
 515                 if test $NOTFOUND = 0; then
 516                         AC_MSG_RESULT([no pkg for libdlm, using -ldlm])
 517                         DLM_LIBS="-ldlm -lpthread"
 518                         HAVE_DLM=yes
 519                 fi])
 520 fi
 521
 522 dnl -- If we are autodetecting, we need to re-create
 523 dnl -- the depedencies checks and set a proper CLVMD.
 524 if test x$CLVMD = xall; then
 525         if test x$HAVE_CCS = xyes && \
 526            test x$HAVE_GULM = xyes; then
 527                 AC_MSG_RESULT([Enabling clvmd gulm backend])
 528                 NEWCLVMD="$NEWCLVMD,gulm"
 529         fi
 530         if test x$HAVE_CMAN = xyes && \
 531            test x$HAVE_DLM = xyes; then
 532                 AC_MSG_RESULT([Enabling clvmd cman backend])
 533                 NEWCLVMD="$NEWCLVMD,cman"
 534         fi
 535         if test x$HAVE_COROSYNC = xyes && \
 536            test x$HAVE_QUORUM = xyes && \
 537            test x$HAVE_CPG = xyes && \
 538            test x$HAVE_DLM = xyes && \
 539            test x$HAVE_CONFDB = xyes; then
 540                 AC_MSG_RESULT([Enabling clvmd corosync backend])
 541                 NEWCLVMD="$NEWCLVMD,corosync"
 542         fi
 543         if test x$HAVE_COROSYNC = xyes && \
 544            test x$HAVE_CPG = xyes && \
 545            test x$HAVE_SALCK = xyes; then
 546                 AC_MSG_RESULT([Enabling clvmd openais backend])
 547                 NEWCLVMD="$NEWCLVMD,openais"
 548         fi
 549         CLVMD="$NEWCLVMD"
 550 fi
 551
 552 ################################################################################
 553 dnl -- Build cluster log daemon
 554 AC_MSG_CHECKING(whether to build cluster log daemon)
 555 AC_ARG_ENABLE(clogd, [  --enable-clogd          Enable the cluster log daemon],
 556 CLOGD=$enableval)
 557 AC_MSG_RESULT($CLOGD)
 558
 559 dnl -- Look for corosync libraries if required.
 560 if [[ "x$CLOGD" = xall -o `expr x"$CLOGD" : '.*corosync.*'` != 0 ]]; then
 561 #
 562 #       FIXME: ALSO NEED TO CHECK FOR CHECKPOINT MODULE
 563 #
 564         PKG_CHECK_MODULES(CPG, libcpg, [],
 565                 [AC_MSG_RESULT([no pkg for libcpg library, using -lcpg]);
 566                 CPG_LIBS="-lcpg"])
 567 fi
 568
 569 ################################################################################
 570 dnl -- Enable debugging
 571 AC_MSG_CHECKING(whether to enable debugging)
 572 AC_ARG_ENABLE(debug,    [  --enable-debug          Enable debugging],
 573   DEBUG=$enableval, DEBUG=no)
 574 AC_MSG_RESULT($DEBUG)
 575
 576 dnl -- Normally turn off optimisation for debug builds
 577 if test x$DEBUG = xyes; then
 578         COPTIMISE_FLAG=
 579 else
 580         CSCOPE_CMD=
 581 fi
 582
 583 ################################################################################
 584 dnl -- Override optimisation
 585 AC_MSG_CHECKING(for C optimisation flag)
 586 AC_ARG_WITH(optimisation,
 587   [  --with-optimisation=OPT C optimisation flag [[OPT=-O2]] ],
 588   [ COPTIMISE_FLAG="$withval" ])
 589 AC_MSG_RESULT($COPTIMISE_FLAG)
 590
 591 ################################################################################
 592 dnl -- Enable profiling
 593 AC_MSG_CHECKING(whether to gather gcov profiling data)
 594 AC_ARG_ENABLE(profiling,
 595   AC_HELP_STRING(--enable-profiling, [Gather gcov profiling data]),
 596   PROFILING=$enableval, PROFILING=no)
 597 AC_MSG_RESULT($PROFILING)
 598
 599 if test "x$PROFILING" = xyes; then
 600   COPTIMISE_FLAG="$COPTIMISE_FLAG -fprofile-arcs -ftest-coverage"
 601   AC_PATH_PROG(LCOV, lcov, no)
 602   AC_PATH_PROG(GENHTML, genhtml, no)
 603   if test "$LCOV" = no -o "$GENHTML" = no ; then
 604     AC_MSG_ERROR([lcov and genhtml are required for profiling])
 605   fi
 606 fi
 607
 608 ################################################################################
 609 dnl -- Disable devmapper
 610 AC_MSG_CHECKING(whether to use device-mapper)
 611 AC_ARG_ENABLE(devmapper, [  --disable-devmapper     Disable LVM2 device-mapper interaction],
 612 DEVMAPPER=$enableval)
 613 AC_MSG_RESULT($DEVMAPPER)
 614
 615 if test x$DEVMAPPER = xyes; then
 616         AC_DEFINE([DEVMAPPER_SUPPORT], 1, [Define to 1 to enable LVM2 device-mapper interaction.])
 617 fi
 618
 619 ################################################################################
 620 dnl -- Enable udev synchronisation
 621 AC_MSG_CHECKING(whether to enable synchronisation with udev processing)
 622 AC_ARG_ENABLE(udev_sync, [  --enable-udev_sync      Enable synchronisation with udev processing],
 623 UDEV_SYNC=$enableval, UDEV_SYNC=no)
 624 AC_MSG_RESULT($UDEV_SYNC)
 625
 626 if test x$UDEV_SYNC = xyes; then
 627         AC_DEFINE([UDEV_SYNC_SUPPORT], 1, [Define to 1 to enable synchronisation with udev processing.])
 628 fi
 629
 630 dnl -- Enable udev rules
 631 AC_MSG_CHECKING(whether to enable installation of udev rules required for synchronisation)
 632 AC_ARG_ENABLE(udev_rules, [  --enable-udev_rules     Install rule files needed for udev synchronisation],
 633 UDEV_RULES=$enableval, UDEV_RULES=$UDEV_SYNC)
 634 AC_MSG_RESULT($UDEV_RULES)
 635
 636 ################################################################################
 637 dnl -- Compatibility mode
 638 AC_ARG_ENABLE(compat,   [  --enable-compat         Enable support for old device-mapper versions],
 639   DM_COMPAT=$enableval, DM_COMPAT=no)
 640
 641 ################################################################################
 642 dnl -- Disable ioctl
 643 AC_ARG_ENABLE(ioctl,   [  --disable-driver        Disable calls to device-mapper in the kernel],
 644   DM_IOCTLS=$enableval)
 645
 646 ################################################################################
 647 dnl -- Disable O_DIRECT
 648 AC_MSG_CHECKING(whether to enable O_DIRECT)
 649 AC_ARG_ENABLE(o_direct, [  --disable-o_direct      Disable O_DIRECT],
 650 ODIRECT=$enableval)
 651 AC_MSG_RESULT($ODIRECT)
 652
 653 if test x$ODIRECT = xyes; then
 654         AC_DEFINE([O_DIRECT_SUPPORT], 1, [Define to 1 to enable O_DIRECT support.])
 655 fi
 656
 657 ################################################################################
 658 dnl -- Enable liblvm2app.so
 659 AC_MSG_CHECKING(whether to build liblvm2app.so application library)
 660 AC_ARG_ENABLE(applib,
 661   [  --enable-applib         Build application library],
 662   APPLIB=$enableval, APPLIB=no)
 663 AC_MSG_RESULT($APPLIB)
 664 AC_SUBST([LVM2APP_LIB])
 665 test x$APPLIB = xyes \
 666   && LVM2APP_LIB=-llvm2app \
 667   || LVM2APP_LIB=
 668
 669 ################################################################################
 670 dnl -- Enable cmdlib
 671 AC_MSG_CHECKING(whether to compile liblvm2cmd.so)
 672 AC_ARG_ENABLE(cmdlib, [  --enable-cmdlib         Build shared command library],
 673 CMDLIB=$enableval, CMDLIB=no)
 674 AC_MSG_RESULT($CMDLIB)
 675 AC_SUBST([LVM2CMD_LIB])
 676 test x$CMDLIB = xyes \
 677   && LVM2CMD_LIB=-llvm2cmd \
 678   || LVM2CMD_LIB=
 679
 680 ################################################################################
 681 dnl -- Enable pkg-config
 682 AC_ARG_ENABLE(pkgconfig,   [  --enable-pkgconfig      Install pkgconfig support],
 683   PKGCONFIG=$enableval, PKGCONFIG=no)
 684
 685 ################################################################################
 686 dnl -- Enable fsadm
 687 AC_MSG_CHECKING(whether to install fsadm)
 688 AC_ARG_ENABLE(fsadm, [  --enable-fsadm          Enable fsadm],
 689 FSADM=$enableval)
 690 AC_MSG_RESULT($FSADM)
 691
 692 ################################################################################
 693 dnl -- enable dmeventd handling
 694 AC_MSG_CHECKING(whether to use dmeventd)
 695 AC_ARG_ENABLE(dmeventd, [  --enable-dmeventd       Enable the device-mapper event daemon],
 696 DMEVENTD=$enableval)
 697 AC_MSG_RESULT($DMEVENTD)
 698
 699 BUILD_DMEVENTD=$DMEVENTD
 700
 701 dnl -- dmeventd currently requires internal mirror support
 702 if test x$DMEVENTD = xyes; then
 703    if test x$MIRRORS != xinternal; then
 704       AC_MSG_ERROR(
 705         --enable-dmeventd currently requires --with-mirrors=internal
 706       )
 707    fi
 708    if test x$CMDLIB = xno; then
 709       AC_MSG_ERROR(
 710         --enable-dmeventd requires --enable-cmdlib to be used as well
 711       )
 712    fi
 713 fi
 714
 715 if test x$DMEVENTD = xyes; then
 716         AC_DEFINE([DMEVENTD], 1, [Define to 1 to enable the device-mapper event daemon.])
 717 fi
 718
 719 ################################################################################
 720 dnl -- getline included in recent libc
 721
 722 AC_CHECK_LIB(c, getline, AC_DEFINE([HAVE_GETLINE], 1,
 723   [Define to 1 if getline is available.]))
 724
 725 ################################################################################
 726 dnl -- canonicalize_file_name included in recent libc
 727
 728 AC_CHECK_LIB(c, canonicalize_file_name,
 729   AC_DEFINE([HAVE_CANONICALIZE_FILE_NAME], 1,
 730     [Define to 1 if canonicalize_file_name is available.]))
 731
 732 ################################################################################
 733 dnl -- Clear default exec_prefix - install into /sbin rather than /usr/sbin
 734 if [[ "x$exec_prefix" = xNONE -a "x$prefix" = xNONE ]];
 735  then  exec_prefix="";
 736 fi;
 737
 738 ################################################################################
 739 dnl -- Check for termcap (Shamelessly copied from parted 1.4.17)
 740 if test x$READLINE != xno; then
 741         AC_SEARCH_LIBS([tgetent], [tinfo ncurses curses termcap termlib],
 742           [tg_found=yes], [tg_found=no])
 743         test x$READLINE:$tg_found = xyes:no &&
 744           AC_MSG_ERROR(
 745 termcap could not be found which is required for the
 746 --enable-readline option (which is enabled by default).  Either disable readline
 747 support with --disable-readline or download and install termcap from:
 748         ftp.gnu.org/gnu/termcap
 749 Note: if you are using precompiled packages you will also need the development
 750   package as well (which may be called termcap-devel or something similar).
 751 Note: (n)curses also seems to work as a substitute for termcap.  This was
 752   not found either - but you could try installing that as well.
 753 )
 754 fi
 755
 756 ################################################################################
 757 dnl -- Check for dlopen
 758 AC_CHECK_LIB(dl, dlopen, HAVE_LIBDL=yes, HAVE_LIBDL=no)
 759
 760 if [[ "x$HAVE_LIBDL" = xyes ]]; then
 761         AC_DEFINE([HAVE_LIBDL], 1, [Define to 1 if dynamic libraries are available.])
 762         LIBS="-ldl $LIBS"
 763 else
 764         HAVE_LIBDL=no
 765 fi
 766
 767 ################################################################################
 768 dnl -- Check for shared/static conflicts
 769 if [[ \( "x$LVM1" = xshared -o "x$POOL" = xshared -o "x$CLUSTER" = xshared \
 770       -o "x$SNAPSHOTS" = xshared -o "x$MIRRORS" = xshared \
 771       \) -a "x$STATIC_LINK" = xyes ]];
 772  then  AC_MSG_ERROR(
 773 Features cannot be 'shared' when building statically
 774 )
 775 fi
 776
 777 ################################################################################
 778 dnl -- Disable selinux
 779 AC_MSG_CHECKING(whether to enable selinux support)
 780 AC_ARG_ENABLE(selinux, [  --disable-selinux       Disable selinux support],
 781   SELINUX=$enableval)
 782 AC_MSG_RESULT($SELINUX)
 783
 784 ################################################################################
 785 dnl -- Check for selinux
 786 if test x$SELINUX = xyes; then
 787         AC_CHECK_LIB(sepol, sepol_check_context, HAVE_SEPOL=yes, HAVE_SEPOL=no)
 788
 789         if test x$HAVE_SEPOL = xyes; then
 790                 AC_DEFINE([HAVE_SEPOL], 1,
 791                   [Define to 1 if sepol_check_context is available.])
 792                 LIBS="-lsepol $LIBS"
 793         fi
 794
 795         AC_CHECK_LIB(selinux, is_selinux_enabled, HAVE_SELINUX=yes, HAVE_SELINUX=no)
 796
 797         if test x$HAVE_SELINUX = xyes; then
 798                 AC_DEFINE([HAVE_SELINUX], 1, [Define to 1 to include support for selinux.])
 799                 LIBS="-lselinux $LIBS"
 800         else
 801                 AC_MSG_WARN(Disabling selinux)
 802         fi
 803
 804         # With --enable-static_link and selinux enabled, linking
 805         # fails on at least Debian unstable due to unsatisfied references
 806         # to pthread_mutex_lock and _unlock.  See if we need -lpthread.
 807         if test "$STATIC_LINK-$HAVE_SELINUX" = yes-yes; then
 808                 lvm_saved_libs=$LIBS
 809                 LIBS="$LIBS -static"
 810                 AC_SEARCH_LIBS([pthread_mutex_lock], [pthread],
 811                   [test "$ac_cv_search_pthread_mutex_lock" = "none required" ||
 812                                 LIB_PTHREAD=-lpthread])
 813                 LIBS=$lvm_saved_libs
 814         fi
 815 fi
 816
 817 ################################################################################
 818 dnl -- Check for realtime clock support
 819 if test x$REALTIME = xyes; then
 820         AC_CHECK_LIB(rt, clock_gettime, HAVE_REALTIME=yes, HAVE_REALTIME=no)
 821
 822         if test x$HAVE_REALTIME = xyes; then
 823                 AC_DEFINE([HAVE_REALTIME], 1, [Define to 1 to include support for realtime clock.])
 824                 LIBS="-lrt $LIBS"
 825         else
 826                 AC_MSG_WARN(Disabling realtime clock)
 827         fi
 828 fi
 829
 830 ################################################################################
 831 dnl -- Check for getopt
 832 AC_CHECK_HEADERS(getopt.h, AC_DEFINE([HAVE_GETOPTLONG], 1, [Define to 1 if getopt_long is available.]))
 833
 834 ################################################################################
 835 dnl -- Check for readline (Shamelessly copied from parted 1.4.17)
 836 if test x$READLINE != xno; then
 837         rl_found=yes
 838         AC_CHECK_LIB([readline], [readline], , [rl_found=no])
 839         test x$READLINE:$rl_found = xyes:no &&
 840           AC_MSG_ERROR(
 841 GNU Readline could not be found which is required for the
 842 --enable-readline option (which is enabled by default).  Either disable readline
 843 support with --disable-readline or download and install readline from:
 844         ftp.gnu.org/gnu/readline
 845 Note: if you are using precompiled packages you will also need the development
 846 package as well (which may be called readline-devel or something similar).
 847 )
 848         if test $rl_found = yes; then
 849                 AC_CHECK_FUNCS([rl_completion_matches])
 850                 AC_DEFINE([READLINE_SUPPORT], 1,
 851                   [Define to 1 to include the LVM readline shell.])
 852         fi
 853 fi
 854
 855 ################################################################################
 856 dnl -- Internationalisation stuff
 857 AC_MSG_CHECKING(whether to enable internationalisation)
 858 AC_ARG_ENABLE(nls, [  --enable-nls            Enable Native Language Support],
 859                 INTL=$enableval, INTL=no)
 860 AC_MSG_RESULT($INTL)
 861
 862 if test x$INTL = xyes; then
 863 # FIXME - Move this - can be device-mapper too
 864         INTL_PACKAGE="lvm2"
 865         AC_PATH_PROG(MSGFMT, msgfmt)
 866         if [[ "x$MSGFMT" == x ]];
 867                 then  AC_MSG_ERROR(
 868                 msgfmt not found in path $PATH
 869                 )
 870         fi;
 871
 872         AC_ARG_WITH(localedir,
 873                     [  --with-localedir=DIR    Translation files in DIR [[PREFIX/share/locale]] ],
 874                     [ LOCALEDIR="$withval" ],
 875                     [ LOCALEDIR='${prefix}/share/locale' ])
 876 fi
 877
 878 ################################################################################
 879 AC_ARG_WITH(confdir,
 880             [  --with-confdir=DIR      Configuration files in DIR [[/etc]]],
 881             [ CONFDIR="$withval" ],
 882             [ CONFDIR='/etc' ])
 883
 884 AC_ARG_WITH(staticdir,
 885             [  --with-staticdir=DIR    Static binary in DIR [[EPREFIX/sbin]]],
 886             [ STATICDIR="$withval" ],
 887             [ STATICDIR='${exec_prefix}/sbin' ])
 888
 889 AC_ARG_WITH(usrlibdir,
 890             [  --with-usrlibdir=DIR],
 891             [ usrlibdir="$withval"],
 892             [ usrlibdir='${prefix}/lib' ])
 893
 894 AC_ARG_WITH(usrsbindir,
 895             [  --with-usrsbindir=DIR],
 896             [ usrsbindir="$withval"],
 897             [ usrsbindir='${prefix}/sbin' ])
 898
 899 ################################################################################
 900 AC_ARG_WITH(udev_prefix,
 901             [  --with-udev-prefix=UPREFIX      Install udev rule files in UPREFIX [[EPREFIX]]],
 902             [ udev_prefix="$withval"],
 903             [ udev_prefix='${exec_prefix}' ])
 904
 905 AC_ARG_WITH(udevdir,
 906             [  --with-udevdir=DIR      udev rules in DIR [[UPREFIX/lib/udev/rules.d]]],
 907             [ udevdir="$withval"],
 908             [ udevdir='${udev_prefix}/lib/udev/rules.d' ])
 909
 910 ################################################################################
 911 dnl -- Ensure additional headers required
 912 if test x$READLINE = xyes; then
 913         AC_CHECK_HEADERS(readline/readline.h readline/history.h,,AC_MSG_ERROR(bailing out))
 914 fi
 915
 916 if test x$CLVMD != xnone; then
 917         AC_CHECK_HEADERS(mntent.h netdb.h netinet/in.h pthread.h search.h sys/mount.h sys/socket.h sys/uio.h sys/un.h utmpx.h,,AC_MSG_ERROR(bailing out))
 918         AC_CHECK_FUNCS(dup2 getmntent memmove select socket,,AC_MSG_ERROR(bailing out))
 919         AC_FUNC_GETMNTENT
 920 #       AC_FUNC_REALLOC
 921         AC_FUNC_SELECT_ARGTYPES
 922 fi
 923
 924 if test x$CLUSTER != xnone; then
 925         AC_CHECK_HEADERS(sys/socket.h sys/un.h,,AC_MSG_ERROR(bailing out))
 926         AC_CHECK_FUNCS(socket,,AC_MSG_ERROR(bailing out))
 927 fi
 928
 929 if test x$HAVE_LIBDL = xyes; then
 930         AC_CHECK_HEADERS(dlfcn.h,,AC_MSG_ERROR(bailing out))
 931 fi
 932
 933 if test x$INTL = xyes; then
 934         AC_CHECK_HEADERS(libintl.h,,AC_MSG_ERROR(bailing out))
 935 fi
 936
 937 if test x$HAVE_SELINUX = xyes; then
 938         AC_CHECK_HEADERS(selinux/selinux.h,,AC_MSG_ERROR(bailing out))
 939 fi
 940
 941 if test x$UDEV_SYNC = xyes; then
 942         AC_CHECK_HEADERS(sys/ipc.h sys/sem.h,,AC_MSG_ERROR(bailing out))
 943 fi
 944
 945 ################################################################################
 946 AC_PATH_PROG(MODPROBE_CMD, modprobe)
 947
 948 if test x$MODPROBE_CMD != x; then
 949         AC_DEFINE_UNQUOTED([MODPROBE_CMD], ["$MODPROBE_CMD"], [The path to 'modprobe', if available.])
 950 fi
 951
 952 ################################################################################
 953 dnl -- dmeventd pidfile and executable path
 954 AH_TEMPLATE(DMEVENTD_PIDFILE, [Path to dmeventd pidfile.])
 955 if test "$BUILD_DMEVENTD" = yes; then
 956         AC_ARG_WITH(dmeventd-pidfile,
 957                     [  --with-dmeventd-pidfile=PATH    dmeventd pidfile [[/var/run/dmeventd.pid]] ],
 958                     [ AC_DEFINE_UNQUOTED(DMEVENTD_PIDFILE,"$withval") ],
 959                     [ AC_DEFINE_UNQUOTED(DMEVENTD_PIDFILE,"/var/run/dmeventd.pid") ])
 960 fi
 961
 962 AH_TEMPLATE(DMEVENTD_PATH, [Path to dmeventd binary.])
 963 if test "$BUILD_DMEVENTD" = yes; then
 964         dmeventd_prefix="$exec_prefix"
 965         if test "x$dmeventd_prefix" = "xNONE"; then
 966                 dmeventd_prefix="$prefix"
 967         fi
 968         if test "x$dmeventd_prefix" = "xNONE"; then
 969                 dmeventd_prefix=""
 970         fi
 971         AC_ARG_WITH(dmeventd-path,
 972                     [  --with-dmeventd-path=PATH       dmeventd path [[EPREFIX/sbin/dmeventd]] ],
 973                     [ AC_DEFINE_UNQUOTED(DMEVENTD_PATH,"$withval") ],
 974                     [ AC_DEFINE_UNQUOTED(DMEVENTD_PATH,"$dmeventd_prefix/sbin/dmeventd") ])
 975 fi
 976
 977 ################################################################################
 978 dnl -- which kernel interface to use (ioctl only)
 979 AC_MSG_CHECKING(for kernel interface choice)
 980 AC_ARG_WITH(interface,
 981   [  --with-interface=IFACE  Choose kernel interface (ioctl) [[ioctl]] ],
 982   [ interface="$withval" ],
 983   [ interface=ioctl ])
 984 if [[ "x$interface" != xioctl ]];
 985 then
 986   AC_MSG_ERROR(--with-interface=ioctl required. fs no longer supported.)
 987 fi
 988 AC_MSG_RESULT($interface)
 989
 990 ################################################################################
 991 DM_LIB_VERSION="\"`cat VERSION_DM 2>/dev/null || echo Unknown`\""
 992 AC_DEFINE_UNQUOTED(DM_LIB_VERSION, $DM_LIB_VERSION, [Library version])
 993
 994 DM_LIB_PATCHLEVEL=`cat VERSION_DM | $AWK -F '[[-. ]]' '{printf "%s.%s.%s",$1,$2,$3}'`
 995
 996 LVM_VERSION="\"`cat VERSION 2>/dev/null || echo Unknown`\""
 997
 998 VER=`cat VERSION`
 999 LVM_RELEASE_DATE="\"`echo $VER | $SED 's/.* (//;s/).*//'`\""
1000 VER=`echo "$VER" | $AWK '{print $1}'`
1001 LVM_RELEASE="\"`echo "$VER" | $AWK -F '-' '{print $2}'`\""
1002 VER=`echo "$VER" | $AWK -F '-' '{print $1}'`
1003 LVM_MAJOR=`echo "$VER" | $AWK -F '.' '{print $1}'`
1004 LVM_MINOR=`echo "$VER" | $AWK -F '.' '{print $2}'`
1005 LVM_PATCHLEVEL=`echo "$VER" | $AWK -F '[[(.]]' '{print $3}'`
1006 LVM_LIBAPI=`echo "$VER" | $AWK -F '[[()]]' '{print $2}'`
1007
1008 ################################################################################
1009 AC_SUBST(APPLIB)
1010 AC_SUBST(BUILD_DMEVENTD)
1011 AC_SUBST(CCS_CFLAGS)
1012 AC_SUBST(CCS_LIBS)
1013 AC_SUBST(CFLAGS)
1014 AC_SUBST(CFLOW_CMD)
1015 AC_SUBST(CLDFLAGS)
1016 AC_SUBST(CLDNOWHOLEARCHIVE)
1017 AC_SUBST(CLDWHOLEARCHIVE)
1018 AC_SUBST(CLUSTER)
1019 AC_SUBST(CLVMD)
1020 AC_SUBST(CLOGD)
1021 AC_SUBST(CMAN_CFLAGS)
1022 AC_SUBST(CMAN_LIBS)
1023 AC_SUBST(CMDLIB)
1024 AC_SUBST(CONFDB_CFLAGS)
1025 AC_SUBST(CONFDB_LIBS)
1026 AC_SUBST(CONFDIR)
1027 AC_SUBST(COPTIMISE_FLAG)
1028 AC_SUBST(CPG_CFLAGS)
1029 AC_SUBST(CPG_LIBS)
1030 AC_SUBST(CSCOPE_CMD)
1031 AC_SUBST(DEBUG)
1032 AC_SUBST(DEVMAPPER)
1033 AC_SUBST(DLM_CFLAGS)
1034 AC_SUBST(DLM_LIBS)
1035 AC_SUBST(DMEVENTD)
1036 AC_SUBST(DM_COMPAT)
1037 AC_SUBST(DM_DEVICE_GID)
1038 AC_SUBST(DM_DEVICE_MODE)
1039 AC_SUBST(DM_DEVICE_UID)
1040 AC_SUBST(DM_IOCTLS)
1041 AC_SUBST(DM_LIB_VERSION)
1042 AC_SUBST(DM_LIB_PATCHLEVEL)
1043 AC_SUBST(FSADM)
1044 AC_SUBST(GROUP)
1045 AC_SUBST(GULM_CFLAGS)
1046 AC_SUBST(GULM_LIBS)
1047 AC_SUBST(HAVE_LIBDL)
1048 AC_SUBST(HAVE_REALTIME)
1049 AC_SUBST(HAVE_SELINUX)
1050 AC_SUBST(INTL)
1051 AC_SUBST(INTL_PACKAGE)
1052 AC_SUBST(JOBS)
1053 AC_SUBST(LDDEPS)
1054 AC_SUBST(LIBS)
1055 AC_SUBST(LIB_SUFFIX)
1056 AC_SUBST(LOCALEDIR)
1057 AC_SUBST(LVM1)
1058 AC_SUBST(LVM1_FALLBACK)
1059 AC_SUBST(LVM_VERSION)
1060 AC_SUBST(LVM_LIBAPI)
1061 AC_SUBST(LVM_MAJOR)
1062 AC_SUBST(LVM_MINOR)
1063 AC_SUBST(LVM_PATCHLEVEL)
1064 AC_SUBST(LVM_RELEASE)
1065 AC_SUBST(LVM_RELEASE_DATE)
1066 AC_SUBST(MIRRORS)
1067 AC_SUBST(MSGFMT)
1068 AC_SUBST(OWNER)
1069 AC_SUBST(PKGCONFIG)
1070 AC_SUBST(POOL)
1071 AC_SUBST(QUORUM_CFLAGS)
1072 AC_SUBST(QUORUM_LIBS)
1073 AC_SUBST(SALCK_CFLAGS)
1074 AC_SUBST(SALCK_LIBS)
1075 AC_SUBST(SNAPSHOTS)
1076 AC_SUBST(STATICDIR)
1077 AC_SUBST(STATIC_LINK)
1078 AC_SUBST(UDEV_RULES)
1079 AC_SUBST([LIB_PTHREAD])
1080 AC_SUBST(interface)
1081 AC_SUBST(kerneldir)
1082 AC_SUBST(missingkernel)
1083 AC_SUBST(kernelvsn)
1084 AC_SUBST(tmpdir)
1085 AC_SUBST(udev_prefix)
1086 AC_SUBST(udevdir)
1087 AC_SUBST(usrlibdir)
1088 AC_SUBST(usrsbindir)
1089
1090 ################################################################################
1091 dnl -- First and last lines should not contain files to generate in order to
1092 dnl -- keep utility scripts running properly
1093 AC_CONFIG_FILES([
1094 Makefile
1095 make.tmpl
1096 daemons/Makefile
1097 daemons/clvmd/Makefile
1098 daemons/clogd/Makefile
1099 daemons/dmeventd/Makefile
1100 daemons/dmeventd/libdevmapper-event.pc
1101 daemons/dmeventd/plugins/Makefile
1102 daemons/dmeventd/plugins/mirror/Makefile
1103 daemons/dmeventd/plugins/snapshot/Makefile
1104 doc/Makefile
1105 include/Makefile
1106 lib/Makefile
1107 lib/format1/Makefile
1108 lib/format_pool/Makefile
1109 lib/locking/Makefile
1110 lib/mirror/Makefile
1111 lib/misc/lvm-version.h
1112 lib/snapshot/Makefile
1113 libdm/Makefile
1114 libdm/libdevmapper.pc
1115 liblvm/Makefile
1116 liblvm/liblvm2app.pc
1117 man/Makefile
1118 po/Makefile
1119 scripts/clvmd_init_red_hat
1120 scripts/Makefile
1121 test/Makefile
1122 test/api/Makefile
1123 tools/Makefile
1124 udev/Makefile
1125 ])
1126 AC_OUTPUT
1127
1128 if test x$ODIRECT != xyes; then
1129   AC_MSG_WARN(Warning: O_DIRECT disabled: low-memory pvmove may lock up)
1130 fi