configure.in

   1 ###############################################################################
   2 ## Copyright (C) 2000-2004 Sistina Software, Inc. All rights reserved.
   3 ## Copyright (C) 2004-2009 Red Hat, Inc. All rights reserved.
   4 ##
   5 ## This copyrighted material is made available to anyone wishing to use,
   6 ## modify, copy, or redistribute it subject to the terms and conditions
   7 ## of the GNU General Public License v.2.
   8 ##
   9 ## You should have received a copy of the GNU General Public License
  10 ## along with this program; if not, write to the Free Software Foundation,
  11 ## Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  12 ################################################################################
  13
  14 AC_PREREQ(2.61)
  15 ################################################################################
  16 dnl -- Process this file with autoconf to produce a configure script.
  17 AC_INIT
  18 AC_CONFIG_SRCDIR([lib/device/dev-cache.h])
  19 AC_CONFIG_HEADERS([lib/misc/configure.h])
  20
  21 ################################################################################
  22 dnl -- Setup the directory where autoconf has auxilary files
  23 AC_CONFIG_AUX_DIR(autoconf)
  24
  25 ################################################################################
  26 dnl -- Get system type
  27 AC_CANONICAL_TARGET([])
  28
  29 case "$host_os" in
  30         linux*)
  31                 CFLAGS="$CFLAGS"
  32                 COPTIMISE_FLAG="-O2"
  33                 CLDFLAGS="$CLDFLAGS -Wl,--version-script,.export.sym"
  34                 CLDWHOLEARCHIVE="-Wl,-whole-archive"
  35                 CLDNOWHOLEARCHIVE="-Wl,-no-whole-archive"
  36                 LDDEPS="$LDDEPS .export.sym"
  37                 LDFLAGS="$LDFLAGS -Wl,--export-dynamic"
  38                 LIB_SUFFIX=so
  39                 DEVMAPPER=yes
  40                 ODIRECT=yes
  41                 DM_IOCTLS=yes
  42                 SELINUX=yes
  43                 CLUSTER=internal
  44                 FSADM=yes
  45                 ;;
  46         darwin*)
  47                 CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
  48                 COPTIMISE_FLAG="-O2"
  49                 CLDFLAGS="$CLDFLAGS"
  50                 CLDWHOLEARCHIVE="-all_load"
  51                 CLDNOWHOLEARCHIVE=
  52                 LIB_SUFFIX=dylib
  53                 DEVMAPPER=yes
  54                 ODIRECT=no
  55                 DM_IOCTLS=no
  56                 SELINUX=no
  57                 CLUSTER=none
  58                 FSADM=no
  59                 ;;
  60 esac
  61
  62 ################################################################################
  63 dnl -- Checks for programs.
  64 AC_PROG_SED
  65 AC_PROG_AWK
  66 AC_PROG_CC
  67
  68 dnl probably no longer needed in 2008, but...
  69 AC_PROG_GCC_TRADITIONAL
  70 AC_PROG_INSTALL
  71 AC_PROG_LN_S
  72 AC_PROG_MAKE_SET
  73 AC_PROG_MKDIR_P
  74 AC_PROG_RANLIB
  75 AC_PATH_PROG(CFLOW_CMD, cflow)
  76 AC_PATH_PROG(CSCOPE_CMD, cscope)
  77
  78 ################################################################################
  79 dnl -- Check for header files.
  80 AC_HEADER_DIRENT
  81 AC_HEADER_STDC
  82 AC_HEADER_SYS_WAIT
  83 AC_HEADER_TIME
  84
  85 AC_CHECK_HEADERS([locale.h stddef.h syslog.h sys/file.h sys/time.h assert.h \
  86   libgen.h signal.h sys/mman.h sys/resource.h sys/utsname.h sys/wait.h time.h], ,
  87   [AC_MSG_ERROR(bailing out)])
  88
  89 case "$host_os" in
  90         linux*)
  91                 AC_CHECK_HEADERS(asm/byteorder.h linux/fs.h malloc.h,,AC_MSG_ERROR(bailing out)) ;;
  92         darwin*)
  93                 AC_CHECK_HEADERS(machine/endian.h sys/disk.h,,AC_MSG_ERROR(bailing out)) ;;
  94 esac
  95
  96 AC_CHECK_HEADERS([ctype.h dirent.h errno.h fcntl.h getopt.h inttypes.h limits.h \
  97   stdarg.h stdio.h stdlib.h string.h sys/ioctl.h sys/param.h sys/stat.h \
  98   sys/types.h unistd.h], , [AC_MSG_ERROR(bailing out)])
  99 AC_CHECK_HEADERS(termios.h sys/statvfs.h)
 100
 101 ################################################################################
 102 dnl -- Check for typedefs, structures, and compiler characteristics.
 103 AC_C_CONST
 104 AC_C_INLINE
 105 AC_CHECK_MEMBERS([struct stat.st_rdev])
 106 AC_TYPE_OFF_T
 107 AC_TYPE_PID_T
 108 AC_TYPE_SIGNAL
 109 AC_TYPE_SIZE_T
 110 AC_TYPE_MODE_T
 111 AC_CHECK_MEMBERS([struct stat.st_rdev])
 112 AC_STRUCT_TM
 113
 114 ################################################################################
 115 dnl -- Check for functions
 116 AC_CHECK_FUNCS([gethostname getpagesize memset mkdir rmdir munmap setlocale \
 117   strcasecmp strchr strdup strncasecmp strerror strrchr strstr strtol strtoul \
 118   uname], , [AC_MSG_ERROR(bailing out)])
 119 AC_CHECK_FUNCS(siginterrupt)
 120 AC_FUNC_ALLOCA
 121 AC_FUNC_CLOSEDIR_VOID
 122 AC_FUNC_FORK
 123 AC_FUNC_LSTAT
 124 AC_FUNC_MALLOC
 125 AC_FUNC_MEMCMP
 126 AC_FUNC_MMAP
 127 AC_FUNC_STAT
 128 AC_FUNC_STRTOD
 129 AC_FUNC_VPRINTF
 130
 131 ################################################################################
 132 dnl -- Enables statically-linked tools
 133 AC_MSG_CHECKING(whether to use static linking)
 134 AC_ARG_ENABLE(static_link,
 135   [  --enable-static_link    Use this to link the tools to their libraries
 136                           statically.  Default is dynamic linking],
 137   STATIC_LINK=$enableval, STATIC_LINK=no)
 138 AC_MSG_RESULT($STATIC_LINK)
 139
 140 ################################################################################
 141 dnl -- Prefix is /usr by default, the exec_prefix default is setup later
 142 AC_PREFIX_DEFAULT(/usr)
 143
 144 ################################################################################
 145 dnl -- Setup the ownership of the files
 146 AC_MSG_CHECKING(file owner)
 147 OWNER=""
 148
 149 AC_ARG_WITH(user,
 150   [  --with-user=USER        Set the owner of installed files [[USER=]] ],
 151   [ OWNER="$withval" ])
 152 AC_MSG_RESULT($OWNER)
 153
 154 if test x$OWNER != x; then
 155         OWNER="-o $OWNER"
 156 fi
 157
 158 ################################################################################
 159 dnl -- Setup the group ownership of the files
 160 AC_MSG_CHECKING(group owner)
 161 GROUP=""
 162 AC_ARG_WITH(group,
 163   [  --with-group=GROUP      Set the group owner of installed files [[GROUP=]] ],
 164   [ GROUP="$withval" ])
 165 AC_MSG_RESULT($GROUP)
 166
 167 if test x$GROUP != x; then
 168         GROUP="-g $GROUP"
 169 fi
 170
 171 ################################################################################
 172 dnl -- Setup device node ownership
 173 AC_MSG_CHECKING(device node uid)
 174
 175 AC_ARG_WITH(device-uid,
 176   [  --with-device-uid=UID   Set the owner used for new device nodes [[UID=0]] ],
 177   [ DM_DEVICE_UID="$withval" ], [ DM_DEVICE_UID="0" ] )
 178 AC_MSG_RESULT($DM_DEVICE_UID)
 179
 180 ################################################################################
 181 dnl -- Setup device group ownership
 182 AC_MSG_CHECKING(device node gid)
 183
 184 AC_ARG_WITH(device-gid,
 185   [  --with-device-gid=UID   Set the group used for new device nodes [[GID=0]] ],
 186   [ DM_DEVICE_GID="$withval" ], [ DM_DEVICE_GID="0" ] )
 187 AC_MSG_RESULT($DM_DEVICE_GID)
 188
 189 ################################################################################
 190 dnl -- Setup device mode
 191 AC_MSG_CHECKING(device node mode)
 192
 193 AC_ARG_WITH(device-mode,
 194   [  --with-device-mode=MODE Set the mode used for new device nodes [[MODE=0600]] ],
 195   [ DM_DEVICE_MODE="$withval" ], [ DM_DEVICE_MODE="0600" ] )
 196 AC_MSG_RESULT($DM_DEVICE_MODE)
 197
 198 ################################################################################
 199 dnl -- LVM1 tool fallback option
 200 AC_MSG_CHECKING(whether to enable lvm1 fallback)
 201 AC_ARG_ENABLE(lvm1_fallback, [  --enable-lvm1_fallback  Use this to fall back and use LVM1 binaries if
 202                           device-mapper is missing from the kernel],  LVM1_FALLBACK=$enableval, LVM1_FALLBACK=no)
 203 AC_MSG_RESULT($LVM1_FALLBACK)
 204
 205 if test x$LVM1_FALLBACK = xyes; then
 206         AC_DEFINE([LVM1_FALLBACK], 1, [Define to 1 if 'lvm' should fall back to using LVM1 binaries if device-mapper is missing from the kernel])
 207 fi
 208
 209 ################################################################################
 210 dnl -- format1 inclusion type
 211 AC_MSG_CHECKING(whether to include support for lvm1 metadata)
 212 AC_ARG_WITH(lvm1,
 213   [  --with-lvm1=TYPE        LVM1 metadata support: internal/shared/none
 214                           [TYPE=internal] ],
 215   [ LVM1="$withval" ],
 216   [ LVM1="internal" ])
 217 AC_MSG_RESULT($LVM1)
 218
 219 if [[ "x$LVM1" != xnone -a "x$LVM1" != xinternal -a "x$LVM1" != xshared ]];
 220  then  AC_MSG_ERROR(
 221 --with-lvm1 parameter invalid
 222 )
 223 fi;
 224
 225 if test x$LVM1 = xinternal; then
 226         AC_DEFINE([LVM1_INTERNAL], 1, [Define to 1 to include built-in support for LVM1 metadata.])
 227 fi
 228
 229 ################################################################################
 230 dnl -- format_pool inclusion type
 231 AC_MSG_CHECKING(whether to include support for GFS pool metadata)
 232 AC_ARG_WITH(pool,
 233   [  --with-pool=TYPE        GFS pool read-only support: internal/shared/none
 234                           [TYPE=internal] ],
 235   [ POOL="$withval" ],
 236   [ POOL="internal" ])
 237 AC_MSG_RESULT($POOL)
 238
 239 if [[ "x$POOL" != xnone -a "x$POOL" != xinternal -a "x$POOL" != xshared ]];
 240  then  AC_MSG_ERROR(
 241 --with-pool parameter invalid
 242 )
 243 fi;
 244
 245 if test x$POOL = xinternal; then
 246         AC_DEFINE([POOL_INTERNAL], 1, [Define to 1 to include built-in support for GFS pool metadata.])
 247 fi
 248
 249 ################################################################################
 250 dnl -- cluster_locking inclusion type
 251 AC_MSG_CHECKING(whether to include support for cluster locking)
 252 AC_ARG_WITH(cluster,
 253   [  --with-cluster=TYPE     Cluster LVM locking support: internal/shared/none
 254                           [TYPE=internal] ],
 255   [ CLUSTER="$withval" ])
 256 AC_MSG_RESULT($CLUSTER)
 257
 258 if [[ "x$CLUSTER" != xnone -a "x$CLUSTER" != xinternal -a "x$CLUSTER" != xshared ]];
 259  then  AC_MSG_ERROR(
 260 --with-cluster parameter invalid
 261 )
 262 fi;
 263
 264 if test x$CLUSTER = xinternal; then
 265         AC_DEFINE([CLUSTER_LOCKING_INTERNAL], 1, [Define to 1 to include built-in support for clustered LVM locking.])
 266 fi
 267
 268 ################################################################################
 269 dnl -- snapshots inclusion type
 270 AC_MSG_CHECKING(whether to include snapshots)
 271 AC_ARG_WITH(snapshots,
 272   [  --with-snapshots=TYPE   Snapshot support: internal/shared/none
 273                           [TYPE=internal] ],
 274   [ SNAPSHOTS="$withval" ],
 275   [ SNAPSHOTS="internal" ])
 276 AC_MSG_RESULT($SNAPSHOTS)
 277
 278 if [[ "x$SNAPSHOTS" != xnone -a "x$SNAPSHOTS" != xinternal -a "x$SNAPSHOTS" != xshared ]];
 279  then  AC_MSG_ERROR(
 280 --with-snapshots parameter invalid
 281 )
 282 fi;
 283
 284 if test x$SNAPSHOTS = xinternal; then
 285         AC_DEFINE([SNAPSHOT_INTERNAL], 1, [Define to 1 to include built-in support for snapshots.])
 286 fi
 287
 288 ################################################################################
 289 dnl -- mirrors inclusion type
 290 AC_MSG_CHECKING(whether to include mirrors)
 291 AC_ARG_WITH(mirrors,
 292   [  --with-mirrors=TYPE     Mirror support: internal/shared/none
 293                           [TYPE=internal] ],
 294   [ MIRRORS="$withval" ],
 295   [ MIRRORS="internal" ])
 296 AC_MSG_RESULT($MIRRORS)
 297
 298 if [[ "x$MIRRORS" != xnone -a "x$MIRRORS" != xinternal -a "x$MIRRORS" != xshared ]];
 299  then  AC_MSG_ERROR(
 300 --with-mirrors parameter invalid
 301 )
 302 fi;
 303
 304 if test x$MIRRORS = xinternal; then
 305         AC_DEFINE([MIRRORED_INTERNAL], 1, [Define to 1 to include built-in support for mirrors.])
 306 fi
 307
 308 ################################################################################
 309 dnl -- Disable readline
 310 AC_MSG_CHECKING(whether to enable readline)
 311 AC_ARG_ENABLE([readline],
 312   [  --disable-readline      Disable readline support],
 313   [READLINE=$enableval], [READLINE=maybe])
 314 AC_MSG_RESULT($READLINE)
 315
 316 ################################################################################
 317 dnl -- Disable realtime clock support
 318 AC_MSG_CHECKING(whether to enable realtime support)
 319 AC_ARG_ENABLE(realtime, [  --enable-realtime       Enable realtime clock support],
 320 REALTIME=$enableval)
 321 AC_MSG_RESULT($REALTIME)
 322
 323 ################################################################################
 324 dnl -- Init pkg-config with dummy invokation:
 325 dnl -- this is required because PKG_CHECK_MODULES macro is expanded
 326 dnl -- to initialize the pkg-config environment only at the first invokation,
 327 dnl -- that would be conditional in this configure.in.
 328 pkg_config_init() {
 329         PKG_CHECK_MODULES(PKGCONFIGINIT, pkgconfiginit, [],
 330                 [AC_MSG_RESULT([pkg-config initialized])])
 331         PKGCONFIG_INIT=1
 332 }
 333
 334 ################################################################################
 335 dnl -- Build cluster LVM daemon
 336 AC_MSG_CHECKING(whether to build cluster LVM daemon)
 337 AC_ARG_WITH(clvmd,
 338   [  --with-clvmd=TYPE       Build cluster LVM Daemon.
 339                           The following cluster manager combinations are valid:
 340                            * cman,gulm             (RHEL4 or equivalent)
 341                            * cman                  (RHEL5 or equivalent)
 342                            * cman,corosync,openais (or selection of them)
 343                            * singlenode            (localhost only)
 344                            * all                   (autodetect)
 345                            * none                  (disable build)
 346                           [TYPE=none] ],
 347   [ CLVMD="$withval" ],
 348   [ CLVMD="none" ])
 349 if test x$CLVMD = xyes; then
 350         CLVMD=all
 351 fi
 352 AC_MSG_RESULT($CLVMD)
 353
 354 dnl -- If clvmd enabled without cluster locking, automagically include it
 355 if  test x$CLVMD != xnone && test x$CLUSTER = xnone; then
 356         CLUSTER=internal
 357 fi
 358
 359 dnl -- init pkgconfig if required
 360 if  test x$CLVMD != xnone && test x$PKGCONFIG_INIT != x1; then
 361         pkg_config_init
 362 fi
 363
 364
 365 dnl -- define build types
 366 if [[ `expr x"$CLVMD" : '.*gulm.*'` != 0 ]]; then
 367         BUILDGULM=yes
 368 fi
 369 if [[ `expr x"$CLVMD" : '.*corosync.*'` != 0 ]]; then
 370         BUILDCOROSYNC=yes
 371 fi
 372 if [[ `expr x"$CLVMD" : '.*openais.*'` != 0 ]]; then
 373         BUILDOPENAIS=yes
 374 fi
 375 if [[ `expr x"$CLVMD" : '.*cman.*'` != 0 ]]; then
 376         BUILDCMAN=yes
 377 fi
 378
 379 dnl -- sanity check around user selection
 380 if test x$BUILDGULM = xyes; then
 381         if test x$BUILDCOROSYNC = xyes || \
 382            test x$BUILDOPENAIS = xyes; then
 383                 AC_MSG_ERROR([requested clvmd configuration is not valid])
 384         fi
 385 fi
 386
 387 dnl -- define a soft bailout if we are autodetecting
 388 soft_bailout() {
 389         NOTFOUND=1
 390 }
 391
 392 hard_bailout() {
 393         AC_MSG_ERROR([bailing out])
 394 }
 395
 396 dnl -- if clvmd=all then set soft_bailout (we don't want to error)
 397 dnl -- and set all builds to yes. We need to do this here
 398 dnl -- to skip the gulm + openais|corosync sanity check above.
 399 if test x$CLVMD = xall; then
 400         bailout=soft_bailout
 401         BUILDGULM=yes
 402         BUILDCMAN=yes
 403         BUILDCOROSYNC=yes
 404         BUILDOPENAIS=yes
 405 else
 406         bailout=hard_bailout
 407 fi
 408
 409 dnl -- helper macro to check libs without adding them to LIBS
 410 check_lib_no_libs() {
 411         lib_no_libs_arg1=$1
 412         shift
 413         lib_no_libs_arg2=$1
 414         shift
 415         lib_no_libs_args=$@
 416         AC_CHECK_LIB([$lib_no_libs_arg1],
 417                      [$lib_no_libs_arg2],,
 418                      [$bailout],
 419                      [$lib_no_libs_args])
 420         LIBS=$ac_check_lib_save_LIBS
 421 }
 422
 423 dnl -- Look for gulm libraries if required.
 424 if test x$BUILDGULM = xyes; then
 425         PKG_CHECK_MODULES(CCS, libccs, [HAVE_CCS=yes],
 426                 [NOTFOUND=0
 427                 AC_CHECK_HEADERS(ccs.h,,$bailout)
 428                 check_lib_no_libs ccs ccs_connect
 429                 if test $NOTFOUND = 0; then
 430                         AC_MSG_RESULT([no pkg for libccs, using -lccs])
 431                         CCS_LIBS="-lccs"
 432                         HAVE_CCS=yes
 433                 fi])
 434         PKG_CHECK_MODULES(GULM, libgulm, [HAVE_GULM=yes],
 435                 [NOTFOUND=0
 436                 AC_CHECK_HEADERS(libgulm.h,,$bailout)
 437                 check_lib_no_libs gulm lg_core_login
 438                 if test $NOTFOUND = 0; then
 439                         AC_MSG_RESULT([no pkg for libgulm, using -lgulm])
 440                         GULM_LIBS="-lgulm"
 441                         HAVE_GULM=yes
 442                 fi])
 443 fi
 444
 445 dnl -- Look for cman libraries if required.
 446 if test x$BUILDCMAN = xyes; then
 447         PKG_CHECK_MODULES(CMAN, libcman, [HAVE_CMAN=yes],
 448                 [NOTFOUND=0
 449                 AC_CHECK_HEADERS(libcman.h,,$bailout)
 450                 check_lib_no_libs cman cman_init
 451                 if test $NOTFOUND = 0; then
 452                         AC_MSG_RESULT([no pkg for libcman, using -lcman])
 453                         CMAN_LIBS="-lcman"
 454                         HAVE_CMAN=yes
 455                 fi])
 456         CHECKCONFDB=yes
 457         CHECKDLM=yes
 458 fi
 459
 460 dnl -- Look for corosync that's required also for openais build
 461 dnl -- only enough recent version of corosync ship pkg-config files.
 462 dnl -- We can safely rely on that to detect the correct bits.
 463 if test x$BUILDCOROSYNC = xyes || \
 464    test x$BUILDOPENAIS = xyes; then
 465         PKG_CHECK_MODULES(COROSYNC, corosync, [HAVE_COROSYNC=yes], $bailout)
 466         CHECKCONFDB=yes
 467 fi
 468
 469 dnl -- Look for corosync libraries if required.
 470 if test x$BUILDCOROSYNC = xyes; then
 471         PKG_CHECK_MODULES(QUORUM, libquorum, [HAVE_QUORUM=yes], $bailout)
 472         CHECKCPG=yes
 473         CHECKDLM=yes
 474 fi
 475
 476 dnl -- Look for openais libraries if required.
 477 if test x$BUILDOPENAIS = xyes; then
 478         PKG_CHECK_MODULES(SALCK, libSaLck, [HAVE_SALCK=yes], $bailout)
 479         CHECKCPG=yes
 480 fi
 481
 482 dnl -- Below are checks for libraries common to more than one build.
 483
 484 dnl -- Check confdb library.
 485 dnl -- mandatory for corosync build.
 486 dnl -- optional for openais/cman build.
 487
 488 if test x$CHECKCONFDB = xyes; then
 489         PKG_CHECK_MODULES(CONFDB, libconfdb,
 490                           [HAVE_CONFDB=yes],
 491                           [HAVE_CONFDB=no])
 492
 493         AC_CHECK_HEADERS(corosync/confdb.h,
 494                 [HAVE_CONFDB_H=yes],
 495                 [HAVE_CONFDB_H=no])
 496
 497         if test x$HAVE_CONFDB != xyes && \
 498            test x$HAVE_CONFDB_H = xyes; then
 499                 check_lib_no_libs confdb confdb_initialize
 500                 AC_MSG_RESULT([no pkg for confdb, using -lconfdb])
 501                 CONFDB_LIBS="-lconfdb"
 502                 HAVE_CONFDB=yes
 503         fi
 504
 505         if test x$BUILDCOROSYNC = xyes && \
 506            test x$HAVE_CONFDB != xyes &&
 507            test x$CLVMD != xall; then
 508                 AC_MSG_ERROR([bailing out... confdb library is required])
 509         fi
 510 fi
 511
 512 dnl -- Check cpg library.
 513 if test x$CHECKCPG = xyes; then
 514         PKG_CHECK_MODULES(CPG, libcpg, [HAVE_CPG=yes], $bailout)
 515 fi
 516
 517 dnl -- Check dlm library.
 518 if test x$CHECKDLM = xyes; then
 519         PKG_CHECK_MODULES(DLM, libdlm, [HAVE_DLM=yes],
 520                 [NOTFOUND=0
 521                 AC_CHECK_HEADERS(libdlm.h,,$bailout)
 522                 check_lib_no_libs dlm dlm_lock -lpthread
 523                 if test $NOTFOUND = 0; then
 524                         AC_MSG_RESULT([no pkg for libdlm, using -ldlm])
 525                         DLM_LIBS="-ldlm -lpthread"
 526                         HAVE_DLM=yes
 527                 fi])
 528 fi
 529
 530 dnl -- If we are autodetecting, we need to re-create
 531 dnl -- the depedencies checks and set a proper CLVMD.
 532 if test x$CLVMD = xall; then
 533         CLVMD=none
 534         if test x$HAVE_CCS = xyes && \
 535            test x$HAVE_GULM = xyes; then
 536                 AC_MSG_RESULT([Enabling clvmd gulm cluster manager])
 537                 CLVMD="$CLVMD,gulm"
 538         fi
 539         if test x$HAVE_CMAN = xyes && \
 540            test x$HAVE_DLM = xyes; then
 541                 AC_MSG_RESULT([Enabling clvmd cman cluster manager])
 542                 CLVMD="$CLVMD,cman"
 543         fi
 544         if test x$HAVE_COROSYNC = xyes && \
 545            test x$HAVE_QUORUM = xyes && \
 546            test x$HAVE_CPG = xyes && \
 547            test x$HAVE_DLM = xyes && \
 548            test x$HAVE_CONFDB = xyes; then
 549                 AC_MSG_RESULT([Enabling clvmd corosync cluster manager])
 550                 CLVMD="$CLVMD,corosync"
 551         fi
 552         if test x$HAVE_COROSYNC = xyes && \
 553            test x$HAVE_CPG = xyes && \
 554            test x$HAVE_SALCK = xyes; then
 555                 AC_MSG_RESULT([Enabling clvmd openais cluster manager])
 556                 CLVMD="$CLVMD,openais"
 557         fi
 558         if test x$CLVMD = xnone; then
 559                 AC_MSG_RESULT([Disabling clvmd build. No cluster manager detected.])
 560         fi
 561 fi
 562
 563 ################################################################################
 564 dnl -- Build cluster mirror log daemon
 565 AC_MSG_CHECKING(whether to build cluster mirror log daemon)
 566 AC_ARG_ENABLE(cmirrord, [  --enable-cmirrord       Enable the cluster mirror log daemon],
 567 CMIRRORD=$enableval, CMIRRORD=no)
 568 AC_MSG_RESULT($CMIRRORD)
 569
 570 BUILD_CMIRRORD=$CMIRRORD
 571
 572 ################################################################################
 573 dnl -- cmirrord pidfile
 574 AH_TEMPLATE(CMIRRORD_PIDFILE, [Path to cmirrord pidfile.])
 575 if test "x$BUILD_CMIRRORD" = xyes; then
 576         AC_ARG_WITH(cmirrord-pidfile,
 577                     [  --with-cmirrord-pidfile=PATH    cmirrord pidfile [[/var/run/cmirrord.pid]] ],
 578                     [ AC_DEFINE_UNQUOTED(CMIRRORD_PIDFILE,"$withval") ],
 579                     [ AC_DEFINE_UNQUOTED(CMIRRORD_PIDFILE,"/var/run/cmirrord.pid") ])
 580 fi
 581
 582 ################################################################################
 583 dnl -- Look for corosync libraries if required.
 584 if [[ "x$BUILD_CMIRRORD" = xyes ]]; then
 585         dnl -- init pkgconfig if required
 586         if  test x$PKGCONFIG_INIT != x1; then
 587                 pkg_config_init
 588         fi
 589         PKG_CHECK_MODULES(SACKPT, libSaCkpt)
 590         if test x$HAVE_CPG != xyes; then
 591                 PKG_CHECK_MODULES(CPG, libcpg)
 592         fi
 593 fi
 594
 595 ################################################################################
 596 dnl -- Enable debugging
 597 AC_MSG_CHECKING(whether to enable debugging)
 598 AC_ARG_ENABLE(debug,    [  --enable-debug          Enable debugging],
 599   DEBUG=$enableval, DEBUG=no)
 600 AC_MSG_RESULT($DEBUG)
 601
 602 dnl -- Normally turn off optimisation for debug builds
 603 if test x$DEBUG = xyes; then
 604         COPTIMISE_FLAG=
 605 else
 606         CSCOPE_CMD=
 607 fi
 608
 609 ################################################################################
 610 dnl -- Override optimisation
 611 AC_MSG_CHECKING(for C optimisation flag)
 612 AC_ARG_WITH(optimisation,
 613   [  --with-optimisation=OPT C optimisation flag [[OPT=-O2]] ],
 614   [ COPTIMISE_FLAG="$withval" ])
 615 AC_MSG_RESULT($COPTIMISE_FLAG)
 616
 617 ################################################################################
 618 dnl -- Enable profiling
 619 AC_MSG_CHECKING(whether to gather gcov profiling data)
 620 AC_ARG_ENABLE(profiling,
 621   AC_HELP_STRING(--enable-profiling, [Gather gcov profiling data]),
 622   PROFILING=$enableval, PROFILING=no)
 623 AC_MSG_RESULT($PROFILING)
 624
 625 if test "x$PROFILING" = xyes; then
 626   COPTIMISE_FLAG="$COPTIMISE_FLAG -fprofile-arcs -ftest-coverage"
 627   AC_PATH_PROG(LCOV, lcov, no)
 628   AC_PATH_PROG(GENHTML, genhtml, no)
 629   if test "$LCOV" = no -o "$GENHTML" = no ; then
 630     AC_MSG_ERROR([lcov and genhtml are required for profiling])
 631   fi
 632 fi
 633
 634 ################################################################################
 635 dnl -- Disable devmapper
 636 AC_MSG_CHECKING(whether to use device-mapper)
 637 AC_ARG_ENABLE(devmapper, [  --disable-devmapper     Disable LVM2 device-mapper interaction],
 638 DEVMAPPER=$enableval)
 639 AC_MSG_RESULT($DEVMAPPER)
 640
 641 if test x$DEVMAPPER = xyes; then
 642         AC_DEFINE([DEVMAPPER_SUPPORT], 1, [Define to 1 to enable LVM2 device-mapper interaction.])
 643 fi
 644
 645 ################################################################################
 646 dnl -- Enable udev synchronisation
 647 AC_MSG_CHECKING(whether to enable synchronisation with udev processing)
 648 AC_ARG_ENABLE(udev_sync, [  --enable-udev_sync      Enable synchronisation with udev processing],
 649 UDEV_SYNC=$enableval, UDEV_SYNC=no)
 650 AC_MSG_RESULT($UDEV_SYNC)
 651
 652 if test x$UDEV_SYNC = xyes; then
 653         AC_CHECK_LIB(udev, udev_queue_get_udev_is_active, UDEV_LIBS="-ludev", AC_MSG_ERROR(bailing out... libudev library is required))
 654         AC_DEFINE([UDEV_SYNC_SUPPORT], 1, [Define to 1 to enable synchronisation with udev processing.])
 655 fi
 656
 657 dnl -- Enable udev rules
 658 AC_MSG_CHECKING(whether to enable installation of udev rules required for synchronisation)
 659 AC_ARG_ENABLE(udev_rules, [  --enable-udev_rules     Install rule files needed for udev synchronisation],
 660 UDEV_RULES=$enableval, UDEV_RULES=$UDEV_SYNC)
 661 AC_MSG_RESULT($UDEV_RULES)
 662
 663 ################################################################################
 664 dnl -- Compatibility mode
 665 AC_ARG_ENABLE(compat,   [  --enable-compat         Enable support for old device-mapper versions],
 666   DM_COMPAT=$enableval, DM_COMPAT=no)
 667
 668 ################################################################################
 669 dnl -- Compatible units suffix mode
 670 AC_ARG_ENABLE(units-compat,
 671   [  --enable-units-compat   Enable output compatibility with old versions that
 672                           that don't use KiB-style unit suffixes],
 673   UNITS_COMPAT=$enableval, UNITS_COMPAT=no)
 674
 675 if test x$UNITS_COMPAT = xyes; then
 676         AC_DEFINE([DEFAULT_SI_UNIT_CONSISTENCY], 0, [Define to 0 to reinstate the pre-2.02.54 handling of unit suffixes.])
 677 fi
 678
 679 ################################################################################
 680 dnl -- Disable ioctl
 681 AC_ARG_ENABLE(ioctl,   [  --disable-driver        Disable calls to device-mapper in the kernel],
 682   DM_IOCTLS=$enableval)
 683
 684 ################################################################################
 685 dnl -- Disable O_DIRECT
 686 AC_MSG_CHECKING(whether to enable O_DIRECT)
 687 AC_ARG_ENABLE(o_direct, [  --disable-o_direct      Disable O_DIRECT],
 688 ODIRECT=$enableval)
 689 AC_MSG_RESULT($ODIRECT)
 690
 691 if test x$ODIRECT = xyes; then
 692         AC_DEFINE([O_DIRECT_SUPPORT], 1, [Define to 1 to enable O_DIRECT support.])
 693 fi
 694
 695 ################################################################################
 696 dnl -- Enable liblvm2app.so
 697 AC_MSG_CHECKING(whether to build liblvm2app.so application library)
 698 AC_ARG_ENABLE(applib,
 699   [  --enable-applib         Build application library],
 700   APPLIB=$enableval, APPLIB=no)
 701 AC_MSG_RESULT($APPLIB)
 702 AC_SUBST([LVM2APP_LIB])
 703 test x$APPLIB = xyes \
 704   && LVM2APP_LIB=-llvm2app \
 705   || LVM2APP_LIB=
 706
 707 ################################################################################
 708 dnl -- Enable cmdlib
 709 AC_MSG_CHECKING(whether to compile liblvm2cmd.so)
 710 AC_ARG_ENABLE(cmdlib, [  --enable-cmdlib         Build shared command library],
 711 CMDLIB=$enableval, CMDLIB=no)
 712 AC_MSG_RESULT($CMDLIB)
 713 AC_SUBST([LVM2CMD_LIB])
 714 test x$CMDLIB = xyes \
 715   && LVM2CMD_LIB=-llvm2cmd \
 716   || LVM2CMD_LIB=
 717
 718 ################################################################################
 719 dnl -- Enable pkg-config
 720 AC_ARG_ENABLE(pkgconfig,   [  --enable-pkgconfig      Install pkgconfig support],
 721   PKGCONFIG=$enableval, PKGCONFIG=no)
 722
 723 ################################################################################
 724 dnl -- Enable fsadm
 725 AC_MSG_CHECKING(whether to install fsadm)
 726 AC_ARG_ENABLE(fsadm, [AC_HELP_STRING([--disable-fsadm], [Disable fsadm])],
 727         FSADM=$enableval)
 728 AC_MSG_RESULT($FSADM)
 729
 730 ################################################################################
 731 dnl -- enable dmeventd handling
 732 AC_MSG_CHECKING(whether to use dmeventd)
 733 AC_ARG_ENABLE(dmeventd, [  --enable-dmeventd       Enable the device-mapper event daemon],
 734 DMEVENTD=$enableval)
 735 AC_MSG_RESULT($DMEVENTD)
 736
 737 BUILD_DMEVENTD=$DMEVENTD
 738
 739 dnl -- dmeventd currently requires internal mirror support
 740 if test x$DMEVENTD = xyes; then
 741    if test x$MIRRORS != xinternal; then
 742       AC_MSG_ERROR(
 743         --enable-dmeventd currently requires --with-mirrors=internal
 744       )
 745    fi
 746    if test x$CMDLIB = xno; then
 747       AC_MSG_ERROR(
 748         --enable-dmeventd requires --enable-cmdlib to be used as well
 749       )
 750    fi
 751 fi
 752
 753 if test x$DMEVENTD = xyes; then
 754         AC_DEFINE([DMEVENTD], 1, [Define to 1 to enable the device-mapper event daemon.])
 755 fi
 756
 757 ################################################################################
 758 dnl -- getline included in recent libc
 759
 760 AC_CHECK_LIB(c, getline, AC_DEFINE([HAVE_GETLINE], 1,
 761   [Define to 1 if getline is available.]))
 762
 763 ################################################################################
 764 dnl -- canonicalize_file_name included in recent libc
 765
 766 AC_CHECK_LIB(c, canonicalize_file_name,
 767   AC_DEFINE([HAVE_CANONICALIZE_FILE_NAME], 1,
 768     [Define to 1 if canonicalize_file_name is available.]))
 769
 770 ################################################################################
 771 dnl -- Clear default exec_prefix - install into /sbin rather than /usr/sbin
 772 if [[ "x$exec_prefix" = xNONE -a "x$prefix" = xNONE ]];
 773  then  exec_prefix="";
 774 fi;
 775
 776 ################################################################################
 777 dnl -- Check for dlopen
 778 AC_CHECK_LIB(dl, dlopen, [
 779         AC_DEFINE([HAVE_LIBDL], 1, [Define to 1 if dynamic libraries are available.])
 780         DL_LIBS="-ldl"
 781         HAVE_LIBDL=yes ], [
 782         DL_LIBS=
 783         HAVE_LIBDL=no ])
 784
 785 ################################################################################
 786 dnl -- Check for shared/static conflicts
 787 if [[ \( "x$LVM1" = xshared -o "x$POOL" = xshared -o "x$CLUSTER" = xshared \
 788       -o "x$SNAPSHOTS" = xshared -o "x$MIRRORS" = xshared \
 789       \) -a "x$STATIC_LINK" = xyes ]];
 790  then  AC_MSG_ERROR(
 791 Features cannot be 'shared' when building statically
 792 )
 793 fi
 794
 795 ################################################################################
 796 if [[ "$DMEVENTD" = yes -o "$CLVMD" != none ]] ; then
 797         AC_CHECK_LIB([pthread], [pthread_mutex_lock],
 798                 [PTHREAD_LIBS="-lpthread"], hard_bailout)
 799 fi
 800
 801 ################################################################################
 802 dnl -- Disable selinux
 803 AC_MSG_CHECKING(whether to enable selinux support)
 804 AC_ARG_ENABLE(selinux, [  --disable-selinux       Disable selinux support],
 805   SELINUX=$enableval)
 806 AC_MSG_RESULT($SELINUX)
 807
 808 ################################################################################
 809 dnl -- Check for selinux
 810 if test x$SELINUX = xyes; then
 811         AC_CHECK_LIB([sepol], [sepol_check_context], [
 812                 AC_DEFINE([HAVE_SEPOL], 1, [Define to 1 if sepol_check_context is available.])
 813                 SELINUX_LIBS="-lsepol"])
 814
 815         AC_CHECK_LIB([selinux], [is_selinux_enabled], [
 816                 AC_CHECK_HEADERS([selinux/selinux.h],, hard_bailout)
 817                 AC_DEFINE([HAVE_SELINUX], 1, [Define to 1 to include support for selinux.])
 818                 SELINUX_LIBS="-lselinux $SELINUX_LIBS"
 819                 HAVE_SELINUX=yes ], [
 820                 AC_MSG_WARN(Disabling selinux)
 821                 SELINUX_LIBS=
 822                 HAVE_SELINUX=no ])
 823 fi
 824
 825 ################################################################################
 826 dnl -- Check for realtime clock support
 827 if test x$REALTIME = xyes; then
 828         AC_CHECK_LIB(rt, clock_gettime, HAVE_REALTIME=yes, HAVE_REALTIME=no)
 829
 830         if test x$HAVE_REALTIME = xyes; then
 831                 AC_DEFINE([HAVE_REALTIME], 1, [Define to 1 to include support for realtime clock.])
 832                 LIBS="-lrt $LIBS"
 833         else
 834                 AC_MSG_WARN(Disabling realtime clock)
 835         fi
 836 fi
 837
 838 ################################################################################
 839 dnl -- Check for getopt
 840 AC_CHECK_HEADERS(getopt.h, AC_DEFINE([HAVE_GETOPTLONG], 1, [Define to 1 if getopt_long is available.]))
 841
 842 ################################################################################
 843 dnl -- Check for readline (Shamelessly copied from parted 1.4.17)
 844 if test x$READLINE != xno; then
 845         lvm_saved_libs=$LIBS
 846         AC_SEARCH_LIBS([tgetent], [tinfo ncurses curses termcap termlib],
 847                 READLINE_LIBS=$ac_cv_search_tgetent, [
 848                 if test "$READLINE" = yes; then
 849                         AC_MSG_ERROR(
 850 [termcap could not be found which is required for the
 851 --enable-readline option (which is enabled by default).  Either disable readline
 852 support with --disable-readline or download and install termcap from:
 853         ftp.gnu.org/gnu/termcap
 854 Note: if you are using precompiled packages you will also need the development
 855   package as well (which may be called termcap-devel or something similar).
 856 Note: (n)curses also seems to work as a substitute for termcap.  This was
 857   not found either - but you could try installing that as well.])
 858                 fi])
 859         dnl -- Old systems may need extra termcap dependency explicitly in LIBS
 860         AC_CHECK_LIB([readline], [readline], [
 861                 AC_DEFINE([READLINE_SUPPORT], 1,
 862                         [Define to 1 to include the LVM readline shell.])
 863                 dnl -- Try only with -lreadline and check for different symbol
 864                 LIBS=$lvm_saved_libs
 865                 AC_CHECK_LIB([readline], [rl_line_buffer],
 866                         [ READLINE_LIBS="-lreadline" ], [
 867                           AC_MSG_RESULT([linking -lreadline with $READLINE_LIBS needed])
 868                           READLINE_LIBS="-lreadline $READLINE_LIBS"
 869                         ]) ], [
 870                 READLINE_LIBS=
 871                 if test "$READLINE" = yes; then
 872                         AC_MSG_ERROR(
 873 [GNU Readline could not be found which is required for the
 874 --enable-readline option (which is enabled by default).  Either disable readline
 875 support with --disable-readline or download and install readline from:
 876         ftp.gnu.org/gnu/readline
 877 Note: if you are using precompiled packages you will also need the development
 878 package as well (which may be called readline-devel or something similar).])
 879                 fi ])
 880         LIBS="$READLINE_LIBS $lvm_saved_libs"
 881         AC_CHECK_FUNCS([rl_completion_matches])
 882         LIBS=$lvm_saved_libs
 883 fi
 884
 885 ################################################################################
 886 dnl -- Internationalisation stuff
 887 AC_MSG_CHECKING(whether to enable internationalisation)
 888 AC_ARG_ENABLE(nls, [  --enable-nls            Enable Native Language Support],
 889                 INTL=$enableval, INTL=no)
 890 AC_MSG_RESULT($INTL)
 891
 892 if test x$INTL = xyes; then
 893 # FIXME - Move this - can be device-mapper too
 894         INTL_PACKAGE="lvm2"
 895         AC_PATH_PROG(MSGFMT, msgfmt)
 896         if [[ "x$MSGFMT" == x ]];
 897                 then  AC_MSG_ERROR(
 898                 msgfmt not found in path $PATH
 899                 )
 900         fi;
 901
 902         AC_ARG_WITH(localedir,
 903                     [  --with-localedir=DIR    Translation files in DIR [[PREFIX/share/locale]] ],
 904                     [ LOCALEDIR="$withval" ],
 905                     [ LOCALEDIR='${prefix}/share/locale' ])
 906 fi
 907
 908 ################################################################################
 909 AC_ARG_WITH(confdir,
 910             [  --with-confdir=DIR      Configuration files in DIR [[/etc]]],
 911             [ CONFDIR="$withval" ],
 912             [ CONFDIR='/etc' ])
 913
 914 AC_ARG_WITH(staticdir,
 915             [  --with-staticdir=DIR    Static binary in DIR [[EPREFIX/sbin]]],
 916             [ STATICDIR="$withval" ],
 917             [ STATICDIR='${exec_prefix}/sbin' ])
 918
 919 AC_ARG_WITH(usrlibdir,
 920             [  --with-usrlibdir=DIR],
 921             [ usrlibdir="$withval"],
 922             [ usrlibdir='${prefix}/lib' ])
 923
 924 AC_ARG_WITH(usrsbindir,
 925             [  --with-usrsbindir=DIR],
 926             [ usrsbindir="$withval"],
 927             [ usrsbindir='${prefix}/sbin' ])
 928
 929 ################################################################################
 930 AC_ARG_WITH(udev_prefix,
 931             [  --with-udev-prefix=UPREFIX      Install udev rule files in UPREFIX [[EPREFIX]]],
 932             [ udev_prefix="$withval"],
 933             [ udev_prefix='${exec_prefix}' ])
 934
 935 AC_ARG_WITH(udevdir,
 936             [  --with-udevdir=DIR      udev rules in DIR [[UPREFIX/lib/udev/rules.d]]],
 937             [ udevdir="$withval"],
 938             [ udevdir='${udev_prefix}/lib/udev/rules.d' ])
 939
 940 ################################################################################
 941 dnl -- Ensure additional headers required
 942 if test x$READLINE = xyes; then
 943         AC_CHECK_HEADERS(readline/readline.h readline/history.h,,AC_MSG_ERROR(bailing out))
 944 fi
 945
 946 if test x$CLVMD != xnone; then
 947         AC_CHECK_HEADERS(mntent.h netdb.h netinet/in.h pthread.h search.h sys/mount.h sys/socket.h sys/uio.h sys/un.h utmpx.h,,AC_MSG_ERROR(bailing out))
 948         AC_CHECK_FUNCS(dup2 getmntent memmove select socket,,AC_MSG_ERROR(bailing out))
 949         AC_FUNC_GETMNTENT
 950 #       AC_FUNC_REALLOC
 951         AC_FUNC_SELECT_ARGTYPES
 952 fi
 953
 954 if test x$CLUSTER != xnone; then
 955         AC_CHECK_HEADERS(sys/socket.h sys/un.h,,AC_MSG_ERROR(bailing out))
 956         AC_CHECK_FUNCS(socket,,AC_MSG_ERROR(bailing out))
 957 fi
 958
 959 if test x$HAVE_LIBDL = xyes; then
 960         AC_CHECK_HEADERS(dlfcn.h,,AC_MSG_ERROR(bailing out))
 961 fi
 962
 963 if test x$INTL = xyes; then
 964         AC_CHECK_HEADERS(libintl.h,,AC_MSG_ERROR(bailing out))
 965 fi
 966
 967 if test x$UDEV_SYNC = xyes; then
 968         AC_CHECK_HEADERS(sys/ipc.h sys/sem.h,,AC_MSG_ERROR(bailing out))
 969 fi
 970
 971 ################################################################################
 972 AC_PATH_PROG(MODPROBE_CMD, modprobe)
 973
 974 if test x$MODPROBE_CMD != x; then
 975         AC_DEFINE_UNQUOTED([MODPROBE_CMD], ["$MODPROBE_CMD"], [The path to 'modprobe', if available.])
 976 fi
 977
 978 ################################################################################
 979 dnl -- dmeventd pidfile and executable path
 980 AH_TEMPLATE(DMEVENTD_PIDFILE, [Path to dmeventd pidfile.])
 981 if test "$BUILD_DMEVENTD" = yes; then
 982         AC_ARG_WITH(dmeventd-pidfile,
 983                     [  --with-dmeventd-pidfile=PATH    dmeventd pidfile [[/var/run/dmeventd.pid]] ],
 984                     [ AC_DEFINE_UNQUOTED(DMEVENTD_PIDFILE,"$withval") ],
 985                     [ AC_DEFINE_UNQUOTED(DMEVENTD_PIDFILE,"/var/run/dmeventd.pid") ])
 986 fi
 987
 988 AH_TEMPLATE(DMEVENTD_PATH, [Path to dmeventd binary.])
 989 if test "$BUILD_DMEVENTD" = yes; then
 990         dmeventd_prefix="$exec_prefix"
 991         if test "x$dmeventd_prefix" = "xNONE"; then
 992                 dmeventd_prefix="$prefix"
 993         fi
 994         if test "x$dmeventd_prefix" = "xNONE"; then
 995                 dmeventd_prefix=""
 996         fi
 997         AC_ARG_WITH(dmeventd-path,
 998                     [  --with-dmeventd-path=PATH       dmeventd path [[EPREFIX/sbin/dmeventd]] ],
 999                     [ AC_DEFINE_UNQUOTED(DMEVENTD_PATH,"$withval") ],
1000                     [ AC_DEFINE_UNQUOTED(DMEVENTD_PATH,"$dmeventd_prefix/sbin/dmeventd") ])
1001 fi
1002
1003 ################################################################################
1004 dnl -- which kernel interface to use (ioctl only)
1005 AC_MSG_CHECKING(for kernel interface choice)
1006 AC_ARG_WITH(interface,
1007   [  --with-interface=IFACE  Choose kernel interface (ioctl) [[ioctl]] ],
1008   [ interface="$withval" ],
1009   [ interface=ioctl ])
1010 if [[ "x$interface" != xioctl ]];
1011 then
1012   AC_MSG_ERROR(--with-interface=ioctl required. fs no longer supported.)
1013 fi
1014 AC_MSG_RESULT($interface)
1015
1016 ################################################################################
1017 DM_LIB_VERSION="\"`cat "$srcdir"/VERSION_DM 2>/dev/null || echo Unknown`\""
1018 AC_DEFINE_UNQUOTED(DM_LIB_VERSION, $DM_LIB_VERSION, [Library version])
1019
1020 DM_LIB_PATCHLEVEL=`cat "$srcdir"/VERSION_DM | $AWK -F '[[-. ]]' '{printf "%s.%s.%s",$1,$2,$3}'`
1021
1022 LVM_VERSION="\"`cat "$srcdir"/VERSION 2>/dev/null || echo Unknown`\""
1023
1024 VER=`cat "$srcdir"/VERSION`
1025 LVM_RELEASE_DATE="\"`echo $VER | $SED 's/.* (//;s/).*//'`\""
1026 VER=`echo "$VER" | $AWK '{print $1}'`
1027 LVM_RELEASE="\"`echo "$VER" | $AWK -F '-' '{print $2}'`\""
1028 VER=`echo "$VER" | $AWK -F '-' '{print $1}'`
1029 LVM_MAJOR=`echo "$VER" | $AWK -F '.' '{print $1}'`
1030 LVM_MINOR=`echo "$VER" | $AWK -F '.' '{print $2}'`
1031 LVM_PATCHLEVEL=`echo "$VER" | $AWK -F '[[(.]]' '{print $3}'`
1032 LVM_LIBAPI=`echo "$VER" | $AWK -F '[[()]]' '{print $2}'`
1033
1034 ################################################################################
1035 AC_SUBST(APPLIB)
1036 AC_SUBST(BUILD_CMIRRORD)
1037 AC_SUBST(BUILD_DMEVENTD)
1038 AC_SUBST(CCS_CFLAGS)
1039 AC_SUBST(CCS_LIBS)
1040 AC_SUBST(CFLAGS)
1041 AC_SUBST(CFLOW_CMD)
1042 AC_SUBST(CLDFLAGS)
1043 AC_SUBST(CLDNOWHOLEARCHIVE)
1044 AC_SUBST(CLDWHOLEARCHIVE)
1045 AC_SUBST(CLUSTER)
1046 AC_SUBST(CLVMD)
1047 AC_SUBST(CMAN_CFLAGS)
1048 AC_SUBST(CMAN_LIBS)
1049 AC_SUBST(CMDLIB)
1050 AC_SUBST(CONFDB_CFLAGS)
1051 AC_SUBST(CONFDB_LIBS)
1052 AC_SUBST(CONFDIR)
1053 AC_SUBST(COPTIMISE_FLAG)
1054 AC_SUBST(CPG_CFLAGS)
1055 AC_SUBST(CPG_LIBS)
1056 AC_SUBST(CSCOPE_CMD)
1057 AC_SUBST(DEBUG)
1058 AC_SUBST(DEVMAPPER)
1059 AC_SUBST(DLM_CFLAGS)
1060 AC_SUBST(DLM_LIBS)
1061 AC_SUBST(DL_LIBS)
1062 AC_SUBST(DMEVENTD)
1063 AC_SUBST(DM_COMPAT)
1064 AC_SUBST(DM_DEVICE_GID)
1065 AC_SUBST(DM_DEVICE_MODE)
1066 AC_SUBST(DM_DEVICE_UID)
1067 AC_SUBST(DM_IOCTLS)
1068 AC_SUBST(DM_LIB_VERSION)
1069 AC_SUBST(DM_LIB_PATCHLEVEL)
1070 AC_SUBST(FSADM)
1071 AC_SUBST(GROUP)
1072 AC_SUBST(GULM_CFLAGS)
1073 AC_SUBST(GULM_LIBS)
1074 AC_SUBST(HAVE_LIBDL)
1075 AC_SUBST(HAVE_REALTIME)
1076 AC_SUBST(INTL)
1077 AC_SUBST(INTL_PACKAGE)
1078 AC_SUBST(JOBS)
1079 AC_SUBST(LDDEPS)
1080 AC_SUBST(LIBS)
1081 AC_SUBST(LIB_SUFFIX)
1082 AC_SUBST(LOCALEDIR)
1083 AC_SUBST(LVM1)
1084 AC_SUBST(LVM1_FALLBACK)
1085 AC_SUBST(LVM_VERSION)
1086 AC_SUBST(LVM_LIBAPI)
1087 AC_SUBST(LVM_MAJOR)
1088 AC_SUBST(LVM_MINOR)
1089 AC_SUBST(LVM_PATCHLEVEL)
1090 AC_SUBST(LVM_RELEASE)
1091 AC_SUBST(LVM_RELEASE_DATE)
1092 AC_SUBST(MIRRORS)
1093 AC_SUBST(MSGFMT)
1094 AC_SUBST(OWNER)
1095 AC_SUBST(PKGCONFIG)
1096 AC_SUBST(POOL)
1097 AC_SUBST(PTHREAD_LIBS)
1098 AC_SUBST(QUORUM_CFLAGS)
1099 AC_SUBST(QUORUM_LIBS)
1100 AC_SUBST(READLINE_LIBS)
1101 AC_SUBST(SACKPT_CFLAGS)
1102 AC_SUBST(SACKPT_LIBS)
1103 AC_SUBST(SALCK_CFLAGS)
1104 AC_SUBST(SALCK_LIBS)
1105 AC_SUBST(SELINUX_LIBS)
1106 AC_SUBST(SNAPSHOTS)
1107 AC_SUBST(STATICDIR)
1108 AC_SUBST(STATIC_LINK)
1109 AC_SUBST(UDEV_LIBS)
1110 AC_SUBST(UDEV_RULES)
1111 AC_SUBST(UDEV_SYNC)
1112 AC_SUBST(interface)
1113 AC_SUBST(kerneldir)
1114 AC_SUBST(missingkernel)
1115 AC_SUBST(kernelvsn)
1116 AC_SUBST(tmpdir)
1117 AC_SUBST(udev_prefix)
1118 AC_SUBST(udevdir)
1119 AC_SUBST(usrlibdir)
1120 AC_SUBST(usrsbindir)
1121
1122 ################################################################################
1123 dnl -- First and last lines should not contain files to generate in order to
1124 dnl -- keep utility scripts running properly
1125 AC_CONFIG_FILES([
1126 Makefile
1127 make.tmpl
1128 daemons/Makefile
1129 daemons/clvmd/Makefile
1130 daemons/cmirrord/Makefile
1131 daemons/dmeventd/Makefile
1132 daemons/dmeventd/libdevmapper-event.pc
1133 daemons/dmeventd/plugins/Makefile
1134 daemons/dmeventd/plugins/lvm2/Makefile
1135 daemons/dmeventd/plugins/mirror/Makefile
1136 daemons/dmeventd/plugins/snapshot/Makefile
1137 doc/Makefile
1138 include/.symlinks
1139 include/Makefile
1140 lib/Makefile
1141 lib/format1/Makefile
1142 lib/format_pool/Makefile
1143 lib/locking/Makefile
1144 lib/mirror/Makefile
1145 lib/misc/lvm-version.h
1146 lib/snapshot/Makefile
1147 libdm/Makefile
1148 libdm/libdevmapper.pc
1149 liblvm/Makefile
1150 liblvm/liblvm2app.pc
1151 man/Makefile
1152 po/Makefile
1153 scripts/clvmd_init_red_hat
1154 scripts/cmirrord_init_red_hat
1155 scripts/lvm2_monitoring_init_red_hat
1156 scripts/Makefile
1157 test/Makefile
1158 test/api/Makefile
1159 tools/Makefile
1160 udev/Makefile
1161 ])
1162 AC_OUTPUT
1163
1164 if test x$ODIRECT != xyes; then
1165   AC_MSG_WARN(Warning: O_DIRECT disabled: low-memory pvmove may lock up)
1166 fi