configure.in

   1 ###############################################################################
   2 ## Copyright (C) 2000-2004 Sistina Software, Inc. All rights reserved.
   3 ## Copyright (C) 2004-2009 Red Hat, Inc. All rights reserved.
   4 ##
   5 ## This copyrighted material is made available to anyone wishing to use,
   6 ## modify, copy, or redistribute it subject to the terms and conditions
   7 ## of the GNU General Public License v.2.
   8 ##
   9 ## You should have received a copy of the GNU General Public License
  10 ## along with this program; if not, write to the Free Software Foundation,
  11 ## Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  12 ################################################################################
  13
  14 AC_PREREQ(2.61)
  15 ################################################################################
  16 dnl -- Process this file with autoconf to produce a configure script.
  17 AC_INIT
  18 AC_CONFIG_SRCDIR([lib/device/dev-cache.h])
  19 AC_CONFIG_HEADERS([lib/misc/configure.h])
  20
  21 ################################################################################
  22 dnl -- Setup the directory where autoconf has auxilary files
  23 AC_CONFIG_AUX_DIR(autoconf)
  24
  25 ################################################################################
  26 dnl -- Get system type
  27 AC_CANONICAL_TARGET([])
  28
  29 case "$host_os" in
  30         linux*)
  31                 CFLAGS="$CFLAGS"
  32                 COPTIMISE_FLAG="-O2"
  33                 CLDFLAGS="$CLDFLAGS -Wl,--version-script,.export.sym"
  34                 CLDWHOLEARCHIVE="-Wl,-whole-archive"
  35                 CLDNOWHOLEARCHIVE="-Wl,-no-whole-archive"
  36                 LDDEPS="$LDDEPS .export.sym"
  37                 LDFLAGS="$LDFLAGS -Wl,--export-dynamic"
  38                 LIB_SUFFIX=so
  39                 DEVMAPPER=yes
  40                 ODIRECT=yes
  41                 DM_IOCTLS=yes
  42                 SELINUX=yes
  43                 CLUSTER=internal
  44                 FSADM=yes
  45                 ;;
  46         darwin*)
  47                 CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
  48                 COPTIMISE_FLAG="-O2"
  49                 CLDFLAGS="$CLDFLAGS"
  50                 CLDWHOLEARCHIVE="-all_load"
  51                 CLDNOWHOLEARCHIVE=
  52                 LIB_SUFFIX=dylib
  53                 DEVMAPPER=yes
  54                 ODIRECT=no
  55                 DM_IOCTLS=no
  56                 SELINUX=no
  57                 CLUSTER=none
  58                 FSADM=no
  59                 ;;
  60 esac
  61
  62 ################################################################################
  63 dnl -- Checks for programs.
  64 AC_PROG_SED
  65 AC_PROG_AWK
  66 AC_PROG_CC
  67
  68 dnl probably no longer needed in 2008, but...
  69 AC_PROG_GCC_TRADITIONAL
  70 AC_PROG_INSTALL
  71 AC_PROG_LN_S
  72 AC_PROG_MAKE_SET
  73 AC_PROG_MKDIR_P
  74 AC_PROG_RANLIB
  75 AC_PATH_PROG(CFLOW_CMD, cflow)
  76 AC_PATH_PROG(CSCOPE_CMD, cscope)
  77
  78 ################################################################################
  79 dnl -- Check for header files.
  80 AC_HEADER_DIRENT
  81 AC_HEADER_MAJOR
  82 AC_HEADER_STDC
  83 AC_HEADER_SYS_WAIT
  84 AC_HEADER_TIME
  85
  86 AC_CHECK_HEADERS([locale.h stddef.h syslog.h sys/file.h sys/time.h assert.h \
  87   langinfo.h libgen.h signal.h sys/mman.h sys/resource.h sys/utsname.h \
  88   sys/wait.h time.h], ,
  89   [AC_MSG_ERROR(bailing out)])
  90
  91 case "$host_os" in
  92         linux*)
  93                 AC_CHECK_HEADERS(asm/byteorder.h linux/fs.h malloc.h,,AC_MSG_ERROR(bailing out)) ;;
  94         darwin*)
  95                 AC_CHECK_HEADERS(machine/endian.h sys/disk.h,,AC_MSG_ERROR(bailing out)) ;;
  96 esac
  97
  98 AC_CHECK_HEADERS([ctype.h dirent.h errno.h fcntl.h getopt.h inttypes.h limits.h \
  99   stdarg.h stdio.h stdlib.h string.h sys/ioctl.h sys/param.h sys/stat.h \
 100   sys/types.h unistd.h], , [AC_MSG_ERROR(bailing out)])
 101 AC_CHECK_HEADERS(termios.h sys/statvfs.h)
 102
 103 ################################################################################
 104 dnl -- Check for typedefs, structures, and compiler characteristics.
 105 AC_C_CONST
 106 AC_C_INLINE
 107 AC_CHECK_MEMBERS([struct stat.st_rdev])
 108 AC_TYPE_OFF_T
 109 AC_TYPE_PID_T
 110 AC_TYPE_SIGNAL
 111 AC_TYPE_SIZE_T
 112 AC_TYPE_MODE_T
 113 AC_TYPE_INT8_T
 114 AC_TYPE_INT16_T
 115 AC_TYPE_INT32_T
 116 AC_TYPE_INT64_T
 117 AC_TYPE_SSIZE_T
 118 AC_TYPE_UID_T
 119 AC_TYPE_UINT8_T
 120 AC_TYPE_UINT16_T
 121 AC_TYPE_UINT32_T
 122 AC_TYPE_UINT64_T
 123 AC_CHECK_MEMBERS([struct stat.st_rdev])
 124 AC_STRUCT_TM
 125
 126 ################################################################################
 127 dnl -- Check for functions
 128 AC_CHECK_FUNCS([ftruncate gethostname getpagesize \
 129   gettimeofday memset mkdir mkfifo rmdir munmap nl_langinfo setenv setlocale \
 130   strcasecmp strchr strcspn strspn strdup strncasecmp strerror strrchr \
 131   strstr strtol strtoul uname], , [AC_MSG_ERROR(bailing out)])
 132 AC_CHECK_FUNCS(siginterrupt)
 133 AC_FUNC_ALLOCA
 134 AC_FUNC_CLOSEDIR_VOID
 135 AC_FUNC_CHOWN
 136 AC_FUNC_FORK
 137 AC_FUNC_LSTAT
 138 AC_FUNC_MALLOC
 139 AC_FUNC_MEMCMP
 140 AC_FUNC_MMAP
 141 AC_FUNC_REALLOC
 142 AC_FUNC_STAT
 143 AC_FUNC_STRTOD
 144 AC_FUNC_VPRINTF
 145
 146 ################################################################################
 147 dnl -- Enables statically-linked tools
 148 AC_MSG_CHECKING(whether to use static linking)
 149 AC_ARG_ENABLE(static_link,
 150               AC_HELP_STRING([--enable-static_link],
 151                              [use this to link the tools to their libraries
 152                               statically (default is dynamic linking]),
 153               STATIC_LINK=$enableval, STATIC_LINK=no)
 154 AC_MSG_RESULT($STATIC_LINK)
 155
 156 ################################################################################
 157 dnl -- Prefix is /usr by default, the exec_prefix default is setup later
 158 AC_PREFIX_DEFAULT(/usr)
 159
 160 ################################################################################
 161 dnl -- Setup the ownership of the files
 162 AC_MSG_CHECKING(file owner)
 163 AC_ARG_WITH(user,
 164             AC_HELP_STRING([--with-user=USER],
 165                            [set the owner of installed files [[USER=]]]),
 166             OWNER=$withval)
 167 AC_MSG_RESULT($OWNER)
 168
 169 if test x$OWNER != x; then
 170         INSTALL="$INSTALL -o $OWNER"
 171 fi
 172
 173 ################################################################################
 174 dnl -- Setup the group ownership of the files
 175 AC_MSG_CHECKING(group owner)
 176 AC_ARG_WITH(group,
 177             AC_HELP_STRING([--with-group=GROUP],
 178                            [set the group owner of installed files [[GROUP=]]]),
 179             GROUP=$withval)
 180 AC_MSG_RESULT($GROUP)
 181
 182 if test x$GROUP != x; then
 183         INSTALL="$INSTALL -g $GROUP"
 184 fi
 185
 186 ################################################################################
 187 dnl -- Setup device node ownership
 188 AC_MSG_CHECKING(device node uid)
 189
 190 AC_ARG_WITH(device-uid,
 191             AC_HELP_STRING([--with-device-uid=UID],
 192                            [set the owner used for new device nodes [[UID=0]]]),
 193             DM_DEVICE_UID=$withval, DM_DEVICE_UID=0)
 194 AC_MSG_RESULT($DM_DEVICE_UID)
 195
 196 ################################################################################
 197 dnl -- Setup device group ownership
 198 AC_MSG_CHECKING(device node gid)
 199
 200 AC_ARG_WITH(device-gid,
 201             AC_HELP_STRING([--with-device-gid=GID],
 202                            [set the group used for new device nodes [[GID=0]]]),
 203             DM_DEVICE_GID=$withval, DM_DEVICE_GID=0)
 204 AC_MSG_RESULT($DM_DEVICE_GID)
 205
 206 ################################################################################
 207 dnl -- Setup device mode
 208 AC_MSG_CHECKING(device node mode)
 209
 210 AC_ARG_WITH(device-mode,
 211             AC_HELP_STRING([--with-device-mode=MODE],
 212                            [set the mode used for new device nodes [[MODE=0600]]]),
 213             DM_DEVICE_MODE=$withval, DM_DEVICE_MODE=0600)
 214 AC_MSG_RESULT($DM_DEVICE_MODE)
 215
 216 AC_MSG_CHECKING(when to create device nodes)
 217 AC_ARG_WITH(device-nodes-on,
 218             AC_HELP_STRING([--with-device-nodes-on=ON],
 219                            [create nodes on resume or create [[ON=resume]]]),
 220             ADD_NODE=$withval, ADD_NODE=resume)
 221 case "$ADD_NODE" in
 222  resume) add_on=DM_ADD_NODE_ON_RESUME;;
 223  create) add_on=DM_ADD_NODE_ON_CREATE;;
 224  *) AC_MSG_ERROR([--with-device-nodes-on parameter invalid]);;
 225 esac
 226 AC_MSG_RESULT(on $ADD_NODE)
 227 AC_DEFINE_UNQUOTED([DEFAULT_DM_ADD_NODE], $add_on, [Define default node creation behavior with dmsetup create])
 228
 229 ################################################################################
 230 dnl -- LVM1 tool fallback option
 231 AC_MSG_CHECKING(whether to enable lvm1 fallback)
 232 AC_ARG_ENABLE(lvm1_fallback,
 233               AC_HELP_STRING([--enable-lvm1_fallback],
 234                              [use this to fall back and use LVM1 binaries if
 235                               device-mapper is missing from the kernel]),
 236               LVM1_FALLBACK=$enableval, LVM1_FALLBACK=no)
 237 AC_MSG_RESULT($LVM1_FALLBACK)
 238
 239 if test x$LVM1_FALLBACK = xyes; then
 240         AC_DEFINE([LVM1_FALLBACK], 1, [Define to 1 if 'lvm' should fall back to using LVM1 binaries if device-mapper is missing from the kernel])
 241 fi
 242
 243 ################################################################################
 244 dnl -- format1 inclusion type
 245 AC_MSG_CHECKING(whether to include support for lvm1 metadata)
 246 AC_ARG_WITH(lvm1,
 247             AC_HELP_STRING([--with-lvm1=TYPE],
 248                            [LVM1 metadata support: internal/shared/none
 249                             [[TYPE=internal]]]),
 250             LVM1=$withval, LVM1=internal)
 251 AC_MSG_RESULT($LVM1)
 252
 253 if [[ "x$LVM1" != xnone -a "x$LVM1" != xinternal -a "x$LVM1" != xshared ]];
 254  then  AC_MSG_ERROR(
 255 --with-lvm1 parameter invalid
 256 )
 257 fi;
 258
 259 if test x$LVM1 = xinternal; then
 260         AC_DEFINE([LVM1_INTERNAL], 1, [Define to 1 to include built-in support for LVM1 metadata.])
 261 fi
 262
 263 ################################################################################
 264 dnl -- format_pool inclusion type
 265 AC_MSG_CHECKING(whether to include support for GFS pool metadata)
 266 AC_ARG_WITH(pool,
 267             AC_HELP_STRING([--with-pool=TYPE],
 268                            [GFS pool read-only support: internal/shared/none
 269                             [[TYPE=internal]]]),
 270             POOL=$withval, POOL=internal)
 271 AC_MSG_RESULT($POOL)
 272
 273 if [[ "x$POOL" != xnone -a "x$POOL" != xinternal -a "x$POOL" != xshared ]];
 274  then  AC_MSG_ERROR(
 275 --with-pool parameter invalid
 276 )
 277 fi;
 278
 279 if test x$POOL = xinternal; then
 280         AC_DEFINE([POOL_INTERNAL], 1, [Define to 1 to include built-in support for GFS pool metadata.])
 281 fi
 282
 283 ################################################################################
 284 dnl -- cluster_locking inclusion type
 285 AC_MSG_CHECKING(whether to include support for cluster locking)
 286 AC_ARG_WITH(cluster,
 287             AC_HELP_STRING([--with-cluster=TYPE],
 288                            [cluster LVM locking support: internal/shared/none
 289                             [[TYPE=internal]]]),
 290             CLUSTER=$withval)
 291 AC_MSG_RESULT($CLUSTER)
 292
 293 if [[ "x$CLUSTER" != xnone -a "x$CLUSTER" != xinternal -a "x$CLUSTER" != xshared ]];
 294  then  AC_MSG_ERROR(
 295 --with-cluster parameter invalid
 296 )
 297 fi;
 298
 299 if test x$CLUSTER = xinternal; then
 300         AC_DEFINE([CLUSTER_LOCKING_INTERNAL], 1, [Define to 1 to include built-in support for clustered LVM locking.])
 301 fi
 302
 303 ################################################################################
 304 dnl -- snapshots inclusion type
 305 AC_MSG_CHECKING(whether to include snapshots)
 306 AC_ARG_WITH(snapshots,
 307             AC_HELP_STRING([--with-snapshots=TYPE],
 308                            [snapshot support: internal/shared/none
 309                             [[TYPE=internal]]]),
 310             SNAPSHOTS=$withval, SNAPSHOTS=internal)
 311 AC_MSG_RESULT($SNAPSHOTS)
 312
 313 if [[ "x$SNAPSHOTS" != xnone -a "x$SNAPSHOTS" != xinternal -a "x$SNAPSHOTS" != xshared ]];
 314  then  AC_MSG_ERROR(
 315 --with-snapshots parameter invalid
 316 )
 317 fi;
 318
 319 if test x$SNAPSHOTS = xinternal; then
 320         AC_DEFINE([SNAPSHOT_INTERNAL], 1, [Define to 1 to include built-in support for snapshots.])
 321 fi
 322
 323 ################################################################################
 324 dnl -- mirrors inclusion type
 325 AC_MSG_CHECKING(whether to include mirrors)
 326 AC_ARG_WITH(mirrors,
 327             AC_HELP_STRING([--with-mirrors=TYPE],
 328                            [mirror support: internal/shared/none
 329                             [[TYPE=internal]]]),
 330             MIRRORS=$withval, MIRRORS=internal)
 331 AC_MSG_RESULT($MIRRORS)
 332
 333 if [[ "x$MIRRORS" != xnone -a "x$MIRRORS" != xinternal -a "x$MIRRORS" != xshared ]];
 334  then  AC_MSG_ERROR(
 335 --with-mirrors parameter invalid
 336 )
 337 fi;
 338
 339 if test x$MIRRORS = xinternal; then
 340         AC_DEFINE([MIRRORED_INTERNAL], 1, [Define to 1 to include built-in support for mirrors.])
 341 fi
 342
 343 ################################################################################
 344 dnl -- asynchronous volume replicator inclusion type
 345 AC_MSG_CHECKING(whether to include replicators)
 346 AC_ARG_WITH(replicators,
 347             AC_HELP_STRING([--with-replicators=TYPE],
 348                            [replicator support: internal/shared/none
 349                             [[TYPE=none]]]),
 350             REPLICATORS=$withval, REPLICATORS=none)
 351 AC_MSG_RESULT($REPLICATORS)
 352
 353 case "$REPLICATORS" in
 354   none|shared) ;;
 355   internal) AC_DEFINE([REPLICATOR_INTERNAL], 1,
 356                 [Define to 1 to include built-in support for replicators.]) ;;
 357   *) AC_MSG_ERROR([--with-replicators parameter invalid ($REPLICATORS)]) ;;
 358 esac
 359
 360 ################################################################################
 361 dnl -- Disable readline
 362 AC_MSG_CHECKING(whether to enable readline)
 363 AC_ARG_ENABLE([readline],
 364               AC_HELP_STRING([--disable-readline], [disable readline support]),
 365               READLINE=$enableval, READLINE=maybe)
 366 AC_MSG_RESULT($READLINE)
 367
 368 ################################################################################
 369 dnl -- Disable realtime clock support
 370 AC_MSG_CHECKING(whether to enable realtime support)
 371 AC_ARG_ENABLE(realtime,
 372               AC_HELP_STRING([--enable-realtime], [enable realtime clock support]),
 373               REALTIME=$enableval)
 374 AC_MSG_RESULT($REALTIME)
 375
 376 ################################################################################
 377 dnl -- disable OCF resource agents
 378 AC_MSG_CHECKING(whether to enable OCF resource agents)
 379 AC_ARG_ENABLE(ocf,
 380               AC_HELP_STRING([--enable-ocf],
 381                              [enable Open Cluster Framework (OCF) compliant resource agents]),
 382               OCF=$enableval, OCF=no)
 383 AC_MSG_RESULT($OCF)
 384 AC_ARG_WITH(ocfdir,
 385             AC_HELP_STRING([--with-ocfdir=DIR],
 386                            [install OCF files in DIR [[PREFIX/lib/ocf/resource.d/lvm2]]]),
 387             OCFDIR=$withval, OCFDIR='${prefix}/lib/ocf/resource.d/lvm2')
 388
 389 ################################################################################
 390 dnl -- Init pkg-config with dummy invokation:
 391 dnl -- this is required because PKG_CHECK_MODULES macro is expanded
 392 dnl -- to initialize the pkg-config environment only at the first invokation,
 393 dnl -- that would be conditional in this configure.in.
 394 pkg_config_init() {
 395         PKG_CHECK_MODULES(PKGCONFIGINIT, pkgconfiginit, [],
 396                 [AC_MSG_RESULT([pkg-config initialized])])
 397         PKGCONFIG_INIT=1
 398 }
 399
 400 ################################################################################
 401 dnl -- Build cluster LVM daemon
 402 AC_MSG_CHECKING(whether to build cluster LVM daemon)
 403 AC_ARG_WITH(clvmd,
 404   [  --with-clvmd=TYPE       build cluster LVM Daemon
 405                           The following cluster manager combinations are valid:
 406                            * cman,gulm             (RHEL4 or equivalent)
 407                            * cman                  (RHEL5 or equivalent)
 408                            * cman,corosync,openais (or selection of them)
 409                            * singlenode            (localhost only)
 410                            * all                   (autodetect)
 411                            * none                  (disable build)
 412                           [[TYPE=none]]],
 413             CLVMD=$withval, CLVMD=none)
 414 if test x$CLVMD = xyes; then
 415         CLVMD=all
 416 fi
 417 AC_MSG_RESULT($CLVMD)
 418
 419 dnl -- If clvmd enabled without cluster locking, automagically include it
 420 if  test x$CLVMD != xnone && test x$CLUSTER = xnone; then
 421         CLUSTER=internal
 422 fi
 423
 424 dnl -- init pkgconfig if required
 425 if test x$CLVMD != xnone && test x$PKGCONFIG_INIT != x1; then
 426         pkg_config_init
 427 fi
 428
 429 dnl -- Express clvmd init script Required-Start / Required-Stop
 430 CLVMD_CMANAGERS=""
 431 dnl -- On RHEL4/RHEL5, qdiskd is started from a separate init script.
 432 dnl -- Enable if we are build for either cman or gulm.
 433 CLVMD_NEEDS_QDISKD=no
 434
 435 dnl -- define build types
 436 if [[ `expr x"$CLVMD" : '.*gulm.*'` != 0 ]]; then
 437         BUILDGULM=yes
 438         CLVMD_CMANAGERS="$CLVMD_CMANAGERS lock_gulmd"
 439         CLVMD_NEEDS_QDISKD=yes
 440 fi
 441 if [[ `expr x"$CLVMD" : '.*cman.*'` != 0 ]]; then
 442         BUILDCMAN=yes
 443         CLVMD_CMANAGERS="$CLVMD_CMANAGERS cman"
 444         CLVMD_NEEDS_QDISKD=yes
 445 fi
 446 if [[ `expr x"$CLVMD" : '.*corosync.*'` != 0 ]]; then
 447         BUILDCOROSYNC=yes
 448         CLVMD_CMANAGERS="$CLVMD_CMANAGERS corosync"
 449 fi
 450 if [[ `expr x"$CLVMD" : '.*openais.*'` != 0 ]]; then
 451         BUILDOPENAIS=yes
 452         CLVMD_CMANAGERS="$CLVMD_CMANAGERS openais"
 453 fi
 454 if test x$CLVMD_NEEDS_QDISKD != xno; then
 455         CLVMD_CMANAGERS="$CLVMD_CMANAGERS qdiskd"
 456 fi
 457
 458 dnl -- sanity check around user selection
 459 if test x$BUILDGULM = xyes; then
 460         if test x$BUILDCOROSYNC = xyes || \
 461            test x$BUILDOPENAIS = xyes; then
 462                 AC_MSG_ERROR([requested clvmd configuration is not valid])
 463         fi
 464 fi
 465
 466 dnl -- define a soft bailout if we are autodetecting
 467 soft_bailout() {
 468         NOTFOUND=1
 469 }
 470
 471 hard_bailout() {
 472         AC_MSG_ERROR([bailing out])
 473 }
 474
 475 dnl -- if clvmd=all then set soft_bailout (we don't want to error)
 476 dnl -- and set all builds to yes. We need to do this here
 477 dnl -- to skip the gulm + openais|corosync sanity check above.
 478 if test x$CLVMD = xall; then
 479         bailout=soft_bailout
 480         BUILDGULM=yes
 481         BUILDCMAN=yes
 482         BUILDCOROSYNC=yes
 483         BUILDOPENAIS=yes
 484 else
 485         bailout=hard_bailout
 486 fi
 487
 488 dnl -- helper macro to check libs without adding them to LIBS
 489 check_lib_no_libs() {
 490         lib_no_libs_arg1=$1
 491         shift
 492         lib_no_libs_arg2=$1
 493         shift
 494         lib_no_libs_args=$@
 495         AC_CHECK_LIB([$lib_no_libs_arg1],
 496                      [$lib_no_libs_arg2],,
 497                      [$bailout],
 498                      [$lib_no_libs_args])
 499         LIBS=$ac_check_lib_save_LIBS
 500 }
 501
 502 dnl -- Look for gulm libraries if required.
 503 if test x$BUILDGULM = xyes; then
 504         PKG_CHECK_MODULES(CCS, libccs, [HAVE_CCS=yes],
 505                 [NOTFOUND=0
 506                 AC_CHECK_HEADERS(ccs.h,,$bailout)
 507                 check_lib_no_libs ccs ccs_connect
 508                 if test $NOTFOUND = 0; then
 509                         AC_MSG_RESULT([no pkg for libccs, using -lccs])
 510                         CCS_LIBS="-lccs"
 511                         HAVE_CCS=yes
 512                 fi])
 513         PKG_CHECK_MODULES(GULM, libgulm, [HAVE_GULM=yes],
 514                 [NOTFOUND=0
 515                 AC_CHECK_HEADERS(libgulm.h,,$bailout)
 516                 check_lib_no_libs gulm lg_core_login
 517                 if test $NOTFOUND = 0; then
 518                         AC_MSG_RESULT([no pkg for libgulm, using -lgulm])
 519                         GULM_LIBS="-lgulm"
 520                         HAVE_GULM=yes
 521                 fi])
 522 fi
 523
 524 dnl -- Look for cman libraries if required.
 525 if test x$BUILDCMAN = xyes; then
 526         PKG_CHECK_MODULES(CMAN, libcman, [HAVE_CMAN=yes],
 527                 [NOTFOUND=0
 528                 AC_CHECK_HEADERS(libcman.h,,$bailout)
 529                 check_lib_no_libs cman cman_init
 530                 if test $NOTFOUND = 0; then
 531                         AC_MSG_RESULT([no pkg for libcman, using -lcman])
 532                         CMAN_LIBS="-lcman"
 533                         HAVE_CMAN=yes
 534                 fi])
 535         CHECKCONFDB=yes
 536         CHECKDLM=yes
 537 fi
 538
 539 dnl -- Look for corosync that's required also for openais build
 540 dnl -- only enough recent version of corosync ship pkg-config files.
 541 dnl -- We can safely rely on that to detect the correct bits.
 542 if test x$BUILDCOROSYNC = xyes || \
 543    test x$BUILDOPENAIS = xyes; then
 544         PKG_CHECK_MODULES(COROSYNC, corosync, [HAVE_COROSYNC=yes], $bailout)
 545         CHECKCONFDB=yes
 546 fi
 547
 548 dnl -- Look for corosync libraries if required.
 549 if test x$BUILDCOROSYNC = xyes; then
 550         PKG_CHECK_MODULES(QUORUM, libquorum, [HAVE_QUORUM=yes], $bailout)
 551         CHECKCPG=yes
 552         CHECKDLM=yes
 553 fi
 554
 555 dnl -- Look for openais libraries if required.
 556 if test x$BUILDOPENAIS = xyes; then
 557         PKG_CHECK_MODULES(SALCK, libSaLck, [HAVE_SALCK=yes], $bailout)
 558         CHECKCPG=yes
 559 fi
 560
 561 dnl -- Below are checks for libraries common to more than one build.
 562
 563 dnl -- Check confdb library.
 564 dnl -- mandatory for corosync build.
 565 dnl -- optional for openais/cman build.
 566
 567 if test x$CHECKCONFDB = xyes; then
 568         PKG_CHECK_MODULES(CONFDB, libconfdb,
 569                           [HAVE_CONFDB=yes],
 570                           [HAVE_CONFDB=no])
 571
 572         AC_CHECK_HEADERS(corosync/confdb.h,
 573                 [HAVE_CONFDB_H=yes],
 574                 [HAVE_CONFDB_H=no])
 575
 576         if test x$HAVE_CONFDB != xyes && \
 577            test x$HAVE_CONFDB_H = xyes; then
 578                 check_lib_no_libs confdb confdb_initialize
 579                 AC_MSG_RESULT([no pkg for confdb, using -lconfdb])
 580                 CONFDB_LIBS="-lconfdb"
 581                 HAVE_CONFDB=yes
 582         fi
 583
 584         if test x$BUILDCOROSYNC = xyes && \
 585            test x$HAVE_CONFDB != xyes &&
 586            test x$CLVMD != xall; then
 587                 AC_MSG_ERROR([bailing out... confdb library is required])
 588         fi
 589 fi
 590
 591 dnl -- Check cpg library.
 592 if test x$CHECKCPG = xyes; then
 593         PKG_CHECK_MODULES(CPG, libcpg, [HAVE_CPG=yes], $bailout)
 594 fi
 595
 596 dnl -- Check dlm library.
 597 if test x$CHECKDLM = xyes; then
 598         PKG_CHECK_MODULES(DLM, libdlm, [HAVE_DLM=yes],
 599                 [NOTFOUND=0
 600                 AC_CHECK_HEADERS(libdlm.h,,$bailout)
 601                 check_lib_no_libs dlm dlm_lock -lpthread
 602                 if test $NOTFOUND = 0; then
 603                         AC_MSG_RESULT([no pkg for libdlm, using -ldlm])
 604                         DLM_LIBS="-ldlm -lpthread"
 605                         HAVE_DLM=yes
 606                 fi])
 607 fi
 608
 609 dnl -- If we are autodetecting, we need to re-create
 610 dnl -- the depedencies checks and set a proper CLVMD,
 611 dnl -- together with init script Required-Start/Stop entries.
 612 if test x$CLVMD = xall; then
 613         CLVMD=none
 614         CLVMD_CMANAGERS=""
 615         CLVMD_NEEDS_QDISKD=no
 616         if test x$HAVE_CCS = xyes && \
 617            test x$HAVE_GULM = xyes; then
 618                 AC_MSG_RESULT([Enabling clvmd gulm cluster manager])
 619                 CLVMD="$CLVMD,gulm"
 620                 CLVMD_CMANAGERS="$CLVMD_CMANAGERS lock_gulmd"
 621                 CLVMD_NEEDS_QDISKD=yes
 622         fi
 623         if test x$HAVE_CMAN = xyes && \
 624            test x$HAVE_DLM = xyes; then
 625                 AC_MSG_RESULT([Enabling clvmd cman cluster manager])
 626                 CLVMD="$CLVMD,cman"
 627                 CLVMD_CMANAGERS="$CLVMD_CMANAGERS cman"
 628                 CLVMD_NEEDS_QDISKD=yes
 629         fi
 630         if test x$HAVE_COROSYNC = xyes && \
 631            test x$HAVE_QUORUM = xyes && \
 632            test x$HAVE_CPG = xyes && \
 633            test x$HAVE_DLM = xyes && \
 634            test x$HAVE_CONFDB = xyes; then
 635                 AC_MSG_RESULT([Enabling clvmd corosync cluster manager])
 636                 CLVMD="$CLVMD,corosync"
 637                 CLVMD_CMANAGERS="$CLVMD_CMANAGERS corosync"
 638         fi
 639         if test x$HAVE_COROSYNC = xyes && \
 640            test x$HAVE_CPG = xyes && \
 641            test x$HAVE_SALCK = xyes; then
 642                 AC_MSG_RESULT([Enabling clvmd openais cluster manager])
 643                 CLVMD="$CLVMD,openais"
 644                 CLVMD_CMANAGERS="$CLVMD_CMANAGERS openais"
 645         fi
 646         if test x$CLVMD_NEEDS_QDISKD != xno; then
 647                 CLVMD_CMANAGERS="$CLVMD_CMANAGERS qdiskd"
 648         fi
 649         if test x$CLVMD = xnone; then
 650                 AC_MSG_RESULT([Disabling clvmd build. No cluster manager detected.])
 651         fi
 652 fi
 653
 654 ################################################################################
 655 dnl -- clvmd pidfile
 656 if test "x$CLVMD" != xnone; then
 657         AC_ARG_WITH(clvmd-pidfile,
 658                     AC_HELP_STRING([--with-clvmd-pidfile=PATH],
 659                                    [clvmd pidfile [[/var/run/clvmd.pid]]]),
 660                     CLVMD_PIDFILE=$withval,
 661                     CLVMD_PIDFILE="/var/run/clvmd.pid")
 662         AC_DEFINE_UNQUOTED(CLVMD_PIDFILE, ["$CLVMD_PIDFILE"],
 663                            [Path to clvmd pidfile.])
 664 fi
 665
 666 ################################################################################
 667 dnl -- Build cluster mirror log daemon
 668 AC_MSG_CHECKING(whether to build cluster mirror log daemon)
 669 AC_ARG_ENABLE(cmirrord,
 670               AC_HELP_STRING([--enable-cmirrord],
 671                              [enable the cluster mirror log daemon]),
 672               CMIRRORD=$enableval, CMIRRORD=no)
 673 AC_MSG_RESULT($CMIRRORD)
 674
 675 BUILD_CMIRRORD=$CMIRRORD
 676
 677 ################################################################################
 678 dnl -- cmirrord pidfile
 679 if test "x$BUILD_CMIRRORD" = xyes; then
 680         AC_ARG_WITH(cmirrord-pidfile,
 681                     AC_HELP_STRING([--with-cmirrord-pidfile=PATH],
 682                                    [cmirrord pidfile [[/var/run/cmirrord.pid]]]),
 683                     CMIRRORD_PIDFILE=$withval,
 684                     CMIRRORD_PIDFILE="/var/run/cmirrord.pid")
 685         AC_DEFINE_UNQUOTED(CMIRRORD_PIDFILE, ["$CMIRRORD_PIDFILE"],
 686                            [Path to cmirrord pidfile.])
 687 fi
 688
 689 ################################################################################
 690 dnl -- Look for corosync libraries if required.
 691 if [[ "x$BUILD_CMIRRORD" = xyes ]]; then
 692         dnl -- init pkgconfig if required
 693         if  test x$PKGCONFIG_INIT != x1; then
 694                 pkg_config_init
 695         fi
 696         PKG_CHECK_MODULES(SACKPT, libSaCkpt)
 697         if test x$HAVE_CPG != xyes; then
 698                 PKG_CHECK_MODULES(CPG, libcpg)
 699         fi
 700 fi
 701
 702 ################################################################################
 703 dnl -- Enable debugging
 704 AC_MSG_CHECKING(whether to enable debugging)
 705 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [enable debugging]),
 706               DEBUG=$enableval, DEBUG=no)
 707 AC_MSG_RESULT($DEBUG)
 708
 709 dnl -- Normally turn off optimisation for debug builds
 710 if test x$DEBUG = xyes; then
 711         COPTIMISE_FLAG=
 712 else
 713         CSCOPE_CMD=
 714 fi
 715
 716 ################################################################################
 717 dnl -- Override optimisation
 718 AC_MSG_CHECKING(for C optimisation flag)
 719 AC_ARG_WITH(optimisation,
 720             AC_HELP_STRING([--with-optimisation=OPT],
 721                            [C optimisation flag [[OPT=-O2]]]),
 722             COPTIMISE_FLAG=$withval)
 723 AC_MSG_RESULT($COPTIMISE_FLAG)
 724
 725 ################################################################################
 726 dnl -- Enable profiling
 727 AC_MSG_CHECKING(whether to gather gcov profiling data)
 728 AC_ARG_ENABLE(profiling,
 729               AC_HELP_STRING(--enable-profiling, [gather gcov profiling data]),
 730               PROFILING=$enableval, PROFILING=no)
 731 AC_MSG_RESULT($PROFILING)
 732
 733 if test "x$PROFILING" = xyes; then
 734   COPTIMISE_FLAG="$COPTIMISE_FLAG -fprofile-arcs -ftest-coverage"
 735   AC_PATH_PROG(LCOV, lcov)
 736   AC_PATH_PROG(GENHTML, genhtml)
 737   if test -z "$LCOV" -o -z "$GENHTML"; then
 738     AC_MSG_ERROR([lcov and genhtml are required for profiling])
 739   fi
 740   AC_PATH_PROG(GENPNG, genpng)
 741   if test -n "$GENPNG"; then
 742     AC_MSG_CHECKING([whether $GENPNG has all required modules])
 743     if $GENPNG --help > /dev/null 2>&1 ; then
 744       AC_MSG_RESULT(ok)
 745       GENHTML="$GENHTML --frames"
 746     else
 747       AC_MSG_RESULT(not supported)
 748       AC_MSG_WARN([GD.pm perl module is not installed])
 749       GENPNG=
 750     fi
 751   fi
 752 fi
 753
 754 ################################################################################
 755 dnl -- Enable testing
 756 AC_MSG_CHECKING(whether to enable unit testing)
 757 AC_ARG_ENABLE(testing,
 758               AC_HELP_STRING(--enable-testing, [enable testing targets in the makefile]),
 759               TESTING=$enableval, TESTING=no)
 760 AC_MSG_RESULT($TESTING)
 761
 762 if test "$TESTING" = yes; then
 763    AC_PATH_PROG(RUBY19, ruby1.9)
 764    AC_PATH_PROG(VALGRIND, valgrind)
 765    if test -z "$RUBY19" -o -z "$VALGRIND"; then
 766        AC_MSG_ERROR([ruby1.9 and valgrind are required for testing])
 767    fi
 768 fi
 769
 770 ################################################################################
 771 dnl -- Enable valgrind awareness of memory pools
 772 AC_MSG_CHECKING(whether to enable valgrind awareness of pools)
 773 AC_ARG_ENABLE(valgrind_pool,
 774               AC_HELP_STRING(--enable-valgrind-pool, [enable valgrind awareness of pools]),
 775               VALGRIND_POOL=$enableval, VALGRIND_POOL=no)
 776 AC_MSG_RESULT($VALGRIND_POOL)
 777
 778 if test "$VALGRIND_POOL" = yes; then
 779     AC_CHECK_HEADERS([valgrind/memcheck.h], , [AC_MSG_ERROR(bailing out)])
 780     AC_DEFINE([VALGRIND_POOL], 1, [Enable a valgrind aware build of pool])
 781 fi
 782
 783 ################################################################################
 784 dnl -- Disable devmapper
 785 AC_MSG_CHECKING(whether to use device-mapper)
 786 AC_ARG_ENABLE(devmapper,
 787               AC_HELP_STRING([--disable-devmapper],
 788                              [disable LVM2 device-mapper interaction]),
 789               DEVMAPPER=$enableval)
 790 AC_MSG_RESULT($DEVMAPPER)
 791
 792 if test x$DEVMAPPER = xyes; then
 793         AC_DEFINE([DEVMAPPER_SUPPORT], 1, [Define to 1 to enable LVM2 device-mapper interaction.])
 794 fi
 795
 796 ################################################################################
 797 dnl -- Enable udev synchronisation
 798 AC_MSG_CHECKING(whether to enable synchronisation with udev processing)
 799 AC_ARG_ENABLE(udev_sync,
 800               AC_HELP_STRING([--enable-udev_sync],
 801                              [enable synchronisation with udev processing]),
 802               UDEV_SYNC=$enableval, UDEV_SYNC=no)
 803 AC_MSG_RESULT($UDEV_SYNC)
 804
 805 if test x$UDEV_SYNC = xyes; then
 806         dnl -- init pkgconfig if required
 807         if  test x$PKGCONFIG_INIT != x1; then
 808                 pkg_config_init
 809         fi
 810         PKG_CHECK_MODULES(UDEV, libudev >= 143, [UDEV_PC="libudev"])
 811         AC_DEFINE([UDEV_SYNC_SUPPORT], 1, [Define to 1 to enable synchronisation with udev processing.])
 812 fi
 813
 814 dnl -- Enable udev rules
 815 AC_MSG_CHECKING(whether to enable installation of udev rules required for synchronisation)
 816 AC_ARG_ENABLE(udev_rules,
 817               AC_HELP_STRING([--enable-udev_rules],
 818                              [install rule files needed for udev synchronisation]),
 819               UDEV_RULES=$enableval, UDEV_RULES=$UDEV_SYNC)
 820 AC_MSG_RESULT($UDEV_RULES)
 821
 822 ################################################################################
 823 dnl -- Compatibility mode
 824 AC_ARG_ENABLE(compat,
 825               AC_HELP_STRING([--enable-compat],
 826                              [enable support for old device-mapper versions]),
 827               DM_COMPAT=$enableval, DM_COMPAT=no)
 828
 829 ################################################################################
 830 dnl -- Compatible units suffix mode
 831 AC_ARG_ENABLE(units-compat,
 832               AC_HELP_STRING([--enable-units-compat],
 833                              [enable output compatibility with old versions that
 834                               that do not use KiB-style unit suffixes]),
 835               UNITS_COMPAT=$enableval, UNITS_COMPAT=no)
 836
 837 if test x$UNITS_COMPAT = xyes; then
 838         AC_DEFINE([DEFAULT_SI_UNIT_CONSISTENCY], 0, [Define to 0 to reinstate the pre-2.02.54 handling of unit suffixes.])
 839 fi
 840
 841 ################################################################################
 842 dnl -- Disable ioctl
 843 AC_ARG_ENABLE(ioctl,
 844               AC_HELP_STRING([--disable-driver],
 845                              [disable calls to device-mapper in the kernel]),
 846               DM_IOCTLS=$enableval)
 847
 848 ################################################################################
 849 dnl -- Disable O_DIRECT
 850 AC_MSG_CHECKING(whether to enable O_DIRECT)
 851 AC_ARG_ENABLE(o_direct,
 852               AC_HELP_STRING([--disable-o_direct], [disable O_DIRECT]),
 853               ODIRECT=$enableval)
 854 AC_MSG_RESULT($ODIRECT)
 855
 856 if test x$ODIRECT = xyes; then
 857         AC_DEFINE([O_DIRECT_SUPPORT], 1, [Define to 1 to enable O_DIRECT support.])
 858 fi
 859
 860 ################################################################################
 861 dnl -- Enable liblvm2app.so
 862 AC_MSG_CHECKING(whether to build liblvm2app.so application library)
 863 AC_ARG_ENABLE(applib,
 864               AC_HELP_STRING([--enable-applib], [build application library]),
 865               APPLIB=$enableval, APPLIB=no)
 866 AC_MSG_RESULT($APPLIB)
 867 AC_SUBST([LVM2APP_LIB])
 868 test x$APPLIB = xyes \
 869   && LVM2APP_LIB=-llvm2app \
 870   || LVM2APP_LIB=
 871
 872 ################################################################################
 873 dnl -- Enable cmdlib
 874 AC_MSG_CHECKING(whether to compile liblvm2cmd.so)
 875 AC_ARG_ENABLE(cmdlib,
 876               AC_HELP_STRING([--enable-cmdlib], [build shared command library]),
 877               CMDLIB=$enableval, CMDLIB=no)
 878 AC_MSG_RESULT($CMDLIB)
 879 AC_SUBST([LVM2CMD_LIB])
 880 test x$CMDLIB = xyes \
 881   && LVM2CMD_LIB=-llvm2cmd \
 882   || LVM2CMD_LIB=
 883
 884 ################################################################################
 885 dnl -- Enable pkg-config
 886 AC_ARG_ENABLE(pkgconfig,
 887               AC_HELP_STRING([--enable-pkgconfig], [install pkgconfig support]),
 888               PKGCONFIG=$enableval, PKGCONFIG=no)
 889
 890 ################################################################################
 891 dnl -- Enable installation of writable files by user
 892 AC_ARG_ENABLE(write_install,
 893               AC_HELP_STRING([--enable-write_install],
 894                              [install user writable files]),
 895               WRITE_INSTALL=$enableval, WRITE_INSTALL=no)
 896
 897 ################################################################################
 898 dnl -- Enable fsadm
 899 AC_MSG_CHECKING(whether to install fsadm)
 900 AC_ARG_ENABLE(fsadm, AC_HELP_STRING([--disable-fsadm], [disable fsadm]),
 901               FSADM=$enableval)
 902 AC_MSG_RESULT($FSADM)
 903
 904 ################################################################################
 905 dnl -- enable dmeventd handling
 906 AC_MSG_CHECKING(whether to use dmeventd)
 907 AC_ARG_ENABLE(dmeventd, AC_HELP_STRING([--enable-dmeventd],
 908                                        [enable the device-mapper event daemon]),
 909               DMEVENTD=$enableval)
 910 AC_MSG_RESULT($DMEVENTD)
 911
 912 BUILD_DMEVENTD=$DMEVENTD
 913
 914 dnl -- dmeventd currently requires internal mirror support
 915 if test x$DMEVENTD = xyes; then
 916    if test x$MIRRORS != xinternal; then
 917       AC_MSG_ERROR(
 918         --enable-dmeventd currently requires --with-mirrors=internal
 919       )
 920    fi
 921    if test x$CMDLIB = xno; then
 922       AC_MSG_ERROR(
 923         --enable-dmeventd requires --enable-cmdlib to be used as well
 924       )
 925    fi
 926 fi
 927
 928 if test x$DMEVENTD = xyes; then
 929         AC_DEFINE([DMEVENTD], 1, [Define to 1 to enable the device-mapper event daemon.])
 930 fi
 931
 932 ################################################################################
 933 dnl -- getline included in recent libc
 934
 935 AC_CHECK_LIB(c, getline, AC_DEFINE([HAVE_GETLINE], 1,
 936   [Define to 1 if getline is available.]))
 937
 938 ################################################################################
 939 dnl -- canonicalize_file_name included in recent libc
 940
 941 AC_CHECK_LIB(c, canonicalize_file_name,
 942   AC_DEFINE([HAVE_CANONICALIZE_FILE_NAME], 1,
 943     [Define to 1 if canonicalize_file_name is available.]))
 944
 945 ################################################################################
 946 dnl -- Clear default exec_prefix - install into /sbin rather than /usr/sbin
 947 if [[ "x$exec_prefix" = xNONE -a "x$prefix" = xNONE ]];
 948  then  exec_prefix="";
 949 fi;
 950
 951 ################################################################################
 952 dnl -- Check for dlopen
 953 AC_CHECK_LIB(dl, dlopen, [
 954         AC_DEFINE([HAVE_LIBDL], 1, [Define to 1 if dynamic libraries are available.])
 955         DL_LIBS="-ldl"
 956         HAVE_LIBDL=yes ], [
 957         DL_LIBS=
 958         HAVE_LIBDL=no ])
 959
 960 ################################################################################
 961 dnl -- Check for shared/static conflicts
 962 if [[ \( "x$LVM1" = xshared -o "x$POOL" = xshared -o "x$CLUSTER" = xshared \
 963       -o "x$SNAPSHOTS" = xshared -o "x$MIRRORS" = xshared \
 964       \) -a "x$STATIC_LINK" = xyes ]];
 965  then  AC_MSG_ERROR(
 966 Features cannot be 'shared' when building statically
 967 )
 968 fi
 969
 970 ################################################################################
 971 if [[ "$DMEVENTD" = yes -o "$CLVMD" != none ]] ; then
 972         AC_CHECK_LIB([pthread], [pthread_mutex_lock],
 973                 [PTHREAD_LIBS="-lpthread"], hard_bailout)
 974 fi
 975
 976 ################################################################################
 977 dnl -- Disable selinux
 978 AC_MSG_CHECKING(whether to enable selinux support)
 979 AC_ARG_ENABLE(selinux,
 980               AC_HELP_STRING([--disable-selinux], [disable selinux support]),
 981               SELINUX=$enableval)
 982 AC_MSG_RESULT($SELINUX)
 983
 984 ################################################################################
 985 dnl -- Check for selinux
 986 if test x$SELINUX = xyes; then
 987         AC_CHECK_LIB([sepol], [sepol_check_context], [
 988                 AC_DEFINE([HAVE_SEPOL], 1, [Define to 1 if sepol_check_context is available.])
 989                 SELINUX_LIBS="-lsepol"])
 990
 991         AC_CHECK_LIB([selinux], [is_selinux_enabled], [
 992                 AC_CHECK_HEADERS([selinux/selinux.h],, hard_bailout)
 993                 AC_CHECK_HEADERS([selinux/label.h])
 994                 AC_DEFINE([HAVE_SELINUX], 1, [Define to 1 to include support for selinux.])
 995                 SELINUX_LIBS="-lselinux $SELINUX_LIBS"
 996                 SELINUX_PC="libselinux"
 997                 HAVE_SELINUX=yes ], [
 998                 AC_MSG_WARN(Disabling selinux)
 999                 SELINUX_LIBS=
1000                 SELINUX_PC=
1001                 HAVE_SELINUX=no ])
1002 fi
1003
1004 ################################################################################
1005 dnl -- Check for realtime clock support
1006 if test x$REALTIME = xyes; then
1007         AC_CHECK_LIB(rt, clock_gettime, HAVE_REALTIME=yes, HAVE_REALTIME=no)
1008
1009         if test x$HAVE_REALTIME = xyes; then
1010                 AC_DEFINE([HAVE_REALTIME], 1, [Define to 1 to include support for realtime clock.])
1011                 LIBS="-lrt $LIBS"
1012         else
1013                 AC_MSG_WARN(Disabling realtime clock)
1014         fi
1015 fi
1016
1017 ################################################################################
1018 dnl -- Check for getopt
1019 AC_CHECK_HEADERS(getopt.h, AC_DEFINE([HAVE_GETOPTLONG], 1, [Define to 1 if getopt_long is available.]))
1020
1021 ################################################################################
1022 dnl -- Check for readline (Shamelessly copied from parted 1.4.17)
1023 if test x$READLINE != xno; then
1024         lvm_saved_libs=$LIBS
1025         AC_SEARCH_LIBS([tgetent], [tinfo ncurses curses termcap termlib],
1026                 READLINE_LIBS=$ac_cv_search_tgetent, [
1027                 if test "$READLINE" = yes; then
1028                         AC_MSG_ERROR(
1029 [termcap could not be found which is required for the
1030 --enable-readline option (which is enabled by default).  Either disable readline
1031 support with --disable-readline or download and install termcap from:
1032         ftp.gnu.org/gnu/termcap
1033 Note: if you are using precompiled packages you will also need the development
1034   package as well (which may be called termcap-devel or something similar).
1035 Note: (n)curses also seems to work as a substitute for termcap.  This was
1036   not found either - but you could try installing that as well.])
1037                 fi])
1038         dnl -- Old systems may need extra termcap dependency explicitly in LIBS
1039         AC_CHECK_LIB([readline], [readline], [
1040                 AC_DEFINE([READLINE_SUPPORT], 1,
1041                         [Define to 1 to include the LVM readline shell.])
1042                 dnl -- Try only with -lreadline and check for different symbol
1043                 LIBS=$lvm_saved_libs
1044                 AC_CHECK_LIB([readline], [rl_line_buffer],
1045                         [ READLINE_LIBS="-lreadline" ], [
1046                           AC_MSG_RESULT([linking -lreadline with $READLINE_LIBS needed])
1047                           READLINE_LIBS="-lreadline $READLINE_LIBS"
1048                         ]) ], [
1049                 READLINE_LIBS=
1050                 if test "$READLINE" = yes; then
1051                         AC_MSG_ERROR(
1052 [GNU Readline could not be found which is required for the
1053 --enable-readline option (which is enabled by default).  Either disable readline
1054 support with --disable-readline or download and install readline from:
1055         ftp.gnu.org/gnu/readline
1056 Note: if you are using precompiled packages you will also need the development
1057 package as well (which may be called readline-devel or something similar).])
1058                 fi ])
1059         LIBS="$READLINE_LIBS $lvm_saved_libs"
1060         AC_CHECK_FUNCS([rl_completion_matches])
1061         LIBS=$lvm_saved_libs
1062 fi
1063
1064 ################################################################################
1065 dnl -- Internationalisation stuff
1066 AC_MSG_CHECKING(whether to enable internationalisation)
1067 AC_ARG_ENABLE(nls,
1068               AC_HELP_STRING([--enable-nls], [enable Native Language Support]),
1069               INTL=$enableval, INTL=no)
1070 AC_MSG_RESULT($INTL)
1071
1072 if test x$INTL = xyes; then
1073 # FIXME - Move this - can be device-mapper too
1074         INTL_PACKAGE="lvm2"
1075         AC_PATH_PROG(MSGFMT, msgfmt)
1076         if [[ "x$MSGFMT" == x ]];
1077                 then  AC_MSG_ERROR(
1078                 msgfmt not found in path $PATH
1079                 )
1080         fi;
1081
1082         AC_ARG_WITH(localedir,
1083                     AC_HELP_STRING([--with-localedir=DIR],
1084                                    [translation files in DIR
1085                                     [[PREFIX/share/locale]]]),
1086                     LOCALEDIR=$withval, LOCALEDIR='${prefix}/share/locale')
1087 fi
1088
1089 ################################################################################
1090 AC_ARG_WITH(confdir,
1091             AC_HELP_STRING([--with-confdir=DIR],
1092                            [configuration files in DIR [[/etc]]]),
1093             CONFDIR=$withval, CONFDIR="/etc")
1094
1095 AC_ARG_WITH(staticdir,
1096             AC_HELP_STRING([--with-staticdir=DIR],
1097                            [static binaries in DIR [[EPREFIX/sbin]]]),
1098             STATICDIR=$withval, STATICDIR='${exec_prefix}/sbin')
1099
1100 AC_ARG_WITH(usrlibdir,
1101             AC_HELP_STRING([--with-usrlibdir=DIR],
1102                            [usrlib in DIR [[PREFIX/lib]]]),
1103             usrlibdir=$withval, usrlibdir='${prefix}/lib')
1104
1105 AC_ARG_WITH(usrsbindir,
1106             AC_HELP_STRING([--with-usrsbindir=DIR],
1107                            [usrsbin executables in DIR [[PREFIX/sbin]]]),
1108             usrsbindir=$withval, usrsbindir='${prefix}/sbin')
1109
1110 ################################################################################
1111 AC_ARG_WITH(udev_prefix,
1112             AC_HELP_STRING([--with-udev-prefix=UPREFIX],
1113                            [install udev rule files in UPREFIX [[EPREFIX]]]),
1114             udev_prefix=$withval, udev_prefix='${exec_prefix}')
1115
1116 AC_ARG_WITH(udevdir,
1117             AC_HELP_STRING([--with-udevdir=DIR],
1118                            [udev rules in DIR [[UPREFIX/lib/udev/rules.d]]]),
1119             udevdir=$withval, udevdir='${udev_prefix}/lib/udev/rules.d')
1120
1121 ################################################################################
1122 dnl -- Ensure additional headers required
1123 if test x$READLINE = xyes; then
1124         AC_CHECK_HEADERS(readline/readline.h readline/history.h,,AC_MSG_ERROR(bailing out))
1125 fi
1126
1127 if test x$CLVMD != xnone; then
1128         AC_CHECK_HEADERS(mntent.h netdb.h netinet/in.h pthread.h search.h sys/mount.h sys/socket.h sys/uio.h sys/un.h utmpx.h,,AC_MSG_ERROR(bailing out))
1129         AC_CHECK_FUNCS(dup2 getmntent memmove select socket,,AC_MSG_ERROR(bailing out))
1130         AC_FUNC_GETMNTENT
1131         AC_FUNC_SELECT_ARGTYPES
1132 fi
1133
1134 if test x$CLUSTER != xnone; then
1135         AC_CHECK_HEADERS(sys/socket.h sys/un.h,,AC_MSG_ERROR(bailing out))
1136         AC_CHECK_FUNCS(socket,,AC_MSG_ERROR(bailing out))
1137 fi
1138
1139 if test x$DMEVENTD = xyes; then
1140         AC_CHECK_HEADERS(arpa/inet.h,,AC_MSG_ERROR(bailing out))
1141 fi
1142
1143 if test x$HAVE_LIBDL = xyes; then
1144         AC_CHECK_HEADERS(dlfcn.h,,AC_MSG_ERROR(bailing out))
1145 fi
1146
1147 if test x$INTL = xyes; then
1148         AC_CHECK_HEADERS(libintl.h,,AC_MSG_ERROR(bailing out))
1149 fi
1150
1151 if test x$UDEV_SYNC = xyes; then
1152         AC_CHECK_HEADERS(sys/ipc.h sys/sem.h,,AC_MSG_ERROR(bailing out))
1153 fi
1154
1155 ################################################################################
1156 AC_PATH_PROG(MODPROBE_CMD, modprobe)
1157
1158 if test x$MODPROBE_CMD != x; then
1159         AC_DEFINE_UNQUOTED([MODPROBE_CMD], ["$MODPROBE_CMD"], [The path to 'modprobe', if available.])
1160 fi
1161
1162
1163 lvm_exec_prefix=$exec_prefix
1164 test "$lvm_exec_prefix" = NONE && lvm_exec_prefix=$prefix
1165 test "$lvm_exec_prefix" = NONE && lvm_exec_prefix=$ac_default_prefix
1166 AC_DEFINE_UNQUOTED(LVM_PATH, ["$lvm_exec_prefix/sbin/lvm"], [Path to lvm binary.])
1167
1168 if  test "$CLVMD" != none; then
1169         clvmd_prefix=$ac_default_prefix
1170         test "$prefix" != NONE && clvmd_prefix=$prefix
1171         AC_DEFINE_UNQUOTED(CLVMD_PATH, ["$clvmd_prefix/sbin/clvmd"],
1172                            [Path to clvmd binary.])
1173 fi
1174
1175 ################################################################################
1176 dnl -- dmeventd pidfile and executable path
1177 if test "$BUILD_DMEVENTD" = yes; then
1178         AC_ARG_WITH(dmeventd-pidfile,
1179                     AC_HELP_STRING([--with-dmeventd-pidfile=PATH],
1180                                    [dmeventd pidfile [[/var/run/dmeventd.pid]]]),
1181                     DMEVENTD_PIDFILE=$withval,
1182                     DMEVENTD_PIDFILE="/var/run/dmeventd.pid")
1183         AC_DEFINE_UNQUOTED(DMEVENTD_PIDFILE, ["$DMEVENTD_PIDFILE"],
1184                            [Path to dmeventd pidfile.])
1185 fi
1186
1187 if test "$BUILD_DMEVENTD" = yes; then
1188         AC_ARG_WITH(dmeventd-path,
1189                     AC_HELP_STRING([--with-dmeventd-path=PATH],
1190                                    [dmeventd path [[EPREFIX/sbin/dmeventd]]]),
1191                     DMEVENTD_PATH=$withval,
1192                     DMEVENTD_PATH="$lvm_exec_prefix/sbin/dmeventd")
1193         AC_DEFINE_UNQUOTED(DMEVENTD_PATH, ["$DMEVENTD_PATH"],
1194                            [Path to dmeventd binary.])
1195 fi
1196
1197 AH_TEMPLATE(DEFAULT_RUN_DIR, [Name of default run directory.])
1198 AC_ARG_WITH(default-run-dir,
1199             [  --with-default-run-dir=DIR       Default run directory [[/var/run/lvm]] ],
1200             [ DEFAULT_RUN_DIR="$withval" ],
1201             [ DEFAULT_RUN_DIR="/var/run/lvm" ])
1202 AC_DEFINE_UNQUOTED(DEFAULT_RUN_DIR,["$DEFAULT_RUN_DIR"] )
1203
1204 ################################################################################
1205 dnl -- various defaults
1206 AC_ARG_WITH(default-system-dir,
1207             AC_HELP_STRING([--with-default-system-dir=DIR],
1208                            [default LVM system directory [[/etc/lvm]]]),
1209             DEFAULT_SYS_DIR=$withval, DEFAULT_SYS_DIR="/etc/lvm")
1210 AC_DEFINE_UNQUOTED(DEFAULT_SYS_DIR, ["$DEFAULT_SYS_DIR"],
1211                    [Path to LVM system directory.])
1212
1213 AC_ARG_WITH(default-archive-subdir,
1214             AC_HELP_STRING([--with-default-archive-subdir=SUBDIR],
1215                            [default metadata archive subdir [[archive]]]),
1216             DEFAULT_ARCHIVE_SUBDIR=$withval, DEFAULT_ARCHIVE_SUBDIR=archive)
1217 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_SUBDIR, ["$DEFAULT_ARCHIVE_SUBDIR"],
1218                    [Name of default metadata archive subdirectory.])
1219
1220 AC_ARG_WITH(default-backup-subdir,
1221             AC_HELP_STRING([--with-default-backup-subdir=SUBDIR],
1222                            [default metadata backup subdir [[backup]]]),
1223             DEFAULT_BACKUP_SUBDIR=$withval, DEFAULT_BACKUP_SUBDIR=backup)
1224 AC_DEFINE_UNQUOTED(DEFAULT_BACKUP_SUBDIR, ["$DEFAULT_BACKUP_SUBDIR"],
1225                    [Name of default metadata backup subdirectory.])
1226
1227 AC_ARG_WITH(default-cache-subdir,
1228             AC_HELP_STRING([--with-default-cache-subdir=SUBDIR],
1229                            [default metadata cache subdir [[cache]]]),
1230             DEFAULT_CACHE_SUBDIR=$withval, DEFAULT_CACHE_SUBDIR=cache)
1231 AC_DEFINE_UNQUOTED(DEFAULT_CACHE_SUBDIR, ["$DEFAULT_CACHE_SUBDIR"],
1232                    [Name of default metadata cache subdirectory.])
1233
1234 AC_ARG_WITH(default-locking-dir,
1235             AC_HELP_STRING([--with-default-locking-dir=DIR],
1236                            [default locking directory [[/var/lock/lvm]]]),
1237             DEFAULT_LOCK_DIR=$withval, DEFAULT_LOCK_DIR="/var/lock/lvm")
1238 AC_DEFINE_UNQUOTED(DEFAULT_LOCK_DIR, ["$DEFAULT_LOCK_DIR"],
1239                    [Name of default locking directory.])
1240
1241 ################################################################################
1242 dnl -- Setup default data alignment
1243 AC_ARG_WITH(default-data-alignment,
1244             AC_HELP_STRING([--with-default-data-alignment=NUM],
1245                            [set the default data alignment in MiB [[1]]]),
1246             DEFAULT_DATA_ALIGNMENT=$withval, DEFAULT_DATA_ALIGNMENT=1)
1247 AC_DEFINE_UNQUOTED(DEFAULT_DATA_ALIGNMENT, [$DEFAULT_DATA_ALIGNMENT],
1248                    [Default data alignment.])
1249
1250 ################################################################################
1251 dnl -- which kernel interface to use (ioctl only)
1252 AC_MSG_CHECKING(for kernel interface choice)
1253 AC_ARG_WITH(interface,
1254             AC_HELP_STRING([--with-interface=IFACE],
1255                            [choose kernel interface (ioctl) [[ioctl]]]),
1256             interface=$withval, interface=ioctl)
1257 if [[ "x$interface" != xioctl ]];
1258 then
1259   AC_MSG_ERROR(--with-interface=ioctl required. fs no longer supported.)
1260 fi
1261 AC_MSG_RESULT($interface)
1262
1263 ################################################################################
1264 DM_LIB_VERSION="\"`cat "$srcdir"/VERSION_DM 2>/dev/null || echo Unknown`\""
1265 AC_DEFINE_UNQUOTED(DM_LIB_VERSION, $DM_LIB_VERSION, [Library version])
1266
1267 DM_LIB_PATCHLEVEL=`cat "$srcdir"/VERSION_DM | $AWK -F '[[-. ]]' '{printf "%s.%s.%s",$1,$2,$3}'`
1268
1269 LVM_VERSION="\"`cat "$srcdir"/VERSION 2>/dev/null || echo Unknown`\""
1270
1271 VER=`cat "$srcdir"/VERSION`
1272 LVM_RELEASE_DATE="\"`echo $VER | $SED 's/.* (//;s/).*//'`\""
1273 VER=`echo "$VER" | $AWK '{print $1}'`
1274 LVM_RELEASE="\"`echo "$VER" | $AWK -F '-' '{print $2}'`\""
1275 VER=`echo "$VER" | $AWK -F '-' '{print $1}'`
1276 LVM_MAJOR=`echo "$VER" | $AWK -F '.' '{print $1}'`
1277 LVM_MINOR=`echo "$VER" | $AWK -F '.' '{print $2}'`
1278 LVM_PATCHLEVEL=`echo "$VER" | $AWK -F '[[(.]]' '{print $3}'`
1279 LVM_LIBAPI=`echo "$VER" | $AWK -F '[[()]]' '{print $2}'`
1280
1281 ################################################################################
1282 AC_SUBST(APPLIB)
1283 AC_SUBST(AWK)
1284 AC_SUBST(BUILD_CMIRRORD)
1285 AC_SUBST(BUILD_DMEVENTD)
1286 AC_SUBST(CCS_CFLAGS)
1287 AC_SUBST(CCS_LIBS)
1288 AC_SUBST(CFLAGS)
1289 AC_SUBST(CFLOW_CMD)
1290 AC_SUBST(CLDFLAGS)
1291 AC_SUBST(CLDNOWHOLEARCHIVE)
1292 AC_SUBST(CLDWHOLEARCHIVE)
1293 AC_SUBST(CLUSTER)
1294 AC_SUBST(CLVMD)
1295 AC_SUBST(CLVMD_CMANAGERS)
1296 AC_SUBST(CMAN_CFLAGS)
1297 AC_SUBST(CMAN_LIBS)
1298 AC_SUBST(CMDLIB)
1299 AC_SUBST(CONFDB_CFLAGS)
1300 AC_SUBST(CONFDB_LIBS)
1301 AC_SUBST(CONFDIR)
1302 AC_SUBST(COPTIMISE_FLAG)
1303 AC_SUBST(CPG_CFLAGS)
1304 AC_SUBST(CPG_LIBS)
1305 AC_SUBST(CSCOPE_CMD)
1306 AC_SUBST(DEBUG)
1307 AC_SUBST(DEFAULT_SYS_DIR)
1308 AC_SUBST(DEFAULT_ARCHIVE_SUBDIR)
1309 AC_SUBST(DEFAULT_BACKUP_SUBDIR)
1310 AC_SUBST(DEFAULT_CACHE_SUBDIR)
1311 AC_SUBST(DEFAULT_DATA_ALIGNMENT)
1312 AC_SUBST(DEFAULT_LOCK_DIR)
1313 AC_SUBST(DEFAULT_RUN_DIR)
1314 AC_SUBST(DEVMAPPER)
1315 AC_SUBST(DLM_CFLAGS)
1316 AC_SUBST(DLM_LIBS)
1317 AC_SUBST(DL_LIBS)
1318 AC_SUBST(DMEVENTD)
1319 AC_SUBST(DMEVENTD_PATH)
1320 AC_SUBST(DM_COMPAT)
1321 AC_SUBST(DM_DEVICE_GID)
1322 AC_SUBST(DM_DEVICE_MODE)
1323 AC_SUBST(DM_DEVICE_UID)
1324 AC_SUBST(DM_IOCTLS)
1325 AC_SUBST(DM_LIB_VERSION)
1326 AC_SUBST(DM_LIB_PATCHLEVEL)
1327 AC_SUBST(FSADM)
1328 AC_SUBST(GULM_CFLAGS)
1329 AC_SUBST(GULM_LIBS)
1330 AC_SUBST(HAVE_LIBDL)
1331 AC_SUBST(HAVE_REALTIME)
1332 AC_SUBST(INTL)
1333 AC_SUBST(INTL_PACKAGE)
1334 AC_SUBST(JOBS)
1335 AC_SUBST(LDDEPS)
1336 AC_SUBST(LIBS)
1337 AC_SUBST(LIB_SUFFIX)
1338 AC_SUBST(LOCALEDIR)
1339 AC_SUBST(LVM1)
1340 AC_SUBST(LVM1_FALLBACK)
1341 AC_SUBST(LVM_VERSION)
1342 AC_SUBST(LVM_LIBAPI)
1343 AC_SUBST(LVM_MAJOR)
1344 AC_SUBST(LVM_MINOR)
1345 AC_SUBST(LVM_PATCHLEVEL)
1346 AC_SUBST(LVM_RELEASE)
1347 AC_SUBST(LVM_RELEASE_DATE)
1348 AC_SUBST(MIRRORS)
1349 AC_SUBST(OCF)
1350 AC_SUBST(OCFDIR)
1351 AC_SUBST(REPLICATORS)
1352 AC_SUBST(MSGFMT)
1353 AC_SUBST(PKGCONFIG)
1354 AC_SUBST(POOL)
1355 AC_SUBST(PTHREAD_LIBS)
1356 AC_SUBST(QUORUM_CFLAGS)
1357 AC_SUBST(QUORUM_LIBS)
1358 AC_SUBST(READLINE_LIBS)
1359 AC_SUBST(SACKPT_CFLAGS)
1360 AC_SUBST(SACKPT_LIBS)
1361 AC_SUBST(SALCK_CFLAGS)
1362 AC_SUBST(SALCK_LIBS)
1363 AC_SUBST(SELINUX_LIBS)
1364 AC_SUBST(SELINUX_PC)
1365 AC_SUBST(SNAPSHOTS)
1366 AC_SUBST(STATICDIR)
1367 AC_SUBST(STATIC_LINK)
1368 AC_SUBST(TESTING)
1369 AC_SUBST(UDEV_LIBS)
1370 AC_SUBST(UDEV_PC)
1371 AC_SUBST(UDEV_RULES)
1372 AC_SUBST(UDEV_SYNC)
1373 AC_SUBST(WRITE_INSTALL)
1374 AC_SUBST(DMEVENTD_PIDFILE)
1375 AC_SUBST(interface)
1376 AC_SUBST(kerneldir)
1377 AC_SUBST(missingkernel)
1378 AC_SUBST(kernelvsn)
1379 AC_SUBST(tmpdir)
1380 AC_SUBST(udev_prefix)
1381 AC_SUBST(udevdir)
1382 AC_SUBST(usrlibdir)
1383 AC_SUBST(usrsbindir)
1384
1385 ################################################################################
1386 dnl -- First and last lines should not contain files to generate in order to
1387 dnl -- keep utility scripts running properly
1388 AC_CONFIG_FILES([
1389 Makefile
1390 make.tmpl
1391 daemons/Makefile
1392 daemons/clvmd/Makefile
1393 daemons/cmirrord/Makefile
1394 daemons/dmeventd/Makefile
1395 daemons/dmeventd/libdevmapper-event.pc
1396 daemons/dmeventd/plugins/Makefile
1397 daemons/dmeventd/plugins/lvm2/Makefile
1398 daemons/dmeventd/plugins/mirror/Makefile
1399 daemons/dmeventd/plugins/snapshot/Makefile
1400 doc/Makefile
1401 doc/example.conf
1402 include/.symlinks
1403 include/Makefile
1404 lib/Makefile
1405 lib/format1/Makefile
1406 lib/format_pool/Makefile
1407 lib/locking/Makefile
1408 lib/mirror/Makefile
1409 lib/replicator/Makefile
1410 lib/misc/lvm-version.h
1411 lib/snapshot/Makefile
1412 libdm/Makefile
1413 libdm/libdevmapper.pc
1414 liblvm/Makefile
1415 liblvm/liblvm2app.pc
1416 man/Makefile
1417 po/Makefile
1418 scripts/clvmd_init_red_hat
1419 scripts/cmirrord_init_red_hat
1420 scripts/lvm2_monitoring_init_red_hat
1421 scripts/dm_event_systemd_red_hat.service
1422 scripts/lvm2_monitoring_systemd_red_hat.service
1423 scripts/Makefile
1424 test/Makefile
1425 test/api/Makefile
1426 tools/Makefile
1427 udev/Makefile
1428 unit-tests/datastruct/Makefile
1429 unit-tests/regex/Makefile
1430 unit-tests/mm/Makefile
1431 ])
1432 AC_OUTPUT
1433
1434 if test x$ODIRECT != xyes; then
1435   AC_MSG_WARN(Warning: O_DIRECT disabled: low-memory pvmove may lock up)
1436 fi