configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  36 AC_ARG_WITH(gd, dnl
  37   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  38             [dnl
  39 case "$with_gd" in
  40 yes|''|no) ;;
  41 *) libgd_include="-I$withval/include"
  42    libgd_ldflags="-L$withval/lib" ;;
  43 esac
  44 ])
  45 AC_ARG_WITH(gd-include, dnl
  46   --with-gd-include=DIR   find libgd include files in DIR,
  47             [dnl
  48 case "$with_gd_include" in
  49 ''|no) ;;
  50 *) libgd_include="-I$withval" ;;
  51 esac
  52 ])
  53 AC_ARG_WITH(gd-lib, dnl
  54   --with-gd-lib=DIR       find libgd library files in DIR,
  55             [dnl
  56 case "$with_gd_lib" in
  57 ''|no) ;;
  58 *) libgd_ldflags="-L$withval" ;;
  59 esac
  60 ])
  61
  62 if test -n "$libgd_include"; then
  63   config_vars="$config_vars
  64 CFLAGS-memprofstat.c = $libgd_include"
  65 fi
  66 if test -n "$libgd_ldflags"; then
  67   config_vars="$config_vars
  68 libgd-LDFLAGS = $libgd_ldflags"
  69 fi
  70
  71 dnl Arguments to specify presence of other packages/features.
  72 AC_ARG_WITH(fp, dnl
  73 [  --with-fp              if using floating-point hardware [default=yes]],
  74             with_fp=$withval, with_fp=yes)
  75 AC_ARG_WITH(binutils, dnl
  76   --with-binutils=PATH    specify location of binutils (as and ld),
  77             path_binutils=$withval, path_binutils='')
  78 AC_ARG_WITH(elf, dnl
  79   --with-elf              if using the ELF object format,
  80             elf=$withval, elf=no)
  81 AC_ARG_WITH(cvs, dnl
  82 [  --without-cvs          if CVS should not be used],
  83             with_cvs=$withval, with_cvs=yes)
  84 AC_SUBST(with_cvs)
  85
  86 AC_ARG_WITH(headers, dnl
  87 [  --with-headers=PATH     location of system headers to use
  88                           [e.g. /usr/src/linux/include]
  89                           [default=compiler default]],
  90             sysheaders=$withval, sysheaders='')
  91
  92 AC_ARG_ENABLE(libio, dnl
  93 [  --enable-libio          build in GNU libio instead of GNU stdio],
  94               [if test $enableval = yes; then
  95                  stdio=libio
  96                else
  97                  stdio=stdio
  98                fi],
  99               stdio=default)
 100
 101 AC_ARG_ENABLE(sanity-checks, dnl
 102 [  --disable-sanity-checks really do not use threads (should not be used
 103                           except in special situations) [default=yes]],
 104               enable_sanity=$enableval, enable_sanity=yes)
 105
 106 dnl Arguments to enable or disable building the static, shared, profiled,
 107 dnl and -fomit-frame-pointer libraries.
 108 dnl I've disabled this for now since we cannot build glibc without static
 109 dnl libraries built in the moment.
 110 dnl AC_ARG_ENABLE(static, dnl
 111 dnl [  --enable-static         build static library [default=yes]],
 112 dnl           static=$enableval, static=yes)
 113 static=yes
 114 AC_ARG_ENABLE(shared, dnl
 115 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 116               shared=$enableval, shared=default)
 117 AC_ARG_ENABLE(profile, dnl
 118 [  --enable-profile        build profiled library [default=yes]],
 119               profile=$enableval, profile=yes)
 120 AC_ARG_ENABLE(omitfp, dnl
 121 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 122               omitfp=$enableval, omitfp=no)
 123 AC_ARG_ENABLE(bounded, dnl
 124 [  --enable-bounded        build with runtime bounds checking [default=no]],
 125               bounded=$enableval, bounded=no)
 126 AC_ARG_ENABLE(versioning, dnl
 127 [  --disable-versioning    do not include versioning information in the
 128                           library objects [default=yes if supported]],
 129              enable_versioning=$enableval, enable_versioning=yes)
 130
 131 dnl Generic infrastructure for drop-in additions to libc.
 132 AC_ARG_ENABLE(add-ons, dnl
 133 [  --enable-add-ons[=DIR1,DIR2]...
 134                           configure and build add-ons in DIR1,DIR2,...
 135                           search for add-ons if no parameter given],
 136   [case "$enableval" in
 137     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 138          test "$add_ons" = "*" && add_ons= ;;
 139     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 140    esac],
 141   [add_ons=])
 142
 143 AC_CONFIG_SUBDIRS($add_ons)
 144 add_ons_pfx=
 145 if test x"$add_ons" != x; then
 146   for f in $add_ons; do
 147     # Test whether such a subdir really exists.
 148     if test -d $srcdir/$f; then
 149       add_ons_pfx="$add_ons_pfx $f/"
 150     else
 151       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 152     fi
 153   done
 154 fi
 155
 156 dnl On some platforms we cannot use dynamic loading.  We must provide
 157 dnl static NSS modules.
 158 AC_ARG_ENABLE(static-nss, dnl
 159 [  --enable-static-nss     build static NSS modules [default=no]],
 160               static_nss=$enableval, static_nss=no)
 161 if test x"$static_nss" = xyes; then
 162   AC_DEFINE(DO_STATIC_NSS)
 163 fi
 164
 165 AC_ARG_ENABLE(force-install,
 166 [  --disable-force-install don't force installation of files from this package,
 167                           even if they are older than the installed files],
 168               force_install=$enableval, force_install=yes)
 169 AC_SUBST(force_install)
 170
 171 dnl On some platforms we allow dropping compatibility with all kernel
 172 dnl versions.
 173 AC_ARG_ENABLE(kernel,
 174 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 175                            than VERSION],
 176               minimum_kernel=$enableval)
 177 dnl Prevent unreasonable values.
 178 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 179   # Better nothing than this.
 180   minimum_kernel=""
 181 else
 182   if test "$minimum_kernel" = current; then
 183     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 184   fi
 185 fi
 186
 187 AC_CANONICAL_HOST
 188
 189 # The way shlib-versions is used to generate soversions.mk uses a
 190 # fairly simplistic model for name recognition that can't distinguish
 191 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 192 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 193 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 194 case "$host_os" in
 195 linux*)
 196   ;;
 197 gnu*)
 198   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 199   ;;
 200 esac
 201
 202 # We keep the original values in `$config_*' and never modify them, so we
 203 # can write them unchanged into config.make.  Everything else uses
 204 # $machine, $vendor, and $os, and changes them whenever convenient.
 205 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 206
 207 # Some configurations imply other options.
 208 case "$host_os" in
 209 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 210   # These systems always use GNU tools.
 211   gnu_ld=yes gnu_as=yes ;;
 212 esac
 213 case "$host_os" in
 214 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 215 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 216   ;;
 217 gnu* | linux* | sysv4* | solaris2* | irix6*)
 218   # These systems (almost) always use the ELF format.
 219   elf=yes
 220   ;;
 221 esac
 222
 223 machine=$config_machine
 224 vendor=$config_vendor
 225 os=$config_os
 226
 227 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 228 # Unify this here.
 229 if test "$machine" = rs6000; then
 230   machine="powerpc"
 231 fi
 232
 233 ###
 234 ### I put this here to prevent those annoying emails from people who cannot
 235 ### read and try to compile glibc on unsupported platforms.  --drepper
 236 ###
 237 ### By using the undocumented --enable-hacker-mode option for configure
 238 ### one can skip this test to make the configuration not fail for unsupported
 239 ### platforms.
 240 ###
 241 if test -z "$enable_hacker_mode"; then
 242   case "$machine-$host_os" in
 243   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 244     ;;
 245   *)
 246     echo "*** The GNU C library is currently not available for this platform."
 247     echo "*** So far nobody cared to port it and if there is no volunteer it"
 248     echo "*** might never happen.  So, if you have interest to see glibc on"
 249     echo "*** this platform visit"
 250     echo "***   http://www.gnu.org/software/libc/porting.html"
 251     echo "*** and join the group of porters"
 252     exit 1
 253     ;;
 254   esac
 255 fi
 256
 257 dnl We need to use [ and ] for other purposes for a while now.
 258 changequote(,)dnl
 259 # Expand the configuration machine name into a subdirectory by architecture
 260 # type and particular chip.
 261 case "$machine" in
 262 a29k | am29000) base_machine=a29k machine=a29k ;;
 263 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 264 arm*)           base_machine=arm machine=arm/$machine ;;
 265 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 266 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 267 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 268 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 269 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 270 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 271 m88???)         base_machine=m88k machine=m88k/$machine ;;
 272 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 273 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 274 mips*)          base_machine=mips
 275                 case "`uname -m`" in
 276                 IP22) machine=mips/mips3 ;;
 277                 *)    machine=mips/$machine ;;
 278                 esac ;;
 279 sparc | sparcv[67])
 280                 base_machine=sparc machine=sparc/sparc32 ;;
 281 sparcv8 | supersparc | hypersparc)
 282                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 283 sparcv8plus | sparcv8plusa | sparcv9)
 284                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 285 sparc64 | ultrasparc)
 286                 base_machine=sparc machine=sparc/sparc64 ;;
 287 esac
 288 changequote([,])dnl
 289 AC_SUBST(base_machine)
 290
 291 if test "$base_machine" = "i386"; then
 292   AC_DEFINE(USE_REGPARMS)
 293 fi
 294
 295 # Compute the list of sysdep directories for this configuration.
 296 # This can take a while to compute.
 297 sysdep_dir=$srcdir/sysdeps
 298 AC_MSG_CHECKING(sysdep dirs)
 299 dnl We need to use [ and ] for other purposes for a while now.
 300 changequote(,)dnl
 301 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 302 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 303
 304 case "$os" in
 305 gnu*)
 306   base_os=mach/hurd ;;
 307 netbsd* | 386bsd* | freebsd* | bsdi*)
 308   base_os=unix/bsd/bsd4.4 ;;
 309 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 310   base_os=unix/bsd ;;
 311 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 312   base_os=unix/sysv ;;
 313 irix6*)
 314   base_os=unix/sysv/irix6/$os ;;
 315 solaris[2-9]*)
 316   base_os=unix/sysv/sysv4 ;;
 317 hpux*)
 318   base_os=unix/sysv/hpux/$os ;;
 319 aix4.3*)
 320   base_os=unix/sysv/aix/aix4.3 ;;
 321 none)
 322   base_os=standalone ;;
 323 *)
 324   base_os='' ;;
 325 esac
 326
 327 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 328 tail=$os
 329 ostry=$os
 330 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 331   ostry="$ostry /$o"
 332   tail=$o
 333 done
 334 o=`echo $tail | sed 's/[0-9]*$//'`
 335 if test $o != $tail; then
 336   ostry="$ostry /$o"
 337 fi
 338 # For linux-gnu, try linux-gnu, then linux.
 339 o=`echo $tail | sed 's/-.*$//'`
 340 if test $o != $tail; then
 341   ostry="$ostry /$o"
 342 fi
 343
 344 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 345 base=
 346 tail=$base_os
 347 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 348   set $b
 349   base="$base /$1"
 350   tail="$2"
 351 done
 352
 353 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 354 mach=
 355 tail=$machine
 356 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 357   set $m
 358   # Prepend the machine's FPU directory unless --without-fp.
 359   if test "$with_fp" = yes; then
 360     mach="$mach /$1/fpu"
 361   fi
 362   mach="$mach /$1"
 363   tail="$2"
 364 done
 365
 366 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 367 changequote([,])dnl
 368
 369 # Find what sysdep directories exist.
 370 sysnames=
 371 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 372 for d in $add_ons_pfx ''; do
 373   for b in $base ''; do
 374     for m0 in $mach ''; do
 375       for v in /$vendor ''; do
 376         test "$v" = / && continue
 377         for o in /$ostry ''; do
 378           test "$o" = / && continue
 379           for m in $mach ''; do
 380             if test "$m0$b$v$o$m"; then
 381               try="${d}sysdeps$m0$b$v$o$m"
 382               test -n "$enable_debug_configure" &&
 383               echo "$0 [DEBUG]: try $try" >&2
 384               if test -d $srcdir/$try; then
 385                 sysnames="$sysnames $try"
 386                 { test -n "$o" || test -n "$b"; } && os_used=t
 387                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 388               fi
 389             fi
 390           done
 391         done
 392       done
 393     done
 394   done
 395 done
 396 IFS="$ac_save_ifs"
 397
 398 if test -z "$os_used" && test "$os" != none; then
 399   AC_MSG_ERROR(Operating system $os is not supported.)
 400 fi
 401 if test -z "$machine_used" && test "$machine" != none; then
 402   AC_MSG_ERROR(The $machine is not supported.)
 403 fi
 404
 405 # We have now validated the configuration.
 406
 407
 408 # If using ELF, look for an `elf' subdirectory of each machine directory.
 409 # We prepend these rather than inserting them whereever the machine appears
 410 # because things specified by the machine's ELF ABI should override
 411 # OS-specific things, and should always be the same for any OS on the
 412 # machine (otherwise what's the point of an ABI?).
 413 if test "$elf" = yes; then
 414   elf_dirs=
 415   for d in $add_ons_pfx ''; do
 416     for m in $mach; do
 417       if test -d $srcdir/${d}sysdeps$m/elf; then
 418         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 419       fi
 420     done
 421   done
 422   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 423 fi
 424
 425
 426 # Expand the list of system names into a full list of directories
 427 # from each element's parent name and Implies file (if present).
 428 set $sysnames
 429 names=
 430 while test $# -gt 0; do
 431   name=$1
 432   shift
 433
 434   case " $names " in *" $name "*)
 435     # Already in the list.
 436     continue
 437   esac
 438
 439   # Report each name as we discover it, so there is no long pause in output.
 440   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 441
 442   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 443
 444   case $name in
 445     /*) xsrcdir= ;;
 446     *)  xsrcdir=$srcdir/ ;;
 447   esac
 448   test -n "$enable_debug_configure" &&
 449   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 450
 451   if test -f $xsrcdir$name/Implies; then
 452     # Collect more names from the `Implies' file (removing comments).
 453     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 454     implied=
 455     for x in $implied_candidate; do
 456       if test -d $xsrcdir$name_base/$x; then
 457         implied="$implied $name_base/$x";
 458       else
 459         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 460       fi
 461     done
 462   else
 463     implied=
 464   fi
 465
 466   # Add NAME to the list of names.
 467   names="$names $name"
 468
 469   # Find the parent of NAME, using the empty string if it has none.
 470 changequote(,)dnl
 471   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 472 changequote([,])dnl
 473
 474   # Add the names implied by NAME, and NAME's parent (if it has one), to
 475   # the list of names to be processed (the argument list).  We prepend the
 476   # implied names to the list and append the parent.  We want implied
 477   # directories to come before further directories inferred from the
 478   # configuration components; this ensures that for sysv4, unix/common
 479   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 480   # after sysv4).
 481   sysnames="`echo $implied $* $parent`"
 482   test -n "$sysnames" && set $sysnames
 483 done
 484
 485 # Add the default directories.
 486 default_sysnames=sysdeps/generic
 487 if test "$elf" = yes; then
 488   default_sysnames="sysdeps/generic/elf $default_sysnames"
 489 fi
 490 sysnames="$names $default_sysnames"
 491 AC_SUBST(sysnames)
 492 # The other names were emitted during the scan.
 493 AC_MSG_RESULT($default_sysnames)
 494
 495
 496 ### Locate tools.
 497
 498 AC_PROG_INSTALL
 499 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 500   # The makefiles need to use a different form to find it in $srcdir.
 501   INSTALL='\$(..)./scripts/install-sh -c'
 502 fi
 503 AC_PROG_LN_S
 504
 505 # These programs are version sensitive.
 506 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 507 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 508   [version \([egcygnustp-]*[0-9.]*\)],
 509   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]],
 510   critic_missing=t)
 511 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 512   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 513   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 514
 515 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 516   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 517   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 518 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 519   [GNU texinfo.* \([0-9][0-9.]*\)],
 520   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 521 AC_CHECK_PROG_VER(SED, gsed sed, --version,
 522   [GNU sed version \([0-9]*\.[0-9.]*\)],
 523   [3.0[2-9]|3.[1-9]*|[4-9]*], SED=: aux_missing=t)
 524
 525 if test -n "$critic_missing"; then
 526 AC_MSG_ERROR([
 527 *** Some critical program is missing or too old.
 528 *** Check the INSTALL file for required versions.])
 529 fi
 530
 531 test -n "$aux_missing" && AC_MSG_WARN([
 532 *** An auxiliary program is missing or too old;
 533 *** some features will be disabled.
 534 *** Check the INSTALL file for required versions.])
 535
 536 # glibcbug.in wants to know the compiler version.
 537 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 538 AC_SUBST(CCVERSION)
 539
 540 AC_PROG_CC_LOCAL
 541 AC_CANONICAL_BUILD
 542 if test $host != $build; then
 543   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 544 fi
 545 AC_SUBST(cross_compiling)
 546 AC_PROG_CPP
 547 LIBC_PROG_BINUTILS
 548 AC_CHECK_TOOL(MIG, mig)
 549
 550 # if using special system headers, find out the compiler's sekrit
 551 # header directory and add that to the list.  NOTE: Only does the right
 552 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 553 if test -n "$sysheaders"; then
 554   ccheaders=`$CC -print-file-name=include`
 555   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 556 fi
 557 AC_SUBST(SYSINCLUDES)
 558
 559 # check if ranlib is necessary
 560 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 561 cat > conftest.c <<EOF
 562 int a;
 563 char b;
 564 void c(void) {}
 565 EOF
 566 $CC $CFLAGS -c conftest.c
 567 $AR cr conftest.a conftest.c
 568 cp conftest.a conftest2.a
 569 $RANLIB conftest.a
 570 if cmp -s conftest.a conftest2.a; then
 571   libc_cv_ranlib_necessary=no
 572 else
 573   libc_cv_ranlib_necessary=yes
 574 fi
 575 rm -rf conftest*])
 576 if test "$libc_cv_ranlib_necessary" = no; then
 577  RANLIB=:
 578 fi
 579
 580 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 581 # since this would lead to problems installing/building glibc.
 582 # LD_LIBRARY_PATH contains the current directory if one of the following
 583 # is true:
 584 # - one of the terminals (":" and ";") is the first or last sign
 585 # - two terminals occur directly after each other
 586 # - the path contains an element with a dot in it
 587 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 588 changequote(,)dnl
 589 case ${LD_LIBRARY_PATH} in
 590   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 591     ld_library_path_setting="contains current directory"
 592     ;;
 593   *)
 594     ld_library_path_setting="ok"
 595     ;;
 596 esac
 597 changequote([,])dnl
 598 AC_MSG_RESULT($ld_library_path_setting)
 599 if test "$ld_library_path_setting" != "ok"; then
 600 AC_MSG_ERROR([
 601 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 602 *** building glibc. Please change the environment variable
 603 *** and run configure again.])
 604 fi
 605
 606 AC_PATH_PROG(BASH, bash, no)
 607 if test "$BASH" != no &&
 608    $BASH -c 'test "$BASH_VERSINFO" \
 609              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 610   libc_cv_have_bash2=yes
 611 else
 612   libc_cv_have_bash2=no
 613 fi
 614 AC_SUBST(libc_cv_have_bash2)
 615
 616 dnl We need a ksh compatible shell for tzselect.
 617 if test "$BASH" = no; then
 618   AC_PATH_PROG(KSH, ksh, no)
 619   if test "$KSH" = no; then
 620     libc_cv_have_ksh=no
 621   else
 622     libc_cv_have_ksh=yes
 623   fi
 624 else
 625   KSH="$BASH"
 626   AC_SUBST(KSH)
 627   libc_cv_have_ksh=yes
 628 fi
 629 AC_SUBST(libc_cv_have_ksh)
 630
 631 AC_PROG_AWK
 632 AC_PATH_PROG(PERL, perl, no)
 633 if test "$PERL" != no &&
 634    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
 635   PERL=no
 636 fi
 637 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 638              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 639 if test "$INSTALL_INFO" != "no"; then
 640 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 641  [mkdir conftest.d
 642   # There is a hard ^_ on the next line.  I am open to better ideas.
 643   (echo '\1f'
 644   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 645   echo '* Menu:') >conftest.d/dir
 646   (echo 'INFO-DIR-SECTION i-d-s works'
 647   echo 'START-INFO-DIR-ENTRY'
 648   echo '* Prog: (prog).   Program.'
 649   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 650   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 651   then
 652     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 653     then libc_cv_old_debian_install_info=no
 654     else libc_cv_old_debian_install_info=yes
 655     fi
 656   else libc_cv_old_debian_install_info=no testfailed=t
 657   fi
 658   rm -fr conftest.d])
 659 if test -n "$testfailed"
 660 then AC_MSG_WARN([install-info errored out, check config.log])
 661 fi
 662 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 663 fi
 664 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 665
 666 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 667 echo '#include <stddef.h>
 668 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 669 if eval "$ac_cpp conftest.c 2>/dev/null" \
 670 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 671   libc_cv_signed_size_t=no
 672 else
 673   libc_cv_signed_size_t=yes
 674 fi
 675 rm -f conftest*])
 676 if test $libc_cv_signed_size_t = yes; then
 677   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 678   cat >> confdefs.h <<\EOF
 679 #undef __SIZE_TYPE__
 680 #define __SIZE_TYPE__ unsigned
 681 EOF
 682 fi
 683
 684 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 685 AC_TRY_COMPILE(dnl
 686 [#define __need_size_t
 687 #define __need_wchar_t
 688 #include <stddef.h>
 689 #define __need_NULL
 690 #include <stddef.h>], [size_t size; wchar_t wchar;
 691 #ifdef offsetof
 692 #error stddef.h ignored __need_*
 693 #endif
 694 if (&size == NULL || &wchar == NULL) abort ();],
 695                libc_cv_friendly_stddef=yes,
 696                libc_cv_friendly_stddef=no)])
 697 if test $libc_cv_friendly_stddef = yes; then
 698   config_vars="$config_vars
 699 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 700 fi
 701
 702 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 703                libc_cv_need_minus_P, [dnl
 704 cat > conftest.S <<EOF
 705 #include "confdefs.h"
 706 /* Nothing whatsoever.  */
 707 EOF
 708 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 709   libc_cv_need_minus_P=no
 710 else
 711   libc_cv_need_minus_P=yes
 712 fi
 713 rm -f conftest*])
 714 if test $libc_cv_need_minus_P = yes; then
 715   config_vars="$config_vars
 716 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 717 fi
 718
 719 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 720 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 721 cat > conftest.s <<EOF
 722 .text
 723 EOF
 724 libc_cv_dot_text=
 725 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 726   libc_cv_dot_text=.text
 727 fi
 728 rm -f conftest*])
 729 if test -z "$libc_cv_dot_text"; then
 730   AC_MSG_RESULT(no)
 731 else
 732   AC_MSG_RESULT(yes)
 733 fi
 734
 735 AC_CACHE_CHECK(for assembler global-symbol directive,
 736                libc_cv_asm_global_directive, [dnl
 737 libc_cv_asm_global_directive=UNKNOWN
 738 for ac_globl in .globl .global .EXPORT; do
 739   cat > conftest.s <<EOF
 740         ${libc_cv_dot_text}
 741         ${ac_globl} foo
 742 foo:
 743 EOF
 744   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 745     libc_cv_asm_global_directive=${ac_globl}
 746   fi
 747   rm -f conftest*
 748   test $libc_cv_asm_global_directive != UNKNOWN && break
 749 done])
 750 if test $libc_cv_asm_global_directive = UNKNOWN; then
 751   AC_MSG_ERROR(cannot determine asm global directive)
 752 else
 753   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 754 fi
 755
 756 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 757 cat > conftest.s <<EOF
 758 ${libc_cv_dot_text}
 759 foo:
 760 .set glibc_conftest_frobozz,foo
 761 $libc_cv_asm_global_directive glibc_conftest_frobozz
 762 EOF
 763 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 764 # (but it doesn't work), so we must do a linking check to be sure.
 765 cat > conftest1.c <<\EOF
 766 extern int glibc_conftest_frobozz;
 767 main () { printf ("%d\n", glibc_conftest_frobozz); }
 768 EOF
 769 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 770             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 771   libc_cv_asm_set_directive=yes
 772 else
 773   libc_cv_asm_set_directive=no
 774 fi
 775 rm -f conftest*])
 776 if test $libc_cv_asm_set_directive = yes; then
 777   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 778 fi
 779
 780 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 781 [cat > conftest.s <<EOF
 782 ${libc_cv_dot_text}
 783 _sym:
 784 .symver _sym,sym@VERS
 785 EOF
 786 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 787   libc_cv_asm_symver_directive=yes
 788 else
 789   libc_cv_asm_symver_directive=no
 790 fi
 791 rm -f conftest*])
 792 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 793 if test $libc_cv_asm_symver_directive = yes; then
 794   cat > conftest.s <<EOF
 795 ${libc_cv_dot_text}
 796 _sym:
 797 .symver _sym,sym@VERS
 798 EOF
 799   cat > conftest.map <<EOF
 800 VERS_1 {
 801         global: sym;
 802 };
 803
 804 VERS_2 {
 805         global: sym;
 806 } VERS_1;
 807 EOF
 808   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 809     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 810                                         -nostartfiles -nostdlib
 811                                         -Wl,--version-script,conftest.map
 812                        1>&AC_FD_CC]);
 813     then
 814       libc_cv_ld_version_script_option=yes
 815     else
 816       libc_cv_ld_version_script_option=no
 817     fi
 818   else
 819     libc_cv_ld_version_script_option=no
 820   fi
 821 else
 822   libc_cv_ld_version_script_option=no
 823 fi
 824 rm -f conftest*])
 825 if test $libc_cv_asm_symver_directive = yes &&
 826    test $libc_cv_ld_version_script_option = yes &&
 827    test $enable_versioning = yes; then
 828   VERSIONING=yes
 829   AC_DEFINE(DO_VERSIONING)
 830 else
 831   VERSIONING=no
 832 fi
 833 AC_SUBST(VERSIONING)
 834
 835 if test $VERSIONING = no; then
 836   echo "\
 837 *** WARNING: You should not compile GNU libc without versioning. Not using
 838 *** versioning will introduce incompatibilities so that old binaries
 839 *** will not run anymore.
 840 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 841 fi
 842 if test $elf = yes; then
 843   AC_CACHE_CHECK(for .previous assembler directive,
 844                  libc_cv_asm_previous_directive, [dnl
 845   cat > conftest.s <<EOF
 846 .section foo_section
 847 .previous
 848 EOF
 849   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 850     libc_cv_asm_previous_directive=yes
 851   else
 852     libc_cv_asm_previous_directive=no
 853   fi
 854   rm -f conftest*])
 855   if test $libc_cv_asm_previous_directive = yes; then
 856     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 857   else
 858     AC_CACHE_CHECK(for .popsection assembler directive,
 859                    libc_cv_asm_popsection_directive, [dnl
 860     cat > conftest.s <<EOF
 861 .pushsection foo_section
 862 .popsection
 863 EOF
 864     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 865       libc_cv_asm_popsection_directive=yes
 866     else
 867       libc_cv_asm_popsection_directive=no
 868     fi
 869     rm -f conftest*])
 870     if test $libc_cv_asm_popsection_directive = yes; then
 871       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 872     fi
 873   fi
 874 fi
 875
 876 if test $elf != yes; then
 877   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 878                  [AC_TRY_COMPILE(, [asm (".section .init");
 879                                     asm (".section .fini");
 880                                     asm ("${libc_cv_dot_text}");],
 881                                  libc_cv_have_initfini=yes,
 882                                  libc_cv_have_initfini=no)])
 883   AC_SUBST(libc_cv_have_initfini)dnl
 884   if test $libc_cv_have_initfini = yes; then
 885     AC_DEFINE(HAVE_INITFINI)
 886   fi
 887 fi
 888
 889 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 890 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 891 [cat > conftest.$ac_ext <<EOF
 892 dnl This sometimes fails to find confdefs.h, for some reason.
 893 dnl [#]line __oline__ "[$]0"
 894 [#]line __oline__ "configure"
 895 #include "confdefs.h"
 896 void underscore_test(void) {
 897 return; }
 898 EOF
 899 if AC_TRY_EVAL(ac_compile); then
 900   if grep _underscore_test conftest* >/dev/null; then
 901     ifelse([$1], , :, [rm -f conftest*
 902     $1])
 903   else
 904     ifelse([$2], , , [rm -f conftest*
 905     $2])
 906   fi
 907 else
 908   echo "configure: failed program was:" >&AC_FD_CC
 909   cat conftest.$ac_ext >&AC_FD_CC
 910   ifelse([$2], , , [rm -f conftest*
 911   $2])
 912 fi
 913 rm -f conftest*])
 914
 915 if test $elf = yes; then
 916   libc_cv_asm_underscores=no
 917 else
 918   if test $ac_cv_prog_cc_works = yes; then
 919     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 920                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 921                                 libc_cv_asm_underscores=yes,
 922                                 libc_cv_asm_underscores=no)])
 923   else
 924     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 925                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 926                                             libc_cv_asm_underscores=no)])
 927   fi
 928 fi
 929 if test $libc_cv_asm_underscores = no; then
 930   AC_DEFINE(NO_UNDERSCORES)
 931 fi
 932
 933 if test $elf = yes; then
 934   libc_cv_weak_symbols=yes
 935 fi
 936
 937 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 938                [dnl
 939 cat > conftest.s <<EOF
 940 ${libc_cv_dot_text}
 941 ${libc_cv_asm_global_directive} foo
 942 foo:
 943 .weak foo
 944 .weak bar; bar = foo
 945 EOF
 946 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 947   libc_cv_asm_weak_directive=yes
 948 else
 949   libc_cv_asm_weak_directive=no
 950 fi
 951 rm -f conftest*])
 952
 953 if test $libc_cv_asm_weak_directive = no; then
 954   AC_CACHE_CHECK(for assembler .weakext directive,
 955                  libc_cv_asm_weakext_directive,
 956                  [dnl
 957 cat > conftest.s <<EOF
 958 ${libc_cv_dot_text}
 959 ${libc_cv_asm_global_directive} foo
 960 foo:
 961 .weakext bar foo
 962 .weakext baz
 963 ${libc_cv_asm_global_directive} baz
 964 baz:
 965 EOF
 966   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 967     libc_cv_asm_weakext_directive=yes
 968   else
 969     libc_cv_asm_weakext_directive=no
 970   fi
 971   rm -f conftest*])
 972
 973 fi # no .weak
 974
 975 if test $libc_cv_asm_weak_directive = yes; then
 976   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 977 elif test $libc_cv_asm_weakext_directive = yes; then
 978   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 979 fi
 980
 981 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 982 cat > conftest.c <<\EOF
 983 _start () {}
 984 int __eh_pc;
 985 __throw () {}
 986 EOF
 987 dnl No \ in command here because it ends up inside ''.
 988 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 989                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 990                             -o conftest conftest.c 1>&AC_FD_CC]); then
 991   libc_cv_ld_no_whole_archive=yes
 992 else
 993   libc_cv_ld_no_whole_archive=no
 994 fi
 995 rm -f conftest*])
 996 if test $libc_cv_ld_no_whole_archive = yes; then
 997   no_whole_archive=-Wl,--no-whole-archive
 998 fi
 999 AC_SUBST(no_whole_archive)dnl
1000
1001 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1002 cat > conftest.c <<\EOF
1003 _start () {}
1004 int __eh_pc;
1005 __throw () {}
1006 EOF
1007 dnl No \ in command here because it ends up inside ''.
1008 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1009                             -nostdlib -nostartfiles -fexceptions
1010                             -o conftest conftest.c 1>&AC_FD_CC]); then
1011   libc_cv_gcc_exceptions=yes
1012 else
1013   libc_cv_gcc_exceptions=no
1014 fi
1015 rm -f conftest*])
1016 if test $libc_cv_gcc_exceptions = yes; then
1017   exceptions=-fexceptions
1018 fi
1019 AC_SUBST(exceptions)dnl
1020
1021 if test "$base_machine" = alpha ; then
1022 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1023 cat > conftest.c <<\EOF
1024 foo () { }
1025 EOF
1026 dnl
1027 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1028 then
1029   libc_cv_gcc_alpha_ng_prefix=yes
1030 else
1031   libc_cv_gcc_alpha_ng_prefix=no
1032 fi
1033 rm -f conftest* ])
1034 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1035   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1036 else
1037   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1038 fi
1039 fi
1040
1041 if test "$host_cpu" = powerpc ; then
1042 # Check for a bug present in at least versions 2.8.x of GCC
1043 # and versions 1.0.x of EGCS.
1044 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1045 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1046                libc_cv_c_asmcr0_bug='no',
1047                libc_cv_c_asmcr0_bug='yes')])
1048 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1049   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1050 fi
1051 fi
1052
1053 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1054 [cat > conftest.c <<EOF
1055 #line __oline__ "configure"
1056 static char __EH_FRAME_BEGIN__[];
1057 _start ()
1058 {
1059 #ifdef CHECK__register_frame
1060   __register_frame (__EH_FRAME_BEGIN__);
1061   __deregister_frame (__EH_FRAME_BEGIN__);
1062 #endif
1063 #ifdef CHECK__register_frame_info
1064   __register_frame_info (__EH_FRAME_BEGIN__);
1065   __deregister_frame_info (__EH_FRAME_BEGIN__);
1066 #endif
1067 }
1068 int __eh_pc;
1069 __throw () {}
1070 /* FIXME: this is fragile.  */
1071 malloc () {}
1072 strcmp () {}
1073 strlen () {}
1074 memcpy () {}
1075 memset () {}
1076 free () {}
1077 abort () {}
1078 __bzero () {}
1079 EOF
1080 dnl No \ in command here because it ends up inside ''.
1081 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1082                             -nostdlib -nostartfiles
1083                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1084   libc_cv_gcc_dwarf2_unwind_info=static
1085 else
1086   libc_cv_gcc_dwarf2_unwind_info=no
1087 fi
1088 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1089   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1090                               -nostdlib -nostartfiles
1091                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1092     libc_cv_gcc_dwarf2_unwind_info=yes
1093   else
1094     libc_cv_gcc_dwarf2_unwind_info=no
1095   fi
1096 fi
1097 rm -f conftest*])
1098 case $libc_cv_gcc_dwarf2_unwind_info in
1099 yes)
1100   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1101   ;;
1102 static)
1103   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1104   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1105   ;;
1106 esac
1107
1108 dnl Check whether compiler understands __builtin_expect.
1109 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1110 [cat > conftest.c <<EOF
1111 #line __oline__ "configure"
1112 int foo (int a)
1113 {
1114   a = __builtin_expect (a, 10);
1115   return a == 10 ? 0 : 1;
1116 }
1117 EOF
1118 dnl No \ in command here because it ends up inside ''.
1119 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1120                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1121   libc_cv_gcc_builtin_expect=yes
1122 else
1123   libc_cv_gcc_builtin_expect=no
1124 fi
1125 rm -f conftest*])
1126 if test "$libc_cv_gcc_builtin_expect" = yes; then
1127   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1128 fi
1129
1130 dnl Check whether the compiler supports subtraction of local labels.
1131 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1132 [cat > conftest.c <<EOF
1133 changequote(,)dnl
1134 #line __oline__ "configure"
1135 int foo (int a)
1136 {
1137   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1138   void *p = &&l1 + ar[a];
1139   goto *p;
1140  l1:
1141   return 1;
1142  l2:
1143   return 2;
1144 }
1145 changequote([,])dnl
1146 EOF
1147 dnl No \ in command here because it ends up inside ''.
1148 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1149                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1150   libc_cv_gcc_subtract_local_labels=yes
1151 else
1152   libc_cv_gcc_subtract_local_labels=no
1153 fi
1154 rm -f conftest*])
1155 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1156   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1157 fi
1158
1159 dnl Check whether we have the gd library available.
1160 AC_MSG_CHECKING(for libgd)
1161 old_CFLAGS="$CFLAGS"
1162 CFLAGS="$CFLAGS $libgd_include"
1163 old_LDFLAGS="$LDFLAGS"
1164 LDFLAGS="$LDFLAGS $libgd_ldflags"
1165 old_LIBS="$LIBS"
1166 LIBS="$LIBS -lgd -lpng -lz"
1167 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1168 CFLAGS="$old_CFLAGS"
1169 LDFLAGS="$old_LDFLAGS"
1170 LIBS="$old_LIBS"
1171 AC_MSG_RESULT($LIBGD)
1172 AC_SUBST(LIBGD)
1173
1174 dnl check for the size of 'long double'.
1175 AC_CHECK_SIZEOF(long double, 0)
1176 sizeof_long_double=$ac_cv_sizeof_long_double
1177 AC_SUBST(sizeof_long_double)
1178
1179 ### End of automated tests.
1180 ### Now run sysdeps configure fragments.
1181
1182 # sysdeps configure fragments may set these with files to be linked below.
1183 libc_link_dests=
1184 libc_link_sources=
1185
1186 # They also can set these variables.
1187 use_ldconfig=no
1188 ldd_rewrite_script=no
1189
1190 # Iterate over all the sysdep directories we will use, running their
1191 # configure fragments, and looking for a uname implementation.
1192 uname=
1193 for dir in $sysnames; do
1194   case $dir in
1195     /*) dest=$dir ;;
1196     *)  dest=$srcdir/$dir ;;
1197   esac
1198   if test -r $dest/configure; then
1199     AC_MSG_RESULT(running configure fragment for $dest)
1200     . $dest/configure
1201   fi
1202 [
1203   if test -z "$uname"; then
1204     if test -r $dest/uname.c ||
1205        test -r $dest/uname.S ||
1206        { test -r $dest/syscalls.list &&
1207          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1208       uname=$dir
1209     fi
1210   fi
1211 ]dnl
1212 done
1213
1214 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1215
1216 # If we will use the generic uname implementation, we must figure out what
1217 # it will say by examining the system, and write the results in config-name.h.
1218 if test "$uname" = "sysdeps/generic"; then
1219
1220 changequote(,)dnl
1221   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1222 changequote([,])dnl
1223   if test $uname_sysname != $config_os; then
1224     config_release=`echo $config_os | sed s/$uname_sysname//`
1225   fi
1226 dnl
1227 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1228     if test -r /vmunix; then
1229       kernel_id=`strings /vmunix | grep UNIX`
1230     elif test -r /dynix; then
1231       kernel_id=`strings /dynix | grep DYNIX`
1232     else
1233       kernel_id=
1234     fi
1235 ])dnl
1236
1237   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1238 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1239 changequote(,)dnl
1240   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1241 changequote([,])dnl
1242   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1243          != x$config_release; then
1244     # The configuration release is a substring of the kernel release.
1245     libc_cv_uname_release=$kernel_release
1246   elif test x$config_release != x; then
1247     libc_cv_uname_release=$config_release
1248   elif test x$kernel_release != x; then
1249     libc_cv_uname_release=$kernel_release
1250   else
1251     libc_cv_uname_release=unknown
1252   fi])
1253   uname_release="$libc_cv_uname_release"
1254
1255   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1256 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1257 changequote(,)dnl
1258   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1259 changequote([,])dnl
1260   if test -n "$kernel_version"; then
1261     libc_cv_uname_version="$kernel_version"
1262   else
1263     libc_cv_uname_version=unknown
1264   fi])
1265   uname_version="$libc_cv_uname_version"
1266
1267 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1268   config_uname=config-name.h:config-name.in
1269 else
1270   # For non-generic uname, we don't need to create config-name.h at all.
1271   config_uname=
1272 fi
1273
1274 AC_MSG_CHECKING(stdio selection)
1275 AC_SUBST(stdio)
1276 case $stdio in
1277 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1278 default) stdio=stdio ;;
1279 esac
1280 AC_MSG_RESULT($stdio)
1281
1282 # Test for old glibc 2.0.x headers so that they can be removed properly
1283 # Search only in includedir.
1284 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1285 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1286 then
1287   old_glibc_headers=yes
1288 else
1289   old_glibc_headers=no
1290 fi
1291 AC_MSG_RESULT($old_glibc_headers)
1292 if test ${old_glibc_headers} = yes; then
1293   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1294   AC_MSG_WARN(*** be removed.)
1295 fi
1296 AC_SUBST(old_glibc_headers)
1297
1298 AC_SUBST(libc_cv_slibdir)
1299 AC_SUBST(libc_cv_localedir)
1300 AC_SUBST(libc_cv_sysconfdir)
1301 AC_SUBST(libc_cv_rootsbindir)
1302
1303 AC_SUBST(use_ldconfig)
1304 AC_SUBST(ldd_rewrite_script)
1305
1306 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1307 if test $gnu_ld = yes; then
1308   AC_DEFINE(HAVE_GNU_LD)
1309 fi
1310 if test $gnu_as = yes; then
1311   AC_DEFINE(HAVE_GNU_AS)
1312 fi
1313 if test $elf = yes; then
1314   AC_DEFINE(HAVE_ELF)
1315 fi
1316
1317 AC_SUBST(static)
1318 AC_SUBST(shared)
1319 if test $shared = default; then
1320   if test $gnu_ld = yes; then
1321     shared=$elf
1322   else
1323     # For now we do not assume shared libs are available.  In future more
1324     # tests might become available.
1325     shared=no
1326   fi
1327 fi
1328
1329 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1330 [pic_default=yes
1331 cat > conftest.c <<EOF
1332 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1333 # error PIC is default.
1334 #endif
1335 EOF
1336 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1337   pic_default=no
1338 fi
1339 rm -f conftest.*])
1340 AC_SUBST(pic_default)
1341
1342 AC_SUBST(profile)
1343 AC_SUBST(omitfp)
1344 AC_SUBST(bounded)
1345 AC_SUBST(static_nss)
1346 AC_SUBST(nopic_initfini)
1347
1348 AC_SUBST(DEFINES)
1349
1350 case "$add_ons" in
1351   *door*) linux_doors=yes ;;
1352   *) linux_doors=no ;;
1353 esac
1354 AC_SUBST(linux_doors)
1355
1356 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1357   config_makefile=
1358 else
1359   config_makefile=Makefile
1360 fi
1361
1362 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1363 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1364 AC_SUBST(VERSION)
1365 AC_SUBST(RELEASE)
1366
1367 echo '*** Do NOT install this release on any production system!'
1368 echo '*** It is known to be broken and will be so for quite some time.'
1369 echo '*** Use the latest released version instead.'
1370
1371 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1372 case $CONFIG_FILES in *config.make*)
1373 echo "$config_vars" >> config.make;;
1374 esac
1375 test -d bits || mkdir bits], [config_vars='$config_vars'])