configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.4.2)dnl             dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21
  22 dnl Arguments to specify presence of other packages/features.
  23 AC_ARG_WITH(fp, dnl
  24   --with-fp               if using floating-point hardware,
  25             with_fp=$withval, with_fp=yes)
  26 AC_ARG_WITH(gnu-binutils, dnl
  27   --with-gnu-binutils     if using GNU binutils (as and ld),
  28             gnu_binutils=$withval, gnu_binutils=no)
  29 AC_ARG_WITH(gnu-ld, dnl
  30   --with-gnu-ld           if using GNU ld (in the binutils package),
  31             gnu_ld=$withval, gnu_ld=no)
  32 AC_ARG_WITH(gnu-as, dnl
  33   --with-gnu-as           if using GNU as (in the binutils package),
  34             gnu_as=$withval, gnu_as=no)
  35 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  36 AC_ARG_WITH(elf, dnl
  37   --with-elf              if using the ELF object format,
  38             elf=$withval, elf=no)
  39 AC_ARG_WITH(weak-symbols, dnl
  40   --with-weak-symbols     if weak symbols are available in as and ld,
  41             weak=$withval, weak=no)
  42
  43 AC_ARG_ENABLE(libio, dnl
  44 [  --enable-libio          build in GNU libio instead of GNU stdio],
  45               stdio=libio, stdio=stdio)
  46
  47 dnl Arguments to enable or disable building the shared, profiled, and
  48 dnl -fomit-frame-pointer libraries.
  49 AC_ARG_ENABLE(shared, dnl
  50 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  51             shared=$enableval, shared=default)
  52 AC_ARG_ENABLE(profile, dnl
  53 [  --enable-profile        build profiled library [default=yes]],
  54             profile=$enableval, profile=yes)
  55 AC_ARG_ENABLE(omitfp, dnl
  56 [  --enable-omitfp       build undebuggable optimized library [default=no]],
  57             omitfp=$enableval, omitfp=no)
  58
  59 AC_MSG_CHECKING(stdio selection)
  60 AC_SUBST(stdio)
  61 if test $stdio = libio; then
  62   AC_DEFINE(USE_IN_LIBIO)
  63 fi
  64 AC_MSG_RESULT($stdio)
  65
  66 AC_CANONICAL_HOST
  67 # We keep the original values in `$config_*' and never modify them, so we
  68 # can write them unchanged into config.make.  Everything else uses
  69 # $machine, $vendor, and $os, and changes them whenever convenient.
  70 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  71
  72 # Some configurations imply other options.
  73 case "$host_os" in
  74 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
  75   # These systems always use GNU tools.
  76   gnu_ld=yes gnu_as=yes
  77 esac
  78 case "$host_os" in
  79 gnu* | linux* | sysv4* | solaris2*)
  80   # These systems always use the ELF format.
  81   elf=yes
  82 esac
  83
  84 # Compute the list of sysdep directories for this configuration.
  85 sysdep_dir=$srcdir/sysdeps
  86 AC_CACHE_CHECK(sysdep dirs, libc_cv_sysdirs, [dnl
  87 machine=$config_machine
  88 vendor=$config_vendor
  89 os=$config_os
  90
  91 dnl We need to use [ and ] for other purposes for a while now.
  92 changequote(,)dnl
  93 # Expand the configuration machine name into a subdirectory by architecture
  94 # type and particular chip.
  95 case "$machine" in
  96 a29k | am29000) machine=a29k ;;
  97 alpha*)         machine=alpha/$machine ;;
  98 hppa*)          machine=hppa/$machine ;;
  99 i[345]86)       machine=i386/$machine ;;
 100 m680?0)         machine=m68k/$machine ;;
 101 m68k)           machine=m68k/m68020 ;;
 102 m88???)         machine=m88k/$machine ;;
 103 m88k)           machine=m88k/m88100 ;;
 104 mips*)          machine=mips/$machine ;;
 105 mips64*)        machine=mips/mips64/$machine ;;
 106 sparc[6789])    machine=sparc/$machine ;;
 107 supersparc)     machine=sparc/sparc8 ;;
 108 esac
 109
 110 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 111 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 112
 113 case "$os" in
 114 gnu*)
 115   base_os=mach/hurd ;;
 116 netbsd* | 386bsd* | freebsd* | bsdi*)
 117   base_os=unix/bsd/bsd4.4 ;;
 118 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 119   base_os=unix/bsd ;;
 120 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 121   base_os=unix/sysv ;;
 122 solaris[2-9]*)
 123   base_os=unix/sysv/sysv4 ;;
 124 none)
 125   base_os=standalone ;;
 126 *)
 127   base_os='' ;;
 128 esac
 129
 130 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 131 tail=$os
 132 ostry=$os
 133 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 134   ostry="$ostry /$o"
 135   tail=$o
 136 done
 137 o=`echo $tail | sed 's/[0-9]*$//'`
 138 if test $o != $tail; then
 139   ostry="$ostry /$o"
 140 fi
 141
 142 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 143 base=
 144 tail=$base_os
 145 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 146   set $b
 147   base="$base /$1"
 148   tail="$2"
 149 done
 150
 151 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 152 mach=
 153 tail=$machine
 154 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 155   set $m
 156   # Prepend the machine's FPU directory unless --without-fp.
 157   if test "$with_fp" = yes; then
 158     mach="$mach /$1/fpu"
 159   fi
 160   mach="$mach /$1"
 161   tail="$2"
 162 done
 163
 164 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 165 changequote([,])dnl
 166
 167 # Find what sysdep directories exist.
 168 sysnames=
 169 for b in $base ''; do
 170   for m0 in $mach ''; do
 171     for v in /$vendor ''; do
 172       for o in /$ostry ''; do
 173         for m in $mach ''; do
 174           try="$m0$b$v$o$m"
 175           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
 176           if test -d $sysdep_dir$try; then
 177             sysnames="$sysnames $try"
 178             { test -n "$o" || test -n "$b"; } && os_used=t
 179             { test -n "$m" || test -n "$m0"; } && machine_used=t
 180           fi
 181         done
 182       done
 183     done
 184   done
 185 done
 186
 187 if test -z "$os_used" && test "$os" != none; then
 188   AC_MSG_ERROR(Operating system $os is not supported.)
 189 fi
 190 if test -z "$machine_used" && test "$machine" != none; then
 191   AC_MSG_ERROR(The $machine is not supported.)
 192 fi
 193
 194 # We have now validated the configuration.
 195
 196
 197 # If using ELF, look for an `elf' subdirectory of each machine directory.
 198 # We prepend these rather than inserting them whereever the machine appears
 199 # because things specified by the machine's ELF ABI should override
 200 # OS-specific things, and should always be the same for any OS on the
 201 # machine (otherwise what's the point of an ABI?).
 202 if test "$elf" = yes; then
 203   elf_dirs=
 204   for m in $mach; do
 205     if test -d $sysdep_dir$m/elf; then
 206       elf_dirs="$elf_dirs $m/elf"
 207     fi
 208   done
 209   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
 210 fi
 211
 212
 213 # Remove the leading slashes.
 214 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
 215
 216
 217 # Expand the list of system names into a full list of directories
 218 # from each element's parent name and Implies file (if present).
 219 set $sysnames
 220 while test $# -gt 0; do
 221   name=$1
 222   shift
 223
 224   if test -f $sysdep_dir/$name/Implies; then
 225     # Collect more names from the `Implies' file (removing comments).
 226     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
 227     for x in $implied; do
 228       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
 229     done
 230   else
 231     implied=
 232   fi
 233
 234   # Add NAME to the list of names.
 235   names="$names $name"
 236
 237   # Find the parent of NAME, using the empty string if it has none.
 238 changequote(,)dnl
 239   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
 240 changequote([,])dnl
 241
 242   # Add the names implied by NAME, and NAME's parent (if it has one), to
 243   # the list of names to be processed (the argument list).  We prepend the
 244   # implied names to the list and append the parent.  We want implied
 245   # directories to come before further directories inferred from the
 246   # configuration components; this ensures that for sysv4, unix/common
 247   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 248   # after sysv4).
 249   sysnames="`echo $implied $* $parent`"
 250   test -n "$sysnames" && set $sysnames
 251 done
 252
 253 # Add the default directories.
 254 names="$names generic stub"
 255
 256 # Now uniquize the list.
 257 seen=
 258 sysnames=
 259 for name in $names; do
 260   if echo "$seen" | fgrep -x $name >/dev/null; then
 261     # Already in the list.
 262     true;
 263   else
 264     # A new one.
 265     if test -z "$seen"; then
 266       seen="$name" sysnames="$name"
 267     else
 268       seen="$seen
 269 $name"
 270       sysnames="$sysnames $name"
 271     fi
 272   fi
 273 done
 274 libc_cv_sysdirs="$sysnames"])
 275 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
 276
 277 AC_PROG_INSTALL
 278 if test "$INSTALL" = "${srcdir}/install-sh"; then
 279   # The makefiles need to use a different form to find it in $srcdir.
 280   INSTALL='$(..)./install-sh'
 281 fi
 282
 283 AC_CHECK_TOOL(CC, gcc)
 284 AC_CHECK_TOOL(AR, ar)
 285 AC_CHECK_TOOL(RANLIB, ranlib, :)
 286 AC_PROG_CPP
 287
 288 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 289 echo '#include <stddef.h>
 290 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 291 if eval "$ac_cpp conftest.c 2>/dev/null" \
 292 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 293   libc_cv_signed_size_t=no
 294 else
 295   libc_cv_signed_size_t=yes
 296 fi
 297 rm -f conftest*])
 298 if test $libc_cv_signed_size_t = yes; then
 299   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 300   cat >> confdefs.h <<\EOF
 301 #undef __SIZE_TYPE__
 302 #define __SIZE_TYPE__ unsigned
 303 EOF
 304 fi
 305
 306 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 307 AC_TRY_COMPILE(dnl
 308 [#define __need_size_t
 309 #define __need_wchar_t
 310 #include <stddef.h>
 311 #define __need_NULL
 312 #include <stddef.h>], [size_t size; wchar_t wchar;
 313 #ifdef offsetof
 314 #error stddef.h ignored __need_*
 315 #endif
 316 if (&size == NULL || &wchar == NULL) abort ();],
 317                libc_cv_friendly_stddef=yes,
 318                libc_cv_friendly_stddef=no)])
 319 if test $libc_cv_friendly_stddef = yes; then
 320   config_vars="$config_vars
 321 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 322 fi
 323
 324 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 325                libc_cv_need_minus_P, [dnl
 326 cat > conftest.S <<EOF
 327 #include "confdefs.h"
 328 /* Nothing whatsoever.  */
 329 EOF
 330 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 331   libc_cv_need_minus_P=no
 332 else
 333   libc_cv_need_minus_P=yes
 334 fi
 335 rm -f conftest*])
 336 if test $libc_cv_need_minus_P = yes; then
 337   config_vars="$config_vars
 338 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 339 fi
 340
 341 AC_CACHE_CHECK(for assembler global-symbol directive,
 342                libc_cv_asm_global_directive, [dnl
 343 libc_cv_asm_global_directive=UNKNOWN
 344 for ac_globl in .globl .global; do
 345   cat > conftest.s <<EOF
 346 .text
 347 ${ac_globl} foo
 348 foo: .long 0
 349 EOF
 350   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 351     libc_cv_asm_global_directive=${ac_globl}
 352   fi
 353   rm -f conftest*
 354   test $libc_cv_asm_global_directive != UNKNOWN && break
 355 done])
 356 if test $libc_cv_asm_global_directive = UNKNOWN; then
 357   AC_MSG_ERROR(cannot determine asm global directive)
 358 else
 359   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 360 fi
 361
 362 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 363 cat > conftest.s <<EOF
 364 .text
 365 foo: .long 0
 366 .set glibc_conftest_frobozz,foo
 367 $libc_cv_asm_global_directive glibc_conftest_frobozz
 368 EOF
 369 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 370 # (but it doesn't work), so we must do a linking check to be sure.
 371 cat > conftest1.c <<\EOF
 372 extern int glibc_conftest_frobozz;
 373 main () { printf ("%d\n", glibc_conftest_frobozz); }
 374 EOF
 375 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 376             conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 377   libc_cv_asm_set_directive=yes
 378 else
 379   libc_cv_asm_set_directive=no
 380 fi
 381 rm -f conftest*])
 382 if test $libc_cv_asm_set_directive = yes; then
 383   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 384 fi
 385
 386 if test $elf != yes; then
 387   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 388                  [AC_TRY_COMPILE(, [asm (".section .init");
 389                                     asm (".section .fini");],
 390                                  libc_cv_have_initfini=yes,
 391                                  libc_cv_have_initfini=no)])
 392   AC_SUBST(libc_cv_have_initfini)dnl
 393   if test $libc_cv_have_initfini = yes; then
 394     AC_DEFINE(HAVE_INITFINI)
 395   fi
 396 fi
 397
 398 # sysdeps configure fragments may set these with files to be linked below.
 399 libc_link_dests=
 400 libc_link_sources=
 401
 402 # Iterate over all the sysdep directories we will use, running their
 403 # configure fragments, and looking for a uname implementation.
 404 uname=
 405 for dir in $sysnames; do
 406   if test -r $sysdep_dir/$dir/configure; then
 407     AC_MSG_RESULT(running configure fragment for $dir)
 408     . $sysdep_dir/$dir/configure
 409   fi
 410   if test -z "$uname"; then
 411     { test -r $sysdep_dir/$dir/uname.c || test -r $sysdep_dir/$dir/uname.S; } \
 412     && uname=$dir
 413   fi
 414 done
 415
 416 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 417
 418 # If we will use the generic uname implementation, we must figure out what
 419 # it will say by examining the system, and write the results in config-name.h.
 420 if test "$uname" = generic; then
 421
 422 changequote(,)dnl
 423   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 424 changequote([,])dnl
 425   if test $uname_sysname != $config_os; then
 426     config_release=`echo $config_os | sed s/$uname_sysname//`
 427   fi
 428 dnl
 429 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 430     if test -r /vmunix; then
 431       kernel_id=`strings /vmunix | grep UNIX`
 432     elif test -r /dynix; then
 433       kernel_id=`strings /dynix | grep DYNIX`
 434     else
 435       kernel_id=
 436     fi
 437 ])dnl
 438
 439   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 440 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 441 changequote(,)dnl
 442   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 443 changequote([,])dnl
 444   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 445          != x$config_release; then
 446     # The configuration release is a substring of the kernel release.
 447     libc_cv_uname_release=$kernel_release
 448   elif test x$config_release != x; then
 449     libc_cv_uname_release=$config_release
 450   elif test x$kernel_release != x; then
 451     libc_cv_uname_release=$kernel_release
 452   else
 453     libc_cv_uname_release=unknown
 454   fi])
 455   uname_release="$libc_cv_uname_release"
 456
 457   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 458 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 459 changequote(,)dnl
 460   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 461 changequote([,])dnl
 462   if test -n "$kernel_version"; then
 463     libc_cv_uname_version="$kernel_version"
 464   else
 465     libc_cv_uname_version=unknown
 466   fi])
 467   uname_version="$libc_cv_uname_version"
 468
 469 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 470   config_uname=config-name.h:config-name.in
 471 else
 472   # For non-generic uname, we don't need to create config-name.h at all.
 473   config_uname=
 474 fi
 475
 476 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf) AC_SUBST(weak)
 477 if test $gnu_ld = yes; then
 478   AC_DEFINE(HAVE_GNU_LD)
 479 fi
 480 if test $gnu_as = yes; then
 481   AC_DEFINE(HAVE_GNU_AS)
 482 fi
 483 if test $elf = yes; then
 484   AC_DEFINE(HAVE_ELF)
 485 fi
 486 if test $weak = yes; then
 487   AC_DEFINE(HAVE_WEAK_SYMBOLS)
 488 fi
 489
 490 AC_SUBST(shared)
 491 if test $shared = default; then
 492   if test $gnu_ld = yes; then
 493     shared=$elf
 494   fi
 495 fi
 496 AC_SUBST(profile)
 497 AC_SUBST(omitfp)
 498
 499 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 500   config_makefile=
 501 else
 502   config_makefile=Makefile
 503 fi
 504
 505 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 506           [echo '$config_vars' >> config.make])