configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  23 AC_ARG_WITH(gd, dnl
  24   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  25             [dnl
  26 case "$with_gd" in
  27 yes|''|no) ;;
  28 *) libgd_include="-I$withval/include"
  29    libgd_ldflags="-L$withval/lib" ;;
  30 esac
  31 ])
  32 AC_ARG_WITH(gd-include, dnl
  33   --with-gd-include=DIR   find libgd include files in DIR,
  34             [dnl
  35 case "$with_gd_include" in
  36 ''|no) ;;
  37 *) libgd_include="-I$withval" ;;
  38 esac
  39 ])
  40 AC_ARG_WITH(gd-lib, dnl
  41   --with-gd-lib=DIR       find libgd library files in DIR,
  42             [dnl
  43 case "$with_gd_lib" in
  44 ''|no) ;;
  45 *) libgd_ldflags="-L$withval" ;;
  46 esac
  47 ])
  48
  49 if test -n "$libgd_include"; then
  50   config_vars="$config_vars
  51 CFLAGS-memusagestat.c = $libgd_include"
  52 fi
  53 if test -n "$libgd_ldflags"; then
  54   config_vars="$config_vars
  55 libgd-LDFLAGS = $libgd_ldflags"
  56 fi
  57
  58 dnl Arguments to specify presence of other packages/features.
  59 AC_ARG_WITH(fp, dnl
  60 [  --with-fp              if using floating-point hardware [default=yes]],
  61             with_fp=$withval, with_fp=yes)
  62 AC_ARG_WITH(binutils, dnl
  63   --with-binutils=PATH    specify location of binutils (as and ld),
  64             path_binutils=$withval, path_binutils='')
  65 AC_ARG_WITH(elf, dnl
  66   --with-elf              if using the ELF object format,
  67             elf=$withval, elf=no)
  68 AC_ARG_WITH(cvs, dnl
  69 [  --without-cvs           if CVS should not be used],
  70             with_cvs=$withval, with_cvs=yes)
  71 if test "$with_cvs" = yes; then
  72   if test -d $srcdir/CVS && grep :pserver: $srcdir/CVS/Root > /dev/null
  73   then
  74     with_cvs=no
  75   fi
  76 fi
  77 AC_SUBST(with_cvs)
  78
  79 AC_ARG_WITH(headers, dnl
  80 [  --with-headers=PATH     location of system headers to use
  81                           [e.g. /usr/src/linux/include]
  82                           [default=compiler default]],
  83             sysheaders=$withval, sysheaders='')
  84
  85 AC_ARG_ENABLE(libio, dnl
  86 [  --enable-libio          build in GNU libio instead of GNU stdio],
  87               [if test $enableval = yes; then
  88                  stdio=libio
  89                else
  90                  stdio=stdio
  91                fi],
  92               stdio=default)
  93
  94 AC_ARG_ENABLE(sanity-checks, dnl
  95 [  --disable-sanity-checks really do not use threads (should not be used
  96                           except in special situations) [default=yes]],
  97               enable_sanity=$enableval, enable_sanity=yes)
  98
  99 dnl Arguments to enable or disable building the static, shared, profiled,
 100 dnl and -fomit-frame-pointer libraries.
 101 dnl I've disabled this for now since we cannot build glibc without static
 102 dnl libraries built in the moment.
 103 dnl AC_ARG_ENABLE(static, dnl
 104 dnl [  --enable-static         build static library [default=yes]],
 105 dnl           static=$enableval, static=yes)
 106 static=yes
 107 AC_ARG_ENABLE(shared, dnl
 108 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 109               shared=$enableval, shared=default)
 110 AC_ARG_ENABLE(profile, dnl
 111 [  --enable-profile        build profiled library [default=yes]],
 112               profile=$enableval, profile=yes)
 113 AC_ARG_ENABLE(omitfp, dnl
 114 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 115               omitfp=$enableval, omitfp=no)
 116 AC_ARG_ENABLE(bounded, dnl
 117 [  --enable-bounded        build with runtime bounds checking [default=no]],
 118               bounded=$enableval, bounded=no)
 119 AC_ARG_ENABLE(versioning, dnl
 120 [  --disable-versioning    do not include versioning information in the
 121                           library objects [default=yes if supported]],
 122              enable_versioning=$enableval, enable_versioning=yes)
 123
 124 AC_ARG_ENABLE(oldest-abi, dnl
 125 [  --enable-oldest-abi=ABI configure the oldest ABI supported [e.g. 2.2]
 126                           [default=glibc default]],
 127             oldest_abi=$enableval, oldest_abi=no)
 128 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 129   oldest_abi=default
 130 else
 131   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 132 fi
 133 AC_SUBST(oldest_abi)
 134
 135 dnl Generic infrastructure for drop-in additions to libc.
 136 AC_ARG_ENABLE(add-ons, dnl
 137 [  --enable-add-ons[=DIR1,DIR2]...
 138                           configure and build add-ons in DIR1,DIR2,...
 139                           search for add-ons if no parameter given],
 140   [case "$enableval" in
 141     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 142          test "$add_ons" = "*" && add_ons= ;;
 143     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 144    esac],
 145   [add_ons=])
 146
 147 AC_CONFIG_SUBDIRS($add_ons)
 148 add_ons_pfx=
 149 if test x"$add_ons" != x; then
 150   for f in $add_ons; do
 151     # Some sanity checks
 152     if test "$f" = "crypt"; then
 153       AC_MSG_ERROR([
 154 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 155 *** part of glibc and using the old add-on will not work with this
 156 *** release.  Start again with fresh sources and without the old
 157 *** \`crypt' add-on.])
 158     fi
 159     if test "$f" = "localedata"; then
 160       AC_MSG_ERROR([
 161 *** It seems that you're using an old \`localedata' add-on.  localedata
 162 *** is now part of glibc and using the old add-on will not work with
 163 *** this release.  Start again with fresh sources and without the old
 164 *** \`localedata' add-on.])
 165     fi
 166     # Test whether such a subdir really exists.
 167     if test -d $srcdir/$f; then
 168       add_ons_pfx="$add_ons_pfx $f/"
 169     else
 170       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 171     fi
 172   done
 173 fi
 174
 175 dnl On some platforms we cannot use dynamic loading.  We must provide
 176 dnl static NSS modules.
 177 AC_ARG_ENABLE(static-nss, dnl
 178 [  --enable-static-nss     build static NSS modules [default=no]],
 179               static_nss=$enableval, static_nss=no)
 180 if test x"$static_nss" = xyes; then
 181   AC_DEFINE(DO_STATIC_NSS)
 182 fi
 183
 184 AC_ARG_ENABLE(force-install,
 185 [  --disable-force-install don't force installation of files from this package,
 186                           even if they are older than the installed files],
 187               force_install=$enableval, force_install=yes)
 188 AC_SUBST(force_install)
 189
 190 dnl On some platforms we allow dropping compatibility with all kernel
 191 dnl versions.
 192 AC_ARG_ENABLE(kernel,
 193 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 194                            than VERSION],
 195               minimum_kernel=$enableval)
 196 dnl Prevent unreasonable values.
 197 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 198   # Better nothing than this.
 199   minimum_kernel=""
 200 else
 201   if test "$minimum_kernel" = current; then
 202     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 203   fi
 204 fi
 205
 206 dnl For the development we sometimes want gcc to issue even more warnings.
 207 dnl This is not the default since many of the extra warnings are not
 208 dnl appropriate.
 209 AC_ARG_ENABLE(all-warnings,
 210 [  --enable-all-warnings   enable all useful warnings gcc can issue],
 211               all_warnings=$enableval)
 212 AC_SUBST(all_warnings)
 213
 214 AC_CANONICAL_HOST
 215
 216 # The way shlib-versions is used to generate soversions.mk uses a
 217 # fairly simplistic model for name recognition that can't distinguish
 218 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 219 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 220 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 221 case "$host_os" in
 222 linux*)
 223   ;;
 224 gnu*)
 225   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 226   ;;
 227 esac
 228
 229 # We keep the original values in `$config_*' and never modify them, so we
 230 # can write them unchanged into config.make.  Everything else uses
 231 # $machine, $vendor, and $os, and changes them whenever convenient.
 232 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 233
 234 # Don't allow vendor == "unknown"
 235 test "$config_vendor" = unknown && config_vendor=
 236 config_os="`echo $config_os | sed 's/^unknown-//'`"
 237
 238 # Some configurations imply other options.
 239 case "$host_os" in
 240 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 241   # These systems always use GNU tools.
 242   gnu_ld=yes gnu_as=yes ;;
 243 esac
 244 case "$host_os" in
 245 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 246 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 247   ;;
 248 gnu* | linux* | sysv4* | solaris2* | irix6*)
 249   # These systems (almost) always use the ELF format.
 250   elf=yes
 251   ;;
 252 esac
 253
 254 machine=$config_machine
 255 vendor=$config_vendor
 256 os=$config_os
 257
 258 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 259 # Unify this here.
 260 if test "$machine" = rs6000; then
 261   machine="powerpc"
 262 fi
 263
 264 ###
 265 ### I put this here to prevent those annoying emails from people who cannot
 266 ### read and try to compile glibc on unsupported platforms.  --drepper
 267 ###
 268 ### By using the undocumented --enable-hacker-mode option for configure
 269 ### one can skip this test to make the configuration not fail for unsupported
 270 ### platforms.
 271 ###
 272 if test -z "$enable_hacker_mode"; then
 273   case "$machine-$host_os" in
 274   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 275     ;;
 276   *)
 277     echo "*** The GNU C library is currently not available for this platform."
 278     echo "*** So far nobody cared to port it and if there is no volunteer it"
 279     echo "*** might never happen.  So, if you have interest to see glibc on"
 280     echo "*** this platform visit"
 281     echo "***   http://www.gnu.org/software/libc/porting.html"
 282     echo "*** and join the group of porters"
 283     exit 1
 284     ;;
 285   esac
 286 fi
 287
 288 dnl We need to use [ and ] for other purposes for a while now.
 289 changequote(,)dnl
 290 # Expand the configuration machine name into a subdirectory by architecture
 291 # type and particular chip.
 292 case "$machine" in
 293 a29k | am29000) base_machine=a29k machine=a29k ;;
 294 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 295 arm*)           base_machine=arm machine=arm/arm32/$machine ;;
 296 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 297 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 298 hppa*64*)       base_machine=hppa machine=hppa/hppa64 ;;
 299 hppa*)          base_machine=hppa machine=hppa/hppa1.1 ;;
 300 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 301 ia64)           base_machine=ia64 machine=ia64 ;;
 302 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 303 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 304 m88???)         base_machine=m88k machine=m88k/$machine ;;
 305 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 306 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 307 mips*)          base_machine=mips
 308                 case "`uname -m`" in
 309                 IP22) machine=mips/mips3 ;;
 310                 *)    machine=mips/$machine ;;
 311                 esac ;;
 312 s390)           base_machine=s390 machine=s390/s390-32 ;;
 313 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 314 sh3*)           base_machine=sh machine=sh/sh3 ;;
 315 sh4*)           base_machine=sh machine=sh/sh4 ;;
 316 sparc | sparcv[67])
 317                 base_machine=sparc machine=sparc/sparc32 ;;
 318 sparcv8 | supersparc | hypersparc)
 319                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 320 sparcv8plus | sparcv8plusa | sparcv9)
 321                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 322 sparc64 | ultrasparc)
 323                 base_machine=sparc machine=sparc/sparc64 ;;
 324 thumb*)         base_machine=thumb machine=arm/thumb/$machine ;;
 325 esac
 326 changequote([,])dnl
 327 AC_SUBST(base_machine)
 328
 329 if test "$base_machine" = "i386"; then
 330   AC_DEFINE(USE_REGPARMS)
 331 fi
 332
 333 # Compute the list of sysdep directories for this configuration.
 334 # This can take a while to compute.
 335 sysdep_dir=$srcdir/sysdeps
 336 AC_MSG_CHECKING(sysdep dirs)
 337 dnl We need to use [ and ] for other purposes for a while now.
 338 changequote(,)dnl
 339 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 340 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 341
 342 case "$os" in
 343 gnu*)
 344   base_os=mach/hurd ;;
 345 netbsd* | 386bsd* | freebsd* | bsdi*)
 346   base_os=unix/bsd/bsd4.4 ;;
 347 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 348   base_os=unix/bsd ;;
 349 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 350   base_os=unix/sysv ;;
 351 irix6*)
 352   base_os=unix/sysv/irix6/$os ;;
 353 solaris[2-9]*)
 354   base_os=unix/sysv/sysv4 ;;
 355 hpux*)
 356   base_os=unix/sysv/hpux/$os ;;
 357 aix4.3*)
 358   base_os=unix/sysv/aix/aix4.3 ;;
 359 none)
 360   base_os=standalone ;;
 361 *)
 362   base_os='' ;;
 363 esac
 364
 365 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 366 tail=$os
 367 ostry=$os
 368 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 369   ostry="$ostry /$o"
 370   tail=$o
 371 done
 372 o=`echo $tail | sed 's/[0-9]*$//'`
 373 if test $o != $tail; then
 374   ostry="$ostry /$o"
 375 fi
 376 # For linux-gnu, try linux-gnu, then linux.
 377 o=`echo $tail | sed 's/-.*$//'`
 378 if test $o != $tail; then
 379   ostry="$ostry /$o"
 380 fi
 381
 382 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 383 base=
 384 tail=$base_os
 385 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 386   set $b
 387   base="$base /$1"
 388   tail="$2"
 389 done
 390
 391 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 392 mach=
 393 tail=$machine
 394 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 395   set $m
 396   # Prepend the machine's FPU directory unless --without-fp.
 397   if test "$with_fp" = yes; then
 398     mach="$mach /$1/fpu"
 399   fi
 400   mach="$mach /$1"
 401   tail="$2"
 402 done
 403
 404 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 405 changequote([,])dnl
 406
 407 # Find what sysdep directories exist.
 408 sysnames=
 409 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 410 for d in $add_ons_pfx ''; do
 411   for b in $base ''; do
 412     for m0 in $mach ''; do
 413       for v in /$vendor ''; do
 414         test "$v" = / && continue
 415         for o in /$ostry ''; do
 416           test "$o" = / && continue
 417           for m in $mach ''; do
 418             if test "$m0$b$v$o$m"; then
 419               try="${d}sysdeps$m0$b$v$o$m"
 420               test -n "$enable_debug_configure" &&
 421               echo "$0 [DEBUG]: try $try" >&2
 422               if test -d $srcdir/$try; then
 423                 sysnames="$sysnames $try"
 424                 { test -n "$o" || test -n "$b"; } && os_used=t
 425                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 426               fi
 427             fi
 428           done
 429         done
 430       done
 431     done
 432   done
 433 done
 434 IFS="$ac_save_ifs"
 435
 436 if test -z "$os_used" && test "$os" != none; then
 437   AC_MSG_ERROR(Operating system $os is not supported.)
 438 fi
 439 if test -z "$machine_used" && test "$machine" != none; then
 440   AC_MSG_ERROR(The $machine is not supported.)
 441 fi
 442
 443 # We have now validated the configuration.
 444
 445
 446 # If using ELF, look for an `elf' subdirectory of each machine directory.
 447 # We prepend these rather than inserting them whereever the machine appears
 448 # because things specified by the machine's ELF ABI should override
 449 # OS-specific things, and should always be the same for any OS on the
 450 # machine (otherwise what's the point of an ABI?).
 451 if test "$elf" = yes; then
 452   elf_dirs=
 453   for d in $add_ons_pfx ''; do
 454     for m in $mach; do
 455       if test -d $srcdir/${d}sysdeps$m/elf; then
 456         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 457       fi
 458     done
 459   done
 460   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 461 fi
 462
 463
 464 # Expand the list of system names into a full list of directories
 465 # from each element's parent name and Implies file (if present).
 466 set $sysnames
 467 names=
 468 while test $# -gt 0; do
 469   name=$1
 470   shift
 471
 472   case " $names " in *" $name "*)
 473     # Already in the list.
 474     continue
 475   esac
 476
 477   # Report each name as we discover it, so there is no long pause in output.
 478   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 479
 480   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 481
 482   case $name in
 483     /*) xsrcdir= ;;
 484     *)  xsrcdir=$srcdir/ ;;
 485   esac
 486   test -n "$enable_debug_configure" &&
 487   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 488
 489   if test -f $xsrcdir$name/Implies; then
 490     # Collect more names from the `Implies' file (removing comments).
 491     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 492     implied=
 493     for x in $implied_candidate; do
 494       if test -d $xsrcdir$name_base/$x; then
 495         implied="$implied $name_base/$x";
 496       else
 497         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 498       fi
 499     done
 500   else
 501     implied=
 502   fi
 503
 504   # Add NAME to the list of names.
 505   names="$names $name"
 506
 507   # Find the parent of NAME, using the empty string if it has none.
 508 changequote(,)dnl
 509   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 510 changequote([,])dnl
 511
 512   # Add the names implied by NAME, and NAME's parent (if it has one), to
 513   # the list of names to be processed (the argument list).  We prepend the
 514   # implied names to the list and append the parent.  We want implied
 515   # directories to come before further directories inferred from the
 516   # configuration components; this ensures that for sysv4, unix/common
 517   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 518   # after sysv4).
 519   sysnames="`echo $implied $* $parent`"
 520   test -n "$sysnames" && set $sysnames
 521 done
 522
 523 # Add the default directories.
 524 default_sysnames=sysdeps/generic
 525 if test "$elf" = yes; then
 526   default_sysnames="sysdeps/generic/elf $default_sysnames"
 527 fi
 528 sysnames="$names $default_sysnames"
 529 AC_SUBST(sysnames)
 530 # The other names were emitted during the scan.
 531 AC_MSG_RESULT($default_sysnames)
 532
 533
 534 ### Locate tools.
 535
 536 AC_PROG_INSTALL
 537 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 538   # The makefiles need to use a different form to find it in $srcdir.
 539   INSTALL='\$(..)./scripts/install-sh -c'
 540 fi
 541 AC_PROG_LN_S
 542
 543 # We need the physical current working directory.  We cannot use the
 544 # "pwd -P" shell builtin since that's not portable.  Instead we try to
 545 # find a pwd binary.  Note that assigning to the PWD environment
 546 # variable might have some interesting side effects, so we don't do
 547 # that.
 548 AC_PATH_PROG(PWD_P, pwd, no)
 549 if test "$PWD_P" = no; then
 550   AC_MSG_ERROR(*** A pwd binary could not be found.)
 551 fi
 552
 553 # These programs are version sensitive.
 554 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 555 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 556   [version \([egcygnustpi-]*[0-9.]*\)],
 557   [*gcc-2.9[5-9].*|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|3.[0-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]|sgicc-*],
 558   critic_missing=t)
 559 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 560   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 561   [3.79* | 3.[89]*], critic_missing=t)
 562
 563 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 564   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 565   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 566 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 567   [GNU texinfo.* \([0-9][0-9.]*\)],
 568   [4.*], MAKEINFO=: aux_missing=t)
 569 AC_CHECK_PROG_VER(SED, gsed sed, --version,
 570   [GNU sed version \([0-9]*\.[0-9.]*\)],
 571   [3.0[2-9]*|3.[1-9]*|[4-9]*], SED=: aux_missing=t)
 572
 573 AC_PROG_CC_LOCAL
 574 AC_CANONICAL_BUILD
 575 if test $host != $build; then
 576   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 577 fi
 578 AC_SUBST(cross_compiling)
 579 AC_PROG_CPP
 580 LIBC_PROG_BINUTILS
 581 AC_CHECK_TOOL(MIG, mig)
 582
 583 # Accept binutils 2.10.1 or newer (and also any ia64 2.9 version)
 584 # XXX Commented out because it filters out too many good versions.
 585 # XXX --drepper
 586 # AC_CHECK_PROG_VER(AS, $AS, --version,
 587 #   [GNU assembler.* \([0-9]*\.[0-9.]*\(-ia64-[0-9]*\)*\)],
 588 #   [2.10.[1-9]* | 2.1[1-9]* | 2.9-ia64-*], AS=: critic_missing=t)
 589
 590 if test -n "$critic_missing"; then
 591 AC_MSG_ERROR([
 592 *** Some critical program is missing or too old.
 593 *** Check the INSTALL file for required versions.])
 594 fi
 595
 596 test -n "$aux_missing" && AC_MSG_WARN([
 597 *** An auxiliary program is missing or too old;
 598 *** some features will be disabled.
 599 *** Check the INSTALL file for required versions.])
 600
 601 # glibcbug.in wants to know the compiler version.
 602 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 603 AC_SUBST(CCVERSION)
 604
 605 # if using special system headers, find out the compiler's sekrit
 606 # header directory and add that to the list.  NOTE: Only does the right
 607 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 608 if test -n "$sysheaders"; then
 609   ccheaders=`$CC -print-file-name=include`
 610   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 611 fi
 612 AC_SUBST(SYSINCLUDES)
 613
 614 # check if ranlib is necessary
 615 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 616 cat > conftest.c <<EOF
 617 int a;
 618 char b;
 619 void c(void) {}
 620 EOF
 621 $CC $CFLAGS -c conftest.c
 622 $AR cr conftest.a conftest.c
 623 cp conftest.a conftest2.a
 624 $RANLIB conftest.a
 625 if cmp -s conftest.a conftest2.a; then
 626   libc_cv_ranlib_necessary=no
 627 else
 628   libc_cv_ranlib_necessary=yes
 629 fi
 630 rm -rf conftest*])
 631 if test "$libc_cv_ranlib_necessary" = no; then
 632  RANLIB=:
 633 fi
 634
 635 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 636 # since this would lead to problems installing/building glibc.
 637 # LD_LIBRARY_PATH contains the current directory if one of the following
 638 # is true:
 639 # - one of the terminals (":" and ";") is the first or last sign
 640 # - two terminals occur directly after each other
 641 # - the path contains an element with a dot in it
 642 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 643 changequote(,)dnl
 644 case ${LD_LIBRARY_PATH} in
 645   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 646     ld_library_path_setting="contains current directory"
 647     ;;
 648   *)
 649     ld_library_path_setting="ok"
 650     ;;
 651 esac
 652 changequote([,])dnl
 653 AC_MSG_RESULT($ld_library_path_setting)
 654 if test "$ld_library_path_setting" != "ok"; then
 655 AC_MSG_ERROR([
 656 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 657 *** building glibc. Please change the environment variable
 658 *** and run configure again.])
 659 fi
 660
 661 AC_PATH_PROG(BASH, bash, no)
 662 if test "$BASH" != no &&
 663    $BASH -c 'test "$BASH_VERSINFO" \
 664              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 665   libc_cv_have_bash2=yes
 666 else
 667   libc_cv_have_bash2=no
 668 fi
 669 AC_SUBST(libc_cv_have_bash2)
 670
 671 dnl We need a ksh compatible shell for tzselect.
 672 if test "$BASH" = no; then
 673   AC_PATH_PROG(KSH, ksh, no)
 674   if test "$KSH" = no; then
 675     libc_cv_have_ksh=no
 676   else
 677     libc_cv_have_ksh=yes
 678   fi
 679 else
 680   KSH="$BASH"
 681   AC_SUBST(KSH)
 682   libc_cv_have_ksh=yes
 683 fi
 684 AC_SUBST(libc_cv_have_ksh)
 685
 686 AC_PROG_AWK
 687 AC_PATH_PROG(PERL, perl, no)
 688 if test "$PERL" != no &&
 689    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
 690   PERL=no
 691 fi
 692 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 693              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 694 if test "$INSTALL_INFO" != "no"; then
 695 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 696  [mkdir conftest.d
 697   # There is a hard ^_ on the next line.  I am open to better ideas.
 698   (echo '\1f'
 699   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 700   echo '* Menu:') >conftest.d/dir
 701   (echo 'INFO-DIR-SECTION i-d-s works'
 702   echo 'START-INFO-DIR-ENTRY'
 703   echo '* Prog: (prog).   Program.'
 704   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 705   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 706   then
 707     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 708     then libc_cv_old_debian_install_info=no
 709     else libc_cv_old_debian_install_info=yes
 710     fi
 711   else libc_cv_old_debian_install_info=no testfailed=t
 712   fi
 713   rm -fr conftest.d])
 714 if test -n "$testfailed"
 715 then AC_MSG_WARN([install-info errored out, check config.log])
 716 fi
 717 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 718 fi
 719 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 720
 721 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
 722
 723 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 724 echo '#include <stddef.h>
 725 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 726 if eval "$ac_cpp conftest.c 2>/dev/null" \
 727 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 728   libc_cv_signed_size_t=no
 729 else
 730   libc_cv_signed_size_t=yes
 731 fi
 732 rm -f conftest*])
 733 if test $libc_cv_signed_size_t = yes; then
 734   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 735   cat >> confdefs.h <<\EOF
 736 #undef __SIZE_TYPE__
 737 #define __SIZE_TYPE__ unsigned
 738 EOF
 739 fi
 740
 741 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 742 AC_TRY_COMPILE(dnl
 743 [#define __need_size_t
 744 #define __need_wchar_t
 745 #include <stddef.h>
 746 #define __need_NULL
 747 #include <stddef.h>], [size_t size; wchar_t wchar;
 748 #ifdef offsetof
 749 #error stddef.h ignored __need_*
 750 #endif
 751 if (&size == NULL || &wchar == NULL) abort ();],
 752                libc_cv_friendly_stddef=yes,
 753                libc_cv_friendly_stddef=no)])
 754 if test $libc_cv_friendly_stddef = yes; then
 755   config_vars="$config_vars
 756 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 757 fi
 758
 759 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 760                libc_cv_need_minus_P, [dnl
 761 cat > conftest.S <<EOF
 762 #include "confdefs.h"
 763 /* Nothing whatsoever.  */
 764 EOF
 765 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 766   libc_cv_need_minus_P=no
 767 else
 768   libc_cv_need_minus_P=yes
 769 fi
 770 rm -f conftest*])
 771 if test $libc_cv_need_minus_P = yes; then
 772   config_vars="$config_vars
 773 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 774 fi
 775
 776 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 777 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 778 cat > conftest.s <<EOF
 779 .text
 780 EOF
 781 libc_cv_dot_text=
 782 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 783   libc_cv_dot_text=.text
 784 fi
 785 rm -f conftest*])
 786 if test -z "$libc_cv_dot_text"; then
 787   AC_MSG_RESULT(no)
 788 else
 789   AC_MSG_RESULT(yes)
 790 fi
 791
 792 AC_CACHE_CHECK(for assembler global-symbol directive,
 793                libc_cv_asm_global_directive, [dnl
 794 libc_cv_asm_global_directive=UNKNOWN
 795 for ac_globl in .globl .global .EXPORT; do
 796   cat > conftest.s <<EOF
 797         ${libc_cv_dot_text}
 798         ${ac_globl} foo
 799 foo:
 800 EOF
 801   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 802     libc_cv_asm_global_directive=${ac_globl}
 803   fi
 804   rm -f conftest*
 805   test $libc_cv_asm_global_directive != UNKNOWN && break
 806 done])
 807 if test $libc_cv_asm_global_directive = UNKNOWN; then
 808   AC_MSG_ERROR(cannot determine asm global directive)
 809 else
 810   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 811 fi
 812
 813 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 814 cat > conftest.s <<EOF
 815 ${libc_cv_dot_text}
 816 foo:
 817 .set glibc_conftest_frobozz,foo
 818 $libc_cv_asm_global_directive glibc_conftest_frobozz
 819 EOF
 820 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 821 # (but it doesn't work), so we must do a linking check to be sure.
 822 cat > conftest1.c <<\EOF
 823 extern int glibc_conftest_frobozz;
 824 main () { printf ("%d\n", glibc_conftest_frobozz); }
 825 EOF
 826 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 827             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 828   libc_cv_asm_set_directive=yes
 829 else
 830   libc_cv_asm_set_directive=no
 831 fi
 832 rm -f conftest*])
 833 if test $libc_cv_asm_set_directive = yes; then
 834   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 835 fi
 836
 837 # The Aix ld uses global .symbol_names instead of symbol_names.
 838 case "$os" in
 839 aix4.3*)
 840   AC_DEFINE(HAVE_ASM_GLOBAL_DOT_NAME)
 841 esac
 842
 843 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 844 [cat > conftest.s <<EOF
 845 ${libc_cv_dot_text}
 846 _sym:
 847 .symver _sym,sym@VERS
 848 EOF
 849 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 850   libc_cv_asm_symver_directive=yes
 851 else
 852   libc_cv_asm_symver_directive=no
 853 fi
 854 rm -f conftest*])
 855 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 856 if test $libc_cv_asm_symver_directive = yes; then
 857   cat > conftest.s <<EOF
 858 ${libc_cv_dot_text}
 859 _sym:
 860 .symver _sym,sym@VERS
 861 EOF
 862   cat > conftest.map <<EOF
 863 VERS_1 {
 864         global: sym;
 865 };
 866
 867 VERS_2 {
 868         global: sym;
 869 } VERS_1;
 870 EOF
 871   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 872     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 873                                         -nostartfiles -nostdlib
 874                                         -Wl,--version-script,conftest.map
 875                        1>&AC_FD_CC]);
 876     then
 877       libc_cv_ld_version_script_option=yes
 878     else
 879       libc_cv_ld_version_script_option=no
 880     fi
 881   else
 882     libc_cv_ld_version_script_option=no
 883   fi
 884 else
 885   libc_cv_ld_version_script_option=no
 886 fi
 887 rm -f conftest*])
 888 if test $shared != no &&
 889    test $libc_cv_asm_symver_directive = yes &&
 890    test $libc_cv_ld_version_script_option = yes &&
 891    test $enable_versioning = yes; then
 892   VERSIONING=yes
 893   AC_DEFINE(DO_VERSIONING)
 894 else
 895   VERSIONING=no
 896 fi
 897 AC_SUBST(VERSIONING)
 898
 899 if test $shared != no && test $VERSIONING = no; then
 900   echo "\
 901 *** WARNING: You should not compile GNU libc without versioning. Not using
 902 *** versioning will introduce incompatibilities so that old binaries
 903 *** will not run anymore.
 904 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 905 fi
 906 if test $elf = yes; then
 907   AC_CACHE_CHECK(for .previous assembler directive,
 908                  libc_cv_asm_previous_directive, [dnl
 909   cat > conftest.s <<EOF
 910 .section foo_section
 911 .previous
 912 EOF
 913   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 914     libc_cv_asm_previous_directive=yes
 915   else
 916     libc_cv_asm_previous_directive=no
 917   fi
 918   rm -f conftest*])
 919   if test $libc_cv_asm_previous_directive = yes; then
 920     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 921   else
 922     AC_CACHE_CHECK(for .popsection assembler directive,
 923                    libc_cv_asm_popsection_directive, [dnl
 924     cat > conftest.s <<EOF
 925 .pushsection foo_section
 926 .popsection
 927 EOF
 928     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 929       libc_cv_asm_popsection_directive=yes
 930     else
 931       libc_cv_asm_popsection_directive=no
 932     fi
 933     rm -f conftest*])
 934     if test $libc_cv_asm_popsection_directive = yes; then
 935       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 936     fi
 937   fi
 938   AC_CACHE_CHECK(for .protected and .hidden assembler directive,
 939                  libc_cv_asm_protected_directive, [dnl
 940   cat > conftest.s <<EOF
 941 .protected foo
 942 foo:
 943 .hidden bar
 944 bar:
 945 EOF
 946   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 947     libc_cv_asm_protected_directive=yes
 948   else
 949     libc_cv_asm_protected_directive=no
 950   fi
 951   rm -f conftest*])
 952   AC_SUBST(libc_cv_asm_protected_directive)
 953
 954   AC_CACHE_CHECK(for -z nodelete option,
 955                  libc_cv_z_nodelete, [dnl
 956   cat > conftest.c <<EOF
 957 int _start (void) { return 42; }
 958 EOF
 959   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,nodelete 1>&AC_FD_CC])
 960   then
 961     libc_cv_z_nodelete=yes
 962   else
 963     libc_cv_z_nodelete=no
 964   fi
 965   rm -f conftest*])
 966   AC_SUBST(libc_cv_z_nodelete)
 967
 968   AC_CACHE_CHECK(for -z nodlopen option,
 969                  libc_cv_z_nodlopen, [dnl
 970   cat > conftest.c <<EOF
 971 int _start (void) { return 42; }
 972 EOF
 973   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,nodlopen 1>&AC_FD_CC])
 974   then
 975     libc_cv_z_nodlopen=yes
 976   else
 977     libc_cv_z_nodlopen=no
 978   fi
 979   rm -f conftest*])
 980   AC_SUBST(libc_cv_z_nodlopen)
 981
 982   AC_CACHE_CHECK(for -z initfirst option,
 983                  libc_cv_z_initfirst, [dnl
 984   cat > conftest.c <<EOF
 985 int _start (void) { return 42; }
 986 EOF
 987   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,initfirst 1>&AC_FD_CC])
 988   then
 989     libc_cv_z_initfirst=yes
 990   else
 991     libc_cv_z_initfirst=no
 992   fi
 993   rm -f conftest*])
 994   AC_SUBST(libc_cv_z_initfirst)
 995 fi
 996
 997 if test $elf != yes; then
 998   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 999                  [AC_TRY_COMPILE(, [asm (".section .init");
1000                                     asm (".section .fini");
1001                                     asm ("${libc_cv_dot_text}");],
1002                                  libc_cv_have_initfini=yes,
1003                                  libc_cv_have_initfini=no)])
1004   AC_SUBST(libc_cv_have_initfini)dnl
1005   if test $libc_cv_have_initfini = yes; then
1006     AC_DEFINE(HAVE_INITFINI)
1007   fi
1008 fi
1009
1010 if test $elf = yes -a $gnu_ld = yes; then
1011   AC_CACHE_CHECK(whether cc puts quotes around section names,
1012                  libc_cv_have_section_quotes,
1013                  [cat > conftest.c <<EOF
1014                   static const int foo
1015                   __attribute__ ((section ("bar"))) = 1;
1016 EOF
1017                   if ${CC-cc} -S conftest.c -o conftest.s; then
1018                     if grep '\.section.*"bar"' conftest.s >/dev/null; then
1019                       libc_cv_have_section_quotes=yes
1020                     else
1021                       libc_cv_have_section_quotes=no
1022                     fi
1023                   else
1024                     libc_cv_have_section_quotes=unknown
1025                   fi
1026                   rm -f conftest.[cs]
1027                  ])
1028   if test $libc_cv_have_section_quotes = yes; then
1029     AC_DEFINE(HAVE_SECTION_QUOTES)
1030   fi
1031 fi
1032
1033 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
1034 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
1035 [cat > conftest.$ac_ext <<EOF
1036 dnl This sometimes fails to find confdefs.h, for some reason.
1037 dnl [#]line __oline__ "[$]0"
1038 [#]line __oline__ "configure"
1039 #include "confdefs.h"
1040 void underscore_test(void) {
1041 return; }
1042 EOF
1043 if AC_TRY_EVAL(ac_compile); then
1044   if grep _underscore_test conftest* >/dev/null; then
1045     ifelse([$1], , :, [rm -f conftest*
1046     $1])
1047   else
1048     ifelse([$2], , , [rm -f conftest*
1049     $2])
1050   fi
1051 else
1052   echo "configure: failed program was:" >&AC_FD_CC
1053   cat conftest.$ac_ext >&AC_FD_CC
1054   ifelse([$2], , , [rm -f conftest*
1055   $2])
1056 fi
1057 rm -f conftest*])
1058
1059 if test $elf = yes; then
1060   libc_cv_asm_underscores=no
1061 else
1062   if test $ac_cv_prog_cc_works = yes; then
1063     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1064                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
1065                                 libc_cv_asm_underscores=yes,
1066                                 libc_cv_asm_underscores=no)])
1067   else
1068     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1069                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
1070                                             libc_cv_asm_underscores=no)])
1071   fi
1072 fi
1073 if test $libc_cv_asm_underscores = no; then
1074   AC_DEFINE(NO_UNDERSCORES)
1075 fi
1076
1077 if test $elf = yes; then
1078   libc_cv_weak_symbols=yes
1079 fi
1080
1081 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1082                [dnl
1083 cat > conftest.s <<EOF
1084 ${libc_cv_dot_text}
1085 ${libc_cv_asm_global_directive} foo
1086 foo:
1087 .weak foo
1088 .weak bar; bar = foo
1089 EOF
1090 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1091   libc_cv_asm_weak_directive=yes
1092 else
1093   libc_cv_asm_weak_directive=no
1094 fi
1095 rm -f conftest*])
1096
1097 if test $libc_cv_asm_weak_directive = no; then
1098   AC_CACHE_CHECK(for assembler .weakext directive,
1099                  libc_cv_asm_weakext_directive,
1100                  [dnl
1101 cat > conftest.s <<EOF
1102 ${libc_cv_dot_text}
1103 ${libc_cv_asm_global_directive} foo
1104 foo:
1105 .weakext bar foo
1106 .weakext baz
1107 ${libc_cv_asm_global_directive} baz
1108 baz:
1109 EOF
1110   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1111     libc_cv_asm_weakext_directive=yes
1112   else
1113     libc_cv_asm_weakext_directive=no
1114   fi
1115   rm -f conftest*])
1116
1117 fi # no .weak
1118
1119 if test $libc_cv_asm_weak_directive = yes; then
1120   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1121 elif test $libc_cv_asm_weakext_directive = yes; then
1122   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1123 fi
1124
1125 dnl The standard hppa assembler uses `;' to start comments and `!'
1126 dnl as a line separator.
1127 case "${host_cpu}-${host_os}" in
1128   hppa*linux*)
1129   AC_CACHE_CHECK(for assembler line separator,
1130                  libc_cv_asm_line_sep, [dnl
1131   cat > conftest.s <<EOF
1132  nop ; is_old_puffin
1133 EOF
1134   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
1135     libc_cv_asm_line_sep='!'
1136   else
1137     if test -z "$enable_hacker_mode"; then
1138       echo "*** You need a newer assembler to compile glibc"
1139       rm -f conftest*
1140       exit 1
1141     fi
1142     libc_cv_asm_line_sep=';'
1143   fi
1144   rm -f conftest*])
1145   AC_DEFINE_UNQUOTED(ASM_LINE_SEP, $libc_cv_asm_line_sep)
1146   ;;
1147 esac
1148
1149 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1150 cat > conftest.c <<\EOF
1151 _start () {}
1152 int __eh_pc;
1153 __throw () {}
1154 EOF
1155 dnl No \ in command here because it ends up inside ''.
1156 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1157                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1158                             -o conftest conftest.c 1>&AC_FD_CC]); then
1159   libc_cv_ld_no_whole_archive=yes
1160 else
1161   libc_cv_ld_no_whole_archive=no
1162 fi
1163 rm -f conftest*])
1164 if test $libc_cv_ld_no_whole_archive = yes; then
1165   no_whole_archive=-Wl,--no-whole-archive
1166 fi
1167 AC_SUBST(no_whole_archive)dnl
1168
1169 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1170 cat > conftest.c <<\EOF
1171 _start () {}
1172 int __eh_pc;
1173 __throw () {}
1174 EOF
1175 dnl No \ in command here because it ends up inside ''.
1176 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1177                             -nostdlib -nostartfiles -fexceptions
1178                             -o conftest conftest.c 1>&AC_FD_CC]); then
1179   libc_cv_gcc_exceptions=yes
1180 else
1181   libc_cv_gcc_exceptions=no
1182 fi
1183 rm -f conftest*])
1184 if test $libc_cv_gcc_exceptions = yes; then
1185   exceptions=-fexceptions
1186 fi
1187 AC_SUBST(exceptions)dnl
1188
1189 if test "$base_machine" = alpha ; then
1190 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1191 cat > conftest.c <<\EOF
1192 foo () { }
1193 EOF
1194 dnl
1195 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1196 then
1197   libc_cv_gcc_alpha_ng_prefix=yes
1198 else
1199   libc_cv_gcc_alpha_ng_prefix=no
1200 fi
1201 rm -f conftest* ])
1202 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1203   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1204 else
1205   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1206 fi
1207 fi
1208
1209 if test "$host_cpu" = powerpc ; then
1210 # Check for a bug present in at least versions 2.8.x of GCC
1211 # and versions 1.0.x of EGCS.
1212 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1213 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1214                libc_cv_c_asmcr0_bug='no',
1215                libc_cv_c_asmcr0_bug='yes')])
1216 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1217   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1218 fi
1219 fi
1220
1221 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1222 [cat > conftest.c <<EOF
1223 #line __oline__ "configure"
1224 static char __EH_FRAME_BEGIN__[];
1225 _start ()
1226 {
1227 #ifdef CHECK__register_frame
1228   __register_frame (__EH_FRAME_BEGIN__);
1229   __deregister_frame (__EH_FRAME_BEGIN__);
1230 #endif
1231 #ifdef CHECK__register_frame_info
1232   __register_frame_info (__EH_FRAME_BEGIN__);
1233   __deregister_frame_info (__EH_FRAME_BEGIN__);
1234 #endif
1235 }
1236 int __eh_pc;
1237 __throw () {}
1238 /* FIXME: this is fragile.  */
1239 malloc () {}
1240 strcmp () {}
1241 strlen () {}
1242 memcpy () {}
1243 memset () {}
1244 free () {}
1245 abort () {}
1246 __bzero () {}
1247 EOF
1248 dnl No \ in command here because it ends up inside ''.
1249 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1250                             -nostdlib -nostartfiles
1251                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1252   libc_cv_gcc_dwarf2_unwind_info=static
1253 else
1254   libc_cv_gcc_dwarf2_unwind_info=no
1255 fi
1256 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1257   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1258                               -nostdlib -nostartfiles
1259                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1260     libc_cv_gcc_dwarf2_unwind_info=yes
1261   else
1262     libc_cv_gcc_dwarf2_unwind_info=no
1263   fi
1264 fi
1265 rm -f conftest*])
1266 case $libc_cv_gcc_dwarf2_unwind_info in
1267 yes)
1268   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1269   ;;
1270 static)
1271   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1272   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1273   ;;
1274 esac
1275
1276 dnl Check whether compiler understands __builtin_expect.
1277 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1278 [cat > conftest.c <<EOF
1279 #line __oline__ "configure"
1280 int foo (int a)
1281 {
1282   a = __builtin_expect (a, 10);
1283   return a == 10 ? 0 : 1;
1284 }
1285 EOF
1286 dnl No \ in command here because it ends up inside ''.
1287 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1288                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1289   libc_cv_gcc_builtin_expect=yes
1290 else
1291   libc_cv_gcc_builtin_expect=no
1292 fi
1293 rm -f conftest*])
1294 if test "$libc_cv_gcc_builtin_expect" = yes; then
1295   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1296 fi
1297
1298 dnl Check whether the compiler supports subtraction of local labels.
1299 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1300 [cat > conftest.c <<EOF
1301 changequote(,)dnl
1302 #line __oline__ "configure"
1303 int foo (int a)
1304 {
1305   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1306   void *p = &&l1 + ar[a];
1307   goto *p;
1308  l1:
1309   return 1;
1310  l2:
1311   return 2;
1312 }
1313 changequote([,])dnl
1314 EOF
1315 dnl No \ in command here because it ends up inside ''.
1316 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1317                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1318   libc_cv_gcc_subtract_local_labels=yes
1319 else
1320   libc_cv_gcc_subtract_local_labels=no
1321 fi
1322 rm -f conftest*])
1323 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1324   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1325 fi
1326
1327 dnl Check whether we have the gd library available.
1328 AC_MSG_CHECKING(for libgd)
1329 if test "$with_gd" != "no"; then
1330   old_CFLAGS="$CFLAGS"
1331   CFLAGS="$CFLAGS $libgd_include"
1332   old_LDFLAGS="$LDFLAGS"
1333   LDFLAGS="$LDFLAGS $libgd_ldflags"
1334   old_LIBS="$LIBS"
1335   LIBS="$LIBS -lgd -lpng -lz -lm"
1336   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1337   CFLAGS="$old_CFLAGS"
1338   LDFLAGS="$old_LDFLAGS"
1339   LIBS="$old_LIBS"
1340 else
1341   LIBGD=no
1342 fi
1343 AC_MSG_RESULT($LIBGD)
1344 AC_SUBST(LIBGD)
1345
1346 dnl check for the size of 'long double'.
1347 AC_CHECK_SIZEOF(long double, 0)
1348 sizeof_long_double=$ac_cv_sizeof_long_double
1349 AC_SUBST(sizeof_long_double)
1350
1351 ### End of automated tests.
1352 ### Now run sysdeps configure fragments.
1353
1354 # sysdeps configure fragments may set these with files to be linked below.
1355 libc_link_dests=
1356 libc_link_sources=
1357
1358 # They also can set these variables.
1359 use_ldconfig=no
1360 ldd_rewrite_script=no
1361
1362 # Iterate over all the sysdep directories we will use, running their
1363 # configure fragments, and looking for a uname implementation.
1364 uname=
1365 for dir in $sysnames; do
1366   case $dir in
1367     /*) dest=$dir ;;
1368     *)  dest=$srcdir/$dir ;;
1369   esac
1370   if test -r $dest/configure; then
1371     AC_MSG_RESULT(running configure fragment for $dest)
1372     . $dest/configure
1373   fi
1374 [
1375   if test -z "$uname"; then
1376     if test -r $dest/uname.c ||
1377        test -r $dest/uname.S ||
1378        { test -r $dest/syscalls.list &&
1379          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1380       uname=$dir
1381     fi
1382   fi
1383 ]dnl
1384 done
1385
1386 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1387
1388 # If we will use the generic uname implementation, we must figure out what
1389 # it will say by examining the system, and write the results in config-name.h.
1390 if test "$uname" = "sysdeps/generic"; then
1391
1392 changequote(,)dnl
1393   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1394 changequote([,])dnl
1395   if test $uname_sysname != $config_os; then
1396     config_release=`echo $config_os | sed s/$uname_sysname//`
1397   fi
1398 dnl
1399 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1400     if test -r /vmunix; then
1401       kernel_id=`strings /vmunix | grep UNIX`
1402     elif test -r /dynix; then
1403       kernel_id=`strings /dynix | grep DYNIX`
1404     else
1405       kernel_id=
1406     fi
1407 ])dnl
1408
1409   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1410 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1411 changequote(,)dnl
1412   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1413 changequote([,])dnl
1414   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1415          != x$config_release; then
1416     # The configuration release is a substring of the kernel release.
1417     libc_cv_uname_release=$kernel_release
1418   elif test x$config_release != x; then
1419     libc_cv_uname_release=$config_release
1420   elif test x$kernel_release != x; then
1421     libc_cv_uname_release=$kernel_release
1422   else
1423     libc_cv_uname_release=unknown
1424   fi])
1425   uname_release="$libc_cv_uname_release"
1426
1427   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1428 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1429 changequote(,)dnl
1430   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1431 changequote([,])dnl
1432   if test -n "$kernel_version"; then
1433     libc_cv_uname_version="$kernel_version"
1434   else
1435     libc_cv_uname_version=unknown
1436   fi])
1437   uname_version="$libc_cv_uname_version"
1438
1439 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1440   config_uname=config-name.h:config-name.in
1441 else
1442   # For non-generic uname, we don't need to create config-name.h at all.
1443   config_uname=
1444 fi
1445
1446 AC_MSG_CHECKING(stdio selection)
1447 AC_SUBST(stdio)
1448 case $stdio in
1449 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1450 default) stdio=stdio ;;
1451 esac
1452 AC_MSG_RESULT($stdio)
1453
1454 # Test for old glibc 2.0.x headers so that they can be removed properly
1455 # Search only in includedir.
1456 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1457 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1458 then
1459   old_glibc_headers=yes
1460 else
1461   old_glibc_headers=no
1462 fi
1463 AC_MSG_RESULT($old_glibc_headers)
1464 if test ${old_glibc_headers} = yes; then
1465   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1466   AC_MSG_WARN(*** be removed.)
1467 fi
1468 AC_SUBST(old_glibc_headers)
1469
1470 AC_SUBST(libc_cv_slibdir)
1471 AC_SUBST(libc_cv_localedir)
1472 AC_SUBST(libc_cv_sysconfdir)
1473 AC_SUBST(libc_cv_rootsbindir)
1474
1475 AC_SUBST(use_ldconfig)
1476 AC_SUBST(ldd_rewrite_script)
1477
1478 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1479 if test $gnu_ld = yes; then
1480   AC_DEFINE(HAVE_GNU_LD)
1481 fi
1482 if test $gnu_as = yes; then
1483   AC_DEFINE(HAVE_GNU_AS)
1484 fi
1485 if test $elf = yes; then
1486   AC_DEFINE(HAVE_ELF)
1487 fi
1488
1489 AC_SUBST(static)
1490 AC_SUBST(shared)
1491 if test $shared = default; then
1492   if test $gnu_ld = yes; then
1493     shared=$elf
1494   else
1495     # For now we do not assume shared libs are available.  In future more
1496     # tests might become available.
1497     shared=no
1498   fi
1499 fi
1500
1501 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1502 [pic_default=yes
1503 cat > conftest.c <<EOF
1504 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1505 # error PIC is default.
1506 #endif
1507 EOF
1508 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1509   pic_default=no
1510 fi
1511 rm -f conftest.*])
1512 AC_SUBST(pic_default)
1513
1514 AC_SUBST(profile)
1515 AC_SUBST(omitfp)
1516 AC_SUBST(bounded)
1517 AC_SUBST(static_nss)
1518 AC_SUBST(nopic_initfini)
1519
1520 AC_SUBST(DEFINES)
1521
1522 case "$add_ons" in
1523   *door*) linux_doors=yes ;;
1524   *) linux_doors=no ;;
1525 esac
1526 AC_SUBST(linux_doors)
1527
1528 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1529   config_makefile=
1530 else
1531   config_makefile=Makefile
1532 fi
1533
1534 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1535 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1536 AC_SUBST(VERSION)
1537 AC_SUBST(RELEASE)
1538
1539 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1540 case $CONFIG_FILES in *config.make*)
1541 echo "$config_vars" >> config.make;;
1542 esac
1543 test -d bits || mkdir bits], [config_vars='$config_vars'])