configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35
  36 dnl Arguments to specify presence of other packages/features.
  37 AC_ARG_WITH(fp, dnl
  38 [  --with-fp              if using floating-point hardware [default=yes]],
  39             with_fp=$withval, with_fp=yes)
  40 AC_ARG_WITH(binutils, dnl
  41   --with-binutils=PATH    specify location of binutils (as and ld),
  42             path_binutils=$withval, path_binutils='')
  43 AC_ARG_WITH(elf, dnl
  44   --with-elf              if using the ELF object format,
  45             elf=$withval, elf=no)
  46 AC_ARG_WITH(cvs, dnl
  47 [  --without-cvs          if CVS should not be used],
  48             with_cvs=$withval, with_cvs=yes)
  49 AC_SUBST(with_cvs)
  50
  51 AC_ARG_WITH(headers, dnl
  52 [  --with-headers=PATH     location of system headers to use
  53                           [e.g. /usr/src/linux/include]
  54                           [default=compiler default]],
  55             sysheaders=$withval, sysheaders='')
  56
  57 AC_ARG_ENABLE(libio, dnl
  58 [  --enable-libio          build in GNU libio instead of GNU stdio],
  59               [if test $enableval = yes; then
  60                  stdio=libio
  61                else
  62                  stdio=stdio
  63                fi],
  64               stdio=default)
  65
  66 AC_ARG_ENABLE(sanity-checks, dnl
  67 [  --disable-sanity-checks really do not use threads (should not be used
  68                           except in special situations) [default=yes]],
  69               enable_sanity=$enableval, enable_sanity=yes)
  70
  71 dnl Arguments to enable or disable building the static, shared, profiled,
  72 dnl and -fomit-frame-pointer libraries.
  73 AC_ARG_ENABLE(static, dnl
  74 [  --enable-static         build static library [default=yes]],
  75               static=$enableval, static=yes)
  76 AC_ARG_ENABLE(shared, dnl
  77 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  78               shared=$enableval, shared=default)
  79 AC_ARG_ENABLE(profile, dnl
  80 [  --enable-profile        build profiled library [default=yes]],
  81               profile=$enableval, profile=yes)
  82 AC_ARG_ENABLE(omitfp, dnl
  83 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  84               omitfp=$enableval, omitfp=no)
  85 AC_ARG_ENABLE(bounded, dnl
  86 [  --enable-bounded        build with runtime bounds checking [default=no]],
  87               bounded=$enableval, bounded=no)
  88 AC_ARG_ENABLE(versioning, dnl
  89 [  --disable-versioning    do not include versioning information in the
  90                           library objects [default=yes if supported]],
  91              enable_versioning=$enableval, enable_versioning=yes)
  92
  93 dnl Generic infrastructure for drop-in additions to libc.
  94 AC_ARG_ENABLE(add-ons, dnl
  95 [  --enable-add-ons[=DIR1,DIR2]...
  96                           configure and build add-ons in DIR1,DIR2,...
  97                           search for add-ons if no parameter given],
  98   [case "$enableval" in
  99     yes) if test "$srcdir" = "."; then
 100            add_ons=`echo */configure | sed -e 's!/configure!!g'`
 101          else
 102            add_ons=`echo $srcdir/*/configure | \
 103                     sed -e 's!/configure!!g' -e "s!$srcdir/!!g"`
 104          fi;;
 105     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 106    esac],
 107   [add_ons=])
 108
 109 AC_CONFIG_SUBDIRS($add_ons)
 110 add_ons_pfx=
 111 if test x"$add_ons" != x; then
 112   for f in $add_ons; do
 113     # Test whether such a subdir really exists.
 114     if test -d $srcdir/$f; then
 115       add_ons_pfx="$add_ons_pfx $f/"
 116     else
 117       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 118     fi
 119   done
 120 fi
 121
 122 dnl On some platforms we cannot use dynamic loading.  We must provide
 123 dnl static NSS modules.
 124 AC_ARG_ENABLE(static-nss, dnl
 125 [  --enable-static-nss     build static NSS modules [default=no]],
 126               static_nss=$enableval, static_nss=no)
 127 if test x"$static_nss" = xyes; then
 128   AC_DEFINE(DO_STATIC_NSS)
 129 fi
 130
 131 AC_ARG_ENABLE(force-install,
 132 [  --disable-force-install don't force installation of files from this package,
 133                           even if they are older than the installed files],
 134               force_install=$enableval, force_install=yes)
 135 AC_SUBST(force_install)
 136
 137 AC_CANONICAL_HOST
 138
 139 # The way shlib-versions is used to generate soversions.mk uses a
 140 # fairly simplistic model for name recognition that can't distinguish
 141 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 142 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 143 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 144 case "$host_os" in
 145 linux*)
 146   ;;
 147 gnu*)
 148   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 149   ;;
 150 esac
 151
 152 ###
 153 ### I put this here to prevent those annoying emails from people who cannot
 154 ### read and try to compile glibc on unsupported platforms.  --drepper
 155 ###
 156 ### By using the undocumented --enable-hacker-mode option for configure
 157 ### one can skip this test to make the configuration not fail for unsupported
 158 ### platforms.
 159 ###
 160 if test -z "$enable_hacker_mode"; then
 161   case "$machine-$host_os" in
 162   *-linux* | *-gnu* | arm*-none*)
 163     ;;
 164   *)
 165     echo "*** The GNU C library is currently not available for this platform."
 166     echo "*** So far nobody cared to port it and if there is no volunteer it"
 167     echo "*** might never happen.  So, if you have interest to see glibc on"
 168     echo "*** this platform visit"
 169     echo "***   http://www.gnu.org/software/libc/porting.html"
 170     echo "*** and join the group of porters"
 171     exit 1
 172     ;;
 173   esac
 174 fi
 175
 176 # We keep the original values in `$config_*' and never modify them, so we
 177 # can write them unchanged into config.make.  Everything else uses
 178 # $machine, $vendor, and $os, and changes them whenever convenient.
 179 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 180
 181 # Some configurations imply other options.
 182 case "$host_os" in
 183 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 184   # These systems always use GNU tools.
 185   gnu_ld=yes gnu_as=yes ;;
 186 esac
 187 case "$host_os" in
 188 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 189 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 190   ;;
 191 gnu* | linux* | sysv4* | solaris2* | irix6*)
 192   # These systems (almost) always use the ELF format.
 193   elf=yes
 194   ;;
 195 esac
 196
 197 machine=$config_machine
 198 vendor=$config_vendor
 199 os=$config_os
 200
 201 dnl We need to use [ and ] for other purposes for a while now.
 202 changequote(,)dnl
 203 # Expand the configuration machine name into a subdirectory by architecture
 204 # type and particular chip.
 205 case "$machine" in
 206 a29k | am29000) base_machine=a29k machine=a29k ;;
 207 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 208 arm*)           base_machine=arm machine=arm/$machine ;;
 209 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 210 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 211 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 212 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 213 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 214 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 215 m88???)         base_machine=m88k machine=m88k/$machine ;;
 216 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 217 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 218 mips*)          base_machine=mips
 219                 case "`uname -m`" in
 220                 IP22) machine=mips/mips3 ;;
 221                 *)    machine=mips/$machine ,,
 222                 esac ;;
 223 sparc | sparcv[67])
 224                 base_machine=sparc machine=sparc/sparc32 ;;
 225 sparcv8 | supersparc | hypersparc)
 226                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 227 sparc64 | ultrasparc)
 228                 base_machine=sparc machine=sparc/sparc64 ;;
 229 esac
 230 changequote([,])dnl
 231 AC_SUBST(base_machine)
 232
 233 if test "$base_machine" = "i386"; then
 234   AC_DEFINE(USE_REGPARMS)
 235 fi
 236
 237 # Compute the list of sysdep directories for this configuration.
 238 # This can take a while to compute.
 239 sysdep_dir=$srcdir/sysdeps
 240 AC_MSG_CHECKING(sysdep dirs)
 241 dnl We need to use [ and ] for other purposes for a while now.
 242 changequote(,)dnl
 243 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 244 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 245
 246 case "$os" in
 247 gnu*)
 248   base_os=mach/hurd ;;
 249 netbsd* | 386bsd* | freebsd* | bsdi*)
 250   base_os=unix/bsd/bsd4.4 ;;
 251 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 252   base_os=unix/bsd ;;
 253 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 254   base_os=unix/sysv ;;
 255 irix6*)
 256   base_os=unix/sysv/irix6/$os ;;
 257 solaris[2-9]*)
 258   base_os=unix/sysv/sysv4 ;;
 259 none)
 260   base_os=standalone ;;
 261 *)
 262   base_os='' ;;
 263 esac
 264
 265 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 266 tail=$os
 267 ostry=$os
 268 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 269   ostry="$ostry /$o"
 270   tail=$o
 271 done
 272 o=`echo $tail | sed 's/[0-9]*$//'`
 273 if test $o != $tail; then
 274   ostry="$ostry /$o"
 275 fi
 276 # For linux-gnu, try linux-gnu, then linux.
 277 o=`echo $tail | sed 's/-.*$//'`
 278 if test $o != $tail; then
 279   ostry="$ostry /$o"
 280 fi
 281
 282 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 283 base=
 284 tail=$base_os
 285 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 286   set $b
 287   base="$base /$1"
 288   tail="$2"
 289 done
 290
 291 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 292 mach=
 293 tail=$machine
 294 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 295   set $m
 296   # Prepend the machine's FPU directory unless --without-fp.
 297   if test "$with_fp" = yes; then
 298     mach="$mach /$1/fpu"
 299   fi
 300   mach="$mach /$1"
 301   tail="$2"
 302 done
 303
 304 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 305 changequote([,])dnl
 306
 307 # Find what sysdep directories exist.
 308 sysnames=
 309 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 310 for d in $add_ons_pfx ''; do
 311   for b in $base ''; do
 312     for m0 in $mach ''; do
 313       for v in /$vendor ''; do
 314         test "$v" = / && continue
 315         for o in /$ostry ''; do
 316           test "$o" = / && continue
 317           for m in $mach ''; do
 318             if test "$m0$b$v$o$m"; then
 319               try="${d}sysdeps$m0$b$v$o$m"
 320               test -n "$enable_debug_configure" &&
 321               echo "$0 [DEBUG]: try $try" >&2
 322               case $try in
 323                 /*) dest=$try ;;
 324                 *)  dest=$srcdir/$try ;;
 325               esac
 326               if test -d $dest; then
 327                 sysnames="$sysnames $try"
 328                 { test -n "$o" || test -n "$b"; } && os_used=t
 329                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 330               fi
 331             fi
 332           done
 333         done
 334       done
 335     done
 336   done
 337 done
 338 IFS="$ac_save_ifs"
 339
 340 if test -z "$os_used" && test "$os" != none; then
 341   AC_MSG_ERROR(Operating system $os is not supported.)
 342 fi
 343 if test -z "$machine_used" && test "$machine" != none; then
 344   AC_MSG_ERROR(The $machine is not supported.)
 345 fi
 346
 347 # We have now validated the configuration.
 348
 349
 350 # If using ELF, look for an `elf' subdirectory of each machine directory.
 351 # We prepend these rather than inserting them whereever the machine appears
 352 # because things specified by the machine's ELF ABI should override
 353 # OS-specific things, and should always be the same for any OS on the
 354 # machine (otherwise what's the point of an ABI?).
 355 if test "$elf" = yes; then
 356   elf_dirs=
 357   for d in $add_ons_pfx ''; do
 358     case $d in
 359       /*) xsrcdir= ;;
 360       *)  xsrcdir=$srcdir/ ;;
 361     esac
 362     for m in $mach; do
 363       if test -d $xsrcdir${d}sysdeps$m/elf; then
 364         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 365       fi
 366     done
 367   done
 368   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 369 fi
 370
 371
 372 # Expand the list of system names into a full list of directories
 373 # from each element's parent name and Implies file (if present).
 374 set $sysnames
 375 names=
 376 while test $# -gt 0; do
 377   name=$1
 378   shift
 379
 380   case " $names " in *" $name "*)
 381     # Already in the list.
 382     continue
 383   esac
 384
 385   # Report each name as we discover it, so there is no long pause in output.
 386   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 387
 388   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 389
 390   case $name in
 391     /*) xsrcdir= ;;
 392     *)  xsrcdir=$srcdir/ ;;
 393   esac
 394   test -n "$enable_debug_configure" &&
 395   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 396
 397   if test -f $xsrcdir$name/Implies; then
 398     # Collect more names from the `Implies' file (removing comments).
 399     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 400     implied=
 401     for x in $implied_candidate; do
 402       if test -d $xsrcdir$name_base/$x; then
 403         implied="$implied $name_base/$x";
 404       else
 405         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 406       fi
 407     done
 408   else
 409     implied=
 410   fi
 411
 412   # Add NAME to the list of names.
 413   names="$names $name"
 414
 415   # Find the parent of NAME, using the empty string if it has none.
 416 changequote(,)dnl
 417   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 418 changequote([,])dnl
 419
 420   # Add the names implied by NAME, and NAME's parent (if it has one), to
 421   # the list of names to be processed (the argument list).  We prepend the
 422   # implied names to the list and append the parent.  We want implied
 423   # directories to come before further directories inferred from the
 424   # configuration components; this ensures that for sysv4, unix/common
 425   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 426   # after sysv4).
 427   sysnames="`echo $implied $* $parent`"
 428   test -n "$sysnames" && set $sysnames
 429 done
 430
 431 # Add the default directories.
 432 default_sysnames=sysdeps/generic
 433 if test "$elf" = yes; then
 434   default_sysnames="sysdeps/generic/elf $default_sysnames"
 435 fi
 436 sysnames="$names $default_sysnames"
 437 AC_SUBST(sysnames)
 438 # The other names were emitted during the scan.
 439 AC_MSG_RESULT($default_sysnames)
 440
 441
 442 ### Locate tools.
 443
 444 AC_PROG_INSTALL
 445 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 446   # The makefiles need to use a different form to find it in $srcdir.
 447   INSTALL='\$(..)./install-sh -c'
 448 fi
 449 AC_PROG_LN_S
 450
 451 # These programs are version sensitive.
 452 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 453 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 454   [version \([egcst0-9.-]*\)],
 455   [egcs-2.91.*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9.[0-9]*],
 456   critic_missing=t)
 457 AC_CHECK_PROG_VER(MAKE, make gmake, --version,
 458   [version \([0-9][0-9.]*\), by],
 459   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 460
 461 AC_CHECK_PROG_VER(MSGFMT, msgfmt gmsgfmt, --version,
 462   [GNU gettext.*\([0-9][0-9]*\.[0-9]*\)],
 463   [0.[1-9][0-9] | [1-9].*], MSGFMT=: aux_missing=t)
 464 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 465   [GNU texinfo \([0-9][0-9.]*\)],
 466   [3.1[1-9] | 3.[2-9][0-9]], MAKEINFO=: aux_missing=t)
 467
 468 if test -n "$critic_missing"; then
 469 AC_MSG_ERROR([
 470 *** Some critical program is missing or too old.
 471 *** Check the INSTALL file for required versions.])
 472 fi
 473
 474 test -n "$aux_missing" && AC_MSG_WARN([
 475 *** An auxiliary program is missing or too old;
 476 *** some features will be disabled.
 477 *** Check the INSTALL file for required versions.])
 478
 479 AC_PROG_CC_LOCAL
 480 AC_CANONICAL_BUILD
 481 if test $host != $build; then
 482   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 483 fi
 484 AC_SUBST(cross_compiling)
 485 AC_PROG_CPP
 486 LIBC_PROG_BINUTILS
 487 AC_CHECK_TOOL(AR, ar)
 488 AC_CHECK_TOOL(RANLIB, ranlib, :)
 489 AC_CHECK_TOOL(MIG, mig)
 490
 491 # if using special system headers, find out the compiler's sekrit
 492 # header directory and add that to the list.  NOTE: Only does the right
 493 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 494 if test -n "$sysheaders"; then
 495   ccheaders=`$CC -print-file-name=include`
 496   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 497 fi
 498 AC_SUBST(SYSINCLUDES)
 499
 500 # check if ranlib is necessary
 501 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 502 cat > conftest.c <<EOF
 503 int a;
 504 char b;
 505 void c(void) {}
 506 EOF
 507 $CC $CFLAGS -c conftest.c
 508 $AR cr conftest.a conftest.c
 509 cp conftest.a conftest2.a
 510 $RANLIB conftest.a
 511 if cmp -s conftest.a conftest2.a; then
 512   libc_cv_ranlib_necessary=no
 513 else
 514   libc_cv_ranlib_necessary=yes
 515 fi
 516 rm -rf conftest*])
 517 if test "$libc_cv_ranlib_necessary" = no; then
 518  RANLIB=:
 519 fi
 520
 521 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 522 # since this would lead to problems installing/building glibc.
 523 # LD_LIBRARY_PATH contains the current directory if one of the following
 524 # is true:
 525 # - one of the terminals (":" and ";") is the first or last sign
 526 # - two terminals occur directly after each other
 527 # - the path contains an element with a dot in it
 528 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 529 changequote(,)dnl
 530 case ${LD_LIBRARY_PATH} in
 531   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 532     ld_library_path_setting="contains current directory"
 533     ;;
 534   *)
 535     ld_library_path_setting="ok"
 536     ;;
 537 esac
 538 changequote([,])dnl
 539 AC_MSG_RESULT($ld_library_path_setting)
 540 if test "$ld_library_path_setting" != "ok"; then
 541 AC_MSG_ERROR([
 542 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 543 *** building glibc. Please change the environment variable
 544 *** and run configure again.])
 545 fi
 546
 547 AC_PATH_PROG(BASH, bash, no)
 548 if test "$BASH" != no &&
 549    $BASH -c 'test "$BASH_VERSINFO" \
 550              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 551   libc_cv_have_bash2=yes
 552 else
 553   libc_cv_have_bash2=no
 554 fi
 555 AC_SUBST(libc_cv_have_bash2)
 556
 557 dnl We need a ksh compatible shell for tzselect.
 558 if test "$BASH" = no; then
 559   AC_PATH_PROG(KSH, ksh, no)
 560   if test "$KSH" = no; then
 561     libc_cv_have_ksh=no
 562   else
 563     libc_cv_have_ksh=yes
 564   fi
 565 else
 566   KSH="$BASH"
 567   AC_SUBST(KSH)
 568   libc_cv_have_ksh=yes
 569 fi
 570 AC_SUBST(libc_cv_have_ksh)
 571
 572 AC_PROG_AWK
 573 AC_PATH_PROGS(PERL, perl, no)
 574 AC_SUBST(PERL)
 575
 576 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 577 echo '#include <stddef.h>
 578 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 579 if eval "$ac_cpp conftest.c 2>/dev/null" \
 580 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 581   libc_cv_signed_size_t=no
 582 else
 583   libc_cv_signed_size_t=yes
 584 fi
 585 rm -f conftest*])
 586 if test $libc_cv_signed_size_t = yes; then
 587   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 588   cat >> confdefs.h <<\EOF
 589 #undef __SIZE_TYPE__
 590 #define __SIZE_TYPE__ unsigned
 591 EOF
 592 fi
 593
 594 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 595 AC_TRY_COMPILE(dnl
 596 [#define __need_size_t
 597 #define __need_wchar_t
 598 #include <stddef.h>
 599 #define __need_NULL
 600 #include <stddef.h>], [size_t size; wchar_t wchar;
 601 #ifdef offsetof
 602 #error stddef.h ignored __need_*
 603 #endif
 604 if (&size == NULL || &wchar == NULL) abort ();],
 605                libc_cv_friendly_stddef=yes,
 606                libc_cv_friendly_stddef=no)])
 607 if test $libc_cv_friendly_stddef = yes; then
 608   config_vars="$config_vars
 609 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 610 fi
 611
 612 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 613                libc_cv_need_minus_P, [dnl
 614 cat > conftest.S <<EOF
 615 #include "confdefs.h"
 616 /* Nothing whatsoever.  */
 617 EOF
 618 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 619   libc_cv_need_minus_P=no
 620 else
 621   libc_cv_need_minus_P=yes
 622 fi
 623 rm -f conftest*])
 624 if test $libc_cv_need_minus_P = yes; then
 625   config_vars="$config_vars
 626 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 627 fi
 628
 629 AC_CACHE_CHECK(for assembler global-symbol directive,
 630                libc_cv_asm_global_directive, [dnl
 631 libc_cv_asm_global_directive=UNKNOWN
 632 for ac_globl in .globl .global; do
 633   cat > conftest.s <<EOF
 634 .text
 635 ${ac_globl} foo
 636 foo:
 637 EOF
 638   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 639     libc_cv_asm_global_directive=${ac_globl}
 640   fi
 641   rm -f conftest*
 642   test $libc_cv_asm_global_directive != UNKNOWN && break
 643 done])
 644 if test $libc_cv_asm_global_directive = UNKNOWN; then
 645   AC_MSG_ERROR(cannot determine asm global directive)
 646 else
 647   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 648 fi
 649
 650 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 651 cat > conftest.s <<EOF
 652 .text
 653 foo:
 654 .set glibc_conftest_frobozz,foo
 655 $libc_cv_asm_global_directive glibc_conftest_frobozz
 656 EOF
 657 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 658 # (but it doesn't work), so we must do a linking check to be sure.
 659 cat > conftest1.c <<\EOF
 660 extern int glibc_conftest_frobozz;
 661 main () { printf ("%d\n", glibc_conftest_frobozz); }
 662 EOF
 663 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 664             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 665   libc_cv_asm_set_directive=yes
 666 else
 667   libc_cv_asm_set_directive=no
 668 fi
 669 rm -f conftest*])
 670 if test $libc_cv_asm_set_directive = yes; then
 671   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 672 fi
 673
 674 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 675 [cat > conftest.s <<EOF
 676 .text
 677 _sym:
 678 .symver _sym,sym@VERS
 679 EOF
 680 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 681   libc_cv_asm_symver_directive=yes
 682 else
 683   libc_cv_asm_symver_directive=no
 684 fi
 685 rm -f conftest*])
 686 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 687 if test $libc_cv_asm_symver_directive = yes; then
 688   cat > conftest.s <<EOF
 689 .text
 690 _sym:
 691 .symver _sym,sym@VERS
 692 EOF
 693   cat > conftest.map <<EOF
 694 VERS_1 {
 695         global: sym;
 696 };
 697
 698 VERS_2 {
 699         global: sym;
 700 } VERS_1;
 701 EOF
 702   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 703     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 704                                         -nostartfiles -nostdlib
 705                                         -Wl,--version-script,conftest.map
 706                        1>&AC_FD_CC]);
 707     then
 708       libc_cv_ld_version_script_option=yes
 709     else
 710       libc_cv_ld_version_script_option=no
 711     fi
 712   else
 713     libc_cv_ld_version_script_option=no
 714   fi
 715 else
 716   libc_cv_ld_version_script_option=no
 717 fi
 718 rm -f conftest*])
 719 if test $libc_cv_asm_symver_directive = yes &&
 720    test $libc_cv_ld_version_script_option = yes &&
 721    test $enable_versioning = yes; then
 722   VERSIONING=yes
 723   AC_DEFINE(DO_VERSIONING)
 724 else
 725   VERSIONING=no
 726 fi
 727 AC_SUBST(VERSIONING)
 728
 729 if test $VERSIONING = no; then
 730   echo "\
 731 *** WARNING: You should not compile GNU libc without versioning. Not using
 732 *** versioning will introduce incompatibilities so that old binaries
 733 *** will not run anymore.
 734 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
 735 fi
 736 if test $elf = yes; then
 737   AC_CACHE_CHECK(for .previous assembler directive,
 738                  libc_cv_asm_previous_directive, [dnl
 739   cat > conftest.s <<EOF
 740 .section foo_section
 741 .previous
 742 EOF
 743   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 744     libc_cv_asm_previous_directive=yes
 745   else
 746     libc_cv_asm_previous_directive=no
 747   fi
 748   rm -f conftest*])
 749   if test $libc_cv_asm_previous_directive = yes; then
 750     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 751   else
 752     AC_CACHE_CHECK(for .popsection assembler directive,
 753                    libc_cv_asm_popsection_directive, [dnl
 754     cat > conftest.s <<EOF
 755 .pushsection foo_section
 756 .popsection
 757 EOF
 758     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 759       libc_cv_asm_popsection_directive=yes
 760     else
 761       libc_cv_asm_popsection_directive=no
 762     fi
 763     rm -f conftest*])
 764     if test $libc_cv_asm_popsection_directive = yes; then
 765       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 766     fi
 767   fi
 768 fi
 769
 770 if test $elf != yes; then
 771   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 772                  [AC_TRY_COMPILE(, [asm (".section .init");
 773                                     asm (".section .fini");
 774                                     asm (".text");],
 775                                  libc_cv_have_initfini=yes,
 776                                  libc_cv_have_initfini=no)])
 777   AC_SUBST(libc_cv_have_initfini)dnl
 778   if test $libc_cv_have_initfini = yes; then
 779     AC_DEFINE(HAVE_INITFINI)
 780   fi
 781 fi
 782
 783 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 784 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 785 [cat > conftest.$ac_ext <<EOF
 786 dnl This sometimes fails to find confdefs.h, for some reason.
 787 dnl [#]line __oline__ "[$]0"
 788 [#]line __oline__ "configure"
 789 #include "confdefs.h"
 790 void underscore_test(void) {
 791 return; }
 792 EOF
 793 if AC_TRY_EVAL(ac_compile); then
 794   if grep _underscore_test conftest* >/dev/null; then
 795     ifelse([$1], , :, [rm -f conftest*
 796     $1])
 797   else
 798     ifelse([$2], , , [rm -f conftest*
 799     $2])
 800   fi
 801 else
 802   echo "configure: failed program was:" >&AC_FD_CC
 803   cat conftest.$ac_ext >&AC_FD_CC
 804   ifelse([$2], , , [rm -f conftest*
 805   $2])
 806 fi
 807 rm -f conftest*])
 808
 809 if test $elf = yes; then
 810   libc_cv_asm_underscores=no
 811 else
 812   if test $ac_cv_prog_cc_works = yes; then
 813     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 814                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 815                                 libc_cv_asm_underscores=yes,
 816                                 libc_cv_asm_underscores=no)])
 817   else
 818     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 819                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 820                                             libc_cv_asm_underscores=no)])
 821   fi
 822 fi
 823 if test $libc_cv_asm_underscores = no; then
 824   AC_DEFINE(NO_UNDERSCORES)
 825 fi
 826
 827 if test $elf = yes; then
 828   libc_cv_weak_symbols=yes
 829 fi
 830
 831 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 832                  [dnl
 833 cat > conftest.s <<EOF
 834 .text
 835 ${libc_cv_asm_global_directive} foo
 836 foo:
 837 .weak foo
 838 .weak bar; bar = foo
 839 EOF
 840 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 841   libc_cv_asm_weak_directive=yes
 842 else
 843   libc_cv_asm_weak_directive=no
 844 fi
 845 rm -f conftest*])
 846
 847 if test $libc_cv_asm_weak_directive = no; then
 848   AC_CACHE_CHECK(for assembler .weakext directive,
 849                  libc_cv_asm_weakext_directive,
 850                  [dnl
 851 cat > conftest.s <<EOF
 852 .text
 853 ${libc_cv_asm_global_directive} foo
 854 foo:
 855 .weakext bar foo
 856 .weakext baz
 857 ${libc_cv_asm_global_directive} baz
 858 baz:
 859 EOF
 860   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 861     libc_cv_asm_weakext_directive=yes
 862   else
 863     libc_cv_asm_weakext_directive=no
 864   fi
 865   rm -f conftest*])
 866
 867 fi # no .weak
 868
 869 if test $libc_cv_asm_weak_directive = yes; then
 870   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 871 elif test $libc_cv_asm_weakext_directive = yes; then
 872   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 873 fi
 874
 875 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 876 cat > conftest.c <<\EOF
 877 _start () {}
 878 int __eh_pc;
 879 __throw () {}
 880 EOF
 881 dnl No \ in command here because it ends up inside ''.
 882 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 883                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 884                             -o conftest conftest.c 1>&AC_FD_CC]); then
 885   libc_cv_ld_no_whole_archive=yes
 886 else
 887   libc_cv_ld_no_whole_archive=no
 888 fi
 889 rm -f conftest*])
 890 if test $libc_cv_ld_no_whole_archive = yes; then
 891   no_whole_archive=-Wl,--no-whole-archive
 892 fi
 893 AC_SUBST(no_whole_archive)dnl
 894
 895 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 896 cat > conftest.c <<\EOF
 897 _start () {}
 898 int __eh_pc;
 899 __throw () {}
 900 EOF
 901 dnl No \ in command here because it ends up inside ''.
 902 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 903                             -nostdlib -nostartfiles -fno-exceptions
 904                             -o conftest conftest.c 1>&AC_FD_CC]); then
 905   libc_cv_gcc_no_exceptions=yes
 906 else
 907   libc_cv_gcc_no_exceptions=no
 908 fi
 909 rm -f conftest*])
 910 if test $libc_cv_ld_no_whole_archive = yes; then
 911   no_exceptions=-fno-exceptions
 912 fi
 913 AC_SUBST(no_exceptions)dnl
 914
 915 if test "$base_machine" = alpha ; then
 916 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 917 cat > conftest.c <<\EOF
 918 foo () { }
 919 EOF
 920 dnl
 921 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 922 then
 923   libc_cv_gcc_alpha_ng_prefix=yes
 924 else
 925   libc_cv_gcc_alpha_ng_prefix=no
 926 fi
 927 rm -f conftest* ])
 928 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 929   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 930 else
 931   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 932 fi
 933 fi
 934
 935 if test "$host_cpu" = powerpc ; then
 936 # Check for a bug present in at least versions 2.8.x of GCC
 937 # and versions 1.0.x of EGCS.
 938 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
 939 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
 940                libc_cv_c_asmcr0_bug='no',
 941                libc_cv_c_asmcr0_bug='yes')])
 942 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
 943   AC_DEFINE(BROKEN_PPC_ASM_CR0)
 944 fi
 945 fi
 946
 947 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 948 [cat > conftest.c <<EOF
 949 #line __oline__ "configure"
 950 static char __EH_FRAME_BEGIN__[];
 951 _start ()
 952 {
 953 #ifdef CHECK__register_frame
 954   __register_frame (__EH_FRAME_BEGIN__);
 955   __deregister_frame (__EH_FRAME_BEGIN__);
 956 #endif
 957 #ifdef CHECK__register_frame_info
 958   __register_frame_info (__EH_FRAME_BEGIN__);
 959   __deregister_frame_info (__EH_FRAME_BEGIN__);
 960 #endif
 961 }
 962 int __eh_pc;
 963 __throw () {}
 964 /* FIXME: this is fragile.  */
 965 malloc () {}
 966 strcmp () {}
 967 strlen () {}
 968 memcpy () {}
 969 memset () {}
 970 free () {}
 971 abort () {}
 972 __bzero () {}
 973 EOF
 974 dnl No \ in command here because it ends up inside ''.
 975 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
 976                             -nostdlib -nostartfiles
 977                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 978   libc_cv_gcc_dwarf2_unwind_info=static
 979 else
 980   libc_cv_gcc_dwarf2_unwind_info=no
 981 fi
 982 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
 983   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
 984                               -nostdlib -nostartfiles
 985                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 986     libc_cv_gcc_dwarf2_unwind_info=yes
 987   else
 988     libc_cv_gcc_dwarf2_unwind_info=no
 989   fi
 990 fi
 991 rm -f conftest*])
 992 case $libc_cv_gcc_dwarf2_unwind_info in
 993 yes)
 994   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
 995   ;;
 996 static)
 997   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
 998   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
 999   ;;
1000 esac
1001
1002 ### End of automated tests.
1003 ### Now run sysdeps configure fragments.
1004
1005 # sysdeps configure fragments may set these with files to be linked below.
1006 libc_link_dests=
1007 libc_link_sources=
1008
1009 # They also can set these variables.
1010 ldd_rewrite_script=no
1011
1012 # Iterate over all the sysdep directories we will use, running their
1013 # configure fragments, and looking for a uname implementation.
1014 uname=
1015 for dir in $sysnames; do
1016   case $dir in
1017     /*) dest=$dir ;;
1018     *)  dest=$srcdir/$dir ;;
1019   esac
1020   if test -r $dest/configure; then
1021     AC_MSG_RESULT(running configure fragment for $dest)
1022     . $dest/configure
1023   fi
1024 [
1025   if test -z "$uname"; then
1026     if test -r $dest/uname.c ||
1027        test -r $dest/uname.S ||
1028        { test -r $dest/syscalls.list &&
1029          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1030       uname=$dir
1031     fi
1032   fi
1033 ]dnl
1034 done
1035
1036 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1037
1038 # If we will use the generic uname implementation, we must figure out what
1039 # it will say by examining the system, and write the results in config-name.h.
1040 if test "$uname" = "sysdeps/generic"; then
1041
1042 changequote(,)dnl
1043   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1044 changequote([,])dnl
1045   if test $uname_sysname != $config_os; then
1046     config_release=`echo $config_os | sed s/$uname_sysname//`
1047   fi
1048 dnl
1049 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1050     if test -r /vmunix; then
1051       kernel_id=`strings /vmunix | grep UNIX`
1052     elif test -r /dynix; then
1053       kernel_id=`strings /dynix | grep DYNIX`
1054     else
1055       kernel_id=
1056     fi
1057 ])dnl
1058
1059   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1060 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1061 changequote(,)dnl
1062   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1063 changequote([,])dnl
1064   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1065          != x$config_release; then
1066     # The configuration release is a substring of the kernel release.
1067     libc_cv_uname_release=$kernel_release
1068   elif test x$config_release != x; then
1069     libc_cv_uname_release=$config_release
1070   elif test x$kernel_release != x; then
1071     libc_cv_uname_release=$kernel_release
1072   else
1073     libc_cv_uname_release=unknown
1074   fi])
1075   uname_release="$libc_cv_uname_release"
1076
1077   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1078 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1079 changequote(,)dnl
1080   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1081 changequote([,])dnl
1082   if test -n "$kernel_version"; then
1083     libc_cv_uname_version="$kernel_version"
1084   else
1085     libc_cv_uname_version=unknown
1086   fi])
1087   uname_version="$libc_cv_uname_version"
1088
1089 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1090   config_uname=config-name.h:config-name.in
1091 else
1092   # For non-generic uname, we don't need to create config-name.h at all.
1093   config_uname=
1094 fi
1095
1096 AC_MSG_CHECKING(stdio selection)
1097 AC_SUBST(stdio)
1098 case $stdio in
1099 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1100 default) stdio=stdio ;;
1101 esac
1102 AC_MSG_RESULT($stdio)
1103
1104 # Test for old glibc 2.0.x headers so that they can be removed properly
1105 # Search only in includedir.
1106 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1107 if eval test -e "${includedir}/elfclass.h" -a -e "${includedir}/fcntlbits.h"
1108 then
1109   old_glibc_headers=yes
1110 else
1111   old_glibc_headers=no
1112 fi
1113 AC_MSG_RESULT($old_glibc_headers)
1114 if test ${old_glibc_headers} = yes; then
1115   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1116   AC_MSG_WARN(*** be removed.)
1117 fi
1118 AC_SUBST(old_glibc_headers)
1119
1120 AC_SUBST(libc_cv_slibdir)
1121 AC_SUBST(libc_cv_sysconfdir)
1122 AC_SUBST(libc_cv_rootsbindir)
1123
1124 AC_SUBST(has_ldconfig)
1125 AC_SUBST(ldd_rewrite_script)
1126
1127 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1128 if test $gnu_ld = yes; then
1129   AC_DEFINE(HAVE_GNU_LD)
1130 fi
1131 if test $gnu_as = yes; then
1132   AC_DEFINE(HAVE_GNU_AS)
1133 fi
1134 if test $elf = yes; then
1135   AC_DEFINE(HAVE_ELF)
1136 fi
1137
1138 AC_SUBST(static)
1139 AC_SUBST(shared)
1140 if test $shared = default; then
1141   if test $gnu_ld = yes; then
1142     shared=$elf
1143   else
1144     # For now we do not assume shared libs are available.  In future more
1145     # tests might become available.
1146     shared=no
1147   fi
1148 fi
1149
1150 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1151 [pic_default=yes
1152 cat > conftest.c <<EOF
1153 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1154 # error PIC is default.
1155 #endif
1156 EOF
1157 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1158   pic_default=no
1159 fi
1160 rm -f conftest.*])
1161 AC_SUBST(pic_default)
1162
1163 AC_SUBST(profile)
1164 AC_SUBST(omitfp)
1165 AC_SUBST(bounded)
1166 AC_SUBST(static_nss)
1167 AC_SUBST(nopic_initfini)
1168
1169 AC_SUBST(DEFINES)
1170
1171 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1172   config_makefile=
1173 else
1174   config_makefile=Makefile
1175 fi
1176
1177 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1178 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1179 AC_SUBST(VERSION)
1180 AC_SUBST(RELEASE)
1181
1182 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1183 case $CONFIG_FILES in *config.make*)
1184 echo "$config_vars" >> config.make;;
1185 esac
1186 test -d bits || mkdir bits], [config_vars='$config_vars'])