configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37 [  --with-fp              if using floating-point hardware [default=yes]],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 AC_ARG_ENABLE(sanity-checks, dnl
  63 [  --disable-sanity-checks really do not use threads (should not be used
  64                           except in special situations) [default=yes]],
  65               enable_sanity=$enableval, enable_sanity=yes)
  66
  67 dnl Arguments to enable or disable building the shared, profiled, and
  68 dnl -fomit-frame-pointer libraries.
  69 AC_ARG_ENABLE(shared, dnl
  70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  71               shared=$enableval, shared=default)
  72 AC_ARG_ENABLE(profile, dnl
  73 [  --enable-profile        build profiled library [default=yes]],
  74               profile=$enableval, profile=yes)
  75 AC_ARG_ENABLE(omitfp, dnl
  76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  77               omitfp=$enableval, omitfp=no)
  78 AC_ARG_ENABLE(bounded, dnl
  79 [  --enable-bounded        build with runtime bounds checking [default=no]],
  80               bounded=$enableval, bounded=no)
  81
  82 dnl Generic infrastructure for drop-in additions to libc.
  83 AC_ARG_ENABLE(add-ons, dnl
  84 [  --enable-add-ons=DIR... configure and build named extra directories],
  85               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
  86               [add_ons=])
  87 AC_CONFIG_SUBDIRS($add_ons)
  88 add_ons_pfx=
  89 if test x"$add_ons" != x; then
  90   for f in $add_ons; do
  91     add_ons_pfx="$add_ons_pfx $f/"
  92   done
  93 fi
  94
  95 dnl On some platforms we cannot use dynamic loading.  We must provide
  96 dnl static NSS modules.
  97 AC_ARG_ENABLE(static-nss, dnl
  98 [  --enable-static-nss     build static NSS modules [default=no]],
  99               static_nss=$enableval, static_nss=no)
 100 if test x"$static_nss" = xyes; then
 101   AC_DEFINE(DO_STATIC_NSS)
 102 fi
 103
 104 AC_CANONICAL_HOST
 105
 106 # The way shlib-versions is used to generate soversions.mk uses a
 107 # fairly simplistic model for name recognition that can't distinguish
 108 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 109 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 110 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 111 case "$host_os" in
 112 linux*)
 113   ;;
 114 gnu*)
 115   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 116   ;;
 117 esac
 118
 119 ###
 120 ### I put this here to prevent those annoying emails from people who cannot
 121 ### read and try to compile glibc on unsupported platforms.  --drepper
 122 ###
 123 case "$host_os" in
 124 linux* | gnu*)
 125   ;;
 126 *)
 127   echo "*** The GNU C library is currently not available for this platform."
 128   echo "*** So far nobody cared to port it and if there is no volunteer it"
 129   echo "*** might never happen.  So, if you have interest to see glibc on"
 130   echo "*** this platform visit"
 131   echo "***     http://www.gnu.ai.mit.edu/software/libc/porting.html"
 132   echo "*** and join the group of porters"
 133   exit 1
 134   ;;
 135 esac
 136
 137 # We keep the original values in `$config_*' and never modify them, so we
 138 # can write them unchanged into config.make.  Everything else uses
 139 # $machine, $vendor, and $os, and changes them whenever convenient.
 140 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 141
 142 # Some configurations imply other options.
 143 case "$host_os" in
 144 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 145   # These systems always use GNU tools.
 146   gnu_ld=yes gnu_as=yes ;;
 147 esac
 148 case "$host_os" in
 149 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 150 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 151   ;;
 152 gnu* | linux* | sysv4* | solaris2*)
 153   # These systems (almost) always use the ELF format.
 154   elf=yes
 155   ;;
 156 esac
 157
 158 machine=$config_machine
 159 vendor=$config_vendor
 160 os=$config_os
 161
 162 dnl We need to use [ and ] for other purposes for a while now.
 163 changequote(,)dnl
 164 # Expand the configuration machine name into a subdirectory by architecture
 165 # type and particular chip.
 166 case "$machine" in
 167 a29k | am29000) base_machine=a29k machine=a29k ;;
 168 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 169 arm*)           base_machine=arm machine=arm/$machine ;;
 170 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 171 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 172 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 173 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 174 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 175 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 176 m88???)         base_machine=m88k machine=m88k/$machine ;;
 177 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 178 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 179 mips*)          base_machine=mips machine=mips/$machine ;;
 180 sparc | sparcv[67])
 181                 base_machine=sparc machine=sparc/sparc32 ;;
 182 sparcv8 | supersparc | hypersparc)
 183                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 184 sparc64 | ultrasparc)
 185                 base_machine=sparc machine=sparc/sparc64 ;;
 186 esac
 187 changequote([,])dnl
 188 AC_SUBST(base_machine)
 189
 190 # Compute the list of sysdep directories for this configuration.
 191 # This can take a while to compute.
 192 sysdep_dir=$srcdir/sysdeps
 193 AC_MSG_CHECKING(sysdep dirs)
 194 dnl We need to use [ and ] for other purposes for a while now.
 195 changequote(,)dnl
 196 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 197 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 198
 199 case "$os" in
 200 gnu*)
 201   base_os=mach/hurd ;;
 202 netbsd* | 386bsd* | freebsd* | bsdi*)
 203   base_os=unix/bsd/bsd4.4 ;;
 204 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 205   base_os=unix/bsd ;;
 206 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 207   base_os=unix/sysv ;;
 208 solaris[2-9]*)
 209   base_os=unix/sysv/sysv4 ;;
 210 none)
 211   base_os=standalone ;;
 212 *)
 213   base_os='' ;;
 214 esac
 215
 216 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 217 tail=$os
 218 ostry=$os
 219 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 220   ostry="$ostry /$o"
 221   tail=$o
 222 done
 223 o=`echo $tail | sed 's/[0-9]*$//'`
 224 if test $o != $tail; then
 225   ostry="$ostry /$o"
 226 fi
 227 # For linux-gnu, try linux-gnu, then linux.
 228 o=`echo $tail | sed 's/-.*$//'`
 229 if test $o != $tail; then
 230   ostry="$ostry /$o"
 231 fi
 232
 233 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 234 base=
 235 tail=$base_os
 236 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 237   set $b
 238   base="$base /$1"
 239   tail="$2"
 240 done
 241
 242 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 243 mach=
 244 tail=$machine
 245 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 246   set $m
 247   # Prepend the machine's FPU directory unless --without-fp.
 248   if test "$with_fp" = yes; then
 249     mach="$mach /$1/fpu"
 250   fi
 251   mach="$mach /$1"
 252   tail="$2"
 253 done
 254
 255 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 256 changequote([,])dnl
 257
 258 # Find what sysdep directories exist.
 259 sysnames=
 260 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 261 for d in $add_ons_pfx ''; do
 262   for b in $base ''; do
 263     for m0 in $mach ''; do
 264       for v in /$vendor ''; do
 265         for o in /$ostry ''; do
 266           for m in $mach ''; do
 267             if test "$m0$b$v$o$m"; then
 268               try="${d}sysdeps$m0$b$v$o$m"
 269               test -n "$enable_debug_configure" &&
 270               echo "$0 [DEBUG]: try $try" >&2
 271               case $try in
 272                 /*) dest=$try ;;
 273                 *)  dest=$srcdir/$try ;;
 274               esac
 275               if test -d $dest; then
 276                 sysnames="$sysnames $try"
 277                 { test -n "$o" || test -n "$b"; } && os_used=t
 278                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 279               fi
 280             fi
 281           done
 282         done
 283       done
 284     done
 285   done
 286 done
 287 IFS="$ac_save_ifs"
 288
 289 if test -z "$os_used" && test "$os" != none; then
 290   AC_MSG_ERROR(Operating system $os is not supported.)
 291 fi
 292 if test -z "$machine_used" && test "$machine" != none; then
 293   AC_MSG_ERROR(The $machine is not supported.)
 294 fi
 295
 296 # We have now validated the configuration.
 297
 298
 299 # If using ELF, look for an `elf' subdirectory of each machine directory.
 300 # We prepend these rather than inserting them whereever the machine appears
 301 # because things specified by the machine's ELF ABI should override
 302 # OS-specific things, and should always be the same for any OS on the
 303 # machine (otherwise what's the point of an ABI?).
 304 if test "$elf" = yes; then
 305   elf_dirs=
 306   for d in $add_ons_pfx ''; do
 307     case $d in
 308       /*) xsrcdir= ;;
 309       *)  xsrcdir=$srcdir/ ;;
 310     esac
 311     for m in $mach; do
 312       if test -d $xsrcdir${d}sysdeps$m/elf; then
 313         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 314       fi
 315     done
 316   done
 317   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 318 fi
 319
 320
 321 # Expand the list of system names into a full list of directories
 322 # from each element's parent name and Implies file (if present).
 323 set $sysnames
 324 names=
 325 while test $# -gt 0; do
 326   name=$1
 327   shift
 328
 329   case " $names " in *" $name "*)
 330     # Already in the list.
 331     continue
 332   esac
 333
 334   # Report each name as we discover it, so there is no long pause in output.
 335   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 336
 337   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 338
 339   case $name in
 340     /*) xsrcdir= ;;
 341     *)  xsrcdir=$srcdir/ ;;
 342   esac
 343   test -n "$enable_debug_configure" &&
 344   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 345
 346   if test -f $xsrcdir$name/Implies; then
 347     # Collect more names from the `Implies' file (removing comments).
 348     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 349     implied=
 350     for x in $implied_candidate; do
 351       if test -d $xsrcdir$name_base/$x; then
 352         implied="$implied $name_base/$x";
 353       else
 354         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 355       fi
 356     done
 357   else
 358     implied=
 359   fi
 360
 361   # Add NAME to the list of names.
 362   names="$names $name"
 363
 364   # Find the parent of NAME, using the empty string if it has none.
 365 changequote(,)dnl
 366   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 367 changequote([,])dnl
 368
 369   # Add the names implied by NAME, and NAME's parent (if it has one), to
 370   # the list of names to be processed (the argument list).  We prepend the
 371   # implied names to the list and append the parent.  We want implied
 372   # directories to come before further directories inferred from the
 373   # configuration components; this ensures that for sysv4, unix/common
 374   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 375   # after sysv4).
 376   sysnames="`echo $implied $* $parent`"
 377   test -n "$sysnames" && set $sysnames
 378 done
 379
 380 # Add the default directories.
 381 sysnames="$names sysdeps/generic sysdeps/stub"
 382 AC_SUBST(sysnames)
 383 # The other names were emitted during the scan.
 384 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
 385
 386
 387 ### Locate tools.
 388
 389 AC_PROG_INSTALL
 390 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 391   # The makefiles need to use a different form to find it in $srcdir.
 392   INSTALL='\$(..)./install-sh -c'
 393 fi
 394 AC_PROG_LN_S
 395 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 396
 397 AC_PROG_CC_LOCAL
 398 AC_CANONICAL_BUILD
 399 if test $host != $build; then
 400   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 401 fi
 402 AC_SUBST(cross_compiling)
 403 AC_PROG_CPP
 404 AC_CHECK_TOOL(AR, ar)
 405 AC_CHECK_TOOL(RANLIB, ranlib, :)
 406
 407 AC_PATH_PROG(BASH, bash, no)
 408 if test "$BASH" != no &&
 409    $BASH -c 'test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 410   libc_cv_have_bash2=yes
 411 else
 412   libc_cv_have_bash2=no
 413 fi
 414 AC_SUBST(libc_cv_have_bash2)
 415
 416 dnl We need a ksh compatible shell for tzselect.
 417 if test "$BASH" = no; then
 418   AC_PATH_PROG(KSH, ksh, no)
 419   if test "$KSH" = no; then
 420     libc_cv_have_ksh=no
 421   else
 422     libc_cv_have_ksh=yes
 423   fi
 424 else
 425   KSH="$BASH"
 426   AC_SUBST(KSH)
 427   libc_cv_have_ksh=yes
 428 fi
 429 AC_SUBST(libc_cv_have_ksh)
 430
 431 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 432 echo '#include <stddef.h>
 433 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 434 if eval "$ac_cpp conftest.c 2>/dev/null" \
 435 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 436   libc_cv_signed_size_t=no
 437 else
 438   libc_cv_signed_size_t=yes
 439 fi
 440 rm -f conftest*])
 441 if test $libc_cv_signed_size_t = yes; then
 442   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 443   cat >> confdefs.h <<\EOF
 444 #undef __SIZE_TYPE__
 445 #define __SIZE_TYPE__ unsigned
 446 EOF
 447 fi
 448
 449 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 450 AC_TRY_COMPILE(dnl
 451 [#define __need_size_t
 452 #define __need_wchar_t
 453 #include <stddef.h>
 454 #define __need_NULL
 455 #include <stddef.h>], [size_t size; wchar_t wchar;
 456 #ifdef offsetof
 457 #error stddef.h ignored __need_*
 458 #endif
 459 if (&size == NULL || &wchar == NULL) abort ();],
 460                libc_cv_friendly_stddef=yes,
 461                libc_cv_friendly_stddef=no)])
 462 if test $libc_cv_friendly_stddef = yes; then
 463   config_vars="$config_vars
 464 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 465 fi
 466
 467 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 468                libc_cv_need_minus_P, [dnl
 469 cat > conftest.S <<EOF
 470 #include "confdefs.h"
 471 /* Nothing whatsoever.  */
 472 EOF
 473 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 474   libc_cv_need_minus_P=no
 475 else
 476   libc_cv_need_minus_P=yes
 477 fi
 478 rm -f conftest*])
 479 if test $libc_cv_need_minus_P = yes; then
 480   config_vars="$config_vars
 481 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 482 fi
 483
 484 AC_CACHE_CHECK(for assembler global-symbol directive,
 485                libc_cv_asm_global_directive, [dnl
 486 libc_cv_asm_global_directive=UNKNOWN
 487 for ac_globl in .globl .global; do
 488   cat > conftest.s <<EOF
 489 .text
 490 ${ac_globl} foo
 491 foo:
 492 EOF
 493   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 494     libc_cv_asm_global_directive=${ac_globl}
 495   fi
 496   rm -f conftest*
 497   test $libc_cv_asm_global_directive != UNKNOWN && break
 498 done])
 499 if test $libc_cv_asm_global_directive = UNKNOWN; then
 500   AC_MSG_ERROR(cannot determine asm global directive)
 501 else
 502   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 503 fi
 504
 505 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 506 cat > conftest.s <<EOF
 507 .text
 508 foo:
 509 .set glibc_conftest_frobozz,foo
 510 $libc_cv_asm_global_directive glibc_conftest_frobozz
 511 EOF
 512 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 513 # (but it doesn't work), so we must do a linking check to be sure.
 514 cat > conftest1.c <<\EOF
 515 extern int glibc_conftest_frobozz;
 516 main () { printf ("%d\n", glibc_conftest_frobozz); }
 517 EOF
 518 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 519             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 520   libc_cv_asm_set_directive=yes
 521 else
 522   libc_cv_asm_set_directive=no
 523 fi
 524 rm -f conftest*])
 525 if test $libc_cv_asm_set_directive = yes; then
 526   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 527 fi
 528
 529 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 530 [cat > conftest.s <<EOF
 531 .text
 532 _sym:
 533 .symver _sym,sym@VERS
 534 EOF
 535 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 536   libc_cv_asm_symver_directive=yes
 537 else
 538   libc_cv_asm_symver_directive=no
 539 fi
 540 rm -f conftest*])
 541 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 542 if test $libc_cv_asm_symver_directive = yes; then
 543   cat > conftest.s <<EOF
 544 .text
 545 _sym:
 546 .symver _sym,sym@VERS
 547 EOF
 548   cat > conftest.map <<EOF
 549 VERS {
 550         global: sym;
 551 };
 552 EOF
 553   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 554     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 555                                         -nostartfiles -nostdlib
 556                                         -Wl,--version-script,conftest.map
 557                        1>&AC_FD_CC]);
 558     then
 559       libc_cv_ld_version_script_option=yes
 560     else
 561       libc_cv_ld_version_script_option=no
 562     fi
 563   else
 564     libc_cv_ld_version_script_option=no
 565   fi
 566 else
 567   libc_cv_ld_version_script_option=no
 568 fi
 569 rm -f conftest*])
 570 if test $libc_cv_asm_symver_directive = yes &&
 571    test $libc_cv_ld_version_script_option = yes; then
 572   VERSIONING=yes
 573   AC_DEFINE(DO_VERSIONING)
 574 else
 575   VERSIONING=no
 576 fi
 577 AC_SUBST(VERSIONING)
 578
 579 if test $elf = yes; then
 580   AC_CACHE_CHECK(for .previous assembler directive,
 581                  libc_cv_asm_previous_directive, [dnl
 582   cat > conftest.s <<EOF
 583 .section foo_section
 584 .previous
 585 EOF
 586   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 587     libc_cv_asm_previous_directive=yes
 588   else
 589     libc_cv_asm_previous_directive=no
 590   fi
 591   rm -f conftest*])
 592   if test $libc_cv_asm_previous_directive = yes; then
 593     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 594   else
 595     AC_CACHE_CHECK(for .popsection assembler directive,
 596                    libc_cv_asm_popsection_directive, [dnl
 597     cat > conftest.s <<EOF
 598 .pushsection foo_section
 599 .popsection
 600 EOF
 601     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 602       libc_cv_asm_popsection_directive=yes
 603     else
 604       libc_cv_asm_popsection_directive=no
 605     fi
 606     rm -f conftest*])
 607     if test $libc_cv_asm_popsection_directive = yes; then
 608       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 609     fi
 610   fi
 611 fi
 612
 613 if test $elf != yes; then
 614   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 615                  [AC_TRY_COMPILE(, [asm (".section .init");
 616                                     asm (".section .fini");
 617                                     asm (".text");],
 618                                  libc_cv_have_initfini=yes,
 619                                  libc_cv_have_initfini=no)])
 620   AC_SUBST(libc_cv_have_initfini)dnl
 621   if test $libc_cv_have_initfini = yes; then
 622     AC_DEFINE(HAVE_INITFINI)
 623   fi
 624 fi
 625
 626 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 627 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 628 [cat > conftest.$ac_ext <<EOF
 629 dnl This sometimes fails to find confdefs.h, for some reason.
 630 dnl [#]line __oline__ "[$]0"
 631 [#]line __oline__ "configure"
 632 #include "confdefs.h"
 633 void underscore_test(void) {
 634 return; }
 635 EOF
 636 if AC_TRY_EVAL(ac_compile); then
 637   if grep _underscore_test conftest* >/dev/null; then
 638     ifelse([$1], , :, [rm -f conftest*
 639     $1])
 640   else
 641     ifelse([$2], , , [rm -f conftest*
 642     $2])
 643   fi
 644 else
 645   echo "configure: failed program was:" >&AC_FD_CC
 646   cat conftest.$ac_ext >&AC_FD_CC
 647   ifelse([$2], , , [rm -f conftest*
 648   $2])
 649 fi
 650 rm -f conftest*])
 651
 652 if test $elf = yes; then
 653   libc_cv_asm_underscores=no
 654 else
 655   if test $ac_cv_prog_cc_works = yes; then
 656     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 657                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 658                                 libc_cv_asm_underscores=yes,
 659                                 libc_cv_asm_underscores=no)])
 660   else
 661     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 662                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 663                                             libc_cv_asm_underscores=no)])
 664   fi
 665 fi
 666 if test $libc_cv_asm_underscores = no; then
 667   AC_DEFINE(NO_UNDERSCORES)
 668 fi
 669
 670 if test $elf = yes; then
 671   libc_cv_weak_symbols=yes
 672   libc_cv_asm_weak_directive=yes
 673   libc_cv_asm_weakext_directive=no
 674 else
 675   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 676                  [dnl
 677 cat > conftest.s <<EOF
 678 .text
 679 ${libc_cv_asm_global_directive} foo
 680 foo:
 681 .weak foo
 682 .weak bar; bar = foo
 683 EOF
 684   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 685     libc_cv_asm_weak_directive=yes
 686   else
 687     libc_cv_asm_weak_directive=no
 688   fi
 689   rm -f conftest*])
 690
 691 if test $libc_cv_asm_weak_directive = no; then
 692   AC_CACHE_CHECK(for assembler .weakext directive,
 693                  libc_cv_asm_weakext_directive,
 694                  [dnl
 695 cat > conftest.s <<EOF
 696 .text
 697 ${libc_cv_asm_global_directive} foo
 698 foo:
 699 .weakext foo
 700 .weakext foo, bar
 701 EOF
 702   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 703     libc_cv_asm_weakext_directive=yes
 704   else
 705     libc_cv_asm_weakext_directive=no
 706   fi
 707   rm -f conftest*])
 708
 709   fi # no .weak
 710 fi # not ELF
 711
 712 if test $libc_cv_asm_weak_directive = yes; then
 713   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 714 elif test $libc_cv_asm_weakext_directive = yes; then
 715   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 716 fi
 717
 718 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 719 cat > conftest.c <<\EOF
 720 _start () {}
 721 int __eh_pc;
 722 __throw () {}
 723 EOF
 724 dnl No \ in command here because it ends up inside ''.
 725 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 726                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 727                             -o conftest conftest.c 1>&AC_FD_CC]); then
 728   libc_cv_ld_no_whole_archive=yes
 729 else
 730   libc_cv_ld_no_whole_archive=no
 731 fi
 732 rm -f conftest*])
 733 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 734
 735 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 736 cat > conftest.c <<\EOF
 737 _start () {}
 738 int __eh_pc;
 739 __throw () {}
 740 EOF
 741 dnl No \ in command here because it ends up inside ''.
 742 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 743                             -nostdlib -nostartfiles -fno-exceptions
 744                             -o conftest conftest.c 1>&AC_FD_CC]); then
 745   libc_cv_gcc_no_exceptions=yes
 746 else
 747   libc_cv_gcc_no_exceptions=no
 748 fi
 749 rm -f conftest*])
 750 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 751
 752 ### End of automated tests.
 753 ### Now run sysdeps configure fragments.
 754
 755 # sysdeps configure fragments may set these with files to be linked below.
 756 libc_link_dests=
 757 libc_link_sources=
 758
 759 # Iterate over all the sysdep directories we will use, running their
 760 # configure fragments, and looking for a uname implementation.
 761 uname=
 762 for dir in $sysnames; do
 763   case $dir in
 764     /*) dest=$dir ;;
 765     *)  dest=$srcdir/$dir ;;
 766   esac
 767   if test -r $dest/configure; then
 768     AC_MSG_RESULT(running configure fragment for $dest)
 769     . $dest/configure
 770   fi
 771 [
 772   if test -z "$uname"; then
 773     if test -r $dest/uname.c ||
 774        test -r $dest/uname.S ||
 775        { test -r $dest/syscalls.list &&
 776          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
 777       uname=$dir
 778     fi
 779   fi
 780 ]dnl
 781 done
 782
 783 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 784
 785 # If we will use the generic uname implementation, we must figure out what
 786 # it will say by examining the system, and write the results in config-name.h.
 787 if test "$uname" = "sysdeps/generic"; then
 788
 789 changequote(,)dnl
 790   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 791 changequote([,])dnl
 792   if test $uname_sysname != $config_os; then
 793     config_release=`echo $config_os | sed s/$uname_sysname//`
 794   fi
 795 dnl
 796 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 797     if test -r /vmunix; then
 798       kernel_id=`strings /vmunix | grep UNIX`
 799     elif test -r /dynix; then
 800       kernel_id=`strings /dynix | grep DYNIX`
 801     else
 802       kernel_id=
 803     fi
 804 ])dnl
 805
 806   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 807 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 808 changequote(,)dnl
 809   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 810 changequote([,])dnl
 811   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 812          != x$config_release; then
 813     # The configuration release is a substring of the kernel release.
 814     libc_cv_uname_release=$kernel_release
 815   elif test x$config_release != x; then
 816     libc_cv_uname_release=$config_release
 817   elif test x$kernel_release != x; then
 818     libc_cv_uname_release=$kernel_release
 819   else
 820     libc_cv_uname_release=unknown
 821   fi])
 822   uname_release="$libc_cv_uname_release"
 823
 824   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 825 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 826 changequote(,)dnl
 827   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 828 changequote([,])dnl
 829   if test -n "$kernel_version"; then
 830     libc_cv_uname_version="$kernel_version"
 831   else
 832     libc_cv_uname_version=unknown
 833   fi])
 834   uname_version="$libc_cv_uname_version"
 835
 836 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 837   config_uname=config-name.h:config-name.in
 838 else
 839   # For non-generic uname, we don't need to create config-name.h at all.
 840   config_uname=
 841 fi
 842
 843 AC_MSG_CHECKING(stdio selection)
 844 AC_SUBST(stdio)
 845 case $stdio in
 846 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 847 default) stdio=stdio ;;
 848 esac
 849 AC_MSG_RESULT($stdio)
 850
 851 AC_MSG_CHECKING(ldap selection)
 852 AC_SUBST(LDAP)
 853 case $add_ons in
 854 *ldap*)
 855    ldap=yes
 856    LDAP=ldap ;;
 857 *) ldap=no
 858    LDAP= ;;
 859 esac
 860 AC_MSG_RESULT($ldap)
 861
 862 AC_SUBST(libc_cv_slibdir)
 863 AC_SUBST(libc_cv_sysconfdir)
 864 AC_SUBST(libc_cv_rootsbindir)
 865
 866 AC_SUBST(has_ldconfig)
 867
 868 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 869 if test $gnu_ld = yes; then
 870   AC_DEFINE(HAVE_GNU_LD)
 871 fi
 872 if test $gnu_as = yes; then
 873   AC_DEFINE(HAVE_GNU_AS)
 874 fi
 875 if test $elf = yes; then
 876   AC_DEFINE(HAVE_ELF)
 877 fi
 878
 879 AC_SUBST(shared)
 880 if test $shared = default; then
 881   if test $gnu_ld = yes; then
 882     shared=$elf
 883   else
 884     # For now we do not assume shared libs are available.  In future more
 885     # tests might become available.
 886     shared=no
 887   fi
 888 fi
 889 AC_SUBST(profile)
 890 AC_SUBST(omitfp)
 891 AC_SUBST(bounded)
 892 AC_SUBST(static_nss)
 893 AC_SUBST(nopic_initfini)
 894
 895 AC_SUBST(DEFINES)
 896
 897 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 898   config_makefile=
 899 else
 900   config_makefile=Makefile
 901 fi
 902
 903 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
 904 AC_SUBST(VERSION)
 905
 906 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
 907           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])