configure.in

   1 ###############################################################################
   2 ## Copyright (C) 2000-2004 Sistina Software, Inc. All rights reserved.
   3 ## Copyright (C) 2004-2012 Red Hat, Inc. All rights reserved.
   4 ##
   5 ## This copyrighted material is made available to anyone wishing to use,
   6 ## modify, copy, or redistribute it subject to the terms and conditions
   7 ## of the GNU General Public License v.2.
   8 ##
   9 ## You should have received a copy of the GNU General Public License
  10 ## along with this program; if not, write to the Free Software Foundation,
  11 ## Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  12 ################################################################################
  13
  14 AC_PREREQ(2.61)
  15 ################################################################################
  16 dnl -- Process this file with autoconf to produce a configure script.
  17 AC_INIT
  18 AC_CONFIG_SRCDIR([lib/device/dev-cache.h])
  19 AC_CONFIG_HEADERS([lib/misc/configure.h])
  20
  21 ################################################################################
  22 dnl -- Setup the directory where autoconf has auxilary files
  23 AC_CONFIG_AUX_DIR(autoconf)
  24
  25 ################################################################################
  26 dnl -- Get system type
  27 AC_CANONICAL_TARGET([])
  28
  29 case "$host_os" in
  30         linux*)
  31                 CFLAGS="$CFLAGS"
  32                 COPTIMISE_FLAG="-O2"
  33                 CLDFLAGS="$CLDFLAGS -Wl,--version-script,.export.sym"
  34                 ELDFLAGS="-Wl,--export-dynamic"
  35                 # FIXME Generate list and use --dynamic-list=.dlopen.sym
  36                 CLDWHOLEARCHIVE="-Wl,-whole-archive"
  37                 CLDNOWHOLEARCHIVE="-Wl,-no-whole-archive"
  38                 LDDEPS="$LDDEPS .export.sym"
  39                 LIB_SUFFIX=so
  40                 DEVMAPPER=yes
  41                 LVMETAD=no
  42                 ODIRECT=yes
  43                 DM_IOCTLS=yes
  44                 SELINUX=yes
  45                 CLUSTER=internal
  46                 FSADM=yes
  47                 ;;
  48         darwin*)
  49                 CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
  50                 COPTIMISE_FLAG="-O2"
  51                 CLDFLAGS="$CLDFLAGS"
  52                 ELDFLAGS=
  53                 CLDWHOLEARCHIVE="-all_load"
  54                 CLDNOWHOLEARCHIVE=
  55                 LIB_SUFFIX=dylib
  56                 DEVMAPPER=yes
  57                 ODIRECT=no
  58                 DM_IOCTLS=no
  59                 SELINUX=no
  60                 CLUSTER=none
  61                 FSADM=no
  62                 ;;
  63 esac
  64
  65 VERITYSETUP=no
  66
  67 ################################################################################
  68 dnl -- Checks for programs.
  69 AC_PROG_SED
  70 AC_PROG_AWK
  71 AC_PROG_CC
  72
  73 dnl probably no longer needed in 2008, but...
  74 AC_PROG_GCC_TRADITIONAL
  75 AC_PROG_INSTALL
  76 AC_PROG_LN_S
  77 AC_PROG_MAKE_SET
  78 AC_PROG_MKDIR_P
  79 AC_PROG_RANLIB
  80 AC_PATH_PROG(CFLOW_CMD, cflow)
  81 AC_PATH_PROG(CSCOPE_CMD, cscope)
  82
  83 ################################################################################
  84 dnl -- Check for header files.
  85 AC_HEADER_DIRENT
  86 AC_HEADER_MAJOR
  87 AC_HEADER_STDC
  88 AC_HEADER_SYS_WAIT
  89 AC_HEADER_TIME
  90
  91 AC_CHECK_HEADERS([locale.h stddef.h syslog.h sys/file.h sys/time.h assert.h \
  92   langinfo.h libgen.h signal.h sys/mman.h sys/resource.h sys/utsname.h \
  93   sys/wait.h time.h], ,
  94   [AC_MSG_ERROR(bailing out)])
  95
  96 case "$host_os" in
  97         linux*)
  98                 AC_CHECK_HEADERS(asm/byteorder.h linux/fs.h malloc.h,,AC_MSG_ERROR(bailing out)) ;;
  99         darwin*)
 100                 AC_CHECK_HEADERS(machine/endian.h sys/disk.h,,AC_MSG_ERROR(bailing out)) ;;
 101 esac
 102
 103 AC_CHECK_HEADERS([ctype.h dirent.h errno.h fcntl.h getopt.h inttypes.h limits.h \
 104   stdarg.h stdio.h stdlib.h string.h sys/ioctl.h sys/param.h sys/stat.h \
 105   sys/types.h unistd.h], , [AC_MSG_ERROR(bailing out)])
 106 AC_CHECK_HEADERS(termios.h sys/statvfs.h)
 107
 108 ################################################################################
 109 dnl -- Check for typedefs, structures, and compiler characteristics.
 110 AC_C_CONST
 111 AC_C_INLINE
 112 AC_CHECK_MEMBERS([struct stat.st_rdev])
 113 AC_TYPE_OFF_T
 114 AC_TYPE_PID_T
 115 AC_TYPE_SIGNAL
 116 AC_TYPE_SIZE_T
 117 AC_TYPE_MODE_T
 118 AC_TYPE_INT8_T
 119 AC_TYPE_INT16_T
 120 AC_TYPE_INT32_T
 121 AC_TYPE_INT64_T
 122 AC_TYPE_SSIZE_T
 123 AC_TYPE_UID_T
 124 AC_TYPE_UINT8_T
 125 AC_TYPE_UINT16_T
 126 AC_TYPE_UINT32_T
 127 AC_TYPE_UINT64_T
 128 AC_CHECK_MEMBERS([struct stat.st_rdev])
 129 AC_STRUCT_TM
 130
 131 ################################################################################
 132 dnl -- Check for functions
 133 AC_CHECK_FUNCS([ftruncate gethostname getpagesize \
 134   gettimeofday memset mkdir mkfifo rmdir munmap nl_langinfo setenv setlocale \
 135   strcasecmp strchr strcspn strspn strdup strncasecmp strerror strrchr \
 136   strstr strtol strtoul uname], , [AC_MSG_ERROR(bailing out)])
 137 AC_CHECK_FUNCS(siginterrupt)
 138 AC_FUNC_ALLOCA
 139 AC_FUNC_CLOSEDIR_VOID
 140 AC_FUNC_CHOWN
 141 AC_FUNC_FORK
 142 AC_FUNC_LSTAT
 143 AC_FUNC_MALLOC
 144 AC_FUNC_MEMCMP
 145 AC_FUNC_MMAP
 146 AC_FUNC_REALLOC
 147 AC_FUNC_STAT
 148 AC_FUNC_STRTOD
 149 AC_FUNC_VPRINTF
 150
 151 ################################################################################
 152 dnl -- Enables statically-linked tools
 153 AC_MSG_CHECKING(whether to use static linking)
 154 AC_ARG_ENABLE(static_link,
 155               AC_HELP_STRING([--enable-static_link],
 156                              [use this to link the tools to their libraries
 157                               statically (default is dynamic linking]),
 158               STATIC_LINK=$enableval, STATIC_LINK=no)
 159 AC_MSG_RESULT($STATIC_LINK)
 160
 161 ################################################################################
 162 dnl -- Prefix is /usr by default, the exec_prefix default is setup later
 163 AC_PREFIX_DEFAULT(/usr)
 164
 165 ################################################################################
 166 dnl -- Setup the ownership of the files
 167 AC_MSG_CHECKING(file owner)
 168 AC_ARG_WITH(user,
 169             AC_HELP_STRING([--with-user=USER],
 170                            [set the owner of installed files [[USER=]]]),
 171             OWNER=$withval)
 172 AC_MSG_RESULT($OWNER)
 173
 174 if test x$OWNER != x; then
 175         INSTALL="$INSTALL -o $OWNER"
 176 fi
 177
 178 ################################################################################
 179 dnl -- Setup the group ownership of the files
 180 AC_MSG_CHECKING(group owner)
 181 AC_ARG_WITH(group,
 182             AC_HELP_STRING([--with-group=GROUP],
 183                            [set the group owner of installed files [[GROUP=]]]),
 184             GROUP=$withval)
 185 AC_MSG_RESULT($GROUP)
 186
 187 if test x$GROUP != x; then
 188         INSTALL="$INSTALL -g $GROUP"
 189 fi
 190
 191 ################################################################################
 192 dnl -- Setup device node ownership
 193 AC_MSG_CHECKING(device node uid)
 194
 195 AC_ARG_WITH(device-uid,
 196             AC_HELP_STRING([--with-device-uid=UID],
 197                            [set the owner used for new device nodes [[UID=0]]]),
 198             DM_DEVICE_UID=$withval, DM_DEVICE_UID=0)
 199 AC_MSG_RESULT($DM_DEVICE_UID)
 200
 201 ################################################################################
 202 dnl -- Setup device group ownership
 203 AC_MSG_CHECKING(device node gid)
 204
 205 AC_ARG_WITH(device-gid,
 206             AC_HELP_STRING([--with-device-gid=GID],
 207                            [set the group used for new device nodes [[GID=0]]]),
 208             DM_DEVICE_GID=$withval, DM_DEVICE_GID=0)
 209 AC_MSG_RESULT($DM_DEVICE_GID)
 210
 211 ################################################################################
 212 dnl -- Setup device mode
 213 AC_MSG_CHECKING(device node mode)
 214
 215 AC_ARG_WITH(device-mode,
 216             AC_HELP_STRING([--with-device-mode=MODE],
 217                            [set the mode used for new device nodes [[MODE=0600]]]),
 218             DM_DEVICE_MODE=$withval, DM_DEVICE_MODE=0600)
 219 AC_MSG_RESULT($DM_DEVICE_MODE)
 220
 221 AC_MSG_CHECKING(when to create device nodes)
 222 AC_ARG_WITH(device-nodes-on,
 223             AC_HELP_STRING([--with-device-nodes-on=ON],
 224                            [create nodes on resume or create [[ON=resume]]]),
 225             ADD_NODE=$withval, ADD_NODE=resume)
 226 case "$ADD_NODE" in
 227  resume) add_on=DM_ADD_NODE_ON_RESUME;;
 228  create) add_on=DM_ADD_NODE_ON_CREATE;;
 229  *) AC_MSG_ERROR([--with-device-nodes-on parameter invalid]);;
 230 esac
 231 AC_MSG_RESULT(on $ADD_NODE)
 232 AC_DEFINE_UNQUOTED([DEFAULT_DM_ADD_NODE], $add_on, [Define default node creation behavior with dmsetup create])
 233
 234 AC_MSG_CHECKING(default name mangling)
 235 AC_ARG_WITH(default-name-mangling,
 236             AC_HELP_STRING([--with-default-name-mangling=MANGLING],
 237                            [default name mangling: auto/none/hex [[MANGLING=auto]]]),
 238             MANGLING=$withval, MANGLING=auto)
 239 case "$MANGLING" in
 240  auto) mangling=DM_STRING_MANGLING_AUTO;;
 241  disabled) mangling=DM_STRING_MANGLING_NONE;;
 242  hex) mangling=DM_STRING_MANGLING_HEX;;
 243  *) AC_MSG_ERROR([--with-default-name-mangling parameter invalid]);;
 244 esac
 245 AC_MSG_RESULT($MANGLING)
 246 AC_DEFINE_UNQUOTED([DEFAULT_DM_NAME_MANGLING], $mangling, [Define default name mangling behaviour])
 247
 248 ################################################################################
 249 dnl -- LVM1 tool fallback option
 250 AC_MSG_CHECKING(whether to enable lvm1 fallback)
 251 AC_ARG_ENABLE(lvm1_fallback,
 252               AC_HELP_STRING([--enable-lvm1_fallback],
 253                              [use this to fall back and use LVM1 binaries if
 254                               device-mapper is missing from the kernel]),
 255               LVM1_FALLBACK=$enableval, LVM1_FALLBACK=no)
 256 AC_MSG_RESULT($LVM1_FALLBACK)
 257
 258 if test x$LVM1_FALLBACK = xyes; then
 259         AC_DEFINE([LVM1_FALLBACK], 1, [Define to 1 if 'lvm' should fall back to using LVM1 binaries if device-mapper is missing from the kernel])
 260 fi
 261
 262 ################################################################################
 263 dnl -- format1 inclusion type
 264 AC_MSG_CHECKING(whether to include support for lvm1 metadata)
 265 AC_ARG_WITH(lvm1,
 266             AC_HELP_STRING([--with-lvm1=TYPE],
 267                            [LVM1 metadata support: internal/shared/none
 268                             [[TYPE=internal]]]),
 269             LVM1=$withval, LVM1=internal)
 270 AC_MSG_RESULT($LVM1)
 271
 272 if [[ "x$LVM1" != xnone -a "x$LVM1" != xinternal -a "x$LVM1" != xshared ]];
 273  then  AC_MSG_ERROR(
 274 --with-lvm1 parameter invalid
 275 )
 276 fi;
 277
 278 if test x$LVM1 = xinternal; then
 279         AC_DEFINE([LVM1_INTERNAL], 1, [Define to 1 to include built-in support for LVM1 metadata.])
 280 fi
 281
 282 ################################################################################
 283 dnl -- format_pool inclusion type
 284 AC_MSG_CHECKING(whether to include support for GFS pool metadata)
 285 AC_ARG_WITH(pool,
 286             AC_HELP_STRING([--with-pool=TYPE],
 287                            [GFS pool read-only support: internal/shared/none
 288                             [[TYPE=internal]]]),
 289             POOL=$withval, POOL=internal)
 290 AC_MSG_RESULT($POOL)
 291
 292 if [[ "x$POOL" != xnone -a "x$POOL" != xinternal -a "x$POOL" != xshared ]];
 293  then  AC_MSG_ERROR(
 294 --with-pool parameter invalid
 295 )
 296 fi;
 297
 298 if test x$POOL = xinternal; then
 299         AC_DEFINE([POOL_INTERNAL], 1, [Define to 1 to include built-in support for GFS pool metadata.])
 300 fi
 301
 302 ################################################################################
 303 dnl -- cluster_locking inclusion type
 304 AC_MSG_CHECKING(whether to include support for cluster locking)
 305 AC_ARG_WITH(cluster,
 306             AC_HELP_STRING([--with-cluster=TYPE],
 307                            [cluster LVM locking support: internal/shared/none
 308                             [[TYPE=internal]]]),
 309             CLUSTER=$withval)
 310 AC_MSG_RESULT($CLUSTER)
 311
 312 if [[ "x$CLUSTER" != xnone -a "x$CLUSTER" != xinternal -a "x$CLUSTER" != xshared ]];
 313  then  AC_MSG_ERROR(
 314 --with-cluster parameter invalid
 315 )
 316 fi;
 317
 318 if test x$CLUSTER = xinternal; then
 319         AC_DEFINE([CLUSTER_LOCKING_INTERNAL], 1, [Define to 1 to include built-in support for clustered LVM locking.])
 320 fi
 321
 322 ################################################################################
 323 dnl -- snapshots inclusion type
 324 AC_MSG_CHECKING(whether to include snapshots)
 325 AC_ARG_WITH(snapshots,
 326             AC_HELP_STRING([--with-snapshots=TYPE],
 327                            [snapshot support: internal/shared/none
 328                             [[TYPE=internal]]]),
 329             SNAPSHOTS=$withval, SNAPSHOTS=internal)
 330 AC_MSG_RESULT($SNAPSHOTS)
 331
 332 if [[ "x$SNAPSHOTS" != xnone -a "x$SNAPSHOTS" != xinternal -a "x$SNAPSHOTS" != xshared ]];
 333  then  AC_MSG_ERROR(
 334 --with-snapshots parameter invalid
 335 )
 336 fi;
 337
 338 if test x$SNAPSHOTS = xinternal; then
 339         AC_DEFINE([SNAPSHOT_INTERNAL], 1, [Define to 1 to include built-in support for snapshots.])
 340 fi
 341
 342 ################################################################################
 343 dnl -- mirrors inclusion type
 344 AC_MSG_CHECKING(whether to include mirrors)
 345 AC_ARG_WITH(mirrors,
 346             AC_HELP_STRING([--with-mirrors=TYPE],
 347                            [mirror support: internal/shared/none
 348                             [[TYPE=internal]]]),
 349             MIRRORS=$withval, MIRRORS=internal)
 350 AC_MSG_RESULT($MIRRORS)
 351
 352 if [[ "x$MIRRORS" != xnone -a "x$MIRRORS" != xinternal -a "x$MIRRORS" != xshared ]];
 353  then  AC_MSG_ERROR(
 354 --with-mirrors parameter invalid
 355 )
 356 fi;
 357
 358 if test x$MIRRORS = xinternal; then
 359         AC_DEFINE([MIRRORED_INTERNAL], 1, [Define to 1 to include built-in support for mirrors.])
 360 fi
 361
 362 ################################################################################
 363 dnl -- raid inclusion type
 364 AC_MSG_CHECKING(whether to include raid)
 365 AC_ARG_WITH(raid,
 366             AC_HELP_STRING([--with-raid=TYPE],
 367                            [mirror support: internal/shared/none
 368                             [[TYPE=internal]]]),
 369             RAID=$withval, RAID=internal)
 370 AC_MSG_RESULT($RAID)
 371
 372 if [[ "x$RAID" != xnone -a "x$RAID" != xinternal -a "x$RAID" != xshared ]];
 373  then  AC_MSG_ERROR(
 374 --with-raid parameter invalid
 375 )
 376 fi;
 377
 378 if test x$RAID = xinternal; then
 379         AC_DEFINE([RAID_INTERNAL], 1, [Define to 1 to include built-in support for raid.])
 380 fi
 381
 382 ################################################################################
 383 dnl -- asynchronous volume replicator inclusion type
 384 AC_MSG_CHECKING(whether to include replicators)
 385 AC_ARG_WITH(replicators,
 386             AC_HELP_STRING([--with-replicators=TYPE],
 387                            [replicator support: internal/shared/none
 388                             [[TYPE=none]]]),
 389             REPLICATORS=$withval, REPLICATORS=none)
 390 AC_MSG_RESULT($REPLICATORS)
 391
 392 case "$REPLICATORS" in
 393   none|shared) ;;
 394   internal) AC_DEFINE([REPLICATOR_INTERNAL], 1,
 395                 [Define to 1 to include built-in support for replicators.]) ;;
 396   *) AC_MSG_ERROR([--with-replicators parameter invalid ($REPLICATORS)]) ;;
 397 esac
 398
 399 ################################################################################
 400 dnl -- thin provisioning
 401 AC_MSG_CHECKING(whether to include thin provisioning)
 402 AC_ARG_WITH(thin,
 403             AC_HELP_STRING([--with-thin=TYPE],
 404                            [thin provisioning support: internal/shared/none
 405                             [[TYPE=none]]]),
 406             THIN=$withval, THIN=none)
 407 AC_MSG_RESULT($THIN)
 408
 409 case "$THIN" in
 410   none|shared) ;;
 411   internal) AC_DEFINE([THIN_INTERNAL], 1,
 412                 [Define to 1 to include built-in support for thin provisioning.]) ;;
 413   *) AC_MSG_ERROR([--with-thin parameter invalid ($THIN)]) ;;
 414 esac
 415
 416 case "$THIN" in
 417   internal|shared)
 418         AC_ARG_WITH(thin-check,
 419                 AC_HELP_STRING([--with-thin-check=PATH],
 420                                [thin_check tool: [[autodetect]]]),
 421                                THIN_CHECK_CMD=$withval, THIN_CHECK_CMD="autodetect")
 422         # Empty means a config way to ignore thin checking
 423         if test "$THIN_CHECK_CMD" = "autodetect"; then
 424                 AC_PATH_PROG(THIN_CHECK_CMD, thin_check)
 425                 test -z "$THIN_CHECK_CMD" && AC_MSG_ERROR(thin_check not found in path $PATH)
 426         fi
 427         ;;
 428 esac
 429
 430 AC_DEFINE_UNQUOTED([THIN_CHECK_CMD], ["$THIN_CHECK_CMD"],
 431                    [The path to 'thin_check', if available.])
 432
 433
 434 ################################################################################
 435 dnl -- Disable readline
 436 AC_MSG_CHECKING(whether to enable readline)
 437 AC_ARG_ENABLE([readline],
 438               AC_HELP_STRING([--disable-readline], [disable readline support]),
 439               READLINE=$enableval, READLINE=maybe)
 440 AC_MSG_RESULT($READLINE)
 441
 442 ################################################################################
 443 dnl -- Disable realtime clock support
 444 AC_MSG_CHECKING(whether to enable realtime support)
 445 AC_ARG_ENABLE(realtime,
 446               AC_HELP_STRING([--enable-realtime], [enable realtime clock support]),
 447               REALTIME=$enableval)
 448 AC_MSG_RESULT($REALTIME)
 449
 450 ################################################################################
 451 dnl -- disable OCF resource agents
 452 AC_MSG_CHECKING(whether to enable OCF resource agents)
 453 AC_ARG_ENABLE(ocf,
 454               AC_HELP_STRING([--enable-ocf],
 455                              [enable Open Cluster Framework (OCF) compliant resource agents]),
 456               OCF=$enableval, OCF=no)
 457 AC_MSG_RESULT($OCF)
 458 AC_ARG_WITH(ocfdir,
 459             AC_HELP_STRING([--with-ocfdir=DIR],
 460                            [install OCF files in DIR [[PREFIX/lib/ocf/resource.d/lvm2]]]),
 461             OCFDIR=$withval, OCFDIR='${prefix}/lib/ocf/resource.d/lvm2')
 462
 463 ################################################################################
 464 dnl -- Init pkg-config with dummy invokation:
 465 dnl -- this is required because PKG_CHECK_MODULES macro is expanded
 466 dnl -- to initialize the pkg-config environment only at the first invokation,
 467 dnl -- that would be conditional in this configure.in.
 468 pkg_config_init() {
 469         PKG_CHECK_MODULES(PKGCONFIGINIT, pkgconfiginit, [],
 470                 [AC_MSG_RESULT([pkg-config initialized])])
 471         PKGCONFIG_INIT=1
 472 }
 473
 474 ################################################################################
 475 dnl -- Build cluster LVM daemon
 476 AC_MSG_CHECKING(whether to build cluster LVM daemon)
 477 AC_ARG_WITH(clvmd,
 478   [  --with-clvmd=TYPE       build cluster LVM Daemon
 479                           The following cluster manager combinations are valid:
 480                            * cman                  (RHEL5 or equivalent)
 481                            * cman,corosync,openais (or selection of them)
 482                            * singlenode            (localhost only)
 483                            * all                   (autodetect)
 484                            * none                  (disable build)
 485                           [[TYPE=none]]],
 486             CLVMD=$withval, CLVMD=none)
 487 if test x$CLVMD = xyes; then
 488         CLVMD=all
 489 fi
 490 AC_MSG_RESULT($CLVMD)
 491
 492 dnl -- If clvmd enabled without cluster locking, automagically include it
 493 if  test x$CLVMD != xnone && test x$CLUSTER = xnone; then
 494         CLUSTER=internal
 495 fi
 496
 497 dnl -- init pkgconfig if required
 498 if test x$CLVMD != xnone && test x$PKGCONFIG_INIT != x1; then
 499         pkg_config_init
 500 fi
 501
 502 dnl -- Express clvmd init script Required-Start / Required-Stop
 503 CLVMD_CMANAGERS=""
 504 dnl -- On RHEL4/RHEL5, qdiskd is started from a separate init script.
 505 dnl -- Enable if we are build for cman.
 506 CLVMD_NEEDS_QDISKD=no
 507
 508 dnl -- define build types
 509 if [[ `expr x"$CLVMD" : '.*gulm.*'` != 0 ]]; then
 510         AC_MSG_ERROR([Since version 2.02.87 GULM locking is no longer supported.]);
 511 fi
 512 if [[ `expr x"$CLVMD" : '.*cman.*'` != 0 ]]; then
 513         BUILDCMAN=yes
 514         CLVMD_CMANAGERS="$CLVMD_CMANAGERS cman"
 515         CLVMD_NEEDS_QDISKD=yes
 516 fi
 517 if [[ `expr x"$CLVMD" : '.*corosync.*'` != 0 ]]; then
 518         BUILDCOROSYNC=yes
 519         CLVMD_CMANAGERS="$CLVMD_CMANAGERS corosync"
 520 fi
 521 if [[ `expr x"$CLVMD" : '.*openais.*'` != 0 ]]; then
 522         BUILDOPENAIS=yes
 523         CLVMD_CMANAGERS="$CLVMD_CMANAGERS openais"
 524 fi
 525 if test x$CLVMD_NEEDS_QDISKD != xno; then
 526         CLVMD_CMANAGERS="$CLVMD_CMANAGERS qdiskd"
 527 fi
 528
 529 dnl -- define a soft bailout if we are autodetecting
 530 soft_bailout() {
 531         NOTFOUND=1
 532 }
 533
 534 hard_bailout() {
 535         AC_MSG_ERROR([bailing out])
 536 }
 537
 538 dnl -- if clvmd=all then set soft_bailout (we don't want to error)
 539 dnl -- and set all builds to yes. We need to do this here
 540 dnl -- to skip the openais|corosync sanity check above.
 541 if test x$CLVMD = xall; then
 542         bailout=soft_bailout
 543         BUILDCMAN=yes
 544         BUILDCOROSYNC=yes
 545         BUILDOPENAIS=yes
 546 else
 547         bailout=hard_bailout
 548 fi
 549
 550 dnl -- helper macro to check libs without adding them to LIBS
 551 check_lib_no_libs() {
 552         lib_no_libs_arg1=$1
 553         shift
 554         lib_no_libs_arg2=$1
 555         shift
 556         lib_no_libs_args=$@
 557         AC_CHECK_LIB([$lib_no_libs_arg1],
 558                      [$lib_no_libs_arg2],,
 559                      [$bailout],
 560                      [$lib_no_libs_args])
 561         LIBS=$ac_check_lib_save_LIBS
 562 }
 563
 564 dnl -- Look for cman libraries if required.
 565 if test x$BUILDCMAN = xyes; then
 566         PKG_CHECK_MODULES(CMAN, libcman, [HAVE_CMAN=yes],
 567                 [NOTFOUND=0
 568                 AC_CHECK_HEADERS(libcman.h,,$bailout)
 569                 check_lib_no_libs cman cman_init
 570                 if test $NOTFOUND = 0; then
 571                         AC_MSG_RESULT([no pkg for libcman, using -lcman])
 572                         CMAN_LIBS="-lcman"
 573                         HAVE_CMAN=yes
 574                 fi])
 575         CHECKCONFDB=yes
 576         CHECKDLM=yes
 577 fi
 578
 579 dnl -- Look for corosync that's required also for openais build
 580 dnl -- only enough recent version of corosync ship pkg-config files.
 581 dnl -- We can safely rely on that to detect the correct bits.
 582 if test x$BUILDCOROSYNC = xyes || \
 583    test x$BUILDOPENAIS = xyes; then
 584         PKG_CHECK_MODULES(COROSYNC, corosync, [HAVE_COROSYNC=yes], $bailout)
 585         CHECKCONFDB=yes
 586         CHECKCMAP=yes
 587 fi
 588
 589 dnl -- Look for corosync libraries if required.
 590 if test x$BUILDCOROSYNC = xyes; then
 591         PKG_CHECK_MODULES(QUORUM, libquorum, [HAVE_QUORUM=yes], $bailout)
 592         CHECKCPG=yes
 593         CHECKDLM=yes
 594 fi
 595
 596 dnl -- Look for openais libraries if required.
 597 if test x$BUILDOPENAIS = xyes; then
 598         PKG_CHECK_MODULES(SALCK, libSaLck, [HAVE_SALCK=yes], $bailout)
 599         CHECKCPG=yes
 600 fi
 601
 602 dnl -- Below are checks for libraries common to more than one build.
 603
 604 dnl -- Check confdb library.
 605 dnl -- mandatory for corosync < 2.0 build.
 606 dnl -- optional for openais/cman build.
 607
 608 if test x$CHECKCONFDB = xyes; then
 609         PKG_CHECK_MODULES(CONFDB, libconfdb,
 610                           [HAVE_CONFDB=yes],
 611                           [HAVE_CONFDB=no])
 612
 613         AC_CHECK_HEADERS(corosync/confdb.h,
 614                 [HAVE_CONFDB_H=yes],
 615                 [HAVE_CONFDB_H=no])
 616
 617         if test x$HAVE_CONFDB != xyes && \
 618            test x$HAVE_CONFDB_H = xyes; then
 619                 check_lib_no_libs confdb confdb_initialize
 620                 AC_MSG_RESULT([no pkg for confdb, using -lconfdb])
 621                 CONFDB_LIBS="-lconfdb"
 622                 HAVE_CONFDB=yes
 623         fi
 624 fi
 625
 626 dnl -- Check cmap library
 627 dnl -- mandatory for corosync >= 2.0 build.
 628
 629 if test x$CHECKCMAP = xyes; then
 630         PKG_CHECK_MODULES(CMAP, libcmap,
 631                           [HAVE_CMAP=yes],
 632                           [HAVE_CMAP=no])
 633
 634         AC_CHECK_HEADERS(corosync/cmap.h,
 635                 [HAVE_CMAP_H=yes],
 636                 [HAVE_CMAP_H=no])
 637
 638         if test x$HAVE_CMAP != xyes && \
 639            test x$HAVE_CMAP_H = xyes; then
 640                 check_lib_no_libs cmap cmap_initialize
 641                 AC_MSG_RESULT([no pkg for cmap, using -lcmap])
 642                 CMAP_LIBS="-lcmap"
 643                 HAVE_CMAP=yes
 644         fi
 645 fi
 646
 647 if test x$BUILDCOROSYNC = xyes; then
 648         if test x$HAVE_CMAP != xyes && \
 649            test x$HAVE_CONFDB != xyes && \
 650            test x$CLVMD != xall; then
 651                 AC_MSG_ERROR([bailing out... cmap (corosync >= 2.0) or confdb (corosync < 2.0) library is required])
 652         fi
 653 fi
 654
 655 dnl -- Check cpg library.
 656 if test x$CHECKCPG = xyes; then
 657         PKG_CHECK_MODULES(CPG, libcpg, [HAVE_CPG=yes], $bailout)
 658 fi
 659
 660 dnl -- Check dlm library.
 661 if test x$CHECKDLM = xyes; then
 662         PKG_CHECK_MODULES(DLM, libdlm, [HAVE_DLM=yes],
 663                 [NOTFOUND=0
 664                 AC_CHECK_HEADERS(libdlm.h,,$bailout)
 665                 check_lib_no_libs dlm dlm_lock -lpthread
 666                 if test $NOTFOUND = 0; then
 667                         AC_MSG_RESULT([no pkg for libdlm, using -ldlm])
 668                         DLM_LIBS="-ldlm -lpthread"
 669                         HAVE_DLM=yes
 670                 fi])
 671 fi
 672
 673 dnl -- If we are autodetecting, we need to re-create
 674 dnl -- the depedencies checks and set a proper CLVMD,
 675 dnl -- together with init script Required-Start/Stop entries.
 676 if test x$CLVMD = xall; then
 677         CLVMD=none
 678         CLVMD_CMANAGERS=""
 679         CLVMD_NEEDS_QDISKD=no
 680         if test x$HAVE_CMAN = xyes && \
 681            test x$HAVE_DLM = xyes; then
 682                 AC_MSG_RESULT([Enabling clvmd cman cluster manager])
 683                 CLVMD="$CLVMD,cman"
 684                 CLVMD_CMANAGERS="$CLVMD_CMANAGERS cman"
 685                 CLVMD_NEEDS_QDISKD=yes
 686         fi
 687         if test x$HAVE_COROSYNC = xyes && \
 688            test x$HAVE_QUORUM = xyes && \
 689            test x$HAVE_CPG = xyes && \
 690            test x$HAVE_DLM = xyes; then
 691            if test x$HAVE_CONFDB = xyes || test x$HAVE_CMAP = xyes; then
 692                 AC_MSG_RESULT([Enabling clvmd corosync cluster manager])
 693                 CLVMD="$CLVMD,corosync"
 694                 CLVMD_CMANAGERS="$CLVMD_CMANAGERS corosync"
 695            fi
 696         fi
 697         if test x$HAVE_COROSYNC = xyes && \
 698            test x$HAVE_CPG = xyes && \
 699            test x$HAVE_SALCK = xyes; then
 700                 AC_MSG_RESULT([Enabling clvmd openais cluster manager])
 701                 CLVMD="$CLVMD,openais"
 702                 CLVMD_CMANAGERS="$CLVMD_CMANAGERS openais"
 703         fi
 704         if test x$CLVMD_NEEDS_QDISKD != xno; then
 705                 CLVMD_CMANAGERS="$CLVMD_CMANAGERS qdiskd"
 706         fi
 707         if test x$CLVMD = xnone; then
 708                 AC_MSG_RESULT([Disabling clvmd build. No cluster manager detected.])
 709         fi
 710 fi
 711
 712 dnl -- Fixup CLVMD_CMANAGERS with new corosync
 713 dnl -- clvmd built with corosync >= 2.0 needs dlm (either init or systemd service)
 714 dnl -- to be started.
 715 if [[ `expr x"$CLVMD" : '.*corosync.*'` != 0 ]]; then
 716    if test x$HAVE_CMAP = xyes; then
 717         CLVMD_CMANAGERS="$CLVMD_CMANAGERS dlm"
 718    fi
 719 fi
 720
 721 ################################################################################
 722 dnl -- clvmd pidfile
 723 if test "x$CLVMD" != xnone; then
 724         AC_ARG_WITH(clvmd-pidfile,
 725                     AC_HELP_STRING([--with-clvmd-pidfile=PATH],
 726                                    [clvmd pidfile [[/var/run/clvmd.pid]]]),
 727                     CLVMD_PIDFILE=$withval,
 728                     CLVMD_PIDFILE="/var/run/clvmd.pid")
 729         AC_DEFINE_UNQUOTED(CLVMD_PIDFILE, ["$CLVMD_PIDFILE"],
 730                            [Path to clvmd pidfile.])
 731 fi
 732
 733 ################################################################################
 734 dnl -- Build cluster mirror log daemon
 735 AC_MSG_CHECKING(whether to build cluster mirror log daemon)
 736 AC_ARG_ENABLE(cmirrord,
 737               AC_HELP_STRING([--enable-cmirrord],
 738                              [enable the cluster mirror log daemon]),
 739               CMIRRORD=$enableval, CMIRRORD=no)
 740 AC_MSG_RESULT($CMIRRORD)
 741
 742 BUILD_CMIRRORD=$CMIRRORD
 743
 744 ################################################################################
 745 dnl -- cmirrord pidfile
 746 if test "x$BUILD_CMIRRORD" = xyes; then
 747         AC_ARG_WITH(cmirrord-pidfile,
 748                     AC_HELP_STRING([--with-cmirrord-pidfile=PATH],
 749                                    [cmirrord pidfile [[/var/run/cmirrord.pid]]]),
 750                     CMIRRORD_PIDFILE=$withval,
 751                     CMIRRORD_PIDFILE="/var/run/cmirrord.pid")
 752         AC_DEFINE_UNQUOTED(CMIRRORD_PIDFILE, ["$CMIRRORD_PIDFILE"],
 753                            [Path to cmirrord pidfile.])
 754 fi
 755
 756 ################################################################################
 757 dnl -- Look for corosync libraries if required.
 758 if [[ "x$BUILD_CMIRRORD" = xyes ]]; then
 759         dnl -- init pkgconfig if required
 760         if  test x$PKGCONFIG_INIT != x1; then
 761                 pkg_config_init
 762         fi
 763
 764         AC_DEFINE([CMIRROR_HAS_CHECKPOINT], 1, [Define to 1 to include libSaCkpt.])
 765         PKG_CHECK_MODULES(SACKPT, libSaCkpt, [HAVE_SACKPT=yes],
 766                 [AC_MSG_RESULT([no libSaCkpt, compiling without it])
 767                 AC_DEFINE([CMIRROR_HAS_CHECKPOINT], 0, [Define to 0 to exclude libSaCkpt.])])
 768
 769         if test x$HAVE_CPG != xyes; then
 770                 PKG_CHECK_MODULES(CPG, libcpg)
 771         fi
 772 fi
 773
 774 ################################################################################
 775 dnl -- Enable debugging
 776 AC_MSG_CHECKING(whether to enable debugging)
 777 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [enable debugging]),
 778               DEBUG=$enableval, DEBUG=no)
 779 AC_MSG_RESULT($DEBUG)
 780
 781 dnl -- Normally turn off optimisation for debug builds
 782 if test x$DEBUG = xyes; then
 783         COPTIMISE_FLAG=
 784 else
 785         CSCOPE_CMD=
 786 fi
 787
 788 ################################################################################
 789 dnl -- Override optimisation
 790 AC_MSG_CHECKING(for C optimisation flag)
 791 AC_ARG_WITH(optimisation,
 792             AC_HELP_STRING([--with-optimisation=OPT],
 793                            [C optimisation flag [[OPT=-O2]]]),
 794             COPTIMISE_FLAG=$withval)
 795 AC_MSG_RESULT($COPTIMISE_FLAG)
 796
 797 ################################################################################
 798 dnl -- Enable profiling
 799 AC_MSG_CHECKING(whether to gather gcov profiling data)
 800 AC_ARG_ENABLE(profiling,
 801               AC_HELP_STRING(--enable-profiling, [gather gcov profiling data]),
 802               PROFILING=$enableval, PROFILING=no)
 803 AC_MSG_RESULT($PROFILING)
 804
 805 if test "x$PROFILING" = xyes; then
 806   COPTIMISE_FLAG="$COPTIMISE_FLAG -fprofile-arcs -ftest-coverage"
 807   AC_PATH_PROG(LCOV, lcov)
 808   AC_PATH_PROG(GENHTML, genhtml)
 809   if test -z "$LCOV" -o -z "$GENHTML"; then
 810     AC_MSG_ERROR([lcov and genhtml are required for profiling])
 811   fi
 812   AC_PATH_PROG(GENPNG, genpng)
 813   if test -n "$GENPNG"; then
 814     AC_MSG_CHECKING([whether $GENPNG has all required modules])
 815     if $GENPNG --help > /dev/null 2>&1 ; then
 816       AC_MSG_RESULT(ok)
 817       GENHTML="$GENHTML --frames"
 818     else
 819       AC_MSG_RESULT(not supported)
 820       AC_MSG_WARN([GD.pm perl module is not installed])
 821       GENPNG=
 822     fi
 823   fi
 824 fi
 825
 826 ################################################################################
 827 dnl -- Enable testing
 828 AC_MSG_CHECKING(whether to enable unit testing)
 829 AC_ARG_ENABLE(testing,
 830               AC_HELP_STRING(--enable-testing, [enable testing targets in the makefile]),
 831               TESTING=$enableval, TESTING=no)
 832 AC_MSG_RESULT($TESTING)
 833
 834 if test "$TESTING" = yes; then
 835         PKG_CHECK_MODULES(CUNIT, cunit >= 2.0)
 836 fi
 837
 838 ################################################################################
 839 dnl -- Enable valgrind awareness of memory pools
 840 AC_MSG_CHECKING(whether to enable valgrind awareness of pools)
 841 AC_ARG_ENABLE(valgrind_pool,
 842               AC_HELP_STRING(--enable-valgrind-pool, [enable valgrind awareness of pools]),
 843               VALGRIND_POOL=$enableval, VALGRIND_POOL=no)
 844 AC_MSG_RESULT($VALGRIND_POOL)
 845
 846 if test "$VALGRIND_POOL" = yes; then
 847     AC_CHECK_HEADERS([valgrind/memcheck.h], , [AC_MSG_ERROR(bailing out)])
 848     AC_DEFINE([VALGRIND_POOL], 1, [Enable a valgrind aware build of pool])
 849 fi
 850
 851 ################################################################################
 852 dnl -- Disable devmapper
 853 AC_MSG_CHECKING(whether to use device-mapper)
 854 AC_ARG_ENABLE(devmapper,
 855               AC_HELP_STRING([--disable-devmapper],
 856                              [disable LVM2 device-mapper interaction]),
 857               DEVMAPPER=$enableval)
 858 AC_MSG_RESULT($DEVMAPPER)
 859
 860 if test x$DEVMAPPER = xyes; then
 861         AC_DEFINE([DEVMAPPER_SUPPORT], 1, [Define to 1 to enable LVM2 device-mapper interaction.])
 862 fi
 863
 864 ################################################################################
 865 dnl -- Build lvmetad
 866 AC_MSG_CHECKING(whether to build LVMetaD)
 867 AC_ARG_ENABLE(lvmetad,
 868               AC_HELP_STRING([--enable-lvmetad],
 869                              [enable the LVM Metadata Daemon]),
 870               LVMETAD=$enableval)
 871 AC_MSG_RESULT($LVMETAD)
 872
 873 BUILD_LVMETAD=$LVMETAD
 874
 875 if test x$BUILD_LVMETAD = xyes; then
 876         AC_DEFINE([LVMETAD_SUPPORT], 1, [Define to 1 to include code that uses lvmetad.])
 877 fi
 878
 879 ################################################################################
 880 dnl -- Enable udev synchronisation
 881 AC_MSG_CHECKING(whether to enable synchronisation with udev processing)
 882 AC_ARG_ENABLE(udev_sync,
 883               AC_HELP_STRING([--enable-udev_sync],
 884                              [enable synchronisation with udev processing]),
 885               UDEV_SYNC=$enableval, UDEV_SYNC=no)
 886 AC_MSG_RESULT($UDEV_SYNC)
 887
 888 if test x$UDEV_SYNC = xyes; then
 889         dnl -- init pkgconfig if required
 890         if  test x$PKGCONFIG_INIT != x1; then
 891                 pkg_config_init
 892         fi
 893         PKG_CHECK_MODULES(UDEV, libudev >= 143, [UDEV_PC="libudev"])
 894         AC_DEFINE([UDEV_SYNC_SUPPORT], 1, [Define to 1 to enable synchronisation with udev processing.])
 895 fi
 896
 897 dnl -- Enable udev rules
 898 AC_MSG_CHECKING(whether to enable installation of udev rules required for synchronisation)
 899 AC_ARG_ENABLE(udev_rules,
 900               AC_HELP_STRING([--enable-udev_rules],
 901                              [install rule files needed for udev synchronisation]),
 902               UDEV_RULES=$enableval, UDEV_RULES=$UDEV_SYNC)
 903 AC_MSG_RESULT($UDEV_RULES)
 904
 905 if test x$UDEV_RULES = xyes; then
 906         AC_MSG_CHECKING(whether udev supports builtin blkid)
 907         udev_version=$(udevadm info --version 2>/dev/null)
 908         if test -n "$udev_version" && test "$udev_version" -ge 176; then
 909                 UDEV_HAS_BUILTIN_BLKID=yes
 910         else
 911                 UDEV_HAS_BUILTIN_BLKID=no
 912         fi
 913         AC_MSG_RESULT($UDEV_HAS_BUILTIN_BLKID)
 914 fi
 915
 916 ################################################################################
 917 dnl -- Compatibility mode
 918 AC_ARG_ENABLE(compat,
 919               AC_HELP_STRING([--enable-compat],
 920                              [enable support for old device-mapper versions]),
 921               DM_COMPAT=$enableval, DM_COMPAT=no)
 922
 923 if test x$DM_COMPAT = xyes; then
 924         AC_MSG_ERROR(
 925                  [--enable-compat is not currently supported.
 926 Since device-mapper version 1.02.66, only one version (4) of the device-mapper
 927 ioctl protocol is supported.]
 928         )
 929 fi
 930
 931 ################################################################################
 932 dnl -- Compatible units suffix mode
 933 AC_ARG_ENABLE(units-compat,
 934               AC_HELP_STRING([--enable-units-compat],
 935                              [enable output compatibility with old versions that
 936                               that do not use KiB-style unit suffixes]),
 937               UNITS_COMPAT=$enableval, UNITS_COMPAT=no)
 938
 939 if test x$UNITS_COMPAT = xyes; then
 940         AC_DEFINE([DEFAULT_SI_UNIT_CONSISTENCY], 0, [Define to 0 to reinstate the pre-2.02.54 handling of unit suffixes.])
 941 fi
 942
 943 ################################################################################
 944 dnl -- Disable ioctl
 945 AC_ARG_ENABLE(ioctl,
 946               AC_HELP_STRING([--disable-driver],
 947                              [disable calls to device-mapper in the kernel]),
 948               DM_IOCTLS=$enableval)
 949
 950 ################################################################################
 951 dnl -- Disable O_DIRECT
 952 AC_MSG_CHECKING(whether to enable O_DIRECT)
 953 AC_ARG_ENABLE(o_direct,
 954               AC_HELP_STRING([--disable-o_direct], [disable O_DIRECT]),
 955               ODIRECT=$enableval)
 956 AC_MSG_RESULT($ODIRECT)
 957
 958 if test x$ODIRECT = xyes; then
 959         AC_DEFINE([O_DIRECT_SUPPORT], 1, [Define to 1 to enable O_DIRECT support.])
 960 fi
 961
 962 ################################################################################
 963 dnl -- Enable liblvm2app.so
 964 AC_MSG_CHECKING(whether to build liblvm2app.so application library)
 965 AC_ARG_ENABLE(applib,
 966               AC_HELP_STRING([--enable-applib], [build application library]),
 967               APPLIB=$enableval, APPLIB=no)
 968 AC_MSG_RESULT($APPLIB)
 969 AC_SUBST([LVM2APP_LIB])
 970 test x$APPLIB = xyes \
 971   && LVM2APP_LIB=-llvm2app \
 972   || LVM2APP_LIB=
 973
 974 ################################################################################
 975 dnl -- Enable cmdlib
 976 AC_MSG_CHECKING(whether to compile liblvm2cmd.so)
 977 AC_ARG_ENABLE(cmdlib,
 978               AC_HELP_STRING([--enable-cmdlib], [build shared command library]),
 979               CMDLIB=$enableval, CMDLIB=no)
 980 AC_MSG_RESULT($CMDLIB)
 981 AC_SUBST([LVM2CMD_LIB])
 982 test x$CMDLIB = xyes \
 983   && LVM2CMD_LIB=-llvm2cmd \
 984   || LVM2CMD_LIB=
 985
 986 ################################################################################
 987 dnl -- Enable pkg-config
 988 AC_ARG_ENABLE(pkgconfig,
 989               AC_HELP_STRING([--enable-pkgconfig], [install pkgconfig support]),
 990               PKGCONFIG=$enableval, PKGCONFIG=no)
 991
 992 ################################################################################
 993 dnl -- Enable installation of writable files by user
 994 AC_ARG_ENABLE(write_install,
 995               AC_HELP_STRING([--enable-write_install],
 996                              [install user writable files]),
 997               WRITE_INSTALL=$enableval, WRITE_INSTALL=no)
 998
 999 ################################################################################
1000 dnl -- Enable fsadm
1001 AC_MSG_CHECKING(whether to install fsadm)
1002 AC_ARG_ENABLE(fsadm, AC_HELP_STRING([--disable-fsadm], [disable fsadm]),
1003               FSADM=$enableval)
1004 AC_MSG_RESULT($FSADM)
1005
1006 ################################################################################
1007 dnl -- enable dmeventd handling
1008 AC_MSG_CHECKING(whether to use dmeventd)
1009 AC_ARG_ENABLE(dmeventd, AC_HELP_STRING([--enable-dmeventd],
1010                                        [enable the device-mapper event daemon]),
1011               DMEVENTD=$enableval)
1012 AC_MSG_RESULT($DMEVENTD)
1013
1014 BUILD_DMEVENTD=$DMEVENTD
1015
1016 dnl -- dmeventd currently requires internal mirror support
1017 if test x$DMEVENTD = xyes; then
1018    if test x$MIRRORS != xinternal; then
1019       AC_MSG_ERROR(
1020         --enable-dmeventd currently requires --with-mirrors=internal
1021       )
1022    fi
1023    if test x$CMDLIB = xno; then
1024       AC_MSG_ERROR(
1025         --enable-dmeventd requires --enable-cmdlib to be used as well
1026       )
1027    fi
1028 fi
1029
1030 if test x$DMEVENTD = xyes; then
1031         AC_DEFINE([DMEVENTD], 1, [Define to 1 to enable the device-mapper event daemon.])
1032 fi
1033
1034 ################################################################################
1035 dnl -- enable veritysetup
1036 AC_MSG_CHECKING(whether to install veritysetup)
1037 AC_ARG_WITH(veritysetup, AC_HELP_STRING([--with-veritysetup=TYPE], [build veritysetup using openssl/nss/gcrypt]),
1038               VERITYSETUP=$withval)
1039 AC_MSG_RESULT($VERITYSETUP)
1040
1041 if test x$VERITYSETUP != xno -a x$VERITYSETUP != x; then
1042         if test x$PKGCONFIG_INIT != x1; then
1043                 pkg_config_init
1044         fi
1045
1046         dnl Test OPENSSL
1047         if test -z "$VERITYSETUP_CFLAGS" && test x$VERITYSETUP = xyes -o x$VERITYSETUP = xopenssl; then
1048                 PKG_CHECK_MODULES(OPENSSL, openssl, [
1049                         AC_DEFINE([CRYPT_OPENSSL], 1, [Define to 1 if OpenSSL encryption is to be used.])
1050                         VERITYSETUP_CFLAGS="$OPENSSL_CFLAGS"
1051                         VERITYSETUP_LIBS="`echo "$OPENSSL_LIBS" | sed 's/-lssl\>//'`"
1052                 ], [
1053                         AC_CHECK_LIB(crypto, EVP_get_digestbyname, [
1054                                 AC_CHECK_HEADER(openssl/evp.h, [
1055                                         AC_DEFINE([CRYPT_OPENSSL], 1, [Define to 1 if OpenSSL encryption is to be used.])
1056                                         VERITYSETUP_CFLAGS=
1057                                         VERITYSETUP_LIBS="-lcrypto"
1058                                 ])
1059                         ])
1060                 ])
1061         fi
1062
1063         dnl Test NSS
1064         if test -z "$VERITYSETUP_CFLAGS" && test x$VERITYSETUP = xyes -o x$VERITYSETUP = xnss; then
1065                 PKG_CHECK_MODULES(NSS, nss, [
1066                         AC_DEFINE([CRYPT_NSS], 1, [Define to 1 if nss encryption is to be used.])
1067                         VERITYSETUP_CFLAGS="$NSS_CFLAGS"
1068                         VERITYSETUP_LIBS="`echo "$NSS_LIBS" | sed 's/-lsmime3\>//' | sed 's/-lssl3\>//'`"
1069                 ], true)
1070         fi
1071
1072         dnl Test GCRYPT
1073         if test -z "$VERITYSETUP_CFLAGS" && test x$VERITYSETUP = xyes -o x$VERITYSETUP = xgcrypt; then
1074                 AC_CHECK_LIB(gcrypt, gcry_md_map_name, [
1075                         AC_CHECK_HEADER(gcrypt.h, [
1076                                 AC_DEFINE([CRYPT_GCRYPT], 1, [Define to 1 if gcrpyt encryption is to be used.])
1077                                 VERITYSETUP_CFLAGS=
1078                                 VERITYSETUP_LIBS="-lgcrypt"
1079                         ])
1080                 ])
1081         fi
1082
1083         if test -z "$VERITYSETUP_LIBS"; then
1084                 AC_MSG_ERROR(No cryptographic library for veritysetup found)
1085         fi
1086         AC_CHECK_LIB(popt, poptGetContext, true, [
1087                 AC_MSG_ERROR(popt library was not found)
1088         ])
1089         AC_CHECK_HEADER(popt.h, true, [
1090                 AC_MSG_ERROR(popt.h was not found)
1091         ])
1092         VERITYSETUP_LIBS="$VERITYSETUP_LIBS -lpopt"
1093         AC_SUBST(VERITYSETUP_CFLAGS)
1094         AC_SUBST(VERITYSETUP_LIBS)
1095         VERITYSETUP=yes
1096 fi
1097 AC_SUBST(VERITYSETUP)
1098
1099 ################################################################################
1100 dnl -- getline included in recent libc
1101
1102 AC_CHECK_LIB(c, getline, AC_DEFINE([HAVE_GETLINE], 1,
1103   [Define to 1 if getline is available.]))
1104
1105 ################################################################################
1106 dnl -- canonicalize_file_name included in recent libc
1107
1108 AC_CHECK_LIB(c, canonicalize_file_name,
1109   AC_DEFINE([HAVE_CANONICALIZE_FILE_NAME], 1,
1110     [Define to 1 if canonicalize_file_name is available.]))
1111
1112 ################################################################################
1113 dnl -- Clear default exec_prefix - install into /sbin rather than /usr/sbin
1114 if [[ "x$exec_prefix" = xNONE -a "x$prefix" = xNONE ]];
1115  then  exec_prefix="";
1116 fi;
1117
1118 ################################################################################
1119 dnl -- Check for dlopen
1120 AC_CHECK_LIB(dl, dlopen, [
1121         AC_DEFINE([HAVE_LIBDL], 1, [Define to 1 if dynamic libraries are available.])
1122         DL_LIBS="-ldl"
1123         HAVE_LIBDL=yes ], [
1124         DL_LIBS=
1125         HAVE_LIBDL=no ])
1126
1127 ################################################################################
1128 dnl -- Check for shared/static conflicts
1129 if [[ \( "x$LVM1" = xshared -o "x$POOL" = xshared -o "x$CLUSTER" = xshared \
1130       -o "x$SNAPSHOTS" = xshared -o "x$MIRRORS" = xshared \
1131       -o "x$RAID" = xshared \
1132       \) -a "x$STATIC_LINK" = xyes ]];
1133  then  AC_MSG_ERROR(
1134 Features cannot be 'shared' when building statically
1135 )
1136 fi
1137
1138 ################################################################################
1139 if [[ "$DMEVENTD" = yes -o "$CLVMD" != none ]] ; then
1140         AC_CHECK_LIB([pthread], [pthread_mutex_lock],
1141                 [PTHREAD_LIBS="-lpthread"], hard_bailout)
1142 fi
1143
1144 ################################################################################
1145 dnl -- Disable selinux
1146 AC_MSG_CHECKING(whether to enable selinux support)
1147 AC_ARG_ENABLE(selinux,
1148               AC_HELP_STRING([--disable-selinux], [disable selinux support]),
1149               SELINUX=$enableval)
1150 AC_MSG_RESULT($SELINUX)
1151
1152 ################################################################################
1153 dnl -- Check for selinux
1154 if test x$SELINUX = xyes; then
1155         AC_CHECK_LIB([sepol], [sepol_check_context], [
1156                 AC_DEFINE([HAVE_SEPOL], 1, [Define to 1 if sepol_check_context is available.])
1157                 SELINUX_LIBS="-lsepol"])
1158
1159         AC_CHECK_LIB([selinux], [is_selinux_enabled], [
1160                 AC_CHECK_HEADERS([selinux/selinux.h],, hard_bailout)
1161                 AC_CHECK_HEADERS([selinux/label.h])
1162                 AC_DEFINE([HAVE_SELINUX], 1, [Define to 1 to include support for selinux.])
1163                 SELINUX_LIBS="-lselinux $SELINUX_LIBS"
1164                 SELINUX_PC="libselinux"
1165                 HAVE_SELINUX=yes ], [
1166                 AC_MSG_WARN(Disabling selinux)
1167                 SELINUX_LIBS=
1168                 SELINUX_PC=
1169                 HAVE_SELINUX=no ])
1170 fi
1171
1172 ################################################################################
1173 dnl -- Check for realtime clock support
1174 if test x$REALTIME = xyes; then
1175         AC_CHECK_LIB(rt, clock_gettime, HAVE_REALTIME=yes, HAVE_REALTIME=no)
1176
1177         if test x$HAVE_REALTIME = xyes; then
1178                 AC_DEFINE([HAVE_REALTIME], 1, [Define to 1 to include support for realtime clock.])
1179                 LIBS="-lrt $LIBS"
1180         else
1181                 AC_MSG_WARN(Disabling realtime clock)
1182         fi
1183 fi
1184
1185 ################################################################################
1186 dnl -- Check for getopt
1187 AC_CHECK_HEADERS(getopt.h, AC_DEFINE([HAVE_GETOPTLONG], 1, [Define to 1 if getopt_long is available.]))
1188
1189 ################################################################################
1190 dnl -- Check for readline (Shamelessly copied from parted 1.4.17)
1191 if test x$READLINE != xno; then
1192         lvm_saved_libs=$LIBS
1193         AC_SEARCH_LIBS([tgetent], [tinfo ncurses curses termcap termlib],
1194                 READLINE_LIBS=$ac_cv_search_tgetent, [
1195                 if test "$READLINE" = yes; then
1196                         AC_MSG_ERROR(
1197 [termcap could not be found which is required for the
1198 --enable-readline option (which is enabled by default).  Either disable readline
1199 support with --disable-readline or download and install termcap from:
1200         ftp.gnu.org/gnu/termcap
1201 Note: if you are using precompiled packages you will also need the development
1202   package as well (which may be called termcap-devel or something similar).
1203 Note: (n)curses also seems to work as a substitute for termcap.  This was
1204   not found either - but you could try installing that as well.])
1205                 fi])
1206         dnl -- Old systems may need extra termcap dependency explicitly in LIBS
1207         AC_CHECK_LIB([readline], [readline], [
1208                 AC_DEFINE([READLINE_SUPPORT], 1,
1209                         [Define to 1 to include the LVM readline shell.])
1210                 dnl -- Try only with -lreadline and check for different symbol
1211                 LIBS=$lvm_saved_libs
1212                 AC_CHECK_LIB([readline], [rl_line_buffer],
1213                         [ READLINE_LIBS="-lreadline" ], [
1214                           AC_MSG_RESULT([linking -lreadline with $READLINE_LIBS needed])
1215                           READLINE_LIBS="-lreadline $READLINE_LIBS"
1216                         ]) ], [
1217                 READLINE_LIBS=
1218                 if test "$READLINE" = yes; then
1219                         AC_MSG_ERROR(
1220 [GNU Readline could not be found which is required for the
1221 --enable-readline option (which is enabled by default).  Either disable readline
1222 support with --disable-readline or download and install readline from:
1223         ftp.gnu.org/gnu/readline
1224 Note: if you are using precompiled packages you will also need the development
1225 package as well (which may be called readline-devel or something similar).])
1226                 fi ])
1227         LIBS="$READLINE_LIBS $lvm_saved_libs"
1228         AC_CHECK_FUNCS([rl_completion_matches])
1229         LIBS=$lvm_saved_libs
1230 fi
1231
1232 ################################################################################
1233 dnl -- Internationalisation stuff
1234 AC_MSG_CHECKING(whether to enable internationalisation)
1235 AC_ARG_ENABLE(nls,
1236               AC_HELP_STRING([--enable-nls], [enable Native Language Support]),
1237               INTL=$enableval, INTL=no)
1238 AC_MSG_RESULT($INTL)
1239
1240 if test x$INTL = xyes; then
1241 # FIXME - Move this - can be device-mapper too
1242         INTL_PACKAGE="lvm2"
1243         AC_PATH_PROG(MSGFMT, msgfmt)
1244         if [[ "x$MSGFMT" == x ]];
1245                 then  AC_MSG_ERROR(
1246                 msgfmt not found in path $PATH
1247                 )
1248         fi;
1249
1250         AC_ARG_WITH(localedir,
1251                     AC_HELP_STRING([--with-localedir=DIR],
1252                                    [translation files in DIR
1253                                     [[PREFIX/share/locale]]]),
1254                     LOCALEDIR=$withval, LOCALEDIR='${prefix}/share/locale')
1255 fi
1256
1257 ################################################################################
1258 AC_ARG_WITH(confdir,
1259             AC_HELP_STRING([--with-confdir=DIR],
1260                            [configuration files in DIR [[/etc]]]),
1261             CONFDIR=$withval, CONFDIR="/etc")
1262
1263 AC_ARG_WITH(staticdir,
1264             AC_HELP_STRING([--with-staticdir=DIR],
1265                            [static binaries in DIR [[EPREFIX/sbin]]]),
1266             STATICDIR=$withval, STATICDIR='${exec_prefix}/sbin')
1267
1268 AC_ARG_WITH(usrlibdir,
1269             AC_HELP_STRING([--with-usrlibdir=DIR],
1270                            [usrlib in DIR [[PREFIX/lib]]]),
1271             usrlibdir=$withval, usrlibdir='${prefix}/lib')
1272
1273 AC_ARG_WITH(usrsbindir,
1274             AC_HELP_STRING([--with-usrsbindir=DIR],
1275                            [usrsbin executables in DIR [[PREFIX/sbin]]]),
1276             usrsbindir=$withval, usrsbindir='${prefix}/sbin')
1277
1278 ################################################################################
1279 AC_ARG_WITH(udev_prefix,
1280             AC_HELP_STRING([--with-udev-prefix=UPREFIX],
1281                            [install udev rule files in UPREFIX [[EPREFIX]]]),
1282             udev_prefix=$withval, udev_prefix='${exec_prefix}')
1283
1284 AC_ARG_WITH(udevdir,
1285             AC_HELP_STRING([--with-udevdir=DIR],
1286                            [udev rules in DIR [[UPREFIX/lib/udev/rules.d]]]),
1287             udevdir=$withval, udevdir='${udev_prefix}/lib/udev/rules.d')
1288
1289 ################################################################################
1290 dnl -- Get the systemd system unit dir value from pkg_config automatically if value not given explicitly.
1291 dnl -- This follows the recommendation for systemd integration best practices mentioned in daemon(7) manpage.
1292 AC_ARG_WITH(systemdsystemunitdir,
1293             AC_HELP_STRING([--with-systemdsystemunitdir=DIR],
1294                            [systemd service files in DIR]),
1295             systemdsystemunitdir=$withval,
1296             pkg_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd))
1297
1298 if test -n "$pkg_systemdsystemunitdir"; then
1299             systemdsystemunitdir=$pkg_systemdsystemunitdir;
1300 fi
1301
1302 if test -z "$systemdsystemunitdir"; then
1303             systemdsystemunitdir='/lib/systemd/system';
1304 fi
1305 ################################################################################
1306 AC_ARG_WITH(tmpfilesdir,
1307             AC_HELP_STRING([--with-tmpfilesdir=DIR],
1308                            [install configuration files for management of volatile files and directories in DIR [[SYSCONFDIR/tmpfiles.d]]]),
1309                            tmpfilesdir=$withval, tmpfilesdir='${sysconfdir}/tmpfiles.d')
1310 ################################################################################
1311 dnl -- Ensure additional headers required
1312 if test x$READLINE = xyes; then
1313         AC_CHECK_HEADERS(readline/readline.h readline/history.h,,AC_MSG_ERROR(bailing out))
1314 fi
1315
1316 if test x$CLVMD != xnone; then
1317         AC_CHECK_HEADERS(mntent.h netdb.h netinet/in.h pthread.h search.h sys/mount.h sys/socket.h sys/uio.h sys/un.h utmpx.h,,AC_MSG_ERROR(bailing out))
1318         AC_CHECK_FUNCS(dup2 getmntent memmove select socket,,AC_MSG_ERROR(bailing out))
1319         AC_FUNC_GETMNTENT
1320         AC_FUNC_SELECT_ARGTYPES
1321 fi
1322
1323 if test x$CLUSTER != xnone; then
1324         AC_CHECK_HEADERS(sys/socket.h sys/un.h,,AC_MSG_ERROR(bailing out))
1325         AC_CHECK_FUNCS(socket,,AC_MSG_ERROR(bailing out))
1326 fi
1327
1328 if test x$DMEVENTD = xyes; then
1329         AC_CHECK_HEADERS(arpa/inet.h,,AC_MSG_ERROR(bailing out))
1330 fi
1331
1332 if test x$HAVE_LIBDL = xyes; then
1333         AC_CHECK_HEADERS(dlfcn.h,,AC_MSG_ERROR(bailing out))
1334 fi
1335
1336 if test x$INTL = xyes; then
1337         AC_CHECK_HEADERS(libintl.h,,AC_MSG_ERROR(bailing out))
1338 fi
1339
1340 if test x$UDEV_SYNC = xyes; then
1341         AC_CHECK_HEADERS(sys/ipc.h sys/sem.h,,AC_MSG_ERROR(bailing out))
1342 fi
1343
1344 ################################################################################
1345 AC_PATH_PROG(MODPROBE_CMD, modprobe)
1346
1347 if test x$MODPROBE_CMD != x; then
1348         AC_DEFINE_UNQUOTED([MODPROBE_CMD], ["$MODPROBE_CMD"], [The path to 'modprobe', if available.])
1349 fi
1350
1351
1352 lvm_exec_prefix=$exec_prefix
1353 test "$lvm_exec_prefix" = NONE && lvm_exec_prefix=$prefix
1354 test "$lvm_exec_prefix" = NONE && lvm_exec_prefix=$ac_default_prefix
1355 LVM_PATH="$lvm_exec_prefix/sbin/lvm"
1356 AC_DEFINE_UNQUOTED(LVM_PATH, ["$LVM_PATH"], [Path to lvm binary.])
1357
1358 if  test "$CLVMD" != none; then
1359         clvmd_prefix=$ac_default_prefix
1360         CLVMD_PATH="$clvmd_prefix/sbin/clvmd"
1361         test "$prefix" != NONE && clvmd_prefix=$prefix
1362         AC_DEFINE_UNQUOTED(CLVMD_PATH, ["$CLVMD_PATH"], [Path to clvmd binary.])
1363 fi
1364
1365 ################################################################################
1366 dnl -- dmeventd pidfile and executable path
1367 if test "$BUILD_DMEVENTD" = yes; then
1368         AC_ARG_WITH(dmeventd-pidfile,
1369                     AC_HELP_STRING([--with-dmeventd-pidfile=PATH],
1370                                    [dmeventd pidfile [[/var/run/dmeventd.pid]]]),
1371                     DMEVENTD_PIDFILE=$withval,
1372                     DMEVENTD_PIDFILE="/var/run/dmeventd.pid")
1373         AC_DEFINE_UNQUOTED(DMEVENTD_PIDFILE, ["$DMEVENTD_PIDFILE"],
1374                            [Path to dmeventd pidfile.])
1375 fi
1376
1377 if test "$BUILD_DMEVENTD" = yes; then
1378         AC_ARG_WITH(dmeventd-path,
1379                     AC_HELP_STRING([--with-dmeventd-path=PATH],
1380                                    [dmeventd path [[EPREFIX/sbin/dmeventd]]]),
1381                     DMEVENTD_PATH=$withval,
1382                     DMEVENTD_PATH="$lvm_exec_prefix/sbin/dmeventd")
1383         AC_DEFINE_UNQUOTED(DMEVENTD_PATH, ["$DMEVENTD_PATH"],
1384                            [Path to dmeventd binary.])
1385 fi
1386
1387 AH_TEMPLATE(DEFAULT_RUN_DIR, [Name of default run directory.])
1388 AC_ARG_WITH(default-run-dir,
1389             [  --with-default-run-dir=DIR       Default run directory [[/var/run/lvm]] ],
1390             [ DEFAULT_RUN_DIR="$withval" ],
1391             [ DEFAULT_RUN_DIR="/var/run/lvm" ])
1392 AC_DEFINE_UNQUOTED(DEFAULT_RUN_DIR,["$DEFAULT_RUN_DIR"] )
1393
1394 ################################################################################
1395 dnl -- various defaults
1396 AC_ARG_WITH(default-system-dir,
1397             AC_HELP_STRING([--with-default-system-dir=DIR],
1398                            [default LVM system directory [[/etc/lvm]]]),
1399             DEFAULT_SYS_DIR=$withval, DEFAULT_SYS_DIR="/etc/lvm")
1400 AC_DEFINE_UNQUOTED(DEFAULT_SYS_DIR, ["$DEFAULT_SYS_DIR"],
1401                    [Path to LVM system directory.])
1402
1403 AC_ARG_WITH(default-archive-subdir,
1404             AC_HELP_STRING([--with-default-archive-subdir=SUBDIR],
1405                            [default metadata archive subdir [[archive]]]),
1406             DEFAULT_ARCHIVE_SUBDIR=$withval, DEFAULT_ARCHIVE_SUBDIR=archive)
1407 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_SUBDIR, ["$DEFAULT_ARCHIVE_SUBDIR"],
1408                    [Name of default metadata archive subdirectory.])
1409
1410 AC_ARG_WITH(default-backup-subdir,
1411             AC_HELP_STRING([--with-default-backup-subdir=SUBDIR],
1412                            [default metadata backup subdir [[backup]]]),
1413             DEFAULT_BACKUP_SUBDIR=$withval, DEFAULT_BACKUP_SUBDIR=backup)
1414 AC_DEFINE_UNQUOTED(DEFAULT_BACKUP_SUBDIR, ["$DEFAULT_BACKUP_SUBDIR"],
1415                    [Name of default metadata backup subdirectory.])
1416
1417 AC_ARG_WITH(default-cache-subdir,
1418             AC_HELP_STRING([--with-default-cache-subdir=SUBDIR],
1419                            [default metadata cache subdir [[cache]]]),
1420             DEFAULT_CACHE_SUBDIR=$withval, DEFAULT_CACHE_SUBDIR=cache)
1421 AC_DEFINE_UNQUOTED(DEFAULT_CACHE_SUBDIR, ["$DEFAULT_CACHE_SUBDIR"],
1422                    [Name of default metadata cache subdirectory.])
1423
1424 AC_ARG_WITH(default-locking-dir,
1425             AC_HELP_STRING([--with-default-locking-dir=DIR],
1426                            [default locking directory [[/var/lock/lvm]]]),
1427             DEFAULT_LOCK_DIR=$withval, DEFAULT_LOCK_DIR="/var/lock/lvm")
1428 AC_DEFINE_UNQUOTED(DEFAULT_LOCK_DIR, ["$DEFAULT_LOCK_DIR"],
1429                    [Name of default locking directory.])
1430
1431 ################################################################################
1432 dnl -- Setup default data alignment
1433 AC_ARG_WITH(default-data-alignment,
1434             AC_HELP_STRING([--with-default-data-alignment=NUM],
1435                            [set the default data alignment in MiB [[1]]]),
1436             DEFAULT_DATA_ALIGNMENT=$withval, DEFAULT_DATA_ALIGNMENT=1)
1437 AC_DEFINE_UNQUOTED(DEFAULT_DATA_ALIGNMENT, [$DEFAULT_DATA_ALIGNMENT],
1438                    [Default data alignment.])
1439
1440 ################################################################################
1441 dnl -- which kernel interface to use (ioctl only)
1442 AC_MSG_CHECKING(for kernel interface choice)
1443 AC_ARG_WITH(interface,
1444             AC_HELP_STRING([--with-interface=IFACE],
1445                            [choose kernel interface (ioctl) [[ioctl]]]),
1446             interface=$withval, interface=ioctl)
1447 if [[ "x$interface" != xioctl ]];
1448 then
1449   AC_MSG_ERROR(--with-interface=ioctl required. fs no longer supported.)
1450 fi
1451 AC_MSG_RESULT($interface)
1452
1453 ################################################################################
1454 DM_LIB_VERSION="\"`cat "$srcdir"/VERSION_DM 2>/dev/null || echo Unknown`\""
1455 AC_DEFINE_UNQUOTED(DM_LIB_VERSION, $DM_LIB_VERSION, [Library version])
1456
1457 DM_LIB_PATCHLEVEL=`cat "$srcdir"/VERSION_DM | $AWK -F '[[-. ]]' '{printf "%s.%s.%s",$1,$2,$3}'`
1458
1459 LVM_VERSION="\"`cat "$srcdir"/VERSION 2>/dev/null || echo Unknown`\""
1460
1461 VER=`cat "$srcdir"/VERSION`
1462 LVM_RELEASE_DATE="\"`echo $VER | $SED 's/.* (//;s/).*//'`\""
1463 VER=`echo "$VER" | $AWK '{print $1}'`
1464 LVM_RELEASE="\"`echo "$VER" | $AWK -F '-' '{print $2}'`\""
1465 VER=`echo "$VER" | $AWK -F '-' '{print $1}'`
1466 LVM_MAJOR=`echo "$VER" | $AWK -F '.' '{print $1}'`
1467 LVM_MINOR=`echo "$VER" | $AWK -F '.' '{print $2}'`
1468 LVM_PATCHLEVEL=`echo "$VER" | $AWK -F '[[(.]]' '{print $3}'`
1469 LVM_LIBAPI=`echo "$VER" | $AWK -F '[[()]]' '{print $2}'`
1470
1471 ################################################################################
1472 AC_SUBST(APPLIB)
1473 AC_SUBST(AWK)
1474 AC_SUBST(BUILD_CMIRRORD)
1475 AC_SUBST(BUILD_DMEVENTD)
1476 AC_SUBST(BUILD_LVMETAD)
1477 AC_SUBST(CFLAGS)
1478 AC_SUBST(CFLOW_CMD)
1479 AC_SUBST(CLDFLAGS)
1480 AC_SUBST(CLDNOWHOLEARCHIVE)
1481 AC_SUBST(CLDWHOLEARCHIVE)
1482 AC_SUBST(CLUSTER)
1483 AC_SUBST(CLVMD)
1484 AC_SUBST(CLVMD_CMANAGERS)
1485 AC_SUBST(CLVMD_PATH)
1486 AC_SUBST(CMAN_CFLAGS)
1487 AC_SUBST(CMAN_LIBS)
1488 AC_SUBST(CMAP_CFLAGS)
1489 AC_SUBST(CMAP_LIBS)
1490 AC_SUBST(CMDLIB)
1491 AC_SUBST(CONFDB_CFLAGS)
1492 AC_SUBST(CONFDB_LIBS)
1493 AC_SUBST(CONFDIR)
1494 AC_SUBST(COPTIMISE_FLAG)
1495 AC_SUBST(CPG_CFLAGS)
1496 AC_SUBST(CPG_LIBS)
1497 AC_SUBST(CSCOPE_CMD)
1498 AC_SUBST(DEBUG)
1499 AC_SUBST(DEFAULT_SYS_DIR)
1500 AC_SUBST(DEFAULT_ARCHIVE_SUBDIR)
1501 AC_SUBST(DEFAULT_BACKUP_SUBDIR)
1502 AC_SUBST(DEFAULT_CACHE_SUBDIR)
1503 AC_SUBST(DEFAULT_DATA_ALIGNMENT)
1504 AC_SUBST(DEFAULT_LOCK_DIR)
1505 AC_SUBST(DEFAULT_RUN_DIR)
1506 AC_SUBST(DEVMAPPER)
1507 AC_SUBST(DLM_CFLAGS)
1508 AC_SUBST(DLM_LIBS)
1509 AC_SUBST(DL_LIBS)
1510 AC_SUBST(DMEVENTD)
1511 AC_SUBST(DMEVENTD_PATH)
1512 AC_SUBST(DM_COMPAT)
1513 AC_SUBST(DM_DEVICE_GID)
1514 AC_SUBST(DM_DEVICE_MODE)
1515 AC_SUBST(DM_DEVICE_UID)
1516 AC_SUBST(DM_IOCTLS)
1517 AC_SUBST(DM_LIB_VERSION)
1518 AC_SUBST(DM_LIB_PATCHLEVEL)
1519 AC_SUBST(ELDFLAGS)
1520 AC_SUBST(FSADM)
1521 AC_SUBST(HAVE_LIBDL)
1522 AC_SUBST(HAVE_REALTIME)
1523 AC_SUBST(INTL)
1524 AC_SUBST(INTL_PACKAGE)
1525 AC_SUBST(JOBS)
1526 AC_SUBST(LDDEPS)
1527 AC_SUBST(LIBS)
1528 AC_SUBST(LIB_SUFFIX)
1529 AC_SUBST(LOCALEDIR)
1530 AC_SUBST(LVM1)
1531 AC_SUBST(LVM1_FALLBACK)
1532 AC_SUBST(LVM_VERSION)
1533 AC_SUBST(LVM_LIBAPI)
1534 AC_SUBST(LVM_MAJOR)
1535 AC_SUBST(LVM_MINOR)
1536 AC_SUBST(LVM_PATCHLEVEL)
1537 AC_SUBST(LVM_PATH)
1538 AC_SUBST(LVM_RELEASE)
1539 AC_SUBST(LVM_RELEASE_DATE)
1540 AC_SUBST(MIRRORS)
1541 AC_SUBST(MSGFMT)
1542 AC_SUBST(OCF)
1543 AC_SUBST(OCFDIR)
1544 AC_SUBST(PKGCONFIG)
1545 AC_SUBST(POOL)
1546 AC_SUBST(PTHREAD_LIBS)
1547 AC_SUBST(QUORUM_CFLAGS)
1548 AC_SUBST(QUORUM_LIBS)
1549 AC_SUBST(RAID)
1550 AC_SUBST(READLINE_LIBS)
1551 AC_SUBST(REPLICATORS)
1552 AC_SUBST(SACKPT_CFLAGS)
1553 AC_SUBST(SACKPT_LIBS)
1554 AC_SUBST(SALCK_CFLAGS)
1555 AC_SUBST(SALCK_LIBS)
1556 AC_SUBST(SELINUX_LIBS)
1557 AC_SUBST(SELINUX_PC)
1558 AC_SUBST(SNAPSHOTS)
1559 AC_SUBST(STATICDIR)
1560 AC_SUBST(STATIC_LINK)
1561 AC_SUBST(TESTING)
1562 AC_SUBST(THIN)
1563 AC_SUBST(THIN_CHECK_CMD)
1564 AC_SUBST(UDEV_LIBS)
1565 AC_SUBST(UDEV_PC)
1566 AC_SUBST(UDEV_RULES)
1567 AC_SUBST(UDEV_SYNC)
1568 AC_SUBST(UDEV_HAS_BUILTIN_BLKID)
1569 AC_SUBST(CUNIT_LIBS)
1570 AC_SUBST(CUNIT_CFLAGS)
1571 AC_SUBST(WRITE_INSTALL)
1572 AC_SUBST(DMEVENTD_PIDFILE)
1573 AC_SUBST(interface)
1574 AC_SUBST(kerneldir)
1575 AC_SUBST(missingkernel)
1576 AC_SUBST(kernelvsn)
1577 AC_SUBST(tmpdir)
1578 AC_SUBST(udev_prefix)
1579 AC_SUBST(udevdir)
1580 AC_SUBST(systemdsystemunitdir)
1581 AC_SUBST(tmpfilesdir)
1582 AC_SUBST(usrlibdir)
1583 AC_SUBST(usrsbindir)
1584
1585 ################################################################################
1586 dnl -- First and last lines should not contain files to generate in order to
1587 dnl -- keep utility scripts running properly
1588 AC_CONFIG_FILES([
1589 Makefile
1590 make.tmpl
1591 daemons/Makefile
1592 daemons/clvmd/Makefile
1593 daemons/cmirrord/Makefile
1594 daemons/dmeventd/Makefile
1595 daemons/dmeventd/libdevmapper-event.pc
1596 daemons/dmeventd/plugins/Makefile
1597 daemons/dmeventd/plugins/lvm2/Makefile
1598 daemons/dmeventd/plugins/raid/Makefile
1599 daemons/dmeventd/plugins/mirror/Makefile
1600 daemons/dmeventd/plugins/snapshot/Makefile
1601 daemons/dmeventd/plugins/thin/Makefile
1602 daemons/lvmetad/Makefile
1603 doc/Makefile
1604 doc/example.conf
1605 include/.symlinks
1606 include/Makefile
1607 lib/Makefile
1608 lib/format1/Makefile
1609 lib/format_pool/Makefile
1610 lib/locking/Makefile
1611 lib/mirror/Makefile
1612 lib/replicator/Makefile
1613 lib/misc/lvm-version.h
1614 lib/raid/Makefile
1615 lib/snapshot/Makefile
1616 lib/thin/Makefile
1617 libdaemon/Makefile
1618 libdaemon/client/Makefile
1619 libdaemon/server/Makefile
1620 libdm/Makefile
1621 libdm/libdevmapper.pc
1622 liblvm/Makefile
1623 liblvm/liblvm2app.pc
1624 man/Makefile
1625 po/Makefile
1626 scripts/clvmd_init_red_hat
1627 scripts/cmirrord_init_red_hat
1628 scripts/lvm2_lvmetad_init_red_hat
1629 scripts/lvm2_lvmetad_systemd_red_hat.socket
1630 scripts/lvm2_lvmetad_systemd_red_hat.service
1631 scripts/lvm2_monitoring_init_red_hat
1632 scripts/dm_event_systemd_red_hat.service
1633 scripts/lvm2_monitoring_systemd_red_hat.service
1634 scripts/lvm2_tmpfiles_red_hat.conf
1635 scripts/Makefile
1636 test/Makefile
1637 test/api/Makefile
1638 test/unit/Makefile
1639 tools/Makefile
1640 udev/Makefile
1641 unit-tests/datastruct/Makefile
1642 unit-tests/regex/Makefile
1643 unit-tests/mm/Makefile
1644 verity/Makefile
1645 ])
1646 AC_OUTPUT
1647
1648 if test x$ODIRECT != xyes; then
1649   AC_MSG_WARN(Warning: O_DIRECT disabled: low-memory pvmove may lock up)
1650 fi