configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  36 AC_ARG_WITH(gd, dnl
  37   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  38             [dnl
  39 case "$with_gd" in
  40 yes|''|no) ;;
  41 *) libgd_include="-I$withval/include"
  42    libgd_ldflags="-L$withval/lib" ;;
  43 esac
  44 ])
  45 AC_ARG_WITH(gd-include, dnl
  46   --with-gd-include=DIR   find libgd include files in DIR,
  47             [dnl
  48 case "$with_gd_include" in
  49 ''|no) ;;
  50 *) libgd_include="-I$withval" ;;
  51 esac
  52 ])
  53 AC_ARG_WITH(gd-lib, dnl
  54   --with-gd-lib=DIR       find libgd library files in DIR,
  55             [dnl
  56 case "$with_gd_lib" in
  57 ''|no) ;;
  58 *) libgd_ldflags="-L$withval" ;;
  59 esac
  60 ])
  61
  62 if test -n "$libgd_include"; then
  63   config_vars="$config_vars
  64 CFLAGS-memprofstat.c = $libgd_include"
  65 fi
  66 if test -n "$libgd_ldflags"; then
  67   config_vars="$config_vars
  68 libgd-LDFLAGS = $libgd_ldflags"
  69 fi
  70
  71 dnl Arguments to specify presence of other packages/features.
  72 AC_ARG_WITH(fp, dnl
  73 [  --with-fp              if using floating-point hardware [default=yes]],
  74             with_fp=$withval, with_fp=yes)
  75 AC_ARG_WITH(binutils, dnl
  76   --with-binutils=PATH    specify location of binutils (as and ld),
  77             path_binutils=$withval, path_binutils='')
  78 AC_ARG_WITH(elf, dnl
  79   --with-elf              if using the ELF object format,
  80             elf=$withval, elf=no)
  81 AC_ARG_WITH(cvs, dnl
  82 [  --without-cvs          if CVS should not be used],
  83             with_cvs=$withval, with_cvs=yes)
  84 AC_SUBST(with_cvs)
  85
  86 AC_ARG_WITH(headers, dnl
  87 [  --with-headers=PATH     location of system headers to use
  88                           [e.g. /usr/src/linux/include]
  89                           [default=compiler default]],
  90             sysheaders=$withval, sysheaders='')
  91
  92 AC_ARG_ENABLE(libio, dnl
  93 [  --enable-libio          build in GNU libio instead of GNU stdio],
  94               [if test $enableval = yes; then
  95                  stdio=libio
  96                else
  97                  stdio=stdio
  98                fi],
  99               stdio=default)
 100
 101 AC_ARG_ENABLE(sanity-checks, dnl
 102 [  --disable-sanity-checks really do not use threads (should not be used
 103                           except in special situations) [default=yes]],
 104               enable_sanity=$enableval, enable_sanity=yes)
 105
 106 dnl Arguments to enable or disable building the static, shared, profiled,
 107 dnl and -fomit-frame-pointer libraries.
 108 dnl I've disabled this for now since we cannot build glibc without static
 109 dnl libraries built in the moment.
 110 dnl AC_ARG_ENABLE(static, dnl
 111 dnl [  --enable-static         build static library [default=yes]],
 112 dnl           static=$enableval, static=yes)
 113 static=yes
 114 AC_ARG_ENABLE(shared, dnl
 115 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 116               shared=$enableval, shared=default)
 117 AC_ARG_ENABLE(profile, dnl
 118 [  --enable-profile        build profiled library [default=yes]],
 119               profile=$enableval, profile=yes)
 120 AC_ARG_ENABLE(omitfp, dnl
 121 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 122               omitfp=$enableval, omitfp=no)
 123 AC_ARG_ENABLE(bounded, dnl
 124 [  --enable-bounded        build with runtime bounds checking [default=no]],
 125               bounded=$enableval, bounded=no)
 126 AC_ARG_ENABLE(versioning, dnl
 127 [  --disable-versioning    do not include versioning information in the
 128                           library objects [default=yes if supported]],
 129              enable_versioning=$enableval, enable_versioning=yes)
 130
 131 dnl Generic infrastructure for drop-in additions to libc.
 132 AC_ARG_ENABLE(add-ons, dnl
 133 [  --enable-add-ons[=DIR1,DIR2]...
 134                           configure and build add-ons in DIR1,DIR2,...
 135                           search for add-ons if no parameter given],
 136   [case "$enableval" in
 137     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 138          test "$add_ons" = "*" && add_ons= ;;
 139     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 140    esac],
 141   [add_ons=])
 142
 143 AC_CONFIG_SUBDIRS($add_ons)
 144 add_ons_pfx=
 145 if test x"$add_ons" != x; then
 146   for f in $add_ons; do
 147     # Test whether such a subdir really exists.
 148     if test -d $srcdir/$f; then
 149       add_ons_pfx="$add_ons_pfx $f/"
 150     else
 151       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 152     fi
 153   done
 154 fi
 155
 156 dnl On some platforms we cannot use dynamic loading.  We must provide
 157 dnl static NSS modules.
 158 AC_ARG_ENABLE(static-nss, dnl
 159 [  --enable-static-nss     build static NSS modules [default=no]],
 160               static_nss=$enableval, static_nss=no)
 161 if test x"$static_nss" = xyes; then
 162   AC_DEFINE(DO_STATIC_NSS)
 163 fi
 164
 165 AC_ARG_ENABLE(force-install,
 166 [  --disable-force-install don't force installation of files from this package,
 167                           even if they are older than the installed files],
 168               force_install=$enableval, force_install=yes)
 169 AC_SUBST(force_install)
 170
 171 dnl On some platforms we allow dropping compatibility with all kernel
 172 dnl versions.
 173 AC_ARG_ENABLE(kernel,
 174 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 175                            than VERSION],
 176               minimum_kernel=$enableval)
 177 dnl Prevent unreasonable values.
 178 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 179   # Better nothing than this.
 180   minimum_kernel=""
 181 else
 182   if test "$minimum_kernel" = current; then
 183     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 184   fi
 185 fi
 186
 187 AC_CANONICAL_HOST
 188
 189 # The way shlib-versions is used to generate soversions.mk uses a
 190 # fairly simplistic model for name recognition that can't distinguish
 191 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 192 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 193 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 194 case "$host_os" in
 195 linux*)
 196   ;;
 197 gnu*)
 198   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 199   ;;
 200 esac
 201
 202 # We keep the original values in `$config_*' and never modify them, so we
 203 # can write them unchanged into config.make.  Everything else uses
 204 # $machine, $vendor, and $os, and changes them whenever convenient.
 205 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 206
 207 # Some configurations imply other options.
 208 case "$host_os" in
 209 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 210   # These systems always use GNU tools.
 211   gnu_ld=yes gnu_as=yes ;;
 212 esac
 213 case "$host_os" in
 214 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 215 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 216   ;;
 217 gnu* | linux* | sysv4* | solaris2* | irix6*)
 218   # These systems (almost) always use the ELF format.
 219   elf=yes
 220   ;;
 221 esac
 222
 223 machine=$config_machine
 224 vendor=$config_vendor
 225 os=$config_os
 226
 227 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 228 # Unify this here.
 229 if test "$machine" = rs6000; then
 230   machine="powerpc"
 231 fi
 232
 233 ###
 234 ### I put this here to prevent those annoying emails from people who cannot
 235 ### read and try to compile glibc on unsupported platforms.  --drepper
 236 ###
 237 ### By using the undocumented --enable-hacker-mode option for configure
 238 ### one can skip this test to make the configuration not fail for unsupported
 239 ### platforms.
 240 ###
 241 if test -z "$enable_hacker_mode"; then
 242   case "$machine-$host_os" in
 243   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 244     ;;
 245   *)
 246     echo "*** The GNU C library is currently not available for this platform."
 247     echo "*** So far nobody cared to port it and if there is no volunteer it"
 248     echo "*** might never happen.  So, if you have interest to see glibc on"
 249     echo "*** this platform visit"
 250     echo "***   http://www.gnu.org/software/libc/porting.html"
 251     echo "*** and join the group of porters"
 252     exit 1
 253     ;;
 254   esac
 255 fi
 256
 257 dnl We need to use [ and ] for other purposes for a while now.
 258 changequote(,)dnl
 259 # Expand the configuration machine name into a subdirectory by architecture
 260 # type and particular chip.
 261 case "$machine" in
 262 a29k | am29000) base_machine=a29k machine=a29k ;;
 263 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 264 arm*)           base_machine=arm machine=arm/$machine ;;
 265 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 266 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 267 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 268 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 269 ia64)           base_machine=ia64 machine=ia64 ;;
 270 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 271 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 272 m88???)         base_machine=m88k machine=m88k/$machine ;;
 273 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 274 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 275 mips*)          base_machine=mips
 276                 case "`uname -m`" in
 277                 IP22) machine=mips/mips3 ;;
 278                 *)    machine=mips/$machine ;;
 279                 esac ;;
 280 sh3*)           base_machine=sh machine=sh/sh3 ;;
 281 sh4*)           base_machine=sh machine=sh/sh4 ;;
 282 sparc | sparcv[67])
 283                 base_machine=sparc machine=sparc/sparc32 ;;
 284 sparcv8 | supersparc | hypersparc)
 285                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 286 sparcv8plus | sparcv8plusa | sparcv9)
 287                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 288 sparc64 | ultrasparc)
 289                 base_machine=sparc machine=sparc/sparc64 ;;
 290 esac
 291 changequote([,])dnl
 292 AC_SUBST(base_machine)
 293
 294 if test "$base_machine" = "i386"; then
 295   AC_DEFINE(USE_REGPARMS)
 296 fi
 297
 298 # Compute the list of sysdep directories for this configuration.
 299 # This can take a while to compute.
 300 sysdep_dir=$srcdir/sysdeps
 301 AC_MSG_CHECKING(sysdep dirs)
 302 dnl We need to use [ and ] for other purposes for a while now.
 303 changequote(,)dnl
 304 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 305 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 306
 307 case "$os" in
 308 gnu*)
 309   base_os=mach/hurd ;;
 310 netbsd* | 386bsd* | freebsd* | bsdi*)
 311   base_os=unix/bsd/bsd4.4 ;;
 312 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 313   base_os=unix/bsd ;;
 314 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 315   base_os=unix/sysv ;;
 316 irix6*)
 317   base_os=unix/sysv/irix6/$os ;;
 318 solaris[2-9]*)
 319   base_os=unix/sysv/sysv4 ;;
 320 hpux*)
 321   base_os=unix/sysv/hpux/$os ;;
 322 aix4.3*)
 323   base_os=unix/sysv/aix/aix4.3 ;;
 324 none)
 325   base_os=standalone ;;
 326 *)
 327   base_os='' ;;
 328 esac
 329
 330 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 331 tail=$os
 332 ostry=$os
 333 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 334   ostry="$ostry /$o"
 335   tail=$o
 336 done
 337 o=`echo $tail | sed 's/[0-9]*$//'`
 338 if test $o != $tail; then
 339   ostry="$ostry /$o"
 340 fi
 341 # For linux-gnu, try linux-gnu, then linux.
 342 o=`echo $tail | sed 's/-.*$//'`
 343 if test $o != $tail; then
 344   ostry="$ostry /$o"
 345 fi
 346
 347 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 348 base=
 349 tail=$base_os
 350 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 351   set $b
 352   base="$base /$1"
 353   tail="$2"
 354 done
 355
 356 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 357 mach=
 358 tail=$machine
 359 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 360   set $m
 361   # Prepend the machine's FPU directory unless --without-fp.
 362   if test "$with_fp" = yes; then
 363     mach="$mach /$1/fpu"
 364   fi
 365   mach="$mach /$1"
 366   tail="$2"
 367 done
 368
 369 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 370 changequote([,])dnl
 371
 372 # Find what sysdep directories exist.
 373 sysnames=
 374 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 375 for d in $add_ons_pfx ''; do
 376   for b in $base ''; do
 377     for m0 in $mach ''; do
 378       for v in /$vendor ''; do
 379         test "$v" = / && continue
 380         for o in /$ostry ''; do
 381           test "$o" = / && continue
 382           for m in $mach ''; do
 383             if test "$m0$b$v$o$m"; then
 384               try="${d}sysdeps$m0$b$v$o$m"
 385               test -n "$enable_debug_configure" &&
 386               echo "$0 [DEBUG]: try $try" >&2
 387               if test -d $srcdir/$try; then
 388                 sysnames="$sysnames $try"
 389                 { test -n "$o" || test -n "$b"; } && os_used=t
 390                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 391               fi
 392             fi
 393           done
 394         done
 395       done
 396     done
 397   done
 398 done
 399 IFS="$ac_save_ifs"
 400
 401 if test -z "$os_used" && test "$os" != none; then
 402   AC_MSG_ERROR(Operating system $os is not supported.)
 403 fi
 404 if test -z "$machine_used" && test "$machine" != none; then
 405   AC_MSG_ERROR(The $machine is not supported.)
 406 fi
 407
 408 # We have now validated the configuration.
 409
 410
 411 # If using ELF, look for an `elf' subdirectory of each machine directory.
 412 # We prepend these rather than inserting them whereever the machine appears
 413 # because things specified by the machine's ELF ABI should override
 414 # OS-specific things, and should always be the same for any OS on the
 415 # machine (otherwise what's the point of an ABI?).
 416 if test "$elf" = yes; then
 417   elf_dirs=
 418   for d in $add_ons_pfx ''; do
 419     for m in $mach; do
 420       if test -d $srcdir/${d}sysdeps$m/elf; then
 421         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 422       fi
 423     done
 424   done
 425   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 426 fi
 427
 428
 429 # Expand the list of system names into a full list of directories
 430 # from each element's parent name and Implies file (if present).
 431 set $sysnames
 432 names=
 433 while test $# -gt 0; do
 434   name=$1
 435   shift
 436
 437   case " $names " in *" $name "*)
 438     # Already in the list.
 439     continue
 440   esac
 441
 442   # Report each name as we discover it, so there is no long pause in output.
 443   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 444
 445   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 446
 447   case $name in
 448     /*) xsrcdir= ;;
 449     *)  xsrcdir=$srcdir/ ;;
 450   esac
 451   test -n "$enable_debug_configure" &&
 452   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 453
 454   if test -f $xsrcdir$name/Implies; then
 455     # Collect more names from the `Implies' file (removing comments).
 456     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 457     implied=
 458     for x in $implied_candidate; do
 459       if test -d $xsrcdir$name_base/$x; then
 460         implied="$implied $name_base/$x";
 461       else
 462         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 463       fi
 464     done
 465   else
 466     implied=
 467   fi
 468
 469   # Add NAME to the list of names.
 470   names="$names $name"
 471
 472   # Find the parent of NAME, using the empty string if it has none.
 473 changequote(,)dnl
 474   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 475 changequote([,])dnl
 476
 477   # Add the names implied by NAME, and NAME's parent (if it has one), to
 478   # the list of names to be processed (the argument list).  We prepend the
 479   # implied names to the list and append the parent.  We want implied
 480   # directories to come before further directories inferred from the
 481   # configuration components; this ensures that for sysv4, unix/common
 482   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 483   # after sysv4).
 484   sysnames="`echo $implied $* $parent`"
 485   test -n "$sysnames" && set $sysnames
 486 done
 487
 488 # Add the default directories.
 489 default_sysnames=sysdeps/generic
 490 if test "$elf" = yes; then
 491   default_sysnames="sysdeps/generic/elf $default_sysnames"
 492 fi
 493 sysnames="$names $default_sysnames"
 494 AC_SUBST(sysnames)
 495 # The other names were emitted during the scan.
 496 AC_MSG_RESULT($default_sysnames)
 497
 498
 499 ### Locate tools.
 500
 501 AC_PROG_INSTALL
 502 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 503   # The makefiles need to use a different form to find it in $srcdir.
 504   INSTALL='\$(..)./scripts/install-sh -c'
 505 fi
 506 AC_PROG_LN_S
 507
 508 # These programs are version sensitive.
 509 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 510 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 511   [version \([egcygnustpi-]*[0-9.]*\)],
 512   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]|sgicc-*],
 513   critic_missing=t)
 514 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 515   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 516   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 517
 518 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 519   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 520   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 521 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 522   [GNU texinfo.* \([0-9][0-9.]*\)],
 523   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 524 AC_CHECK_PROG_VER(SED, gsed sed, --version,
 525   [GNU sed version \([0-9]*\.[0-9.]*\)],
 526   [3.0[2-9]|3.[1-9]*|[4-9]*], SED=: aux_missing=t)
 527
 528 if test -n "$critic_missing"; then
 529 AC_MSG_ERROR([
 530 *** Some critical program is missing or too old.
 531 *** Check the INSTALL file for required versions.])
 532 fi
 533
 534 test -n "$aux_missing" && AC_MSG_WARN([
 535 *** An auxiliary program is missing or too old;
 536 *** some features will be disabled.
 537 *** Check the INSTALL file for required versions.])
 538
 539 # glibcbug.in wants to know the compiler version.
 540 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 541 AC_SUBST(CCVERSION)
 542
 543 AC_PROG_CC_LOCAL
 544 AC_CANONICAL_BUILD
 545 if test $host != $build; then
 546   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 547 fi
 548 AC_SUBST(cross_compiling)
 549 AC_PROG_CPP
 550 LIBC_PROG_BINUTILS
 551 AC_CHECK_TOOL(MIG, mig)
 552
 553 # if using special system headers, find out the compiler's sekrit
 554 # header directory and add that to the list.  NOTE: Only does the right
 555 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 556 if test -n "$sysheaders"; then
 557   ccheaders=`$CC -print-file-name=include`
 558   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 559 fi
 560 AC_SUBST(SYSINCLUDES)
 561
 562 # check if ranlib is necessary
 563 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 564 cat > conftest.c <<EOF
 565 int a;
 566 char b;
 567 void c(void) {}
 568 EOF
 569 $CC $CFLAGS -c conftest.c
 570 $AR cr conftest.a conftest.c
 571 cp conftest.a conftest2.a
 572 $RANLIB conftest.a
 573 if cmp -s conftest.a conftest2.a; then
 574   libc_cv_ranlib_necessary=no
 575 else
 576   libc_cv_ranlib_necessary=yes
 577 fi
 578 rm -rf conftest*])
 579 if test "$libc_cv_ranlib_necessary" = no; then
 580  RANLIB=:
 581 fi
 582
 583 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 584 # since this would lead to problems installing/building glibc.
 585 # LD_LIBRARY_PATH contains the current directory if one of the following
 586 # is true:
 587 # - one of the terminals (":" and ";") is the first or last sign
 588 # - two terminals occur directly after each other
 589 # - the path contains an element with a dot in it
 590 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 591 changequote(,)dnl
 592 case ${LD_LIBRARY_PATH} in
 593   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 594     ld_library_path_setting="contains current directory"
 595     ;;
 596   *)
 597     ld_library_path_setting="ok"
 598     ;;
 599 esac
 600 changequote([,])dnl
 601 AC_MSG_RESULT($ld_library_path_setting)
 602 if test "$ld_library_path_setting" != "ok"; then
 603 AC_MSG_ERROR([
 604 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 605 *** building glibc. Please change the environment variable
 606 *** and run configure again.])
 607 fi
 608
 609 AC_PATH_PROG(BASH, bash, no)
 610 if test "$BASH" != no &&
 611    $BASH -c 'test "$BASH_VERSINFO" \
 612              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 613   libc_cv_have_bash2=yes
 614 else
 615   libc_cv_have_bash2=no
 616 fi
 617 AC_SUBST(libc_cv_have_bash2)
 618
 619 dnl We need a ksh compatible shell for tzselect.
 620 if test "$BASH" = no; then
 621   AC_PATH_PROG(KSH, ksh, no)
 622   if test "$KSH" = no; then
 623     libc_cv_have_ksh=no
 624   else
 625     libc_cv_have_ksh=yes
 626   fi
 627 else
 628   KSH="$BASH"
 629   AC_SUBST(KSH)
 630   libc_cv_have_ksh=yes
 631 fi
 632 AC_SUBST(libc_cv_have_ksh)
 633
 634 AC_PROG_AWK
 635 AC_PATH_PROG(PERL, perl, no)
 636 if test "$PERL" != no &&
 637    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
 638   PERL=no
 639 fi
 640 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 641              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 642 if test "$INSTALL_INFO" != "no"; then
 643 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 644  [mkdir conftest.d
 645   # There is a hard ^_ on the next line.  I am open to better ideas.
 646   (echo '\1f'
 647   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 648   echo '* Menu:') >conftest.d/dir
 649   (echo 'INFO-DIR-SECTION i-d-s works'
 650   echo 'START-INFO-DIR-ENTRY'
 651   echo '* Prog: (prog).   Program.'
 652   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 653   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 654   then
 655     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 656     then libc_cv_old_debian_install_info=no
 657     else libc_cv_old_debian_install_info=yes
 658     fi
 659   else libc_cv_old_debian_install_info=no testfailed=t
 660   fi
 661   rm -fr conftest.d])
 662 if test -n "$testfailed"
 663 then AC_MSG_WARN([install-info errored out, check config.log])
 664 fi
 665 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 666 fi
 667 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 668
 669 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 670 echo '#include <stddef.h>
 671 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 672 if eval "$ac_cpp conftest.c 2>/dev/null" \
 673 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 674   libc_cv_signed_size_t=no
 675 else
 676   libc_cv_signed_size_t=yes
 677 fi
 678 rm -f conftest*])
 679 if test $libc_cv_signed_size_t = yes; then
 680   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 681   cat >> confdefs.h <<\EOF
 682 #undef __SIZE_TYPE__
 683 #define __SIZE_TYPE__ unsigned
 684 EOF
 685 fi
 686
 687 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 688 AC_TRY_COMPILE(dnl
 689 [#define __need_size_t
 690 #define __need_wchar_t
 691 #include <stddef.h>
 692 #define __need_NULL
 693 #include <stddef.h>], [size_t size; wchar_t wchar;
 694 #ifdef offsetof
 695 #error stddef.h ignored __need_*
 696 #endif
 697 if (&size == NULL || &wchar == NULL) abort ();],
 698                libc_cv_friendly_stddef=yes,
 699                libc_cv_friendly_stddef=no)])
 700 if test $libc_cv_friendly_stddef = yes; then
 701   config_vars="$config_vars
 702 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 703 fi
 704
 705 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 706                libc_cv_need_minus_P, [dnl
 707 cat > conftest.S <<EOF
 708 #include "confdefs.h"
 709 /* Nothing whatsoever.  */
 710 EOF
 711 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 712   libc_cv_need_minus_P=no
 713 else
 714   libc_cv_need_minus_P=yes
 715 fi
 716 rm -f conftest*])
 717 if test $libc_cv_need_minus_P = yes; then
 718   config_vars="$config_vars
 719 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 720 fi
 721
 722 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 723 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 724 cat > conftest.s <<EOF
 725 .text
 726 EOF
 727 libc_cv_dot_text=
 728 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 729   libc_cv_dot_text=.text
 730 fi
 731 rm -f conftest*])
 732 if test -z "$libc_cv_dot_text"; then
 733   AC_MSG_RESULT(no)
 734 else
 735   AC_MSG_RESULT(yes)
 736 fi
 737
 738 AC_CACHE_CHECK(for assembler global-symbol directive,
 739                libc_cv_asm_global_directive, [dnl
 740 libc_cv_asm_global_directive=UNKNOWN
 741 for ac_globl in .globl .global .EXPORT; do
 742   cat > conftest.s <<EOF
 743         ${libc_cv_dot_text}
 744         ${ac_globl} foo
 745 foo:
 746 EOF
 747   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 748     libc_cv_asm_global_directive=${ac_globl}
 749   fi
 750   rm -f conftest*
 751   test $libc_cv_asm_global_directive != UNKNOWN && break
 752 done])
 753 if test $libc_cv_asm_global_directive = UNKNOWN; then
 754   AC_MSG_ERROR(cannot determine asm global directive)
 755 else
 756   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 757 fi
 758
 759 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 760 cat > conftest.s <<EOF
 761 ${libc_cv_dot_text}
 762 foo:
 763 .set glibc_conftest_frobozz,foo
 764 $libc_cv_asm_global_directive glibc_conftest_frobozz
 765 EOF
 766 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 767 # (but it doesn't work), so we must do a linking check to be sure.
 768 cat > conftest1.c <<\EOF
 769 extern int glibc_conftest_frobozz;
 770 main () { printf ("%d\n", glibc_conftest_frobozz); }
 771 EOF
 772 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 773             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 774   libc_cv_asm_set_directive=yes
 775 else
 776   libc_cv_asm_set_directive=no
 777 fi
 778 rm -f conftest*])
 779 if test $libc_cv_asm_set_directive = yes; then
 780   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 781 fi
 782
 783 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 784 [cat > conftest.s <<EOF
 785 ${libc_cv_dot_text}
 786 _sym:
 787 .symver _sym,sym@VERS
 788 EOF
 789 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 790   libc_cv_asm_symver_directive=yes
 791 else
 792   libc_cv_asm_symver_directive=no
 793 fi
 794 rm -f conftest*])
 795 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 796 if test $libc_cv_asm_symver_directive = yes; then
 797   cat > conftest.s <<EOF
 798 ${libc_cv_dot_text}
 799 _sym:
 800 .symver _sym,sym@VERS
 801 EOF
 802   cat > conftest.map <<EOF
 803 VERS_1 {
 804         global: sym;
 805 };
 806
 807 VERS_2 {
 808         global: sym;
 809 } VERS_1;
 810 EOF
 811   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 812     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 813                                         -nostartfiles -nostdlib
 814                                         -Wl,--version-script,conftest.map
 815                        1>&AC_FD_CC]);
 816     then
 817       libc_cv_ld_version_script_option=yes
 818     else
 819       libc_cv_ld_version_script_option=no
 820     fi
 821   else
 822     libc_cv_ld_version_script_option=no
 823   fi
 824 else
 825   libc_cv_ld_version_script_option=no
 826 fi
 827 rm -f conftest*])
 828 if test $shared != no &&
 829    test $libc_cv_asm_symver_directive = yes &&
 830    test $libc_cv_ld_version_script_option = yes &&
 831    test $enable_versioning = yes; then
 832   VERSIONING=yes
 833   AC_DEFINE(DO_VERSIONING)
 834 else
 835   VERSIONING=no
 836 fi
 837 AC_SUBST(VERSIONING)
 838
 839 if test $shared != no && test $VERSIONING = no; then
 840   echo "\
 841 *** WARNING: You should not compile GNU libc without versioning. Not using
 842 *** versioning will introduce incompatibilities so that old binaries
 843 *** will not run anymore.
 844 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 845 fi
 846 if test $elf = yes; then
 847   AC_CACHE_CHECK(for .previous assembler directive,
 848                  libc_cv_asm_previous_directive, [dnl
 849   cat > conftest.s <<EOF
 850 .section foo_section
 851 .previous
 852 EOF
 853   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 854     libc_cv_asm_previous_directive=yes
 855   else
 856     libc_cv_asm_previous_directive=no
 857   fi
 858   rm -f conftest*])
 859   if test $libc_cv_asm_previous_directive = yes; then
 860     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 861   else
 862     AC_CACHE_CHECK(for .popsection assembler directive,
 863                    libc_cv_asm_popsection_directive, [dnl
 864     cat > conftest.s <<EOF
 865 .pushsection foo_section
 866 .popsection
 867 EOF
 868     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 869       libc_cv_asm_popsection_directive=yes
 870     else
 871       libc_cv_asm_popsection_directive=no
 872     fi
 873     rm -f conftest*])
 874     if test $libc_cv_asm_popsection_directive = yes; then
 875       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 876     fi
 877   fi
 878   AC_CACHE_CHECK(for .protected and .hidden assembler directive,
 879                  libc_cv_asm_protected_directive, [dnl
 880   cat > conftest.s <<EOF
 881 .protected foo
 882 foo:
 883 .hidden bar
 884 bar:
 885 EOF
 886   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 887     libc_cv_asm_protected_directive=yes
 888   else
 889     libc_cv_asm_protected_directive=no
 890   fi
 891   rm -f conftest*])
 892   AC_SUBST(libc_cv_asm_protected_directive)
 893 fi
 894
 895 if test $elf != yes; then
 896   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 897                  [AC_TRY_COMPILE(, [asm (".section .init");
 898                                     asm (".section .fini");
 899                                     asm ("${libc_cv_dot_text}");],
 900                                  libc_cv_have_initfini=yes,
 901                                  libc_cv_have_initfini=no)])
 902   AC_SUBST(libc_cv_have_initfini)dnl
 903   if test $libc_cv_have_initfini = yes; then
 904     AC_DEFINE(HAVE_INITFINI)
 905   fi
 906 fi
 907
 908 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 909 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 910 [cat > conftest.$ac_ext <<EOF
 911 dnl This sometimes fails to find confdefs.h, for some reason.
 912 dnl [#]line __oline__ "[$]0"
 913 [#]line __oline__ "configure"
 914 #include "confdefs.h"
 915 void underscore_test(void) {
 916 return; }
 917 EOF
 918 if AC_TRY_EVAL(ac_compile); then
 919   if grep _underscore_test conftest* >/dev/null; then
 920     ifelse([$1], , :, [rm -f conftest*
 921     $1])
 922   else
 923     ifelse([$2], , , [rm -f conftest*
 924     $2])
 925   fi
 926 else
 927   echo "configure: failed program was:" >&AC_FD_CC
 928   cat conftest.$ac_ext >&AC_FD_CC
 929   ifelse([$2], , , [rm -f conftest*
 930   $2])
 931 fi
 932 rm -f conftest*])
 933
 934 if test $elf = yes; then
 935   libc_cv_asm_underscores=no
 936 else
 937   if test $ac_cv_prog_cc_works = yes; then
 938     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 939                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 940                                 libc_cv_asm_underscores=yes,
 941                                 libc_cv_asm_underscores=no)])
 942   else
 943     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 944                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 945                                             libc_cv_asm_underscores=no)])
 946   fi
 947 fi
 948 if test $libc_cv_asm_underscores = no; then
 949   AC_DEFINE(NO_UNDERSCORES)
 950 fi
 951
 952 if test $elf = yes; then
 953   libc_cv_weak_symbols=yes
 954 fi
 955
 956 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 957                [dnl
 958 cat > conftest.s <<EOF
 959 ${libc_cv_dot_text}
 960 ${libc_cv_asm_global_directive} foo
 961 foo:
 962 .weak foo
 963 .weak bar; bar = foo
 964 EOF
 965 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 966   libc_cv_asm_weak_directive=yes
 967 else
 968   libc_cv_asm_weak_directive=no
 969 fi
 970 rm -f conftest*])
 971
 972 if test $libc_cv_asm_weak_directive = no; then
 973   AC_CACHE_CHECK(for assembler .weakext directive,
 974                  libc_cv_asm_weakext_directive,
 975                  [dnl
 976 cat > conftest.s <<EOF
 977 ${libc_cv_dot_text}
 978 ${libc_cv_asm_global_directive} foo
 979 foo:
 980 .weakext bar foo
 981 .weakext baz
 982 ${libc_cv_asm_global_directive} baz
 983 baz:
 984 EOF
 985   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 986     libc_cv_asm_weakext_directive=yes
 987   else
 988     libc_cv_asm_weakext_directive=no
 989   fi
 990   rm -f conftest*])
 991
 992 fi # no .weak
 993
 994 if test $libc_cv_asm_weak_directive = yes; then
 995   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 996 elif test $libc_cv_asm_weakext_directive = yes; then
 997   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 998 fi
 999
1000 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1001 cat > conftest.c <<\EOF
1002 _start () {}
1003 int __eh_pc;
1004 __throw () {}
1005 EOF
1006 dnl No \ in command here because it ends up inside ''.
1007 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1008                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1009                             -o conftest conftest.c 1>&AC_FD_CC]); then
1010   libc_cv_ld_no_whole_archive=yes
1011 else
1012   libc_cv_ld_no_whole_archive=no
1013 fi
1014 rm -f conftest*])
1015 if test $libc_cv_ld_no_whole_archive = yes; then
1016   no_whole_archive=-Wl,--no-whole-archive
1017 fi
1018 AC_SUBST(no_whole_archive)dnl
1019
1020 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1021 cat > conftest.c <<\EOF
1022 _start () {}
1023 int __eh_pc;
1024 __throw () {}
1025 EOF
1026 dnl No \ in command here because it ends up inside ''.
1027 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1028                             -nostdlib -nostartfiles -fexceptions
1029                             -o conftest conftest.c 1>&AC_FD_CC]); then
1030   libc_cv_gcc_exceptions=yes
1031 else
1032   libc_cv_gcc_exceptions=no
1033 fi
1034 rm -f conftest*])
1035 if test $libc_cv_gcc_exceptions = yes; then
1036   exceptions=-fexceptions
1037 fi
1038 AC_SUBST(exceptions)dnl
1039
1040 if test "$base_machine" = alpha ; then
1041 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1042 cat > conftest.c <<\EOF
1043 foo () { }
1044 EOF
1045 dnl
1046 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1047 then
1048   libc_cv_gcc_alpha_ng_prefix=yes
1049 else
1050   libc_cv_gcc_alpha_ng_prefix=no
1051 fi
1052 rm -f conftest* ])
1053 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1054   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1055 else
1056   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1057 fi
1058 fi
1059
1060 if test "$host_cpu" = powerpc ; then
1061 # Check for a bug present in at least versions 2.8.x of GCC
1062 # and versions 1.0.x of EGCS.
1063 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1064 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1065                libc_cv_c_asmcr0_bug='no',
1066                libc_cv_c_asmcr0_bug='yes')])
1067 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1068   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1069 fi
1070 fi
1071
1072 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1073 [cat > conftest.c <<EOF
1074 #line __oline__ "configure"
1075 static char __EH_FRAME_BEGIN__[];
1076 _start ()
1077 {
1078 #ifdef CHECK__register_frame
1079   __register_frame (__EH_FRAME_BEGIN__);
1080   __deregister_frame (__EH_FRAME_BEGIN__);
1081 #endif
1082 #ifdef CHECK__register_frame_info
1083   __register_frame_info (__EH_FRAME_BEGIN__);
1084   __deregister_frame_info (__EH_FRAME_BEGIN__);
1085 #endif
1086 }
1087 int __eh_pc;
1088 __throw () {}
1089 /* FIXME: this is fragile.  */
1090 malloc () {}
1091 strcmp () {}
1092 strlen () {}
1093 memcpy () {}
1094 memset () {}
1095 free () {}
1096 abort () {}
1097 __bzero () {}
1098 EOF
1099 dnl No \ in command here because it ends up inside ''.
1100 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1101                             -nostdlib -nostartfiles
1102                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1103   libc_cv_gcc_dwarf2_unwind_info=static
1104 else
1105   libc_cv_gcc_dwarf2_unwind_info=no
1106 fi
1107 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1108   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1109                               -nostdlib -nostartfiles
1110                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1111     libc_cv_gcc_dwarf2_unwind_info=yes
1112   else
1113     libc_cv_gcc_dwarf2_unwind_info=no
1114   fi
1115 fi
1116 rm -f conftest*])
1117 case $libc_cv_gcc_dwarf2_unwind_info in
1118 yes)
1119   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1120   ;;
1121 static)
1122   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1123   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1124   ;;
1125 esac
1126
1127 dnl Check whether compiler understands __builtin_expect.
1128 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1129 [cat > conftest.c <<EOF
1130 #line __oline__ "configure"
1131 int foo (int a)
1132 {
1133   a = __builtin_expect (a, 10);
1134   return a == 10 ? 0 : 1;
1135 }
1136 EOF
1137 dnl No \ in command here because it ends up inside ''.
1138 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1139                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1140   libc_cv_gcc_builtin_expect=yes
1141 else
1142   libc_cv_gcc_builtin_expect=no
1143 fi
1144 rm -f conftest*])
1145 if test "$libc_cv_gcc_builtin_expect" = yes; then
1146   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1147 fi
1148
1149 dnl Check whether the compiler supports subtraction of local labels.
1150 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1151 [cat > conftest.c <<EOF
1152 changequote(,)dnl
1153 #line __oline__ "configure"
1154 int foo (int a)
1155 {
1156   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1157   void *p = &&l1 + ar[a];
1158   goto *p;
1159  l1:
1160   return 1;
1161  l2:
1162   return 2;
1163 }
1164 changequote([,])dnl
1165 EOF
1166 dnl No \ in command here because it ends up inside ''.
1167 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1168                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1169   libc_cv_gcc_subtract_local_labels=yes
1170 else
1171   libc_cv_gcc_subtract_local_labels=no
1172 fi
1173 rm -f conftest*])
1174 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1175   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1176 fi
1177
1178 dnl Check whether we have the gd library available.
1179 AC_MSG_CHECKING(for libgd)
1180 old_CFLAGS="$CFLAGS"
1181 CFLAGS="$CFLAGS $libgd_include"
1182 old_LDFLAGS="$LDFLAGS"
1183 LDFLAGS="$LDFLAGS $libgd_ldflags"
1184 old_LIBS="$LIBS"
1185 LIBS="$LIBS -lgd -lpng -lz"
1186 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1187 CFLAGS="$old_CFLAGS"
1188 LDFLAGS="$old_LDFLAGS"
1189 LIBS="$old_LIBS"
1190 AC_MSG_RESULT($LIBGD)
1191 AC_SUBST(LIBGD)
1192
1193 dnl check for the size of 'long double'.
1194 AC_CHECK_SIZEOF(long double, 0)
1195 sizeof_long_double=$ac_cv_sizeof_long_double
1196 AC_SUBST(sizeof_long_double)
1197
1198 ### End of automated tests.
1199 ### Now run sysdeps configure fragments.
1200
1201 # sysdeps configure fragments may set these with files to be linked below.
1202 libc_link_dests=
1203 libc_link_sources=
1204
1205 # They also can set these variables.
1206 use_ldconfig=no
1207 ldd_rewrite_script=no
1208
1209 # Iterate over all the sysdep directories we will use, running their
1210 # configure fragments, and looking for a uname implementation.
1211 uname=
1212 for dir in $sysnames; do
1213   case $dir in
1214     /*) dest=$dir ;;
1215     *)  dest=$srcdir/$dir ;;
1216   esac
1217   if test -r $dest/configure; then
1218     AC_MSG_RESULT(running configure fragment for $dest)
1219     . $dest/configure
1220   fi
1221 [
1222   if test -z "$uname"; then
1223     if test -r $dest/uname.c ||
1224        test -r $dest/uname.S ||
1225        { test -r $dest/syscalls.list &&
1226          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1227       uname=$dir
1228     fi
1229   fi
1230 ]dnl
1231 done
1232
1233 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1234
1235 # If we will use the generic uname implementation, we must figure out what
1236 # it will say by examining the system, and write the results in config-name.h.
1237 if test "$uname" = "sysdeps/generic"; then
1238
1239 changequote(,)dnl
1240   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1241 changequote([,])dnl
1242   if test $uname_sysname != $config_os; then
1243     config_release=`echo $config_os | sed s/$uname_sysname//`
1244   fi
1245 dnl
1246 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1247     if test -r /vmunix; then
1248       kernel_id=`strings /vmunix | grep UNIX`
1249     elif test -r /dynix; then
1250       kernel_id=`strings /dynix | grep DYNIX`
1251     else
1252       kernel_id=
1253     fi
1254 ])dnl
1255
1256   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1257 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1258 changequote(,)dnl
1259   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1260 changequote([,])dnl
1261   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1262          != x$config_release; then
1263     # The configuration release is a substring of the kernel release.
1264     libc_cv_uname_release=$kernel_release
1265   elif test x$config_release != x; then
1266     libc_cv_uname_release=$config_release
1267   elif test x$kernel_release != x; then
1268     libc_cv_uname_release=$kernel_release
1269   else
1270     libc_cv_uname_release=unknown
1271   fi])
1272   uname_release="$libc_cv_uname_release"
1273
1274   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1275 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1276 changequote(,)dnl
1277   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1278 changequote([,])dnl
1279   if test -n "$kernel_version"; then
1280     libc_cv_uname_version="$kernel_version"
1281   else
1282     libc_cv_uname_version=unknown
1283   fi])
1284   uname_version="$libc_cv_uname_version"
1285
1286 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1287   config_uname=config-name.h:config-name.in
1288 else
1289   # For non-generic uname, we don't need to create config-name.h at all.
1290   config_uname=
1291 fi
1292
1293 AC_MSG_CHECKING(stdio selection)
1294 AC_SUBST(stdio)
1295 case $stdio in
1296 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1297 default) stdio=stdio ;;
1298 esac
1299 AC_MSG_RESULT($stdio)
1300
1301 # Test for old glibc 2.0.x headers so that they can be removed properly
1302 # Search only in includedir.
1303 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1304 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1305 then
1306   old_glibc_headers=yes
1307 else
1308   old_glibc_headers=no
1309 fi
1310 AC_MSG_RESULT($old_glibc_headers)
1311 if test ${old_glibc_headers} = yes; then
1312   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1313   AC_MSG_WARN(*** be removed.)
1314 fi
1315 AC_SUBST(old_glibc_headers)
1316
1317 AC_SUBST(libc_cv_slibdir)
1318 AC_SUBST(libc_cv_localedir)
1319 AC_SUBST(libc_cv_sysconfdir)
1320 AC_SUBST(libc_cv_rootsbindir)
1321
1322 AC_SUBST(use_ldconfig)
1323 AC_SUBST(ldd_rewrite_script)
1324
1325 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1326 if test $gnu_ld = yes; then
1327   AC_DEFINE(HAVE_GNU_LD)
1328 fi
1329 if test $gnu_as = yes; then
1330   AC_DEFINE(HAVE_GNU_AS)
1331 fi
1332 if test $elf = yes; then
1333   AC_DEFINE(HAVE_ELF)
1334 fi
1335
1336 AC_SUBST(static)
1337 AC_SUBST(shared)
1338 if test $shared = default; then
1339   if test $gnu_ld = yes; then
1340     shared=$elf
1341   else
1342     # For now we do not assume shared libs are available.  In future more
1343     # tests might become available.
1344     shared=no
1345   fi
1346 fi
1347
1348 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1349 [pic_default=yes
1350 cat > conftest.c <<EOF
1351 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1352 # error PIC is default.
1353 #endif
1354 EOF
1355 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1356   pic_default=no
1357 fi
1358 rm -f conftest.*])
1359 AC_SUBST(pic_default)
1360
1361 AC_SUBST(profile)
1362 AC_SUBST(omitfp)
1363 AC_SUBST(bounded)
1364 AC_SUBST(static_nss)
1365 AC_SUBST(nopic_initfini)
1366
1367 AC_SUBST(DEFINES)
1368
1369 case "$add_ons" in
1370   *door*) linux_doors=yes ;;
1371   *) linux_doors=no ;;
1372 esac
1373 AC_SUBST(linux_doors)
1374
1375 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1376   config_makefile=
1377 else
1378   config_makefile=Makefile
1379 fi
1380
1381 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1382 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1383 AC_SUBST(VERSION)
1384 AC_SUBST(RELEASE)
1385
1386 echo '*** Do NOT install this release on any production system!'
1387 echo '*** It is known to be broken and will be so for quite some time.'
1388 echo '*** Use the latest released version instead.'
1389
1390 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1391 case $CONFIG_FILES in *config.make*)
1392 echo "$config_vars" >> config.make;;
1393 esac
1394 test -d bits || mkdir bits], [config_vars='$config_vars'])