This is the mail archive of the xsl-list@mulberrytech.com mailing list .


Index Nav: [Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav: [Date Prev] [Date Next] [Thread Prev] [Thread Next]
Other format: [Raw text]

Re: Default template match


Hi Costantino,

> Therefore, how can I refer to the specific customer (from the
> "metadata" file), when I am applying other templates?

Passing it down as a parameter is the only way of doing it.

By the way, you could make your stylesheet more readable and efficient
by changing the way that you access the information in the
metadata.xml document so that you use a key instead. Create a key that
indexes each doc element by its label and lang attributes, as follows:

<xsl:key name="docs" match="doc" use="concat(@lang, '::', @label)" />

Then change your code as follows:

  <!-- iterate over each doc from metadata.xml -->
  <xsl:for-each select="document($metadata)/data/doc">
    <!-- assign the doc to the $doc-ref variable -->
    <xsl:variable name="doc-ref" select="." />

    <doc>
      <!-- create the metadata element for the doc -->
      <metadata><xsl:copy-of select="*" /></metadata>

      <!-- change context to templates.xml -->
      <xsl:for-each select="document($templates)">
      
        <!-- use the key to get hold of the doc -->
        <xsl:variable name="doc"
           select="key('docs', concat($doc-ref/label, '::',
                                      $doc-ref/customer/language))" />

        <!-- create the object and content elements for the doc -->
        <object>
          <xsl:apply-templates select="$doc/object">
            <xsl:with-param name="doc-ref" select="$doc-ref" />
          </xsl:apply-templates>
        </object>
        <content>
          <xsl:apply-templates select="$doc/content">
            <xsl:with-param name="doc-ref" select="$doc-ref" />
          </xsl:apply-templates>
        </content>
      </xsl:for-each>
    </doc>
  </xsl:for-each>

Cheers,

Jeni

---
Jeni Tennison
http://www.jenitennison.com/


 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list


Index Nav: [Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav: [Date Prev] [Date Next] [Thread Prev] [Thread Next]