This is the mail archive of the
mailing list for the libc-ports project.
[PATCH 20/26] arm: Implement armv6t2 optimized strlen
- From: Richard Henderson <rth at twiddle dot net>
- To: libc-ports at sourceware dot org
- Cc: Joseph Myers <joseph at codesourcery dot com>
- Date: Tue, 26 Feb 2013 19:16:20 -0800
- Subject: [PATCH 20/26] arm: Implement armv6t2 optimized strlen
- References: <email@example.com>
Twice as fast for long strings and 50% faster for short strings
over the armv4 version on A15.
* sysdeps/arm/armv6t2/strlen.S: New file.
ports/sysdeps/arm/armv6t2/strlen.S | 93 ++++++++++++++++++++++++++++++++++++++
1 file changed, 93 insertions(+)
create mode 100644 ports/sysdeps/arm/armv6t2/strlen.S
diff --git a/ports/sysdeps/arm/armv6t2/strlen.S b/ports/sysdeps/arm/armv6t2/strlen.S
new file mode 100644
@@ -0,0 +1,93 @@
+/* Copyright (C) 2013 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library. If not, see
+ <http://www.gnu.org/licenses/>. */
+ .syntax unified
+ @ r0 = start of string
+ pld [r0]
+ @ To cater to long strings, we want to search through a few
+ @ characters until we reach an aligned pointer. To cater to
+ @ small strings, we don't want to start doing word operations
+ @ immediately. The compromise is a maximum of 16 bytes less
+ @ whatever is required to end with an aligned pointer.
+ @ r3 = number of characters to search in alignment loop
+ and r3, r0, #7
+ s(mov) r1, r0 @ Save the input pointer
+ rsb r3, r3, #16
+ @ Loop until we find ...
+1: ldrb r2, [r0], #1
+ subs r3, r3, #1 @ ... the aligment point
+ it ne
+ cmpne r2, #0 @ ... or EOS
+ bne 1b
+ @ Disambiguate the exit possibilites above
+ cmp r2, #0 @ Found EOS
+ ittt eq
+ subeq r0, r0, #1 @ Undo post-inc above
+ subeq r0, r0, r1 @ Subtract input to compute length
+ bxeq lr
+ @ So now we're aligned.
+ ldrd r2, r3, [r0], #8
+ movw ip, #0xfefe
+ pld [r0, #64]
+ movt ip, #0xfefe
+ pld [r0, #128]
+ pld [r0, #192]
+ @ Loop searching for EOS or C, 8 bytes at a time.
+ @ Adding (unsigned saturating) 0xfe means result of 0xfe for any byte
+ @ that was originally zero and 0xff otherwise. Therefore we consider
+ @ the lsb of each byte the "found" bit, with 0 for a match.
+ .balign 16
+2: uqadd8 r2, r2, ip @ Find EOS
+ uqadd8 r3, r3, ip
+ pld [r0, #256] @ Prefetch 4 lines ahead
+ s(and) r3, r3, r2 @ Combine the two words
+ mvns r3, r3 @ Test for any found bit true
+ it eq
+ ldrdeq r2, r3, [r0], #8
+ beq 2b
+ @ Found something. Disambiguate between first and second words.
+ @ Adjust r0 to point to the word containing the match.
+ @ Adjust r2 to the found bits for the word containing the match.
+ mvns r2, r2
+ itee ne
+ subne r0, r0, #8
+ moveq r2, r3
+ subeq r0, r0, #4
+ @ Find the bit-offset of the match within the word.
+ rbit r2, r2 @ For LE we need count-trailing-zeros
+ clz r2, r2
+ add r0, r0, r2, lsr #3 @ Adjust the pointer to the found byte
+ s(sub) r0, r0, r1 @ Subtract input to compute length
+ bx lr