This is the mail archive of the libc-hacker@sourceware.org mailing list for the glibc project.
Note that libc-hacker is a closed list. You may look at the archives of this list, but subscription and posting are not open.
Index Nav:	[Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav:	[Date Prev] [Date Next]	[Thread Prev] [Thread Next]
Other format:	[Raw text]
Re: ucontext checking

From: Kaz Kojima <kkojima at rr dot iij4u dot or dot jp>
To: libc-hacker at sources dot redhat dot com
Date: Sun, 16 Oct 2005 19:32:48 +0900 (JST)
Subject: Re: ucontext checking
References: <20051015.140509.35506599.kkojima@rr.iij4u.or.jp><4350903B.7070203@redhat.com><20051015.145332.71553661.kkojima@rr.iij4u.or.jp>
Here is a revised patch with an implementation of *context functions
for SH.  It passed tst-setcontext and tst-ucontext-off on sh4-linux.

Regards,
	kaz
--
2005-10-16  Kaz Kojima  <kkojima@rr.iij4u.or.jp>

	* sysdeps/unix/sysv/linux/sh/bits/mman.h: Define MREMAP_FIXED.

	* sysdeps/unix/sysv/linux/sh/makecontext.S: New file.
	* sysdeps/unix/sysv/linux/sh/sh3/getcontext.S: New file.
	* sysdeps/unix/sysv/linux/sh/sh4/getcontext.S: Likewise.
	* sysdeps/unix/sysv/linux/sh/sh3/setcontext.S: Likewise.
	* sysdeps/unix/sysv/linux/sh/sh4/setcontext.S: Likewise.
	* sysdeps/unix/sysv/linux/sh/sh3/swapcontext.S: Likewise.
	* sysdeps/unix/sysv/linux/sh/sh4/swapcontext.S: Likewise.
	* sysdeps/unix/sysv/linux/sh/sh3/ucontext_i.h: Likewise.
	* sysdeps/unix/sysv/linux/sh/sh4/ucontext_i.h: Likewise.
	* sysdeps/unix/sysv/linux/sh/sys/ucontext.h: Removed.
	* sysdeps/unix/sysv/linux/sh/sh3/sys/ucontext.h: New file.
	* sysdeps/unix/sysv/linux/sh/sh4/sys/ucontext.h: Likewise.

diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/bits/mman.h LOCAL/libc/sysdeps/unix/sysv/linux/sh/bits/mman.h
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/bits/mman.h	2005-03-14 10:01:37.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/bits/mman.h	2005-10-15 12:12:03.000000000 +0900
@@ -78,6 +78,7 @@
 /* Flags for `mremap'.  */
 #ifdef __USE_GNU
 # define MREMAP_MAYMOVE	1
+# define MREMAP_FIXED	2
 #endif
 
 /* Advice to `madvise'.  */
diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/makecontext.S LOCAL/libc/sysdeps/unix/sysv/linux/sh/makecontext.S
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/makecontext.S	1970-01-01 09:00:00.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/makecontext.S	2005-10-16 16:58:56.000000000 +0900
@@ -0,0 +1,145 @@
+/* Create new context.
+   Copyright (C) 2005 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.	 See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+
+#include "ucontext_i.h"
+
+/* void __makecontext (struct ucontext *ucp, void (*func)(), int argc, ...);
+  __makecontext sets up a stack and registers for context to run a given
+  function.  The registers are set up like this:
+    r4-r7: parameters 1 to 4
+    r8	 : uc_link from ucontext structure
+    pc	 : (*func) pointer
+    pr	 : address of exitcode
+    r15	 : stack pointer for func.  */
+
+	.text
+	.align	5
+	cfi_startproc
+ENTRY(__makecontext)
+	mov	#4, r3
+	mov.l	@(oSS_SP,r4), r1
+	mov.l	@(oSS_SIZE,r4), r2
+	add	r1, r2
+	cmp/gt	r6, r3
+	bf/s	1f
+	 shlr2	r2
+	sub	r6, r2
+	add	r3, r2
+1:
+	shll2	r2
+	mov	#oR15, r0
+	mov.l	@(oLINK,r4), r1
+	mov.l	r2, @(r0,r4)
+	mov.l	r1, @(oR8,r4)
+	mov	#oPC, r0
+	mov.l	r5, @(r0,r4)
+
+	cmp/pl	r6
+	bf/s	.L1
+	 dt	r6
+	mov.l	r7, @(oR4,r4)
+	cmp/pl	r6
+	bf/s	.L1
+	 dt	r6
+	mov.l	@(0,r15), r1
+	mov.l	r1, @(oR5,r4)
+	cmp/pl	r6
+	bf/s	.L1
+	 dt	r6
+	mov.l	@(4,r15), r1
+	mov.l	r1, @(oR6,r4)
+	cmp/pl	r6
+	bf/s	.L1
+	 dt	r6
+	mov.l	@(8,r15), r1
+	mov.l	r1, @(oR7,r4)
+	mov	#12,r0
+.L0:
+	cmp/pl	r6
+	bf/s	.L1
+	 dt	r6
+	mov.l	@(r0,r15), r1
+	mov.l	r1, @r2
+	add	#4, r0
+	bra	.L0
+	 add	#4, r2
+.L1:
+#ifdef PIC
+	mova	.Lexitcode, r0
+#else
+	mov.l	.L2, r0
+#endif
+	add	#oPR, r4
+	rts
+	 mov.l	r0, @r4
+#ifndef PIC
+	.align	2
+.L2:
+	.long	.Lexitcode
+#endif
+	cfi_endproc
+
+	.align	5
+.Lexitcode:
+	tst	r8, r8
+	bt/s	2f
+	 mov	r8, r4
+#ifdef PIC
+	mova	.Lgot, r0
+	mov.l	.Lgot, r12
+	add	r0, r12
+	mov.l	.L3, r1
+	bsrf	r1
+.LPCS0:
+	 nop
+#else
+	mov.l	.L3, r1
+	jsr	@r1
+	 nop
+#endif
+2:
+	mov.l	.L4, r1
+#ifdef PIC
+	add	r12, r1
+#endif
+	jsr	@r1
+	 mov	r0, r4
+0:
+	bra	0b
+	 nop
+
+	.align	2
+#ifdef PIC
+.Lgot:
+	.long	_GLOBAL_OFFSET_TABLE_
+.L3:
+	.long	__setcontext@PLT-(.LPCS0+2-(.))
+.L4:
+	.long	HIDDEN_JUMPTARGET(exit)@GOTOFF
+#else
+.L3:
+	.long	__setcontext
+.L4:
+	.long	HIDDEN_JUMPTARGET(exit)
+#endif
+PSEUDO_END(__makecontext)
+
+weak_alias (__makecontext, makecontext)
diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/sh3/getcontext.S LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh3/getcontext.S
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/sh3/getcontext.S	1970-01-01 09:00:00.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh3/getcontext.S	2005-10-16 18:57:04.000000000 +0900
@@ -0,0 +1,90 @@
+/* Save current context.
+   Copyright (C) 2005 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+
+#include "ucontext_i.h"
+
+/*  int __getcontext (ucontext_t *uc);  */
+
+	.text
+	.align  5
+	cfi_startproc
+ENTRY(__getcontext)
+
+	/* Return value of getcontext.  R0 is the only register whose
+	   value is not preserved.  */
+	mov	#0, r0
+	mov.l	r0, @(oR0,r4)
+	mov.l	r1, @(oR1,r4)
+	mov.l	r2, @(oR2,r4)
+	mov.l	r3, @(oR3,r4)
+	mov.l	r4, @(oR4,r4)
+	mov.l	r5, @(oR5,r4)
+	mov.l	r6, @(oR6,r4)
+	mov.l	r7, @(oR7,r4)
+	mov	r4, r0
+	add	#(oMACL+4), r0
+	sts.l	macl, @-r0
+	sts.l	mach, @-r0
+	stc.l	gbr, @-r0
+
+	/* Save T flag to SR.  */
+	movt	r1
+	mov.l	r1, @-r0
+	sts.l	pr, @-r0
+
+	/* The return address of getcontext is the restart pc.  */
+	sts.l	pr, @-r0
+
+	mov.l	r15, @-r0
+	mov.l	r14, @-r0
+	mov.l	r13, @-r0
+	mov.l	r12, @-r0
+	mov.l	r11, @-r0
+	mov.l	r10, @-r0
+	mov.l	r9, @-r0
+	mov.l	r8, @-r0
+
+	/* sigprocmask (SIG_BLOCK, NULL, &uc->uc_sigmask).  */
+	mov	r4, r6
+	add	#oSIGMASK, r6
+	mov	#SIG_BLOCK, r4
+	mov	#0, r5
+	mov	#+SYS_ify(sigprocmask), r3
+	trapa	#0x13
+	mov     r0, r1
+	mov	#-12, r2
+	shad	r2, r1
+	not	r1, r1			// r1=0 means r0 = -1 to -4095
+	tst	r1, r1			// i.e. error in linux
+	bf	.Lgetcontext_end
+.Lsyscall_error:	
+	SYSCALL_ERROR_HANDLER
+.Lgetcontext_end:
+	/* All done, return 0 for success.  */
+	mov	#0, r0
+.Lpseudo_end:
+	rts
+	 nop
+
+	cfi_endproc
+PSEUDO_END(__getcontext)
+
+weak_alias (__getcontext, getcontext)
diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/sh3/setcontext.S LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh3/setcontext.S
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/sh3/setcontext.S	1970-01-01 09:00:00.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh3/setcontext.S	2005-10-16 18:58:20.000000000 +0900
@@ -0,0 +1,101 @@
+/* Install given context.
+   Copyright (C) 2005 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+
+#include "ucontext_i.h"
+
+/*  int __setcontext (const ucontext_t *uc);  */
+
+	.text
+	.align  5
+	cfi_startproc
+ENTRY(__setcontext)
+
+	mov	r4, r8
+
+	/* sigprocmask (SIG_SETMASK, &uc->uc_sigmask, NULL).  */
+	mov	r4, r5
+	add	#oSIGMASK, r5
+	mov	#SIG_SETMASK, r4
+	mov	#0, r6
+	mov	#+SYS_ify(sigprocmask), r3
+	trapa	#0x13
+	mov     r0, r1
+	mov	#-12, r2
+	shad	r2, r1
+	not	r1, r1			// r1=0 means r0 = -1 to -4095
+	tst	r1, r1			// i.e. error in linux
+	bf	.Lsetcontext_restore
+.Lsyscall_error:	
+	SYSCALL_ERROR_HANDLER
+.Lpseudo_end:
+	rts
+	 nop
+
+.Lsetcontext_restore:
+	mov	r8, r0
+	add	#(oPC), r0
+	mov.l	@r0+, r2
+	lds.l	@r0+, pr
+
+	/* Restore T frag.  */
+	mov.l	@r0+, r1
+	shlr	r1
+	/* Skip GBR which is used for thread pointer.  */
+	add	#4, r0
+
+	lds.l	@r0+, mach
+	lds.l	@r0+, macl
+
+	mov	r8, r0
+	add	#(oR9), r0
+	mov.l	@r0+, r9
+	mov.l	@r0+, r10
+	mov.l	@r0+, r11
+	mov.l	@r0+, r12
+	mov.l	@r0+, r13
+	mov.l	@r0+, r14
+	mov.l	@r0+, r15
+
+	mov	r8, r0
+	mov.l	@(oR0,r0), r1
+	mov.l	r1, @-r15
+	cfi_adjust_cfa_offset(4)
+	cfi_rel_offset (r1, 0)
+	mov.l	r2, @-r15
+	cfi_adjust_cfa_offset(4)
+	cfi_rel_offset (r2, 0)
+
+	mov.l	@(oR1,r0), r1
+	mov.l	@(oR2,r0), r2
+	mov.l	@(oR3,r0), r3
+	mov.l	@(oR4,r0), r4
+	mov.l	@(oR5,r0), r5
+	mov.l	@(oR6,r0), r6
+	mov.l	@(oR7,r0), r7
+	mov.l	@(oR8,r0), r8
+	mov.l	@r15+, r0
+	jmp	@r0
+	 mov.l	@r15+, r0
+
+	cfi_endproc
+PSEUDO_END(__setcontext)
+
+weak_alias (__setcontext, setcontext)
diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/sh3/swapcontext.S LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh3/swapcontext.S
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/sh3/swapcontext.S	1970-01-01 09:00:00.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh3/swapcontext.S	2005-10-16 19:00:23.000000000 +0900
@@ -0,0 +1,134 @@
+/* Save current context and install the given one.
+   Copyright (C) 2005 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+
+#include "ucontext_i.h"
+
+/*  int __swapcontext (ucontext_t *ouc, const ucontext_t *uc);  */
+
+	.text
+	.align  5
+	cfi_startproc
+ENTRY(__swapcontext)
+
+	/* Return value of getcontext.  R0 is the only register whose
+	   value is not preserved.  */
+	mov	#0, r0
+	mov.l	r0, @(oR0,r4)
+	mov.l	r1, @(oR1,r4)
+	mov.l	r2, @(oR2,r4)
+	mov.l	r3, @(oR3,r4)
+	mov.l	r4, @(oR4,r4)
+	mov.l	r5, @(oR5,r4)
+	mov.l	r6, @(oR6,r4)
+	mov.l	r7, @(oR7,r4)
+	mov	r4, r0
+	add	#(oMACL+4), r0
+	sts.l	macl, @-r0
+	sts.l	mach, @-r0
+	stc.l	gbr, @-r0
+
+	/* Save T flag to SR.  */
+	movt	r1
+	mov.l	r1, @-r0
+	sts.l	pr, @-r0
+
+	/* The return address of getcontext is the restart pc.  */
+	sts.l	pr, @-r0
+
+	mov.l	r15, @-r0
+	mov.l	r14, @-r0
+	mov.l	r13, @-r0
+	mov.l	r12, @-r0
+	mov.l	r11, @-r0
+	mov.l	r10, @-r0
+	mov.l	r9, @-r0
+	mov.l	r8, @-r0
+
+	mov	r5, r8
+
+	/* sigprocmask (SIG_SETMASK, &uc->uc_sigmask, &ouc->uc_sigmask).  */
+	add	#oSIGMASK, r5
+	mov	r4, r6
+	add	#oSIGMASK, r6
+	mov	#SIG_SETMASK, r4
+	mov	#+SYS_ify(sigprocmask), r3
+	trapa	#0x13
+	mov     r0, r1
+	mov	#-12, r2
+	shad	r2, r1
+	not	r1, r1			// r1=0 means r0 = -1 to -4095
+	tst	r1, r1			// i.e. error in linux
+	bf	.Lswapcontext_restore
+.Lsyscall_error:	
+	SYSCALL_ERROR_HANDLER
+.Lpseudo_end:
+	rts
+	 nop
+.Lswapcontext_restore:	
+	mov	r8, r0
+	add	#(oPC), r0
+	mov.l	@r0+, r2
+	lds.l	@r0+, pr
+
+	/* Restore T frag.  */
+	mov.l	@r0+, r1
+	shlr	r1
+	/* Skip GBR which is used for thread pointer.  */
+	add	#4, r0
+
+	lds.l	@r0+, mach
+	lds.l	@r0+, macl
+
+	mov	r8, r0
+	add	#(oR9), r0
+	mov.l	@r0+, r9
+	mov.l	@r0+, r10
+	mov.l	@r0+, r11
+	mov.l	@r0+, r12
+	mov.l	@r0+, r13
+	mov.l	@r0+, r14
+	mov.l	@r0+, r15
+
+	mov	r8, r0
+	mov.l	@(oR0,r0), r1
+	mov.l	r1, @-r15
+	cfi_adjust_cfa_offset(4)
+	cfi_rel_offset (r1, 0)
+	mov.l	r2, @-r15
+	cfi_adjust_cfa_offset(4)
+	cfi_rel_offset (r2, 0)
+
+	mov.l	@(oR1,r0), r1
+	mov.l	@(oR2,r0), r2
+	mov.l	@(oR3,r0), r3
+	mov.l	@(oR4,r0), r4
+	mov.l	@(oR5,r0), r5
+	mov.l	@(oR6,r0), r6
+	mov.l	@(oR7,r0), r7
+	mov.l	@(oR8,r0), r8
+	mov.l	@r15+, r0
+	jmp	@r0
+	 mov.l	@r15+, r0
+	
+	cfi_endproc
+PSEUDO_END(__swapcontext)
+
+weak_alias (__swapcontext, swapcontext)
diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/sh3/sys/ucontext.h LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh3/sys/ucontext.h
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/sh3/sys/ucontext.h	1970-01-01 09:00:00.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh3/sys/ucontext.h	2005-10-15 13:34:27.000000000 +0900
@@ -0,0 +1,102 @@
+/* Copyright (C) 1999, 2000, 2001, 2005 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+/* Where is System V/SH ABI?  */
+
+#ifndef _SYS_UCONTEXT_H
+#define _SYS_UCONTEXT_H	1
+
+#include <features.h>
+#include <signal.h>
+
+/* We need the signal context definitions even if they are not used
+   included in <signal.h>.  */
+#include <bits/sigcontext.h>
+
+
+typedef int greg_t;
+
+/* Number of general registers.  */
+#define NFPREG	16
+
+/* Container for all general registers.  */
+typedef greg_t gregset_t[NFPREG];
+
+#ifdef __USE_GNU
+/* Number of each register is the `gregset_t' array.  */
+enum
+{
+  R0 = 0,
+#define R0	R0
+  R1 = 1,
+#define R1	R1
+  R2 = 2,
+#define R2	R2
+  R3 = 3,
+#define R3	R3
+  R4 = 4,
+#define R4	R4
+  R5 = 5,
+#define R5	R5
+  R6 = 6,
+#define R6	R6
+  R7 = 7,
+#define R7	R7
+  R8 = 8,
+#define R8	R8
+  R9 = 9,
+#define R9	R9
+  R10 = 10,
+#define R10	R10
+  R11 = 11,
+#define R11	R11
+  R12 = 12,
+#define R12	R12
+  R13 = 13,
+#define R13	R13
+  R14 = 14,
+#define R14	R14
+  R15 = 15,
+#define R15	R15
+};
+#endif
+
+/* Context to describe whole processor state.  */
+typedef struct
+  {
+    unsigned int oldmask;
+    gregset_t gregs;
+    unsigned int pc;
+    unsigned int pr;
+    unsigned int sr;
+    unsigned int gbr;
+    unsigned int mach;
+    unsigned int macl;
+  } mcontext_t;
+
+/* Userlevel context.  */
+typedef struct ucontext
+  {
+    unsigned long int uc_flags;
+    struct ucontext *uc_link;
+    stack_t uc_stack;
+    mcontext_t uc_mcontext;
+    __sigset_t uc_sigmask;
+  } ucontext_t;
+
+#endif /* sys/ucontext.h */
diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/sh3/ucontext_i.h LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh3/ucontext_i.h
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/sh3/ucontext_i.h	1970-01-01 09:00:00.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh3/ucontext_i.h	2005-10-15 12:59:12.000000000 +0900
@@ -0,0 +1,79 @@
+/* Offsets and other constants needed in the *context() function
+   implementation.
+   Copyright (C) 2005 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#define SIG_BLOCK	0
+#define SIG_SETMASK	2
+
+/* Offsets of the fields in the ucontext_t structure.  */
+#define oLINK		4
+#define oSS_SP		8
+#define oSS_SIZE	16
+#define oR0		24
+#define oR1		28
+#define oR2		32
+#define oR3		36
+#define oR4		40
+#define oR5		44
+#define oR6		48
+#define oR7		52
+#define oR8		56
+#define oR9		60
+#define oR10		64
+#define oR11		68
+#define oR12		72
+#define oR13		76
+#define oR14		80
+#define oR15		84
+#define oPC		88
+#define oPR		92
+#define oSR		96
+#define oGBR		100
+#define oMACH		104
+#define oMACL		108
+#define oSIGMASK	112
+
+/* Tests run in stdlib/tst-ucontext-off.  */
+#define TESTS \
+  TEST (uc_link, oLINK);				\
+  TEST (uc_stack.ss_sp, oSS_SP);			\
+  TEST (uc_stack.ss_size, oSS_SIZE);			\
+  TEST (uc_mcontext.gregs[R0], oR0);			\
+  TEST (uc_mcontext.gregs[R1], oR1);			\
+  TEST (uc_mcontext.gregs[R2], oR2);			\
+  TEST (uc_mcontext.gregs[R3], oR3);			\
+  TEST (uc_mcontext.gregs[R4], oR4);			\
+  TEST (uc_mcontext.gregs[R5], oR5);			\
+  TEST (uc_mcontext.gregs[R6], oR6);			\
+  TEST (uc_mcontext.gregs[R7], oR7);			\
+  TEST (uc_mcontext.gregs[R8], oR8);			\
+  TEST (uc_mcontext.gregs[R9], oR9);			\
+  TEST (uc_mcontext.gregs[R10], oR10);			\
+  TEST (uc_mcontext.gregs[R11], oR11);			\
+  TEST (uc_mcontext.gregs[R12], oR12);			\
+  TEST (uc_mcontext.gregs[R13], oR13);			\
+  TEST (uc_mcontext.gregs[R14], oR14);			\
+  TEST (uc_mcontext.gregs[R15], oR15);			\
+  TEST (uc_mcontext.pc, oPC);				\
+  TEST (uc_mcontext.pr, oPR);				\
+  TEST (uc_mcontext.sr, oSR);				\
+  TEST (uc_mcontext.gbr, oGBR);				\
+  TEST (uc_mcontext.mach, oMACH);			\
+  TEST (uc_mcontext.macl, oMACL);			\
+  TEST (uc_sigmask, oSIGMASK);
diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/sh4/getcontext.S LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh4/getcontext.S
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/sh4/getcontext.S	1970-01-01 09:00:00.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh4/getcontext.S	2005-10-16 14:49:58.000000000 +0900
@@ -0,0 +1,133 @@
+/* Save current context.
+   Copyright (C) 2005 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+
+#include "ucontext_i.h"
+
+/*  int __getcontext (ucontext_t *uc);  */
+
+	.text
+	.align  5
+	cfi_startproc
+ENTRY(__getcontext)
+
+	/* Return value of getcontext.  R0 is the only register whose
+	   value is not preserved.  */
+	mov	#0, r0
+	mov.l	r0, @(oR0,r4)
+	mov.l	r1, @(oR1,r4)
+	mov.l	r2, @(oR2,r4)
+	mov.l	r3, @(oR3,r4)
+	mov.l	r4, @(oR4,r4)
+	mov.l	r5, @(oR5,r4)
+	mov.l	r6, @(oR6,r4)
+	mov.l	r7, @(oR7,r4)
+	mov	r4, r0
+	add	#(oMACL+4), r0
+	sts.l	macl, @-r0
+	sts.l	mach, @-r0
+	stc.l	gbr, @-r0
+
+	/* Save T flag to SR.  */
+	movt	r1
+	mov.l	r1, @-r0
+	sts.l	pr, @-r0
+
+	/* The return address of getcontext is the restart pc.  */
+	sts.l	pr, @-r0
+
+	mov.l	r15, @-r0
+	mov.l	r14, @-r0
+	mov.l	r13, @-r0
+	mov.l	r12, @-r0
+	mov.l	r11, @-r0
+	mov.l	r10, @-r0
+	mov.l	r9, @-r0
+	mov.l	r8, @-r0
+
+	mov	r4, r0
+	/* We need 2 add instruction because oFPUL+4 > 127.  */
+	add	#124,r0
+	add	#(oFPUL+4-124),r0
+	sts.l	fpul, @-r0
+	sts.l	fpscr, @-r0
+	frchg
+	fmov.s	fr15, @-r0
+	fmov.s	fr14, @-r0
+	fmov.s	fr13, @-r0
+	fmov.s	fr12, @-r0
+	fmov.s	fr11, @-r0
+	fmov.s	fr10, @-r0
+	fmov.s	fr9, @-r0
+	fmov.s	fr8, @-r0
+	fmov.s	fr7, @-r0
+	fmov.s	fr6, @-r0
+	fmov.s	fr5, @-r0
+	fmov.s	fr4, @-r0
+	fmov.s	fr3, @-r0
+	fmov.s	fr2, @-r0
+	fmov.s	fr1, @-r0
+	fmov.s	fr0, @-r0
+	frchg
+	fmov.s	fr15, @-r0
+	fmov.s	fr14, @-r0
+	fmov.s	fr13, @-r0
+	fmov.s	fr12, @-r0
+	fmov.s	fr11, @-r0
+	fmov.s	fr10, @-r0
+	fmov.s	fr9, @-r0
+	fmov.s	fr8, @-r0
+	fmov.s	fr7, @-r0
+	fmov.s	fr6, @-r0
+	fmov.s	fr5, @-r0
+	fmov.s	fr4, @-r0
+	fmov.s	fr3, @-r0
+	fmov.s	fr2, @-r0
+	fmov.s	fr1, @-r0
+	fmov.s	fr0, @-r0
+
+	/* sigprocmask (SIG_BLOCK, NULL, &uc->uc_sigmask).  */
+	mov	r4, r6
+	/* We need 2 add instruction because oSIGMASK > 127.  */
+	add	#(oSIGMASK/2), r6
+	add	#(oSIGMASK/2), r6
+	mov	#SIG_BLOCK, r4
+	mov	#0, r5
+	mov	#+SYS_ify(sigprocmask), r3
+	trapa	#0x13
+	mov     r0, r1
+	mov	#-12, r2
+	shad	r2, r1
+	not	r1, r1			// r1=0 means r0 = -1 to -4095
+	tst	r1, r1			// i.e. error in linux
+	bf	.Lgetcontext_end
+.Lsyscall_error:	
+	SYSCALL_ERROR_HANDLER
+.Lgetcontext_end:
+	/* All done, return 0 for success.  */
+	mov	#0, r0
+.Lpseudo_end:
+	rts
+	 nop
+
+	cfi_endproc
+PSEUDO_END(__getcontext)
+
+weak_alias (__getcontext, getcontext)
diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/sh4/setcontext.S LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh4/setcontext.S
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/sh4/setcontext.S	1970-01-01 09:00:00.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh4/setcontext.S	2005-10-16 18:50:25.000000000 +0900
@@ -0,0 +1,141 @@
+/* Install given context.
+   Copyright (C) 2005 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+
+#include "ucontext_i.h"
+
+/*  int __setcontext (const ucontext_t *uc);  */
+
+	.text
+	.align  5
+	cfi_startproc
+ENTRY(__setcontext)
+
+	mov	r4, r8
+
+	/* sigprocmask (SIG_SETMASK, &uc->uc_sigmask, NULL).  */
+	mov	r4, r5
+	add	#(oSIGMASK/2), r5
+	add	#(oSIGMASK/2), r5
+	mov	#SIG_SETMASK, r4
+	mov	#0, r6
+	mov	#+SYS_ify(sigprocmask), r3
+	trapa	#0x13
+	mov     r0, r1
+	mov	#-12, r2
+	shad	r2, r1
+	not	r1, r1			// r1=0 means r0 = -1 to -4095
+	tst	r1, r1			// i.e. error in linux
+	bf	.Lsetcontext_restore
+.Lsyscall_error:	
+	SYSCALL_ERROR_HANDLER
+.Lpseudo_end:
+	rts
+	 nop
+
+.Lsetcontext_restore:
+	mov	r8, r0
+	add	#(oFR0),r0
+	fmov.s	@r0+, fr0
+	fmov.s	@r0+, fr1
+	fmov.s	@r0+, fr2
+	fmov.s	@r0+, fr3
+	fmov.s	@r0+, fr4
+	fmov.s	@r0+, fr5
+	fmov.s	@r0+, fr6
+	fmov.s	@r0+, fr7
+	fmov.s	@r0+, fr8
+	fmov.s	@r0+, fr9
+	fmov.s	@r0+, fr10
+	fmov.s	@r0+, fr11
+	fmov.s	@r0+, fr12
+	fmov.s	@r0+, fr13
+	fmov.s	@r0+, fr14
+	fmov.s	@r0+, fr15
+	frchg
+	fmov.s	@r0+, fr0
+	fmov.s	@r0+, fr1
+	fmov.s	@r0+, fr2
+	fmov.s	@r0+, fr3
+	fmov.s	@r0+, fr4
+	fmov.s	@r0+, fr5
+	fmov.s	@r0+, fr6
+	fmov.s	@r0+, fr7
+	fmov.s	@r0+, fr8
+	fmov.s	@r0+, fr9
+	fmov.s	@r0+, fr10
+	fmov.s	@r0+, fr11
+	fmov.s	@r0+, fr12
+	fmov.s	@r0+, fr13
+	fmov.s	@r0+, fr14
+	fmov.s	@r0+, fr15
+	frchg
+	lds.l	@r0+, fpscr
+	lds.l	@r0+, fpul
+
+	mov	r8, r0
+	add	#(oPC), r0
+	mov.l	@r0+, r2
+	lds.l	@r0+, pr
+
+	/* Restore T frag.  */
+	mov.l	@r0+, r1
+	shlr	r1
+	/* Skip GBR which is used for thread pointer.  */
+	add	#4, r0
+
+	lds.l	@r0+, mach
+	lds.l	@r0+, macl
+
+	mov	r8, r0
+	add	#(oR9), r0
+	mov.l	@r0+, r9
+	mov.l	@r0+, r10
+	mov.l	@r0+, r11
+	mov.l	@r0+, r12
+	mov.l	@r0+, r13
+	mov.l	@r0+, r14
+	mov.l	@r0+, r15
+
+	mov	r8, r0
+	mov.l	@(oR0,r0), r1
+	mov.l	r1, @-r15
+	cfi_adjust_cfa_offset(4)
+	cfi_rel_offset (r1, 0)
+	mov.l	r2, @-r15
+	cfi_adjust_cfa_offset(4)
+	cfi_rel_offset (r2, 0)
+
+	mov.l	@(oR1,r0), r1
+	mov.l	@(oR2,r0), r2
+	mov.l	@(oR3,r0), r3
+	mov.l	@(oR4,r0), r4
+	mov.l	@(oR5,r0), r5
+	mov.l	@(oR6,r0), r6
+	mov.l	@(oR7,r0), r7
+	mov.l	@(oR8,r0), r8
+	mov.l	@r15+, r0
+	jmp	@r0
+	 mov.l	@r15+, r0
+
+	cfi_endproc
+PSEUDO_END(__setcontext)
+
+weak_alias (__setcontext, setcontext)
diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/sh4/swapcontext.S LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh4/swapcontext.S
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/sh4/swapcontext.S	1970-01-01 09:00:00.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh4/swapcontext.S	2005-10-16 18:48:35.000000000 +0900
@@ -0,0 +1,216 @@
+/* Save current context and install the given one.
+   Copyright (C) 2005 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+
+#include "ucontext_i.h"
+
+/*  int __swapcontext (ucontext_t *ouc, const ucontext_t *uc);  */
+
+	.text
+	.align  5
+	cfi_startproc
+ENTRY(__swapcontext)
+
+	/* Return value of getcontext.  R0 is the only register whose
+	   value is not preserved.  */
+	mov	#0, r0
+	mov.l	r0, @(oR0,r4)
+	mov.l	r1, @(oR1,r4)
+	mov.l	r2, @(oR2,r4)
+	mov.l	r3, @(oR3,r4)
+	mov.l	r4, @(oR4,r4)
+	mov.l	r5, @(oR5,r4)
+	mov.l	r6, @(oR6,r4)
+	mov.l	r7, @(oR7,r4)
+	mov	r4, r0
+	add	#(oMACL+4), r0
+	sts.l	macl, @-r0
+	sts.l	mach, @-r0
+	stc.l	gbr, @-r0
+
+	/* Save T flag to SR.  */
+	movt	r1
+	mov.l	r1, @-r0
+	sts.l	pr, @-r0
+
+	/* The return address of getcontext is the restart pc.  */
+	sts.l	pr, @-r0
+
+	mov.l	r15, @-r0
+	mov.l	r14, @-r0
+	mov.l	r13, @-r0
+	mov.l	r12, @-r0
+	mov.l	r11, @-r0
+	mov.l	r10, @-r0
+	mov.l	r9, @-r0
+	mov.l	r8, @-r0
+
+	mov	r4, r0
+	/* We need 2 add instruction because oFPUL+4 >= 127.  */
+	add	#124,r0
+	add	#(oFPUL+4-124),r0
+	sts.l	fpul, @-r0
+	sts.l	fpscr, @-r0
+	frchg
+	fmov.s	fr15, @-r0
+	fmov.s	fr14, @-r0
+	fmov.s	fr13, @-r0
+	fmov.s	fr12, @-r0
+	fmov.s	fr11, @-r0
+	fmov.s	fr10, @-r0
+	fmov.s	fr9, @-r0
+	fmov.s	fr8, @-r0
+	fmov.s	fr7, @-r0
+	fmov.s	fr6, @-r0
+	fmov.s	fr5, @-r0
+	fmov.s	fr4, @-r0
+	fmov.s	fr3, @-r0
+	fmov.s	fr2, @-r0
+	fmov.s	fr1, @-r0
+	fmov.s	fr0, @-r0
+	frchg
+	fmov.s	fr15, @-r0
+	fmov.s	fr14, @-r0
+	fmov.s	fr13, @-r0
+	fmov.s	fr12, @-r0
+	fmov.s	fr11, @-r0
+	fmov.s	fr10, @-r0
+	fmov.s	fr9, @-r0
+	fmov.s	fr8, @-r0
+	fmov.s	fr7, @-r0
+	fmov.s	fr6, @-r0
+	fmov.s	fr5, @-r0
+	fmov.s	fr4, @-r0
+	fmov.s	fr3, @-r0
+	fmov.s	fr2, @-r0
+	fmov.s	fr1, @-r0
+	fmov.s	fr0, @-r0
+
+	mov	r5, r8
+
+	/* sigprocmask (SIG_SETMASK, &uc->uc_sigmask, &ouc->uc_sigmask).  */
+	mov	#oSIGMASK, r1
+	extu.b	r1, r1
+	add	r1, r5
+	mov	r4, r6
+	add	r1, r6
+	mov	#SIG_SETMASK, r4
+	mov	#+SYS_ify(sigprocmask), r3
+	trapa	#0x13
+	mov     r0, r1
+	mov	#-12, r2
+	shad	r2, r1
+	not	r1, r1			// r1=0 means r0 = -1 to -4095
+	tst	r1, r1			// i.e. error in linux
+	bf	.Lswapcontext_restore
+.Lsyscall_error:	
+	SYSCALL_ERROR_HANDLER
+.Lpseudo_end:
+	rts
+	 nop
+.Lswapcontext_restore:	
+	mov	r8, r0
+	add	#(oFR0),r0
+	fmov.s	@r0+, fr0
+	fmov.s	@r0+, fr1
+	fmov.s	@r0+, fr2
+	fmov.s	@r0+, fr3
+	fmov.s	@r0+, fr4
+	fmov.s	@r0+, fr5
+	fmov.s	@r0+, fr6
+	fmov.s	@r0+, fr7
+	fmov.s	@r0+, fr8
+	fmov.s	@r0+, fr9
+	fmov.s	@r0+, fr10
+	fmov.s	@r0+, fr11
+	fmov.s	@r0+, fr12
+	fmov.s	@r0+, fr13
+	fmov.s	@r0+, fr14
+	fmov.s	@r0+, fr15
+	frchg
+	fmov.s	@r0+, fr0
+	fmov.s	@r0+, fr1
+	fmov.s	@r0+, fr2
+	fmov.s	@r0+, fr3
+	fmov.s	@r0+, fr4
+	fmov.s	@r0+, fr5
+	fmov.s	@r0+, fr6
+	fmov.s	@r0+, fr7
+	fmov.s	@r0+, fr8
+	fmov.s	@r0+, fr9
+	fmov.s	@r0+, fr10
+	fmov.s	@r0+, fr11
+	fmov.s	@r0+, fr12
+	fmov.s	@r0+, fr13
+	fmov.s	@r0+, fr14
+	fmov.s	@r0+, fr15
+	frchg
+	lds.l	@r0+, fpscr
+	lds.l	@r0+, fpul
+
+	mov	r8, r0
+	add	#(oPC), r0
+	mov.l	@r0+, r2
+	lds.l	@r0+, pr
+
+	/* Restore T frag.  */
+	mov.l	@r0+, r1
+	shlr	r1
+	/* Skip GBR which is used for thread pointer.  */
+	add	#4, r0
+
+	lds.l	@r0+, mach
+	lds.l	@r0+, macl
+
+	mov	r8, r0
+	add	#(oR9), r0
+	mov.l	@r0+, r9
+	mov.l	@r0+, r10
+	mov.l	@r0+, r11
+	mov.l	@r0+, r12
+	mov.l	@r0+, r13
+	mov.l	@r0+, r14
+	mov.l	@r0+, r15
+
+	mov	r8, r0
+	mov.l	@(oR0,r0), r1
+	mov.l	r1, @-r15
+	cfi_adjust_cfa_offset(4)
+	cfi_rel_offset (r1, 0)
+	mov.l	r2, @-r15
+	cfi_adjust_cfa_offset(4)
+	cfi_rel_offset (r2, 0)
+
+	mov.l	@(oR1,r0), r1
+	mov.l	@(oR2,r0), r2
+	mov.l	@(oR3,r0), r3
+	mov.l	@(oR4,r0), r4
+	mov.l	@(oR5,r0), r5
+	mov.l	@(oR6,r0), r6
+	mov.l	@(oR7,r0), r7
+	mov.l	@(oR8,r0), r8
+	mov.l	@r15+, r0
+	jmp	@r0
+	 mov.l	@r15+, r0
+	
+	cfi_endproc
+PSEUDO_END(__swapcontext)
+
+weak_alias (__swapcontext, swapcontext)
diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/sh4/sys/ucontext.h LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh4/sys/ucontext.h
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/sh4/sys/ucontext.h	1970-01-01 09:00:00.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh4/sys/ucontext.h	2005-10-15 13:23:11.000000000 +0900
@@ -0,0 +1,115 @@
+/* Copyright (C) 1999, 2000, 2001, 2005 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+/* Where is System V/SH ABI?  */
+
+#ifndef _SYS_UCONTEXT_H
+#define _SYS_UCONTEXT_H	1
+
+#include <features.h>
+#include <signal.h>
+
+/* We need the signal context definitions even if they are not used
+   included in <signal.h>.  */
+#include <bits/sigcontext.h>
+
+
+typedef int greg_t;
+
+/* Number of general registers.  */
+#define NFPREG	16
+
+/* Container for all general registers.  */
+typedef greg_t gregset_t[NFPREG];
+
+#ifdef __USE_GNU
+/* Number of each register is the `gregset_t' array.  */
+enum
+{
+  R0 = 0,
+#define R0	R0
+  R1 = 1,
+#define R1	R1
+  R2 = 2,
+#define R2	R2
+  R3 = 3,
+#define R3	R3
+  R4 = 4,
+#define R4	R4
+  R5 = 5,
+#define R5	R5
+  R6 = 6,
+#define R6	R6
+  R7 = 7,
+#define R7	R7
+  R8 = 8,
+#define R8	R8
+  R9 = 9,
+#define R9	R9
+  R10 = 10,
+#define R10	R10
+  R11 = 11,
+#define R11	R11
+  R12 = 12,
+#define R12	R12
+  R13 = 13,
+#define R13	R13
+  R14 = 14,
+#define R14	R14
+  R15 = 15,
+#define R15	R15
+};
+#endif
+
+typedef int freg_t;
+
+/* Number of FPU registers.  */
+#define NFPREG	16
+
+/* Structure to describe FPU registers.  */
+typedef freg_t fpregset_t[NFPREG];
+
+/* Context to describe whole processor state.  */
+typedef struct
+  {
+    unsigned int oldmask;
+    gregset_t gregs;
+    unsigned int pc;
+    unsigned int pr;
+    unsigned int sr;
+    unsigned int gbr;
+    unsigned int mach;
+    unsigned int macl;
+    fpregset_t fpregs;
+    fpregset_t xfpregs;
+    unsigned int fpscr;
+    unsigned int fpul;
+    unsigned int ownedfp;
+  } mcontext_t;
+
+/* Userlevel context.  */
+typedef struct ucontext
+  {
+    unsigned long int uc_flags;
+    struct ucontext *uc_link;
+    stack_t uc_stack;
+    mcontext_t uc_mcontext;
+    __sigset_t uc_sigmask;
+  } ucontext_t;
+
+#endif /* sys/ucontext.h */
diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/sh4/ucontext_i.h LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh4/ucontext_i.h
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/sh4/ucontext_i.h	1970-01-01 09:00:00.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/sh4/ucontext_i.h	2005-10-15 13:21:45.000000000 +0900
@@ -0,0 +1,149 @@
+/* Offsets and other constants needed in the *context() function
+   implementation.
+   Copyright (C) 2005 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#define SIG_BLOCK	0
+#define SIG_SETMASK	2
+
+/* Offsets of the fields in the ucontext_t structure.  */
+#define oLINK		4
+#define oSS_SP		8
+#define oSS_SIZE	16
+#define oR0		24
+#define oR1		28
+#define oR2		32
+#define oR3		36
+#define oR4		40
+#define oR5		44
+#define oR6		48
+#define oR7		52
+#define oR8		56
+#define oR9		60
+#define oR10		64
+#define oR11		68
+#define oR12		72
+#define oR13		76
+#define oR14		80
+#define oR15		84
+#define oPC		88
+#define oPR		92
+#define oSR		96
+#define oGBR		100
+#define oMACH		104
+#define oMACL		108
+#define oFR0		112
+#define oFR1		116
+#define oFR2		120
+#define oFR3		124
+#define oFR4		128
+#define oFR5		132
+#define oFR6		136
+#define oFR7		140
+#define oFR8		144
+#define oFR9		148
+#define oFR10		152
+#define oFR11		156
+#define oFR12		160
+#define oFR13		164
+#define oFR14		168
+#define oFR15		172
+#define oXFR0		176
+#define oXFR1		180
+#define oXFR2		184
+#define oXFR3		188
+#define oXFR4		192
+#define oXFR5		196
+#define oXFR6		200
+#define oXFR7		204
+#define oXFR8		208
+#define oXFR9		212
+#define oXFR10		216
+#define oXFR11		220
+#define oXFR12		224
+#define oXFR13		228
+#define oXFR14		232
+#define oXFR15		236
+#define oFPSCR		240
+#define oFPUL		244
+#define oOWNEDFP	248
+#define oSIGMASK	252
+
+/* Tests run in stdlib/tst-ucontext-off.  */
+#define TESTS \
+  TEST (uc_link, oLINK);				\
+  TEST (uc_stack.ss_sp, oSS_SP);			\
+  TEST (uc_stack.ss_size, oSS_SIZE);			\
+  TEST (uc_mcontext.gregs[R0], oR0);			\
+  TEST (uc_mcontext.gregs[R1], oR1);			\
+  TEST (uc_mcontext.gregs[R2], oR2);			\
+  TEST (uc_mcontext.gregs[R3], oR3);			\
+  TEST (uc_mcontext.gregs[R4], oR4);			\
+  TEST (uc_mcontext.gregs[R5], oR5);			\
+  TEST (uc_mcontext.gregs[R6], oR6);			\
+  TEST (uc_mcontext.gregs[R7], oR7);			\
+  TEST (uc_mcontext.gregs[R8], oR8);			\
+  TEST (uc_mcontext.gregs[R9], oR9);			\
+  TEST (uc_mcontext.gregs[R10], oR10);			\
+  TEST (uc_mcontext.gregs[R11], oR11);			\
+  TEST (uc_mcontext.gregs[R12], oR12);			\
+  TEST (uc_mcontext.gregs[R13], oR13);			\
+  TEST (uc_mcontext.gregs[R14], oR14);			\
+  TEST (uc_mcontext.gregs[R15], oR15);			\
+  TEST (uc_mcontext.pc, oPC);				\
+  TEST (uc_mcontext.pr, oPR);				\
+  TEST (uc_mcontext.sr, oSR);				\
+  TEST (uc_mcontext.gbr, oGBR);				\
+  TEST (uc_mcontext.mach, oMACH);			\
+  TEST (uc_mcontext.macl, oMACL);			\
+  TEST (uc_mcontext.fpregs[0], oFR0);			\
+  TEST (uc_mcontext.fpregs[1], oFR1);			\
+  TEST (uc_mcontext.fpregs[2], oFR2);			\
+  TEST (uc_mcontext.fpregs[3], oFR3);			\
+  TEST (uc_mcontext.fpregs[4], oFR4);			\
+  TEST (uc_mcontext.fpregs[5], oFR5);			\
+  TEST (uc_mcontext.fpregs[6], oFR6);			\
+  TEST (uc_mcontext.fpregs[7], oFR7);			\
+  TEST (uc_mcontext.fpregs[8], oFR8);			\
+  TEST (uc_mcontext.fpregs[9], oFR9);			\
+  TEST (uc_mcontext.fpregs[10], oFR10);			\
+  TEST (uc_mcontext.fpregs[11], oFR11);			\
+  TEST (uc_mcontext.fpregs[12], oFR12);			\
+  TEST (uc_mcontext.fpregs[13], oFR13);			\
+  TEST (uc_mcontext.fpregs[14], oFR14);			\
+  TEST (uc_mcontext.fpregs[15], oFR15);			\
+  TEST (uc_mcontext.xfpregs[0], oXFR0);			\
+  TEST (uc_mcontext.xfpregs[1], oXFR1);			\
+  TEST (uc_mcontext.xfpregs[2], oXFR2);			\
+  TEST (uc_mcontext.xfpregs[3], oXFR3);			\
+  TEST (uc_mcontext.xfpregs[4], oXFR4);			\
+  TEST (uc_mcontext.xfpregs[5], oXFR5);			\
+  TEST (uc_mcontext.xfpregs[6], oXFR6);			\
+  TEST (uc_mcontext.xfpregs[7], oXFR7);			\
+  TEST (uc_mcontext.xfpregs[8], oXFR8);			\
+  TEST (uc_mcontext.xfpregs[9], oXFR9);			\
+  TEST (uc_mcontext.xfpregs[10], oXFR10);		\
+  TEST (uc_mcontext.xfpregs[11], oXFR11);		\
+  TEST (uc_mcontext.xfpregs[12], oXFR12);		\
+  TEST (uc_mcontext.xfpregs[13], oXFR13);		\
+  TEST (uc_mcontext.xfpregs[14], oXFR14);		\
+  TEST (uc_mcontext.xfpregs[15], oXFR15);		\
+  TEST (uc_mcontext.fpscr, oFPSCR);			\
+  TEST (uc_mcontext.fpul, oFPUL);			\
+  TEST (uc_mcontext.ownedfp, oOWNEDFP);			\
+  TEST (uc_sigmask, oSIGMASK);
diff -uprN ORIG/libc/sysdeps/unix/sysv/linux/sh/sys/ucontext.h LOCAL/libc/sysdeps/unix/sysv/linux/sh/sys/ucontext.h
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/sys/ucontext.h	2001-07-06 13:56:20.000000000 +0900
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/sys/ucontext.h	1970-01-01 09:00:00.000000000 +0900
@@ -1,109 +0,0 @@
-/* Copyright (C) 1999, 2000, 2001 Free Software Foundation, Inc.
-   This file is part of the GNU C Library.
-
-   The GNU C Library is free software; you can redistribute it and/or
-   modify it under the terms of the GNU Lesser General Public
-   License as published by the Free Software Foundation; either
-   version 2.1 of the License, or (at your option) any later version.
-
-   The GNU C Library is distributed in the hope that it will be useful,
-   but WITHOUT ANY WARRANTY; without even the implied warranty of
-   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
-   Lesser General Public License for more details.
-
-   You should have received a copy of the GNU Lesser General Public
-   License along with the GNU C Library; if not, write to the Free
-   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
-   02111-1307 USA.  */
-
-/* Where is System V/SH ABI?  */
-
-#ifndef _SYS_UCONTEXT_H
-#define _SYS_UCONTEXT_H	1
-
-#include <features.h>
-#include <signal.h>
-
-/* We need the signal context definitions even if they are not used
-   included in <signal.h>.  */
-#include <bits/sigcontext.h>
-
-
-typedef int greg_t;
-
-/* Number of general registers.  */
-#define NFPREG	16
-
-/* Container for all general registers.  */
-typedef greg_t gregset_t[NFPREG];
-
-#ifdef __USE_GNU
-/* Number of each register is the `gregset_t' array.  */
-enum
-{
-  R0 = 0,
-#define R0	R0
-  R1 = 1,
-#define R1	R1
-  R2 = 2,
-#define R2	R2
-  R3 = 3,
-#define R3	R3
-  R4 = 4,
-#define R4	R4
-  R5 = 5,
-#define R5	R5
-  R6 = 6,
-#define R6	R6
-  R7 = 7,
-#define R7	R7
-  R8 = 8,
-#define R8	R8
-  R9 = 9,
-#define R9	R9
-  R10 = 10,
-#define R10	R10
-  R11 = 11,
-#define R11	R11
-  R12 = 12,
-#define R12	R12
-  R13 = 13,
-#define R13	R13
-  R14 = 14,
-#define R14	R14
-  R15 = 15,
-#define R15	R15
-};
-#endif
-
-typedef int freg_t;
-
-/* Number of FPU registers.  */
-#define NFPREG	16
-
-/* Structure to describe FPU registers.  */
-typedef freg_t fpregset_t[NFPREG];
-
-/* Context to describe whole processor state.  */
-typedef struct
-  {
-    gregset_t gregs;
-    fpregset_t fpregs;
-    fpregset_t xfpregs;
-    unsigned int fpscr;
-    unsigned int fpul;
-    unsigned int macl;
-    unsigned int mach;
-  } mcontext_t;
-
-/* Userlevel context.  */
-typedef struct ucontext
-  {
-    unsigned long int uc_flags;
-    struct ucontext *uc_link;
-    stack_t uc_stack;
-    mcontext_t uc_mcontext;
-    __sigset_t uc_sigmask;
-  } ucontext_t;
-
-#endif /* sys/ucontext.h */
Follow-Ups:
- Re: ucontext checking
  - From: Roland McGrath
- Re: ucontext checking
  - From: Ulrich Drepper
References:
- Re: ucontext checking
  - From: Kaz Kojima
- Re: ucontext checking
  - From: Ulrich Drepper
- Re: ucontext checking
  - From: Kaz Kojima
Index Nav:	[Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav:	[Date Prev] [Date Next]	[Thread Prev] [Thread Next]